Koha/Item.pm

   1 package Koha::Item;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 use C4::Context;
  27 use Koha::IssuingRules;
  28 use Koha::Item::Transfer;
  29 use Koha::Patrons;
  30 use Koha::Libraries;
  31
  32 use base qw(Koha::Object);
  33
  34 =head1 NAME
  35
  36 Koha::Item - Koha Item object class
  37
  38 =head1 API
  39
  40 =head2 Class Methods
  41
  42 =cut
  43
  44 =head3 effective_itemtype
  45
  46 Returns the itemtype for the item based on whether item level itemtypes are set or not.
  47
  48 =cut
  49
  50 sub effective_itemtype {
  51     my ( $self ) = @_;
  52
  53     return $self->_result()->effective_itemtype();
  54 }
  55
  56 =head3 home_branch
  57
  58 =cut
  59
  60 sub home_branch {
  61     my ($self) = @_;
  62
  63     $self->{_home_branch} ||= Koha::Libraries->find( $self->homebranch() );
  64
  65     return $self->{_home_branch};
  66 }
  67
  68 =head3 holding_branch
  69
  70 =cut
  71
  72 sub holding_branch {
  73     my ($self) = @_;
  74
  75     $self->{_holding_branch} ||= Koha::Libraries->find( $self->holdingbranch() );
  76
  77     return $self->{_holding_branch};
  78 }
  79
  80 =head3 get_transfer
  81
  82 my $transfer = $item->get_transfer;
  83
  84 Return the transfer if the item is in transit or undef
  85
  86 =cut
  87
  88 sub get_transfer {
  89     my ( $self ) = @_;
  90     my $transfer_rs = $self->_result->branchtransfers->search({ datearrived => undef })->first;
  91     return unless $transfer_rs;
  92     return Koha::Item::Transfer->_new_from_dbic( $transfer_rs );
  93 }
  94
  95 =head3 last_returned_by
  96
  97 Gets and sets the last borrower to return an item.
  98
  99 Accepts and returns Koha::Patron objects
 100
 101 $item->last_returned_by( $borrowernumber );
 102
 103 $last_returned_by = $item->last_returned_by();
 104
 105 =cut
 106
 107 sub last_returned_by {
 108     my ( $self, $borrower ) = @_;
 109
 110     my $items_last_returned_by_rs = Koha::Database->new()->schema()->resultset('ItemsLastBorrower');
 111
 112     if ($borrower) {
 113         return $items_last_returned_by_rs->update_or_create(
 114             { borrowernumber => $borrower->borrowernumber, itemnumber => $self->id } );
 115     }
 116     else {
 117         unless ( $self->{_last_returned_by} ) {
 118             my $result = $items_last_returned_by_rs->single( { itemnumber => $self->id } );
 119             if ($result) {
 120                 $self->{_last_returned_by} = Koha::Patrons->find( $result->get_column('borrowernumber') );
 121             }
 122         }
 123
 124         return $self->{_last_returned_by};
 125     }
 126 }
 127
 128 =head3 can_article_request
 129
 130 my $bool = $item->can_article_request( $borrower )
 131
 132 Returns true if item can be specifically requested
 133
 134 $borrower must be a Koha::Patron object
 135
 136 =cut
 137
 138 sub can_article_request {
 139     my ( $self, $borrower ) = @_;
 140
 141     my $rule = $self->article_request_type($borrower);
 142
 143     return 1 if $rule && $rule ne 'no' && $rule ne 'bib_only';
 144     return q{};
 145 }
 146
 147 =head3 article_request_type
 148
 149 my $type = $item->article_request_type( $borrower )
 150
 151 returns 'yes', 'no', 'bib_only', or 'item_only'
 152
 153 $borrower must be a Koha::Patron object
 154
 155 =cut
 156
 157 sub article_request_type {
 158     my ( $self, $borrower ) = @_;
 159
 160     my $branch_control = C4::Context->preference('HomeOrHoldingBranch');
 161     my $branchcode =
 162         $branch_control eq 'homebranch'    ? $self->homebranch
 163       : $branch_control eq 'holdingbranch' ? $self->holdingbranch
 164       :                                      undef;
 165     my $borrowertype = $borrower->categorycode;
 166     my $itemtype = $self->effective_itemtype();
 167     my $issuing_rule = Koha::IssuingRules->get_effective_issuing_rule({ categorycode => $borrowertype, itemtype => $itemtype, branchcode => $branchcode });
 168
 169     return q{} unless $issuing_rule;
 170     return $issuing_rule->article_requests || q{}
 171 }
 172
 173 =head3 type
 174
 175 =cut
 176
 177 sub _type {
 178     return 'Item';
 179 }
 180
 181 =head1 AUTHOR
 182
 183 Kyle M Hall <kyle@bywatersolutions.com>
 184
 185 =cut
 186
 187 1;