basket/sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use strict;
  19 use warnings;
  20
  21 use CGI qw ( -utf8 );
  22 use Encode qw(encode);
  23 use Carp;
  24
  25 use Mail::Sendmail;
  26 use MIME::QuotedPrint;
  27 use MIME::Base64;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Auth;
  31 use C4::Output;
  32 use C4::Biblio;
  33 use Koha::Email;
  34
  35 my $query = new CGI;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  38     {
  39         template_name   => "basket/sendbasketform.tt",
  40         query           => $query,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrow => 1 },
  44     }
  45 );
  46
  47 my $bib_list     = $query->param('bib_list');
  48 my $email_add    = $query->param('email_add');
  49 my $email_sender = $query->param('email_sender');
  50
  51 my $dbh          = C4::Context->dbh;
  52
  53 if ( $email_add ) {
  54     my $email = Koha::Email->new();
  55     my %mail = $email->create_message_headers({ to => $email_add });
  56     my $comment    = $query->param('comment');
  57     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  58         {
  59             template_name   => "basket/sendbasket.tt",
  60             query           => $query,
  61             type            => "intranet",
  62             authnotrequired => 0,
  63             flagsrequired   => { borrow => 1 },
  64         }
  65     );
  66
  67     my @bibs = split( /\//, $bib_list );
  68     my @results;
  69     my $iso2709;
  70     my $marcflavour = C4::Context->preference('marcflavour');
  71     foreach my $biblionumber (@bibs) {
  72         $template2->param( biblionumber => $biblionumber );
  73
  74         my $dat              = GetBiblioData($biblionumber);
  75         next unless $dat;
  76         my $record           = GetMarcBiblio($biblionumber, 1);
  77         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  78         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  79         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  80
  81         my @items = GetItemsInfo( $biblionumber );
  82
  83         my $hasauthors = 0;
  84         if($dat->{'author'} || @$marcauthorsarray) {
  85           $hasauthors = 1;
  86         }
  87
  88
  89         $dat->{MARCNOTES}      = $marcnotesarray;
  90         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  91         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  92         $dat->{HASAUTHORS}     = $hasauthors;
  93         $dat->{'biblionumber'} = $biblionumber;
  94         $dat->{ITEM_RESULTS}   = \@items;
  95
  96         $iso2709 .= $record->as_usmarc();
  97
  98         push( @results, $dat );
  99     }
 100
 101     my $resultsarray = \@results;
 102     $template2->param(
 103         BIBLIO_RESULTS => $resultsarray,
 104         email_sender   => $email_sender,
 105         comment        => $comment
 106     );
 107
 108     # Getting template result
 109     my $template_res = $template2->output();
 110     my $body;
 111
 112     # Analysing information and getting mail properties
 113     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 114         $mail{subject} = $1;
 115         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 116         $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 117     }
 118     else { $mail{'subject'} = "no subject"; }
 119
 120     my $email_header = "";
 121     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 122         $email_header = $1;
 123         $email_header =~ s|\n?(.*)\n?|$1|;
 124         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 125     }
 126
 127     my $email_file = "basket.txt";
 128     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 129         $email_file = $1;
 130         $email_file =~ s|\n?(.*)\n?|$1|;
 131     }
 132
 133     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 134         $body = $1;
 135         $body =~ s|\n?(.*)\n?|$1|;
 136         $body = encode_qp(Encode::encode("UTF-8", $body));
 137     }
 138
 139     my $boundary = "====" . time() . "====";
 140
 141     # Writing mail
 142     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 143     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 144     $boundary = '--' . $boundary;
 145     $mail{body} = <<END_OF_BODY;
 146 $boundary
 147 Content-Type: text/plain; charset="utf-8"
 148 Content-Transfer-Encoding: quoted-printable
 149
 150 $email_header
 151 $body
 152 $boundary
 153 Content-Type: application/octet-stream; name="basket.iso2709"
 154 Content-Transfer-Encoding: base64
 155 Content-Disposition: attachment; filename="basket.iso2709"
 156
 157 $isofile
 158 $boundary--
 159 END_OF_BODY
 160
 161     # Sending mail
 162     if ( sendmail %mail ) {
 163         # do something if it works....
 164         $template->param( SENT      => "1" );
 165     }
 166     else {
 167         # do something if it doesnt work....
 168         carp "Error sending mail: $Mail::Sendmail::error \n";
 169         $template->param( error => 1 );
 170     }
 171     $template->param( email_add => $email_add );
 172     output_html_with_http_headers $query, $cookie, $template->output;
 173 }
 174 else {
 175     $template->param( bib_list => $bib_list );
 176     $template->param(
 177         url            => "/cgi-bin/koha/basket/sendbasket.pl",
 178         suggestion     => C4::Context->preference("suggestion"),
 179         virtualshelves => C4::Context->preference("virtualshelves"),
 180     );
 181     output_html_with_http_headers $query, $cookie, $template->output;
 182 }