Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  17 # Suite 330, Boston, MA  02111-1307 USA
  18
  19 use strict;
  20 use warnings;
  21 use 5.010;
  22 use DateTime;
  23 use DateTime::Format::DateParse;
  24 use C4::Context;
  25
  26 use base 'Exporter';
  27 use version; our $VERSION = qv('1.0.0');
  28
  29 our @EXPORT = (
  30     qw( dt_from_string output_pref format_sqldatetime output_pref_due format_sqlduedatetime)
  31 );
  32
  33 =head1 DateUtils
  34
  35 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  36
  37 =head1 DESCRIPTION
  38
  39 Koha has historically only used dates not datetimes and been content to
  40 handle these as strings. It also has confused formatting with actual dates
  41 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  42
  43 =cut
  44
  45 =head2 dt_ftom_string
  46
  47 $dt = dt_from_string($date_string, [$format, $timezone ]);
  48
  49 Passed a date string returns a DateTime object format and timezone default
  50 to the system preferences. If the date string is empty DateTime->now is returned
  51
  52 =cut
  53
  54 sub dt_from_string {
  55     my ( $date_string, $date_format, $tz ) = @_;
  56     if ( !$tz ) {
  57         $tz = C4::Context->tz;
  58     }
  59     if ( !$date_format ) {
  60         $date_format = C4::Context->preference('dateformat');
  61     }
  62     if ($date_string) {
  63         if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  64             return $date_string;
  65         }
  66
  67         if ( $date_format eq 'metric' ) {
  68             $date_string =~ s#-#/#g;
  69             $date_string =~ s/^00/01/;    # system allows the 0th of the month
  70             $date_string =~ s#^(\d{1,2})/(\d{1,2})#$2/$1#;
  71         } else {
  72             if ( $date_format eq 'iso' ) {
  73                 $date_string =~ s/-00/-01/;
  74                 if ( $date_string =~ m/^0000-0/ ) {
  75                     return;               # invalid date in db
  76                 }
  77             } elsif ( $date_format eq 'us' ) {
  78                 $date_string =~ s#-#/#g;
  79                 $date_string =~ s[/00/][/01/];
  80             } elsif ( $date_format eq 'sql' ) {
  81                 $date_string =~
  82 s/(\d{4})(\d{2})(\d{2})\s+(\d{2})(\d{2})(\d{2})/$1-$2-$3T$4:$5:$6/;
  83                 $date_string =~ s/00T/01T/;
  84             }
  85         }
  86         return DateTime::Format::DateParse->parse_datetime( $date_string,
  87             $tz->name() );
  88     }
  89     return DateTime->now( time_zone => $tz );
  90
  91 }
  92
  93 =head2 output_pref
  94
  95 $date_string = output_pref($dt, [$format] );
  96
  97 Returns a string containing the time & date formatted as per the C4::Context setting
  98
  99 A second parameter allows overriding of the syspref value. This is for testing only
 100 In usage use the DateTime objects own methods for non standard formatting
 101
 102 =cut
 103
 104 sub output_pref {
 105     my $dt         = shift;
 106     my $force_pref = shift;    # if testing we want to override Context
 107     my $pref =
 108       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 109     given ($pref) {
 110         when (/^iso/) {
 111             return $dt->strftime('%Y-%m-%d %H:%M');
 112         }
 113         when (/^metric/) {
 114             return $dt->strftime('%d/%m/%Y %H:%M');
 115         }
 116         when (/^us/) {
 117             return $dt->strftime('%m/%d/%Y %H:%M');
 118         }
 119         default {
 120             return $dt->strftime('%Y-%m-%d %H:%M');
 121         }
 122
 123     }
 124     return;
 125 }
 126
 127 =head2 output_pref_due
 128
 129 $date_string = output_pref_due($dt, [$format] );
 130
 131 Returns a string containing the time & date formatted as per the C4::Context setting
 132
 133 A second parameter allows overriding of the syspref value. This is for testing only
 134 In usage use the DateTime objects own methods for non standard formatting
 135
 136 This is effectivelyt a wrapper around output_pref for due dates
 137 the time portion is stripped if it is '23:59'
 138
 139 =cut
 140
 141 sub output_pref_due {
 142     my $disp_str = output_pref(@_);
 143     $disp_str =~ s/ 23:59//;
 144     return $disp_str;
 145 }
 146
 147 =head2 format_sqldatetime
 148
 149 $string = format_sqldatetime( $string_as_returned_from_db );
 150
 151 a convenience routine for calling dt_from_string and formatting the result
 152 with output_pref as it is a frequent activity in scripts
 153
 154 =cut
 155
 156 sub format_sqldatetime {
 157     my $str        = shift;
 158     my $force_pref = shift;    # if testing we want to override Context
 159     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 160         my $dt = dt_from_string( $str, 'sql' );
 161         $dt->truncate( to => 'minute' );
 162         return output_pref( $dt, $force_pref );
 163     }
 164     return q{};
 165 }
 166
 167 =head2 format_sqlduedatetime
 168
 169 $string = format_sqldatetime( $string_as_returned_from_db );
 170
 171 a convenience routine for calling dt_from_string and formatting the result
 172 with output_pref_due as it is a frequent activity in scripts
 173
 174 =cut
 175
 176 sub format_sqlduedatetime {
 177     my $str        = shift;
 178     my $force_pref = shift;    # if testing we want to override Context
 179     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 180         my $dt = dt_from_string( $str, 'sql' );
 181         $dt->truncate( to => 'minute' );
 182         return output_pref_due( $dt, $force_pref );
 183     }
 184     return q{};
 185 }
 186
 187 1;