cataloguing/value_builder/stocknumberam123.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2010 BibLibre SARL
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22 use C4::Auth;
  23 use CGI qw ( -utf8 );
  24 use C4::Context;
  25 use C4::Output;
  26
  27 =head1 DESCRIPTION
  28
  29 This plugin is specific to AM123 but could be used as a base for similar operations.
  30 It is used for stocknumber computation.
  31
  32 If the user send an empty string, we return a simple incremented stocknumber.
  33 If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented.
  34 In this case, a stocknumber has this form : "PREFIX 0009678570".
  35  - PREFIX is an upercase word
  36  - a space separator
  37  - 10 digits, with leading 0s if needed
  38
  39 =cut
  40
  41 sub plugin_javascript {
  42     my ($dbh,$record,$tagslib,$field_number,$tabloop) = @_;
  43     my $res="
  44     <script type='text/javascript'>
  45         function Blur$field_number() {
  46                 var code = document.getElementById('$field_number');
  47                 var url = '../cataloguing/plugin_launcher.pl?plugin_name=stocknumberam123.pl&code=' + code.value;
  48                 var req = \$.get(url);
  49                 req.done(function(resp){
  50                     code.value = resp;
  51                     return 1;
  52                 });
  53                 return 1;
  54         }
  55
  56     </script>
  57     ";
  58
  59     return ($field_number,$res);
  60 }
  61
  62 sub plugin {
  63     my ($input) = @_;
  64     my $code = $input->param('code');
  65
  66     my ($template, $loggedinuser, $cookie) = get_template_and_user({
  67         template_name   => "cataloguing/value_builder/ajax.tt",
  68         query           => $input,
  69         type            => "intranet",
  70         authnotrequired => 0,
  71         flagsrequired   => {editcatalogue => '*'},
  72         debug           => 1,
  73     });
  74
  75     my $dbh = C4::Context->dbh;
  76     # If the textbox is empty, we return a simple incremented stocknumber
  77     if ( $code eq "" ) {
  78         my $sth = $dbh->prepare("SELECT MAX(CAST(stocknumber AS SIGNED)) FROM items");
  79         $sth->execute;
  80
  81         if ( my $max = $sth->fetchrow ) {
  82             $template->param(
  83                 return => $max+1,
  84             );
  85         }
  86     # If a prefix is submited, we look for the highest stocknumber with this prefix, and return it incremented
  87     } elsif ( $code =~ m/^[A-Z]+$/ ) {
  88         my $sth = $dbh->prepare("SELECT MAX(CAST(SUBSTRING_INDEX(stocknumber,' ',-1) AS SIGNED)) FROM items WHERE stocknumber LIKE ?");
  89         $sth->execute($code.' %');
  90
  91         if ( my $max = $sth->fetchrow ) {
  92             $template->param(
  93                 return => $code.' '.sprintf('%010s',($max+1)),
  94             );
  95         }
  96     # The user entered a custom value, we don't touch it, this could be handled in js
  97     } else {
  98         $template->param(
  99             return => $code,
 100         );
 101     }
 102     output_html_with_http_headers $input, $cookie, $template->output;
 103 }