tools/batch_delete_records.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2013 BibLibre
   6 #
   7 # Koha is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as
   9 # published by the Free Software Foundation; either version 3
  10 # of the License, or (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General
  18 # Public License along with Koha; if not, see
  19 # <http://www.gnu.org/licenses>
  20
  21 use Modern::Perl;
  22
  23 use CGI;
  24 use List::MoreUtils qw( uniq );
  25
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::AuthoritiesMarc;
  29 use C4::Biblio;
  30 use Koha::Virtualshelves;
  31
  32 use Koha::Authorities;
  33 use Koha::Biblios;
  34 use Koha::Items;
  35
  36 my $input = new CGI;
  37 my $op = $input->param('op') // q|form|;
  38 my $recordtype = $input->param('recordtype') // 'biblio';
  39
  40 my ($template, $loggedinuser, $cookie) = get_template_and_user({
  41         template_name => 'tools/batch_delete_records.tt',
  42         query => $input,
  43         type => "intranet",
  44         authnotrequired => 0,
  45         flagsrequired => { tools => 'records_batchdel' },
  46 });
  47
  48 $template->param( lists => scalar Koha::Virtualshelves->search([{ category => 1, owner => $loggedinuser }, { category => 2 }]) );
  49
  50 my @records;
  51 my @messages;
  52 if ( $op eq 'form' ) {
  53     # Display the form
  54     $template->param( op => 'form' );
  55 } elsif ( $op eq 'list' ) {
  56     # List all records to process
  57     my @record_ids;
  58     if ( my $bib_list = $input->param('bib_list') ) {
  59         # Come from the basket
  60         @record_ids = split /\//, $bib_list;
  61         $recordtype = 'biblio';
  62     } elsif ( my $uploadfile = $input->param('uploadfile') ) {
  63         # A file of id is given
  64         binmode $uploadfile, ':encoding(UTF-8)';
  65         while ( my $content = <$uploadfile> ) {
  66             next unless $content;
  67             $content =~ s/[\r\n]*$//;
  68             push @record_ids, $content if $content;
  69         }
  70     } elsif ( my $shelf_number = $input->param('shelf_number') ) {
  71         my $shelf = Koha::Virtualshelves->find($shelf_number);
  72         my $contents = $shelf->get_contents;
  73         while ( my $content = $contents->next ) {
  74             my $biblionumber = $content->biblionumber;
  75             push @record_ids, $biblionumber;
  76         }
  77     } else {
  78         # The user enters manually the list of id
  79         push @record_ids, split( /\s\n/, $input->param('recordnumber_list') );
  80     }
  81
  82     for my $record_id ( uniq @record_ids ) {
  83         if ( $recordtype eq 'biblio' ) {
  84             # Retrieve biblio information
  85             my $biblio = Koha::Biblios->find( $record_id );
  86             unless ( $biblio ) {
  87                 push @messages, {
  88                     type => 'warning',
  89                     code => 'biblio_not_exists',
  90                     biblionumber => $record_id,
  91                 };
  92                 next;
  93             }
  94             my $holds_count = $biblio->holds->count;
  95             $biblio = $biblio->unblessed;
  96             my $record = &GetMarcBiblio({ biblionumber => $record_id });
  97             $biblio->{itemnumbers} = [Koha::Items->search({ biblionumber => $record_id })->get_column('itemnumber')];
  98             $biblio->{holds_count} = $holds_count;
  99             $biblio->{issues_count} = C4::Biblio::CountItemsIssued( $record_id );
 100             push @records, $biblio;
 101         } else {
 102             # Retrieve authority information
 103             my $authority = C4::AuthoritiesMarc::GetAuthority( $record_id );
 104             unless ( $authority ) {
 105                 push @messages, {
 106                     type => 'warning',
 107                     code => 'authority_not_exists',
 108                     authid => $record_id,
 109                 };
 110                 next;
 111             }
 112
 113             $authority = {
 114                 authid => $record_id,
 115                 summary => C4::AuthoritiesMarc::BuildSummary( $authority, $record_id ),
 116                 count_usage => Koha::Authorities->get_usage_count({ authid => $record_id }),
 117             };
 118             push @records, $authority;
 119         }
 120     }
 121     $template->param(
 122         records => \@records,
 123         op => 'list',
 124     );
 125 } elsif ( $op eq 'delete' ) {
 126     # We want to delete selected records!
 127     my @record_ids = $input->multi_param('record_id');
 128     my $schema = Koha::Database->new->schema;
 129
 130     my $error;
 131     my $report = {
 132         total_records => 0,
 133         total_success => 0,
 134     };
 135     RECORD_IDS: for my $record_id ( sort { $a <=> $b } @record_ids ) {
 136         $report->{total_records}++;
 137         next unless $record_id;
 138         $schema->storage->txn_begin;
 139
 140         if ( $recordtype eq 'biblio' ) {
 141             # Biblios
 142             my $biblionumber = $record_id;
 143             # First, checking if issues exist.
 144             # If yes, nothing to do
 145             my $biblio = Koha::Biblios->find( $biblionumber );
 146
 147             # TODO Replace with $biblio->get_issues->count
 148             if ( C4::Biblio::CountItemsIssued( $biblionumber ) ) {
 149                 push @messages, {
 150                     type => 'warning',
 151                     code => 'item_issued',
 152                     biblionumber => $biblionumber,
 153                 };
 154                 $schema->storage->txn_rollback;
 155                 next;
 156             }
 157
 158             # Cancel reserves
 159             my $holds = $biblio->holds;
 160             while ( my $hold = $holds->next ) {
 161                 eval{
 162                     $hold->cancel;
 163                 };
 164                 if ( $@ ) {
 165                     push @messages, {
 166                         type => 'error',
 167                         code => 'reserve_not_cancelled',
 168                         biblionumber => $biblionumber,
 169                         reserve_id => $hold->reserve_id,
 170                         error => $@,
 171                     };
 172                     $schema->storage->txn_rollback;
 173                     next RECORD_IDS;
 174                 }
 175             }
 176
 177             # Delete items
 178             my $items = Koha::Items->search({ biblionumber => $biblionumber });
 179             while ( my $item = $items->next ) {
 180                 my $deleted_item = eval { $item->safe_delete };
 181                 if ( !ref($deleted_item) or $@ ) {
 182                     push @messages, {
 183                         type => 'error',
 184                         code => 'item_not_deleted',
 185                         biblionumber => $biblionumber,
 186                         itemnumber => $item->itemnumber,
 187                         error => ($@ ? $@ : $error),
 188                     };
 189                     $schema->storage->txn_rollback;
 190                     next RECORD_IDS;
 191                 }
 192             }
 193
 194             # Finally, delete the biblio
 195             my $error = eval {
 196                 C4::Biblio::DelBiblio( $biblionumber );
 197             };
 198             if ( $error or $@ ) {
 199                 push @messages, {
 200                     type => 'error',
 201                     code => 'biblio_not_deleted',
 202                     biblionumber => $biblionumber,
 203                     error => ($@ ? $@ : $error),
 204                 };
 205                 $schema->storage->txn_rollback;
 206                 next;
 207             }
 208
 209             push @messages, {
 210                 type => 'success',
 211                 code => 'biblio_deleted',
 212                 biblionumber => $biblionumber,
 213             };
 214             $report->{total_success}++;
 215             $schema->storage->txn_commit;
 216         } else {
 217             # Authorities
 218             my $authid = $record_id;
 219             eval { C4::AuthoritiesMarc::DelAuthority({ authid => $authid }) };
 220             if ( $@ ) {
 221                 push @messages, {
 222                     type => 'error',
 223                     code => 'authority_not_deleted',
 224                     authid => $authid,
 225                     error => ($@ ? $@ : 0),
 226                 };
 227                 $schema->storage->txn_rollback;
 228                 next;
 229             } else {
 230                 push @messages, {
 231                     type => 'success',
 232                     code => 'authority_deleted',
 233                     authid => $authid,
 234                 };
 235                 $report->{total_success}++;
 236                 $schema->storage->txn_commit;
 237             }
 238         }
 239     }
 240     $template->param(
 241         op => 'report',
 242         report => $report,
 243     );
 244 }
 245
 246 $template->param(
 247     messages => \@messages,
 248     recordtype => $recordtype,
 249 );
 250
 251 output_html_with_http_headers $input, $cookie, $template->output;