opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::External::BakerTaylor qw( image_url link_url );
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Members::AttributeTypes;
  31 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  32 use C4::Output;
  33 use C4::Biblio;
  34 use C4::Items;
  35 use C4::Letters;
  36 use Koha::Account::Lines;
  37 use Koha::Biblios;
  38 use Koha::Libraries;
  39 use Koha::DateUtils;
  40 use Koha::Holds;
  41 use Koha::Database;
  42 use Koha::ItemTypes;
  43 use Koha::Patron::Attribute::Types;
  44 use Koha::Patrons;
  45 use Koha::Patron::Messages;
  46 use Koha::Patron::Discharge;
  47 use Koha::Patrons;
  48
  49 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  50
  51 use Scalar::Util qw(looks_like_number);
  52 use Date::Calc qw(
  53   Today
  54   Add_Delta_Days
  55   Date_to_Days
  56 );
  57
  58 my $query = new CGI;
  59
  60 # CAS single logout handling
  61 # Will print header and exit
  62 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  63
  64 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  65     {
  66         template_name   => "opac-user.tt",
  67         query           => $query,
  68         type            => "opac",
  69         authnotrequired => 0,
  70         debug           => 1,
  71     }
  72 );
  73
  74 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  75
  76 my $show_priority;
  77 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  78     m/priority/ and $show_priority = 1;
  79 }
  80
  81 my $patronupdate = $query->param('patronupdate');
  82 my $canrenew = 1;
  83
  84 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  85
  86 # get borrower information ....
  87 my $patron = Koha::Patrons->find( $borrowernumber );
  88 my $borr = $patron->unblessed;
  89 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
  90 my $borcat = $borr ? $borr->{categorycode} : q{};
  91
  92 my (  $today_year,   $today_month,   $today_day) = Today();
  93 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  94
  95 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
  96 my $userdebarred;
  97
  98 if ($debar) {
  99     $userdebarred = 1;
 100     $template->param( 'userdebarred' => $userdebarred );
 101     if ( $debar ne "9999-12-31" ) {
 102         $borr->{'userdebarreddate'} = $debar;
 103     }
 104     # FIXME looks like $available is not needed
 105     # If a user is discharged they have a validated discharge available
 106     my $available = Koha::Patron::Discharge::count({
 107         borrowernumber => $borrowernumber,
 108         validated      => 1,
 109     });
 110     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 111 }
 112
 113 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 114     $borr->{'flagged'} = 1;
 115     $canrenew = 0;
 116 }
 117
 118 my $amountoutstanding = $patron->account->balance;
 119 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 120 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 121 my $amountoutstandingfornewal =
 122   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 123   ? $amountoutstanding
 124   : $patron->account->outstanding_debits->total_outstanding;
 125
 126 if (   C4::Context->preference('OpacRenewalAllowed')
 127     && defined($no_renewal_amt)
 128     && $amountoutstandingfornewal > $no_renewal_amt )
 129 {
 130     $borr->{'flagged'} = 1;
 131     $canrenew = 0;
 132     $template->param(
 133         renewal_blocked_fines => $no_renewal_amt,
 134         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 135     );
 136 }
 137
 138 my $maxoutstanding = C4::Context->preference('maxoutstanding');
 139 if ( $amountoutstanding && ( $amountoutstanding > $maxoutstanding ) ){
 140     $borr->{blockedonfines} = 1;
 141 }
 142
 143 # Warningdate is the date that the warning starts appearing
 144 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 145     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 146     if ( $days_to_expiry < 0 ) {
 147         #borrower card has expired, warn the borrower
 148         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 149     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 150         # borrower card soon to expire, warn the borrower
 151         $borr->{'warndeparture'} = $borr->{dateexpiry};
 152         if (C4::Context->preference('ReturnBeforeExpiry')){
 153             $borr->{'returnbeforeexpiry'} = 1;
 154         }
 155     }
 156 }
 157
 158 # pass on any renew errors to the template for displaying
 159 my $renew_error = $query->param('renew_error');
 160
 161 $template->param(
 162                     amountoutstanding => $amountoutstanding,
 163                     borrowernumber    => $borrowernumber,
 164                     patron_flagged    => $borr->{flagged},
 165                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 166                     surname           => $borr->{surname},
 167                     RENEW_ERROR       => $renew_error,
 168                     borrower          => $borr,
 169                 );
 170
 171 #get issued items ....
 172
 173 my $count          = 0;
 174 my $overdues_count = 0;
 175 my @overdues;
 176 my @issuedat;
 177 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 178 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 179 if ( $pending_checkouts->count ) { # Useless test
 180     while ( my $c = $pending_checkouts->next ) {
 181         my $issue = $c->unblessed_all_relateds;
 182         # check for reserves
 183         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 184         if ( $restype ) {
 185             $issue->{'reserved'} = 1;
 186         }
 187
 188         # Must be moved in a module if reused
 189         my $charges = Koha::Account::Lines->search(
 190             {
 191                 borrowernumber    => $patron->borrowernumber,
 192                 amountoutstanding => { '>' => 0 },
 193                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 194                 itemnumber        => $issue->{itemnumber}
 195             },
 196         );
 197         $issue->{charges} = $charges->total_outstanding;
 198
 199         my $rental_fines = Koha::Account::Lines->search(
 200             {
 201                 borrowernumber    => $patron->borrowernumber,
 202                 amountoutstanding => { '>' => 0 },
 203                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 204                 itemnumber        => $issue->{itemnumber}
 205             }
 206         );
 207         $issue->{rentalfines} = $rental_fines->total_outstanding;
 208
 209         # check if item is renewable
 210         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 211         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 212         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 213         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 214         if($status && C4::Context->preference("OpacRenewalAllowed")){
 215             $issue->{'status'} = $status;
 216         }
 217
 218         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 219
 220         if ($renewerror) {
 221             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 222             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 223             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 224             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 225             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 226             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 227             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 228             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 229
 230             if ( $renewerror eq 'too_soon' ) {
 231                 $issue->{'too_soon'}         = 1;
 232                 $issue->{'soonestrenewdate'} = output_pref(
 233                     C4::Circulation::GetSoonestRenewDate(
 234                         $issue->{borrowernumber},
 235                         $issue->{itemnumber}
 236                     )
 237                 );
 238             }
 239         }
 240
 241         if ( $c->is_overdue ) {
 242             push @overdues, $issue;
 243             $overdues_count++;
 244             $issue->{'overdue'} = 1;
 245         }
 246         else {
 247             $issue->{'issued'} = 1;
 248         }
 249         # imageurl:
 250         my $itemtype = $issue->{'itemtype'};
 251         if ( $itemtype ) {
 252             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 253             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 254         }
 255
 256         $issue->{biblio_object} = Koha::Biblios->find($issue->{biblionumber});
 257         push @issuedat, $issue;
 258         $count++;
 259
 260         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 261         $issue->{normalized_isbn} = $isbn;
 262         my $marcrecord = GetMarcBiblio({
 263             biblionumber => $issue->{'biblionumber'},
 264             embed_items  => 1,
 265             opac         => 1,
 266             borcat       => $borcat });
 267         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 268
 269                 # My Summary HTML
 270                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 271                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 272                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 273                     $issue->{title} =~ s/\s+$//; # remove trailing space
 274                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 275                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 276                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 277                     $issue->{MySummaryHTML} = $my_summary_html;
 278                 }
 279     }
 280 }
 281 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 282 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 283
 284 $template->param( ISSUES       => \@issuedat );
 285 $template->param( issues_count => $count );
 286 $template->param( canrenew     => $canrenew );
 287 $template->param( OVERDUES       => \@overdues );
 288 $template->param( overdues_count => $overdues_count );
 289
 290 my $show_barcode = Koha::Patron::Attribute::Types->search(
 291     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 292 if ($show_barcode) {
 293     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 294     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 295 }
 296 $template->param( show_barcode => 1 ) if $show_barcode;
 297
 298 # now the reserved items....
 299 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 300
 301 $template->param(
 302     RESERVES       => $reserves,
 303     showpriority   => $show_priority,
 304 );
 305
 306 if (C4::Context->preference('BakerTaylorEnabled')) {
 307     $template->param(
 308         BakerTaylorEnabled  => 1,
 309         BakerTaylorImageURL => &image_url(),
 310         BakerTaylorLinkURL  => &link_url(),
 311         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 312     );
 313 }
 314
 315 if (C4::Context->preference("OPACAmazonCoverImages") or
 316     C4::Context->preference("GoogleJackets") or
 317     C4::Context->preference("BakerTaylorEnabled") or
 318     C4::Context->preference("SyndeticsCoverImages") or
 319     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 320 ) {
 321         $template->param(JacketImages=>1);
 322 }
 323
 324 $template->param(
 325     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 326     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 327     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 328     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 329 );
 330
 331 my $patron_messages = Koha::Patron::Messages->search(
 332     {
 333         borrowernumber => $borrowernumber,
 334         message_type => 'B',
 335     }
 336 );
 337
 338 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 339     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 340 {
 341     my @relatives;
 342     # Filter out guarantees that don't want guarantor to see checkouts
 343     foreach my $gr ( $patron->guarantee_relationships() ) {
 344         my $g = $gr->guarantee;
 345         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 346     }
 347     $template->param( relatives => \@relatives );
 348 }
 349
 350 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 351     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 352 {
 353     my @relatives_with_fines;
 354     # Filter out guarantees that don't want guarantor to see checkouts
 355     foreach my $gr ( $patron->guarantee_relationships() ) {
 356         my $g = $gr->guarantee;
 357         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 358     }
 359     $template->param( relatives_with_fines => \@relatives_with_fines );
 360 }
 361
 362
 363 $template->param(
 364     patron_messages          => $patron_messages,
 365     opacnote                 => $borr->{opacnote},
 366     patronupdate             => $patronupdate,
 367     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 368     userview                 => 1,
 369     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 370     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 371     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 372     failed_holds             => scalar $query->param('failed_holds'),
 373 );
 374
 375 # if not an empty string this indicates to return
 376 # back to the opac-results page
 377 my $search_query = $query->param('has-search-query');
 378
 379 if ($search_query) {
 380
 381     print $query->redirect(
 382         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 383         -cookie => $cookie,
 384     );
 385 }
 386
 387 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };