C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::Account::Lines;
  56 use Koha::Account::Offsets;
  57 use Koha::Config::SysPrefs;
  58 use Koha::Charges::Fees;
  59 use Koha::Util::SystemPreferences;
  60 use Koha::Checkouts::ReturnClaims;
  61 use Koha::SearchEngine::Indexer;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Try::Tiny;
  66 use Date::Calc qw(
  67   Today
  68   Today_and_Now
  69   Add_Delta_YM
  70   Add_Delta_DHMS
  71   Date_to_Days
  72   Day_of_Week
  73   Add_Delta_Days
  74 );
  75 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  76
  77 BEGIN {
  78         require Exporter;
  79         @ISA    = qw(Exporter);
  80
  81         # FIXME subs that should probably be elsewhere
  82         push @EXPORT, qw(
  83                 &barcodedecode
  84         &LostItem
  85         &ReturnLostItem
  86         &GetPendingOnSiteCheckouts
  87         );
  88
  89         # subs to deal with issuing a book
  90         push @EXPORT, qw(
  91                 &CanBookBeIssued
  92                 &CanBookBeRenewed
  93                 &AddIssue
  94                 &AddRenewal
  95                 &GetRenewCount
  96         &GetSoonestRenewDate
  97         &GetLatestAutoRenewDate
  98                 &GetIssuingCharges
  99         &GetBranchBorrowerCircRule
 100         &GetBranchItemRule
 101                 &GetBiblioIssues
 102                 &GetOpenIssue
 103         &CheckIfIssuedToPatron
 104         &IsItemIssued
 105         GetTopIssues
 106         );
 107
 108         # subs to deal with returns
 109         push @EXPORT, qw(
 110                 &AddReturn
 111         &MarkIssueReturned
 112         );
 113
 114         # subs to deal with transfers
 115         push @EXPORT, qw(
 116                 &transferbook
 117                 &GetTransfers
 118                 &GetTransfersFromTo
 119                 &updateWrongTransfer
 120                 &DeleteTransfer
 121                 &IsBranchTransferAllowed
 122                 &CreateBranchTransferLimit
 123                 &DeleteBranchTransferLimits
 124         &TransferSlip
 125         );
 126
 127     # subs to deal with offline circulation
 128     push @EXPORT, qw(
 129       &GetOfflineOperations
 130       &GetOfflineOperation
 131       &AddOfflineOperation
 132       &DeleteOfflineOperation
 133       &ProcessOfflineOperation
 134     );
 135 }
 136
 137 =head1 NAME
 138
 139 C4::Circulation - Koha circulation module
 140
 141 =head1 SYNOPSIS
 142
 143 use C4::Circulation;
 144
 145 =head1 DESCRIPTION
 146
 147 The functions in this module deal with circulation, issues, and
 148 returns, as well as general information about the library.
 149 Also deals with inventory.
 150
 151 =head1 FUNCTIONS
 152
 153 =head2 barcodedecode
 154
 155   $str = &barcodedecode($barcode, [$filter]);
 156
 157 Generic filter function for barcode string.
 158 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 159 Will do some manipulation of the barcode for systems that deliver a barcode
 160 to circulation.pl that differs from the barcode stored for the item.
 161 For proper functioning of this filter, calling the function on the
 162 correct barcode string (items.barcode) should return an unaltered barcode.
 163
 164 The optional $filter argument is to allow for testing or explicit
 165 behavior that ignores the System Pref.  Valid values are the same as the
 166 System Pref options.
 167
 168 =cut
 169
 170 # FIXME -- the &decode fcn below should be wrapped into this one.
 171 # FIXME -- these plugins should be moved out of Circulation.pm
 172 #
 173 sub barcodedecode {
 174     my ($barcode, $filter) = @_;
 175     my $branch = C4::Context::mybranch();
 176     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 177     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 178         if ($filter eq 'whitespace') {
 179                 $barcode =~ s/\s//g;
 180         } elsif ($filter eq 'cuecat') {
 181                 chomp($barcode);
 182             my @fields = split( /\./, $barcode );
 183             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 184             ($#results == 2) and return $results[2];
 185         } elsif ($filter eq 'T-prefix') {
 186                 if ($barcode =~ /^[Tt](\d)/) {
 187                         (defined($1) and $1 eq '0') and return $barcode;
 188             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 189                 }
 190         return sprintf("T%07d", $barcode);
 191         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 192         # Why drop the nonzero digit after the T?
 193         # Why pass non-digits (or empty string) to "T%07d"?
 194         } elsif ($filter eq 'libsuite8') {
 195                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 196                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 197                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 198                         }else{
 199                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 200                         }
 201                 }
 202     } elsif ($filter eq 'EAN13') {
 203         my $ean = CheckDigits('ean');
 204         if ( $ean->is_valid($barcode) ) {
 205             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 206             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 207         } else {
 208             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 209         }
 210         }
 211     return $barcode;    # return barcode, modified or not
 212 }
 213
 214 =head2 decode
 215
 216   $str = &decode($chunk);
 217
 218 Decodes a segment of a string emitted by a CueCat barcode scanner and
 219 returns it.
 220
 221 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 222 or Javascript based decoding on the client side.
 223
 224 =cut
 225
 226 sub decode {
 227     my ($encoded) = @_;
 228     my $seq =
 229       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 230     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 231     my $l = ( $#s + 1 ) % 4;
 232     if ($l) {
 233         if ( $l == 1 ) {
 234             # warn "Error: Cuecat decode parsing failed!";
 235             return;
 236         }
 237         $l = 4 - $l;
 238         $#s += $l;
 239     }
 240     my $r = '';
 241     while ( $#s >= 0 ) {
 242         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 243         $r .=
 244             chr( ( $n >> 16 ) ^ 67 )
 245          .chr( ( $n >> 8 & 255 ) ^ 67 )
 246          .chr( ( $n & 255 ) ^ 67 );
 247         @s = @s[ 4 .. $#s ];
 248     }
 249     $r = substr( $r, 0, length($r) - $l );
 250     return $r;
 251 }
 252
 253 =head2 transferbook
 254
 255   ($dotransfer, $messages, $iteminformation) = &transferbook({
 256                                                    from_branch => $frombranch
 257                                                    to_branch => $tobranch,
 258                                                    barcode => $barcode,
 259                                                    ignore_reserves => $ignore_reserves,
 260                                                    trigger => $trigger
 261                                                 });
 262
 263 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 264
 265 C<$fbr> is the code for the branch initiating the transfer.
 266 C<$tbr> is the code for the branch to which the item should be transferred.
 267
 268 C<$barcode> is the barcode of the item to be transferred.
 269
 270 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 271 Otherwise, if an item is reserved, the transfer fails.
 272
 273 C<$trigger> is the enum value for what triggered the transfer.
 274
 275 Returns three values:
 276
 277 =over
 278
 279 =item $dotransfer
 280
 281 is true if the transfer was successful.
 282
 283 =item $messages
 284
 285 is a reference-to-hash which may have any of the following keys:
 286
 287 =over
 288
 289 =item C<BadBarcode>
 290
 291 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 292
 293 =item C<DestinationEqualsHolding>
 294
 295 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 296
 297 =item C<WasReturned>
 298
 299 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 300
 301 =item C<ResFound>
 302
 303 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 304
 305 =item C<WasTransferred>
 306
 307 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 308
 309 =back
 310
 311 =back
 312
 313 =cut
 314
 315 sub transferbook {
 316     my $params = shift;
 317     my $tbr      = $params->{to_branch};
 318     my $fbr      = $params->{from_branch};
 319     my $ignoreRs = $params->{ignore_reserves};
 320     my $barcode  = $params->{barcode};
 321     my $trigger  = $params->{trigger};
 322     my $messages;
 323     my $dotransfer      = 1;
 324     my $item = Koha::Items->find( { barcode => $barcode } );
 325
 326     Koha::Exceptions::MissingParameter->throw(
 327         "Missing mandatory parameter: from_branch")
 328       unless $fbr;
 329
 330     Koha::Exceptions::MissingParameter->throw(
 331         "Missing mandatory parameter: to_branch")
 332       unless $tbr;
 333
 334     # bad barcode..
 335     unless ( $item ) {
 336         $messages->{'BadBarcode'} = $barcode;
 337         $dotransfer = 0;
 338         return ( $dotransfer, $messages );
 339     }
 340
 341     my $itemnumber = $item->itemnumber;
 342     # get branches of book...
 343     my $hbr = $item->homebranch;
 344
 345     # if using Branch Transfer Limits
 346     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 347         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 348         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 349             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 350                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 351                 $dotransfer = 0;
 352             }
 353         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 354             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 355             $dotransfer = 0;
 356         }
 357     }
 358
 359     # can't transfer book if is already there....
 360     if ( $fbr eq $tbr ) {
 361         $messages->{'DestinationEqualsHolding'} = 1;
 362         $dotransfer = 0;
 363     }
 364
 365     # check if it is still issued to someone, return it...
 366     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 367     if ( $issue ) {
 368         AddReturn( $barcode, $fbr );
 369         $messages->{'WasReturned'} = $issue->borrowernumber;
 370     }
 371
 372     # find reserves.....
 373     # That'll save a database query.
 374     my ( $resfound, $resrec, undef ) =
 375       CheckReserves( $itemnumber );
 376     if ( $resfound and not $ignoreRs ) {
 377         $resrec->{'ResFound'} = $resfound;
 378         $messages->{'ResFound'} = $resrec;
 379         $dotransfer = 1;
 380     }
 381
 382     #actually do the transfer....
 383     if ($dotransfer) {
 384         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 385
 386         # don't need to update MARC anymore, we do it in batch now
 387         $messages->{'WasTransfered'} = 1;
 388
 389     }
 390     ModDateLastSeen( $itemnumber );
 391     return ( $dotransfer, $messages );
 392 }
 393
 394
 395 sub TooMany {
 396     my $borrower        = shift;
 397     my $item_object = shift;
 398     my $params = shift;
 399     my $onsite_checkout = $params->{onsite_checkout} || 0;
 400     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 401     my $cat_borrower    = $borrower->{'categorycode'};
 402     my $dbh             = C4::Context->dbh;
 403     # Get which branchcode we need
 404     my $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 405     my $type = $item_object->effective_itemtype;
 406
 407     my ($type_object, $parent_type, $parent_maxissueqty_rule);
 408     $type_object = Koha::ItemTypes->find( $type );
 409     $parent_type = $type_object->parent_type if $type_object;
 410     my $child_types = Koha::ItemTypes->search({ parent_type => $type });
 411     # Find any children if we are a parent_type;
 412
 413     # given branch, patron category, and item type, determine
 414     # applicable issuing rule
 415
 416     $parent_maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 417         {
 418             categorycode => $cat_borrower,
 419             itemtype     => $parent_type,
 420             branchcode   => $branch,
 421             rule_name    => 'maxissueqty',
 422         }
 423     ) if $parent_type;
 424     # If the parent rule is for default type we discount it
 425     $parent_maxissueqty_rule = undef if $parent_maxissueqty_rule && !defined $parent_maxissueqty_rule->itemtype;
 426
 427     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 428         {
 429             categorycode => $cat_borrower,
 430             itemtype     => $type,
 431             branchcode   => $branch,
 432             rule_name    => 'maxissueqty',
 433         }
 434     );
 435
 436     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 437         {
 438             categorycode => $cat_borrower,
 439             itemtype     => $type,
 440             branchcode   => $branch,
 441             rule_name    => 'maxonsiteissueqty',
 442         }
 443     );
 444
 445
 446     my $patron = Koha::Patrons->find($borrower->{borrowernumber});
 447     # if a rule is found and has a loan limit set, count
 448     # how many loans the patron already has that meet that
 449     # rule
 450     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne "") {
 451
 452         my $checkouts;
 453         if ( $maxissueqty_rule->branchcode ) {
 454             if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 455                 $checkouts = $patron->checkouts->search(
 456                     { 'me.branchcode' => $maxissueqty_rule->branchcode } );
 457             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 458                 $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 459             } else {
 460                 $checkouts = $patron->checkouts->search(
 461                     { 'item.homebranch' => $maxissueqty_rule->branchcode },
 462                     { prefetch          => 'item' } );
 463             }
 464         } else {
 465             $checkouts = $patron->checkouts; # if rule is not branch specific then count all loans by patron
 466         }
 467         my $sum_checkouts;
 468         my $rule_itemtype = $maxissueqty_rule->itemtype;
 469         while ( my $c = $checkouts->next ) {
 470             my $itemtype = $c->item->effective_itemtype;
 471             my @types;
 472             unless ( $rule_itemtype ) {
 473                 # matching rule has the default item type, so count only
 474                 # those existing loans that don't fall under a more
 475                 # specific rule
 476                 @types = Koha::CirculationRules->search(
 477                     {
 478                         branchcode => $maxissueqty_rule->branchcode,
 479                         categorycode => [ $maxissueqty_rule->categorycode, $cat_borrower ],
 480                         itemtype  => { '!=' => undef },
 481                         rule_name => 'maxissueqty'
 482                     }
 483                 )->get_column('itemtype');
 484
 485                 next if grep {$_ eq $itemtype} @types;
 486             } else {
 487                 my @types;
 488                 if ( $parent_maxissueqty_rule ) {
 489                 # if we have a parent item type then we count loans of the
 490                 # specific item type or its siblings or parent
 491                     my $children = Koha::ItemTypes->search({ parent_type => $parent_type });
 492                     @types = $children->get_column('itemtype');
 493                     push @types, $parent_type;
 494                 } elsif ( $child_types ) {
 495                 # If we are a parent type, we need to count all child types and our own type
 496                     @types = $child_types->get_column('itemtype');
 497                     push @types, $type; # And don't forget to count our own types
 498                 } else { push @types, $type; } # Otherwise only count the specific itemtype
 499
 500                 next unless grep {$_ eq $itemtype} @types;
 501             }
 502             $sum_checkouts->{total}++;
 503             $sum_checkouts->{onsite_checkouts}++ if $c->onsite_checkout;
 504             $sum_checkouts->{itemtype}->{$itemtype}++;
 505         }
 506
 507         my $checkout_count_type = $sum_checkouts->{itemtype}->{$type} || 0;
 508         my $checkout_count = $sum_checkouts->{total} || 0;
 509         my $onsite_checkout_count = $sum_checkouts->{onsite_checkouts} || 0;
 510
 511         my $checkout_rules = {
 512             checkout_count               => $checkout_count,
 513             onsite_checkout_count        => $onsite_checkout_count,
 514             onsite_checkout              => $onsite_checkout,
 515             max_checkouts_allowed        => $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef,
 516             max_onsite_checkouts_allowed => $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef,
 517             switch_onsite_checkout       => $switch_onsite_checkout,
 518         };
 519         # If parent rules exists
 520         if ( defined($parent_maxissueqty_rule) and defined($parent_maxissueqty_rule->rule_value) ){
 521             $checkout_rules->{max_checkouts_allowed} = $parent_maxissueqty_rule ? $parent_maxissueqty_rule->rule_value : undef;
 522             my $qty_over = _check_max_qty($checkout_rules);
 523             return $qty_over if defined $qty_over;
 524
 525             # If the parent rule is less than or equal to the child, we only need check the parent
 526             if( $maxissueqty_rule->rule_value < $parent_maxissueqty_rule->rule_value && defined($maxissueqty_rule->itemtype) ) {
 527                 $checkout_rules->{checkout_count} = $checkout_count_type;
 528                 $checkout_rules->{max_checkouts_allowed} = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 529                 my $qty_over = _check_max_qty($checkout_rules);
 530                 return $qty_over if defined $qty_over;
 531             }
 532         } else {
 533             my $qty_over = _check_max_qty($checkout_rules);
 534             return $qty_over if defined $qty_over;
 535         }
 536     }
 537
 538     # Now count total loans against the limit for the branch
 539     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 540     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 541         my $checkouts;
 542         if ( C4::Context->preference('CircControl') eq 'PickupLibrary' ) {
 543             $checkouts = $patron->checkouts->search(
 544                 { 'me.branchcode' => $branch} );
 545         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 546             $checkouts = $patron->checkouts; # if branch is the patron's home branch, then count all loans by patron
 547         } else {
 548             $checkouts = $patron->checkouts->search(
 549                 { 'item.homebranch' => $branch},
 550                 { prefetch          => 'item' } );
 551         }
 552
 553         my $checkout_count = $checkouts->count;
 554         my $onsite_checkout_count = $checkouts->search({ onsite_checkout => 1 })->count;
 555         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 556         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty} || undef;
 557
 558         my $qty_over = _check_max_qty(
 559             {
 560                 checkout_count               => $checkout_count,
 561                 onsite_checkout_count        => $onsite_checkout_count,
 562                 onsite_checkout              => $onsite_checkout,
 563                 max_checkouts_allowed        => $max_checkouts_allowed,
 564                 max_onsite_checkouts_allowed => $max_onsite_checkouts_allowed,
 565                 switch_onsite_checkout       => $switch_onsite_checkout
 566             }
 567         );
 568         return $qty_over if defined $qty_over;
 569     }
 570
 571     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 572         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 573     }
 574
 575     # OK, the patron can issue !!!
 576     return;
 577 }
 578
 579 sub _check_max_qty {
 580     my $params                       = shift;
 581     my $checkout_count               = $params->{checkout_count};
 582     my $onsite_checkout_count        = $params->{onsite_checkout_count};
 583     my $onsite_checkout              = $params->{onsite_checkout};
 584     my $max_checkouts_allowed        = $params->{max_checkouts_allowed};
 585     my $max_onsite_checkouts_allowed = $params->{max_onsite_checkouts_allowed};
 586     my $switch_onsite_checkout       = $params->{switch_onsite_checkout};
 587
 588     if ( $onsite_checkout and defined $max_onsite_checkouts_allowed ) {
 589         if ( $max_onsite_checkouts_allowed eq '' ) { return; }
 590         if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed ) {
 591             return {
 592                 reason      => 'TOO_MANY_ONSITE_CHECKOUTS',
 593                 count       => $onsite_checkout_count,
 594                 max_allowed => $max_onsite_checkouts_allowed,
 595             };
 596         }
 597     }
 598     if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 599         if ( $max_checkouts_allowed eq '' ) { return; }
 600         my $delta = $switch_onsite_checkout ? 1 : 0;
 601         if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 602             return {
 603                 reason      => 'TOO_MANY_CHECKOUTS',
 604                 count       => $checkout_count,
 605                 max_allowed => $max_checkouts_allowed,
 606             };
 607         }
 608     }
 609     elsif ( not $onsite_checkout ) {
 610         if ( $max_checkouts_allowed eq '' ) { return; }
 611         if (
 612             $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )
 613         {
 614             return {
 615                 reason      => 'TOO_MANY_CHECKOUTS',
 616                 count       => $checkout_count - $onsite_checkout_count,
 617                 max_allowed => $max_checkouts_allowed,
 618             };
 619         }
 620     }
 621
 622     return;
 623 }
 624
 625 =head2 CanBookBeIssued
 626
 627   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 628                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 629
 630 Check if a book can be issued.
 631
 632 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 633
 634 IMPORTANT: The assumption by users of this routine is that causes blocking
 635 the issue are keyed by uppercase labels and other returned
 636 data is keyed in lower case!
 637
 638 =over 4
 639
 640 =item C<$patron> is a Koha::Patron
 641
 642 =item C<$barcode> is the bar code of the book being issued.
 643
 644 =item C<$duedates> is a DateTime object.
 645
 646 =item C<$inprocess> boolean switch
 647
 648 =item C<$ignore_reserves> boolean switch
 649
 650 =item C<$params> Hashref of additional parameters
 651
 652 Available keys:
 653     override_high_holds - Ignore high holds
 654     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 655
 656 =back
 657
 658 Returns :
 659
 660 =over 4
 661
 662 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 663 Possible values are :
 664
 665 =back
 666
 667 =head3 INVALID_DATE
 668
 669 sticky due date is invalid
 670
 671 =head3 GNA
 672
 673 borrower gone with no address
 674
 675 =head3 CARD_LOST
 676
 677 borrower declared it's card lost
 678
 679 =head3 DEBARRED
 680
 681 borrower debarred
 682
 683 =head3 UNKNOWN_BARCODE
 684
 685 barcode unknown
 686
 687 =head3 NOT_FOR_LOAN
 688
 689 item is not for loan
 690
 691 =head3 WTHDRAWN
 692
 693 item withdrawn.
 694
 695 =head3 RESTRICTED
 696
 697 item is restricted (set by ??)
 698
 699 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 700 could be prevented, but ones that can be overriden by the operator.
 701
 702 Possible values are :
 703
 704 =head3 DEBT
 705
 706 borrower has debts.
 707
 708 =head3 RENEW_ISSUE
 709
 710 renewing, not issuing
 711
 712 =head3 ISSUED_TO_ANOTHER
 713
 714 issued to someone else.
 715
 716 =head3 RESERVED
 717
 718 reserved for someone else.
 719
 720 =head3 INVALID_DATE
 721
 722 sticky due date is invalid or due date in the past
 723
 724 =head3 TOO_MANY
 725
 726 if the borrower borrows to much things
 727
 728 =cut
 729
 730 sub CanBookBeIssued {
 731     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 732     my %needsconfirmation;    # filled with problems that needs confirmations
 733     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 734     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 735     my %messages;             # filled with information messages that should be displayed.
 736
 737     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 738     my $override_high_holds = $params->{override_high_holds} || 0;
 739
 740     my $item_object = Koha::Items->find({barcode => $barcode });
 741
 742     # MANDATORY CHECKS - unless item exists, nothing else matters
 743     unless ( $item_object ) {
 744         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 745     }
 746     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 747
 748     my $item_unblessed = $item_object->unblessed; # Transition...
 749     my $issue = $item_object->checkout;
 750     my $biblio = $item_object->biblio;
 751
 752     my $biblioitem = $biblio->biblioitem;
 753     my $effective_itemtype = $item_object->effective_itemtype;
 754     my $dbh             = C4::Context->dbh;
 755     my $patron_unblessed = $patron->unblessed;
 756
 757     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 758     #
 759     # DUE DATE is OK ? -- should already have checked.
 760     #
 761     if ($duedate && ref $duedate ne 'DateTime') {
 762         $duedate = dt_from_string($duedate);
 763     }
 764     my $now = dt_from_string();
 765     unless ( $duedate ) {
 766         my $issuedate = $now->clone();
 767
 768         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 769
 770         # Offline circ calls AddIssue directly, doesn't run through here
 771         #  So issuingimpossible should be ok.
 772     }
 773
 774     my $fees = Koha::Charges::Fees->new(
 775         {
 776             patron    => $patron,
 777             library   => $circ_library,
 778             item      => $item_object,
 779             to_date   => $duedate,
 780         }
 781     );
 782
 783     if ($duedate) {
 784         my $today = $now->clone();
 785         $today->truncate( to => 'minute');
 786         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 787             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 788         }
 789     } else {
 790             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 791     }
 792
 793     #
 794     # BORROWER STATUS
 795     #
 796     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 797         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 798         &UpdateStats({
 799                      branch => C4::Context->userenv->{'branch'},
 800                      type => 'localuse',
 801                      itemnumber => $item_object->itemnumber,
 802                      itemtype => $effective_itemtype,
 803                      borrowernumber => $patron->borrowernumber,
 804                      ccode => $item_object->ccode}
 805                     );
 806         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 807         return( { STATS => 1 }, {});
 808     }
 809
 810     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 811         $issuingimpossible{GNA} = 1;
 812     }
 813
 814     if ( $patron->lost && $patron->lost == 1 ) {
 815         $issuingimpossible{CARD_LOST} = 1;
 816     }
 817     if ( $patron->is_debarred ) {
 818         $issuingimpossible{DEBARRED} = 1;
 819     }
 820
 821     if ( $patron->is_expired ) {
 822         $issuingimpossible{EXPIRED} = 1;
 823     }
 824
 825     #
 826     # BORROWER STATUS
 827     #
 828
 829     # DEBTS
 830     my $account = $patron->account;
 831     my $balance = $account->balance;
 832     my $non_issues_charges = $account->non_issues_charges;
 833     my $other_charges = $balance - $non_issues_charges;
 834
 835     my $amountlimit = C4::Context->preference("noissuescharge");
 836     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 837     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 838
 839     # Check the debt of this patrons guarantees
 840     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 841     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 842     if ( defined $no_issues_charge_guarantees ) {
 843         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 844         my $guarantees_non_issues_charges;
 845         foreach my $g ( @guarantees ) {
 846             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 847         }
 848
 849         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 850             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 851         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 852             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 853         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 854             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 855         }
 856     }
 857
 858     # Check the debt of this patrons guarantors *and* the guarantees of those guarantors
 859     my $no_issues_charge_guarantors = C4::Context->preference("NoIssuesChargeGuarantorsWithGuarantees");
 860     $no_issues_charge_guarantors = undef unless looks_like_number( $no_issues_charge_guarantors );
 861     if ( defined $no_issues_charge_guarantors ) {
 862         my $guarantors_non_issues_charges += $patron->relationships_debt({ include_guarantors => 1, only_this_guarantor => 0, include_this_patron => 1 });
 863
 864         if ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && !$allowfineoverride) {
 865             $issuingimpossible{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 866         } elsif ( $guarantors_non_issues_charges > $no_issues_charge_guarantors && !$inprocess && $allowfineoverride) {
 867             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 868         } elsif ( $allfinesneedoverride && $guarantors_non_issues_charges > 0 && $guarantors_non_issues_charges <= $no_issues_charge_guarantors && !$inprocess ) {
 869             $needsconfirmation{DEBT_GUARANTORS} = $guarantors_non_issues_charges;
 870         }
 871     }
 872
 873     if ( C4::Context->preference("IssuingInProcess") ) {
 874         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 875             $issuingimpossible{DEBT} = $non_issues_charges;
 876         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 877             $needsconfirmation{DEBT} = $non_issues_charges;
 878         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 879             $needsconfirmation{DEBT} = $non_issues_charges;
 880         }
 881     }
 882     else {
 883         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 884             $needsconfirmation{DEBT} = $non_issues_charges;
 885         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 886             $issuingimpossible{DEBT} = $non_issues_charges;
 887         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 888             $needsconfirmation{DEBT} = $non_issues_charges;
 889         }
 890     }
 891
 892     if ($balance > 0 && $other_charges > 0) {
 893         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 894     }
 895
 896     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 897     $patron_unblessed = $patron->unblessed;
 898
 899     if ( my $debarred_date = $patron->is_debarred ) {
 900          # patron has accrued fine days or has a restriction. $count is a date
 901         if ($debarred_date eq '9999-12-31') {
 902             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 903         }
 904         else {
 905             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 906         }
 907     } elsif ( my $num_overdues = $patron->has_overdues ) {
 908         ## patron has outstanding overdue loans
 909         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 910             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 911         }
 912         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 913             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 914         }
 915     }
 916
 917     # Additional Materials Check
 918     if ( C4::Context->preference("CircConfirmItemParts")
 919         && $item_object->materials )
 920     {
 921         $needsconfirmation{ADDITIONAL_MATERIALS} = $item_object->materials;
 922     }
 923
 924     #
 925     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 926     #
 927     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 928
 929         # Already issued to current borrower.
 930         # If it is an on-site checkout if it can be switched to a normal checkout
 931         # or ask whether the loan should be renewed
 932
 933         if ( $issue->onsite_checkout
 934                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 935             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 936         } else {
 937             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 938                 $patron->borrowernumber,
 939                 $item_object->itemnumber,
 940             );
 941             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 942                 if ( $renewerror eq 'onsite_checkout' ) {
 943                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 944                 }
 945                 else {
 946                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 947                 }
 948             }
 949             else {
 950                 $needsconfirmation{RENEW_ISSUE} = 1;
 951             }
 952         }
 953     }
 954     elsif ( $issue ) {
 955
 956         # issued to someone else
 957
 958         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 959
 960         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 961
 962         unless ( $can_be_returned ) {
 963             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 964             $issuingimpossible{branch_to_return} = $message;
 965         } else {
 966             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 967                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 968             } else {
 969             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 970             $needsconfirmation{issued_firstname} = $patron->firstname;
 971             $needsconfirmation{issued_surname} = $patron->surname;
 972             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 973             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 974             }
 975         }
 976     }
 977
 978     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 979     #
 980     my $switch_onsite_checkout = (
 981           C4::Context->preference('SwitchOnSiteCheckouts')
 982       and $issue
 983       and $issue->onsite_checkout
 984       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 985     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 986     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 987     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 988         if ( $toomany->{max_allowed} == 0 ) {
 989             $needsconfirmation{PATRON_CANT} = 1;
 990         }
 991         if ( C4::Context->preference("AllowTooManyOverride") ) {
 992             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 993             $needsconfirmation{current_loan_count} = $toomany->{count};
 994             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 995         } else {
 996             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 997             $issuingimpossible{current_loan_count} = $toomany->{count};
 998             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 999         }
1000     }
1001
1002     #
1003     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
1004     #
1005     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
1006     my $wants_check = $patron->wants_check_for_previous_checkout;
1007     $needsconfirmation{PREVISSUE} = 1
1008         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
1009
1010     #
1011     # ITEM CHECKING
1012     #
1013     if ( $item_object->notforloan )
1014     {
1015         if(!C4::Context->preference("AllowNotForLoanOverride")){
1016             $issuingimpossible{NOT_FOR_LOAN} = 1;
1017             $issuingimpossible{item_notforloan} = $item_object->notforloan;
1018         }else{
1019             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1020             $needsconfirmation{item_notforloan} = $item_object->notforloan;
1021         }
1022     }
1023     else {
1024         # we have to check itemtypes.notforloan also
1025         if (C4::Context->preference('item-level_itypes')){
1026             # this should probably be a subroutine
1027             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
1028             $sth->execute($effective_itemtype);
1029             my $notforloan=$sth->fetchrow_hashref();
1030             if ($notforloan->{'notforloan'}) {
1031                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1032                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1033                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1034                 } else {
1035                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1036                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1037                 }
1038             }
1039         }
1040         else {
1041             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
1042             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
1043                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
1044                     $issuingimpossible{NOT_FOR_LOAN} = 1;
1045                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
1046                 } else {
1047                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
1048                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
1049                 }
1050             }
1051         }
1052     }
1053     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
1054     {
1055         $issuingimpossible{WTHDRAWN} = 1;
1056     }
1057     if (   $item_object->restricted
1058         && $item_object->restricted == 1 )
1059     {
1060         $issuingimpossible{RESTRICTED} = 1;
1061     }
1062     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
1063         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
1064         my $code = $av->count ? $av->next->lib : '';
1065         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
1066         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
1067     }
1068     if ( C4::Context->preference("IndependentBranches") ) {
1069         my $userenv = C4::Context->userenv;
1070         unless ( C4::Context->IsSuperLibrarian() ) {
1071             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
1072             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
1073                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
1074                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
1075             }
1076             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1077               if ( $patron->branchcode ne $userenv->{branch} );
1078         }
1079     }
1080
1081     #
1082     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1083     #
1084     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1085     if ($rentalConfirmation) {
1086         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1087
1088         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1089         if ($itemtype_object) {
1090             my $accumulate_charge = $fees->accumulate_rentalcharge();
1091             if ( $accumulate_charge > 0 ) {
1092                 $rentalCharge += $accumulate_charge;
1093             }
1094         }
1095
1096         if ( $rentalCharge > 0 ) {
1097             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1098         }
1099     }
1100
1101     unless ( $ignore_reserves ) {
1102         # See if the item is on reserve.
1103         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1104         if ($restype) {
1105             my $resbor = $res->{'borrowernumber'};
1106             if ( $resbor ne $patron->borrowernumber ) {
1107                 my $patron = Koha::Patrons->find( $resbor );
1108                 if ( $restype eq "Waiting" )
1109                 {
1110                     # The item is on reserve and waiting, but has been
1111                     # reserved by some other patron.
1112                     $needsconfirmation{RESERVE_WAITING} = 1;
1113                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1114                     $needsconfirmation{'ressurname'} = $patron->surname;
1115                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1116                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1117                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1118                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1119                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1120                 }
1121                 elsif ( $restype eq "Reserved" ) {
1122                     # The item is on reserve for someone else.
1123                     $needsconfirmation{RESERVED} = 1;
1124                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1125                     $needsconfirmation{'ressurname'} = $patron->surname;
1126                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1127                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1128                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1129                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1130                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1131                 }
1132             }
1133         }
1134     }
1135
1136     ## CHECK AGE RESTRICTION
1137     my $agerestriction  = $biblioitem->agerestriction;
1138     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1139     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1140         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1141             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1142         }
1143         else {
1144             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1145         }
1146     }
1147
1148     ## check for high holds decreasing loan period
1149     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1150         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1151
1152         if ( $check->{exceeded} ) {
1153             if ($override_high_holds) {
1154                 $alerts{HIGHHOLDS} = {
1155                     num_holds  => $check->{outstanding},
1156                     duration   => $check->{duration},
1157                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1158                 };
1159             }
1160             else {
1161                 $needsconfirmation{HIGHHOLDS} = {
1162                     num_holds  => $check->{outstanding},
1163                     duration   => $check->{duration},
1164                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1165                 };
1166             }
1167         }
1168     }
1169
1170     if (
1171         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1172         # don't do the multiple loans per bib check if we've
1173         # already determined that we've got a loan on the same item
1174         !$issuingimpossible{NO_MORE_RENEWALS} &&
1175         !$needsconfirmation{RENEW_ISSUE}
1176     ) {
1177         # Check if borrower has already issued an item from the same biblio
1178         # Only if it's not a subscription
1179         my $biblionumber = $item_object->biblionumber;
1180         require C4::Serials;
1181         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1182         unless ($is_a_subscription) {
1183             # FIXME Should be $patron->checkouts($args);
1184             my $checkouts = Koha::Checkouts->search(
1185                 {
1186                     borrowernumber => $patron->borrowernumber,
1187                     biblionumber   => $biblionumber,
1188                 },
1189                 {
1190                     join => 'item',
1191                 }
1192             );
1193             # if we get here, we don't already have a loan on this item,
1194             # so if there are any loans on this bib, ask for confirmation
1195             if ( $checkouts->count ) {
1196                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1197             }
1198         }
1199     }
1200
1201     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1202 }
1203
1204 =head2 CanBookBeReturned
1205
1206   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1207
1208 Check whether the item can be returned to the provided branch
1209
1210 =over 4
1211
1212 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1213
1214 =item C<$branch> is the branchcode where the return is taking place
1215
1216 =back
1217
1218 Returns:
1219
1220 =over 4
1221
1222 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1223
1224 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1225
1226 =back
1227
1228 =cut
1229
1230 sub CanBookBeReturned {
1231   my ($item, $branch) = @_;
1232   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1233
1234   # assume return is allowed to start
1235   my $allowed = 1;
1236   my $message;
1237
1238   # identify all cases where return is forbidden
1239   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1240      $allowed = 0;
1241      $message = $item->{'homebranch'};
1242   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1243      $allowed = 0;
1244      $message = $item->{'holdingbranch'};
1245   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1246      $allowed = 0;
1247      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1248   }
1249
1250   return ($allowed, $message);
1251 }
1252
1253 =head2 CheckHighHolds
1254
1255     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1256     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1257     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1258
1259 =cut
1260
1261 sub checkHighHolds {
1262     my ( $item, $borrower ) = @_;
1263     my $branchcode = _GetCircControlBranch( $item, $borrower );
1264     my $item_object = Koha::Items->find( $item->{itemnumber} );
1265
1266     my $return_data = {
1267         exceeded    => 0,
1268         outstanding => 0,
1269         duration    => 0,
1270         due_date    => undef,
1271     };
1272
1273     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1274
1275     if ( $holds->count() ) {
1276         $return_data->{outstanding} = $holds->count();
1277
1278         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1279         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1280         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1281
1282         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1283
1284         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1285
1286             # static means just more than a given number of holds on the record
1287
1288             # If the number of holds is less than the threshold, we can stop here
1289             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1290                 return $return_data;
1291             }
1292         }
1293         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1294
1295             # dynamic means X more than the number of holdable items on the record
1296
1297             # let's get the items
1298             my @items = $holds->next()->biblio()->items()->as_list;
1299
1300             # Remove any items with status defined to be ignored even if the would not make item unholdable
1301             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1302                 @items = grep { !$_->$status } @items;
1303             }
1304
1305             # Remove any items that are not holdable for this patron
1306             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1307
1308             my $items_count = scalar @items;
1309
1310             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1311
1312             # If the number of holds is less than the count of items we have
1313             # plus the number of holds allowed above that count, we can stop here
1314             if ( $holds->count() <= $threshold ) {
1315                 return $return_data;
1316             }
1317         }
1318
1319         my $issuedate = dt_from_string();
1320
1321         my $itype = $item_object->effective_itemtype;
1322         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1323             {
1324                 categorycode => $borrower->{categorycode},
1325                 itemtype     => $itype,
1326                 branchcode   => $branchcode,
1327             }
1328         );
1329         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1330
1331         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1332
1333         my $rule = Koha::CirculationRules->get_effective_rule(
1334             {
1335                 categorycode => $borrower->{categorycode},
1336                 itemtype     => $item_object->effective_itemtype,
1337                 branchcode   => $branchcode,
1338                 rule_name    => 'decreaseloanholds',
1339             }
1340         );
1341
1342         my $duration;
1343         if ( defined($rule) && $rule->rule_value ne '' ){
1344             # overrides decreaseLoanHighHoldsDuration syspref
1345             $duration = $rule->rule_value;
1346         } else {
1347             $duration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1348         }
1349         my $reduced_datedue = $calendar->addDate( $issuedate, $duration );
1350         $reduced_datedue->set_hour($orig_due->hour);
1351         $reduced_datedue->set_minute($orig_due->minute);
1352         $reduced_datedue->truncate( to => 'minute' );
1353
1354         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1355             $return_data->{exceeded} = 1;
1356             $return_data->{duration} = $duration;
1357             $return_data->{due_date} = $reduced_datedue;
1358         }
1359     }
1360
1361     return $return_data;
1362 }
1363
1364 =head2 AddIssue
1365
1366   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1367
1368 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1369
1370 =over 4
1371
1372 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1373
1374 =item C<$barcode> is the barcode of the item being issued.
1375
1376 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1377 Calculated if empty.
1378
1379 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1380
1381 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1382 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1383
1384 AddIssue does the following things :
1385
1386   - step 01: check that there is a borrowernumber & a barcode provided
1387   - check for RENEWAL (book issued & being issued to the same patron)
1388       - renewal YES = Calculate Charge & renew
1389       - renewal NO  =
1390           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1391           * RESERVE PLACED ?
1392               - fill reserve if reserve to this patron
1393               - cancel reserve or not, otherwise
1394           * TRANSFERT PENDING ?
1395               - complete the transfert
1396           * ISSUE THE BOOK
1397
1398 =back
1399
1400 =cut
1401
1402 sub AddIssue {
1403     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1404
1405     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1406     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1407     my $auto_renew = $params && $params->{auto_renew};
1408     my $dbh          = C4::Context->dbh;
1409     my $barcodecheck = CheckValidBarcode($barcode);
1410
1411     my $issue;
1412
1413     if ( $datedue && ref $datedue ne 'DateTime' ) {
1414         $datedue = dt_from_string($datedue);
1415     }
1416
1417     # $issuedate defaults to today.
1418     if ( !defined $issuedate ) {
1419         $issuedate = dt_from_string();
1420     }
1421     else {
1422         if ( ref $issuedate ne 'DateTime' ) {
1423             $issuedate = dt_from_string($issuedate);
1424
1425         }
1426     }
1427
1428     # Stop here if the patron or barcode doesn't exist
1429     if ( $borrower && $barcode && $barcodecheck ) {
1430         # find which item we issue
1431         my $item_object = Koha::Items->find({ barcode => $barcode })
1432           or return;    # if we don't get an Item, abort.
1433         my $item_unblessed = $item_object->unblessed;
1434
1435         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1436
1437         # get actual issuing if there is one
1438         my $actualissue = $item_object->checkout;
1439
1440         # check if we just renew the issue.
1441         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1442                 and not $switch_onsite_checkout ) {
1443             $datedue = AddRenewal(
1444                 $borrower->{'borrowernumber'},
1445                 $item_object->itemnumber,
1446                 $branchcode,
1447                 $datedue,
1448                 $issuedate,    # here interpreted as the renewal date
1449             );
1450         }
1451         else {
1452             unless ($datedue) {
1453                 my $itype = $item_object->effective_itemtype;
1454                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1455
1456             }
1457             $datedue->truncate( to => 'minute' );
1458
1459             my $patron = Koha::Patrons->find( $borrower );
1460             my $library = Koha::Libraries->find( $branchcode );
1461             my $fees = Koha::Charges::Fees->new(
1462                 {
1463                     patron    => $patron,
1464                     library   => $library,
1465                     item      => $item_object,
1466                     to_date   => $datedue,
1467                 }
1468             );
1469
1470             # it's NOT a renewal
1471             if ( $actualissue and not $switch_onsite_checkout ) {
1472                 # This book is currently on loan, but not to the person
1473                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1474                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1475                 return unless $allowed;
1476                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1477             }
1478
1479             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1480
1481             # Starting process for transfer job (checking transfert and validate it if we have one)
1482             if ( my $transfer = $item_object->get_transfer ) {
1483                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1484                 $transfer->set(
1485                     {
1486                         datearrived => dt_from_string,
1487                         tobranch    => C4::Context->userenv->{branch},
1488                         comments    => 'Forced branchtransfer'
1489                     }
1490                 )->store;
1491                 if ( $transfer->reason && $transfer->reason eq 'Reserve' ) {
1492                     my $hold = $item_object->holds->search( { found => 'T' } )->next;
1493                     if ( $hold ) { # Is this really needed?
1494                         $hold->set( { found => undef } )->store;
1495                         C4::Reserves::ModReserveMinusPriority($item_object->itemnumber, $hold->reserve_id);
1496                     }
1497                 }
1498             }
1499
1500             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1501             unless ($auto_renew) {
1502                 my $rule = Koha::CirculationRules->get_effective_rule(
1503                     {
1504                         categorycode => $borrower->{categorycode},
1505                         itemtype     => $item_object->effective_itemtype,
1506                         branchcode   => $branchcode,
1507                         rule_name    => 'auto_renew'
1508                     }
1509                 );
1510
1511                 $auto_renew = $rule->rule_value if $rule;
1512             }
1513
1514             my $issue_attributes = {
1515                 borrowernumber  => $borrower->{'borrowernumber'},
1516                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1517                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1518                 branchcode      => C4::Context->userenv->{'branch'},
1519                 onsite_checkout => $onsite_checkout,
1520                 auto_renew      => $auto_renew ? 1 : 0,
1521             };
1522
1523             # In the case that the borrower has an on-site checkout
1524             # and SwitchOnSiteCheckouts is enabled this converts it to a regular checkout
1525             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1526             if ($issue) {
1527                 $issue->set($issue_attributes)->store;
1528             }
1529             else {
1530                 $issue = Koha::Checkout->new(
1531                     {
1532                         itemnumber => $item_object->itemnumber,
1533                         %$issue_attributes,
1534                     }
1535                 )->store;
1536             }
1537             if ( $item_object->location && $item_object->location eq 'CART'
1538                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1539             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1540                 CartToShelf( $item_object->itemnumber );
1541             }
1542
1543             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1544                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1545             }
1546
1547             # Record if item was lost
1548             my $was_lost = $item_object->itemlost;
1549
1550             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1551             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1552             $item_object->itemlost(0);
1553             $item_object->onloan($datedue->ymd());
1554             $item_object->datelastborrowed( dt_from_string()->ymd() );
1555             $item_object->datelastseen( dt_from_string()->ymd() );
1556             $item_object->store({log_action => 0});
1557
1558             # If the item was lost, it has now been found, charge the overdue if necessary
1559             if ($was_lost) {
1560                 if ( $item_object->{_charge} ) {
1561                     $actualissue //= Koha::Old::Checkouts->search(
1562                         { itemnumber => $item_unblessed->{itemnumber} },
1563                         {
1564                             order_by => { '-desc' => 'returndate' },
1565                             rows     => 1
1566                         }
1567                     )->single;
1568                     unless ( exists( $borrower->{branchcode} ) ) {
1569                         my $patron = $actualissue->patron;
1570                         $borrower = $patron->unblessed;
1571                     }
1572                     _CalculateAndUpdateFine(
1573                         {
1574                             issue       => $actualissue,
1575                             item        => $item_unblessed,
1576                             borrower    => $borrower,
1577                             return_date => $issuedate
1578                         }
1579                     );
1580                     _FixOverduesOnReturn( $borrower->{borrowernumber},
1581                         $item_object->itemnumber, undef, 'RENEWED' );
1582                 }
1583             }
1584
1585             # If it costs to borrow this book, charge it to the patron's account.
1586             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1587             if ( $charge && $charge > 0 ) {
1588                 AddIssuingCharge( $issue, $charge, 'RENT' );
1589             }
1590
1591             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1592             if ( $itemtype_object ) {
1593                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1594                 if ( $accumulate_charge > 0 ) {
1595                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1596                     $charge += $accumulate_charge;
1597                     $item_unblessed->{charge} = $charge;
1598                 }
1599             }
1600
1601             # Record the fact that this book was issued.
1602             &UpdateStats(
1603                 {
1604                     branch => C4::Context->userenv->{'branch'},
1605                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1606                     amount         => $charge,
1607                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1608                     itemnumber     => $item_object->itemnumber,
1609                     itemtype       => $item_object->effective_itemtype,
1610                     location       => $item_object->location,
1611                     borrowernumber => $borrower->{'borrowernumber'},
1612                     ccode          => $item_object->ccode,
1613                 }
1614             );
1615
1616             # Send a checkout slip.
1617             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1618             my %conditions        = (
1619                 branchcode   => $branchcode,
1620                 categorycode => $borrower->{categorycode},
1621                 item_type    => $item_object->effective_itemtype,
1622                 notification => 'CHECKOUT',
1623             );
1624             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1625                 SendCirculationAlert(
1626                     {
1627                         type     => 'CHECKOUT',
1628                         item     => $item_object->unblessed,
1629                         borrower => $borrower,
1630                         branch   => $branchcode,
1631                     }
1632                 );
1633             }
1634             logaction(
1635                 "CIRCULATION", "ISSUE",
1636                 $borrower->{'borrowernumber'},
1637                 $item_object->itemnumber,
1638             ) if C4::Context->preference("IssueLog");
1639
1640             Koha::Plugins->call('after_circ_action', {
1641                 action  => 'checkout',
1642                 payload => {
1643                     type     => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1644                     checkout => $issue->get_from_storage
1645                 }
1646             });
1647         }
1648     }
1649     return $issue;
1650 }
1651
1652 =head2 GetLoanLength
1653
1654   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1655
1656 Get loan length for an itemtype, a borrower type and a branch
1657
1658 =cut
1659
1660 sub GetLoanLength {
1661     my ( $categorycode, $itemtype, $branchcode ) = @_;
1662
1663     # Initialize default values
1664     my $rules = {
1665         issuelength   => 0,
1666         renewalperiod => 0,
1667         lengthunit    => 'days',
1668     };
1669
1670     my $found = Koha::CirculationRules->get_effective_rules( {
1671         branchcode => $branchcode,
1672         categorycode => $categorycode,
1673         itemtype => $itemtype,
1674         rules => [
1675             'issuelength',
1676             'renewalperiod',
1677             'lengthunit'
1678         ],
1679     } );
1680
1681     # Search for rules!
1682     foreach my $rule_name (keys %$found) {
1683         $rules->{$rule_name} = $found->{$rule_name};
1684     }
1685
1686     return $rules;
1687 }
1688
1689
1690 =head2 GetHardDueDate
1691
1692   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1693
1694 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1695
1696 =cut
1697
1698 sub GetHardDueDate {
1699     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1700
1701     my $rules = Koha::CirculationRules->get_effective_rules(
1702         {
1703             categorycode => $borrowertype,
1704             itemtype     => $itemtype,
1705             branchcode   => $branchcode,
1706             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1707         }
1708     );
1709
1710     if ( defined( $rules->{hardduedate} ) ) {
1711         if ( $rules->{hardduedate} ) {
1712             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1713         }
1714         else {
1715             return ( undef, undef );
1716         }
1717     }
1718 }
1719
1720 =head2 GetBranchBorrowerCircRule
1721
1722   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1723
1724 Retrieves circulation rule attributes that apply to the given
1725 branch and patron category, regardless of item type.
1726 The return value is a hashref containing the following key:
1727
1728 patron_maxissueqty - maximum number of loans that a
1729 patron of the given category can have at the given
1730 branch.  If the value is undef, no limit.
1731
1732 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1733 patron of the given category can have at the given
1734 branch.  If the value is undef, no limit.
1735
1736 This will check for different branch/category combinations in the following order:
1737 branch and category
1738 branch only
1739 category only
1740 default branch and category
1741
1742 If no rule has been found in the database, it will default to
1743 the buillt in rule:
1744
1745 patron_maxissueqty - undef
1746 patron_maxonsiteissueqty - undef
1747
1748 C<$branchcode> and C<$categorycode> should contain the
1749 literal branch code and patron category code, respectively - no
1750 wildcards.
1751
1752 =cut
1753
1754 sub GetBranchBorrowerCircRule {
1755     my ( $branchcode, $categorycode ) = @_;
1756
1757     # Initialize default values
1758     my $rules = {
1759         patron_maxissueqty       => undef,
1760         patron_maxonsiteissueqty => undef,
1761     };
1762
1763     # Search for rules!
1764     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1765         my $rule = Koha::CirculationRules->get_effective_rule(
1766             {
1767                 categorycode => $categorycode,
1768                 itemtype     => undef,
1769                 branchcode   => $branchcode,
1770                 rule_name    => $rule_name,
1771             }
1772         );
1773
1774         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1775     }
1776
1777     return $rules;
1778 }
1779
1780 =head2 GetBranchItemRule
1781
1782   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1783
1784 Retrieves circulation rule attributes that apply to the given
1785 branch and item type, regardless of patron category.
1786
1787 The return value is a hashref containing the following keys:
1788
1789 holdallowed => Hold policy for this branch and itemtype. Possible values:
1790   0: No holds allowed.
1791   1: Holds allowed only by patrons that have the same homebranch as the item.
1792   2: Holds allowed from any patron.
1793
1794 returnbranch => branch to which to return item.  Possible values:
1795   noreturn: do not return, let item remain where checked in (floating collections)
1796   homebranch: return to item's home branch
1797   holdingbranch: return to issuer branch
1798
1799 This searches branchitemrules in the following order:
1800
1801   * Same branchcode and itemtype
1802   * Same branchcode, itemtype '*'
1803   * branchcode '*', same itemtype
1804   * branchcode and itemtype '*'
1805
1806 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1807
1808 =cut
1809
1810 sub GetBranchItemRule {
1811     my ( $branchcode, $itemtype ) = @_;
1812
1813     # Search for rules!
1814     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1815         {
1816             branchcode => $branchcode,
1817             itemtype => $itemtype,
1818             rule_name => 'holdallowed',
1819         }
1820     );
1821     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1822         {
1823             branchcode => $branchcode,
1824             itemtype => $itemtype,
1825             rule_name => 'hold_fulfillment_policy',
1826         }
1827     );
1828     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1829         {
1830             branchcode => $branchcode,
1831             itemtype => $itemtype,
1832             rule_name => 'returnbranch',
1833         }
1834     );
1835
1836     # built-in default circulation rule
1837     my $rules;
1838     $rules->{holdallowed} = defined $holdallowed_rule
1839         ? $holdallowed_rule->rule_value
1840         : 2;
1841     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1842         ? $hold_fulfillment_policy_rule->rule_value
1843         : 'any';
1844     $rules->{returnbranch} = defined $returnbranch_rule
1845         ? $returnbranch_rule->rule_value
1846         : 'homebranch';
1847
1848     return $rules;
1849 }
1850
1851 =head2 AddReturn
1852
1853   ($doreturn, $messages, $iteminformation, $borrower) =
1854       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1855
1856 Returns a book.
1857
1858 =over 4
1859
1860 =item C<$barcode> is the bar code of the book being returned.
1861
1862 =item C<$branch> is the code of the branch where the book is being returned.
1863
1864 =item C<$exemptfine> indicates that overdue charges for the item will be
1865 removed. Optional.
1866
1867 =item C<$return_date> allows the default return date to be overridden
1868 by the given return date. Optional.
1869
1870 =back
1871
1872 C<&AddReturn> returns a list of four items:
1873
1874 C<$doreturn> is true iff the return succeeded.
1875
1876 C<$messages> is a reference-to-hash giving feedback on the operation.
1877 The keys of the hash are:
1878
1879 =over 4
1880
1881 =item C<BadBarcode>
1882
1883 No item with this barcode exists. The value is C<$barcode>.
1884
1885 =item C<NotIssued>
1886
1887 The book is not currently on loan. The value is C<$barcode>.
1888
1889 =item C<withdrawn>
1890
1891 This book has been withdrawn/cancelled. The value should be ignored.
1892
1893 =item C<Wrongbranch>
1894
1895 This book has was returned to the wrong branch.  The value is a hashref
1896 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1897 contain the branchcode of the incorrect and correct return library, respectively.
1898
1899 =item C<ResFound>
1900
1901 The item was reserved. The value is a reference-to-hash whose keys are
1902 fields from the reserves table of the Koha database, and
1903 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1904 either C<Waiting>, C<Reserved>, or 0.
1905
1906 =item C<WasReturned>
1907
1908 Value 1 if return is successful.
1909
1910 =item C<NeedsTransfer>
1911
1912 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1913
1914 =back
1915
1916 C<$iteminformation> is a reference-to-hash, giving information about the
1917 returned item from the issues table.
1918
1919 C<$borrower> is a reference-to-hash, giving information about the
1920 patron who last borrowed the book.
1921
1922 =cut
1923
1924 sub AddReturn {
1925     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1926
1927     if ($branch and not Koha::Libraries->find($branch)) {
1928         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1929         undef $branch;
1930     }
1931     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1932     my $return_date_specified = !!$return_date;
1933     $return_date //= dt_from_string();
1934     my $messages;
1935     my $patron;
1936     my $doreturn       = 1;
1937     my $validTransfer = 1;
1938     my $stat_type = 'return';
1939
1940     # get information on item
1941     my $item = Koha::Items->find({ barcode => $barcode });
1942     unless ($item) {
1943         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1944     }
1945
1946     my $itemnumber = $item->itemnumber;
1947     my $itemtype = $item->effective_itemtype;
1948
1949     my $issue  = $item->checkout;
1950     if ( $issue ) {
1951         $patron = $issue->patron
1952             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1953                 . Dumper($issue->unblessed) . "\n";
1954     } else {
1955         $messages->{'NotIssued'} = $barcode;
1956         $item->onloan(undef)->store({skip_record_index=>1}) if defined $item->onloan;
1957
1958         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1959         $doreturn = 0;
1960         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1961         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1962         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1963            $messages->{'LocalUse'} = 1;
1964            $stat_type = 'localuse';
1965         }
1966     }
1967
1968         # full item data, but no borrowernumber or checkout info (no issue)
1969     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1970         # get the proper branch to which to return the item
1971     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1972         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1973     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1974
1975     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1976     my $patron_unblessed = $patron ? $patron->unblessed : {};
1977
1978     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1979     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1980     if ($update_loc_rules) {
1981         if (defined $update_loc_rules->{_ALL_}) {
1982             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1983             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1984             if ( defined $item->location && $item->location ne $update_loc_rules->{_ALL_}) {
1985                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1986                 $item->location($update_loc_rules->{_ALL_})->store({skip_record_index=>1});
1987             }
1988         }
1989         else {
1990             foreach my $key ( keys %$update_loc_rules ) {
1991                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1992                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1993                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1994                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1995                     $item->location($update_loc_rules->{$key})->store({skip_record_index=>1});
1996                     last;
1997                 }
1998             }
1999         }
2000     }
2001
2002     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
2003     if ($yaml) {
2004         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
2005         my $rules;
2006         eval { $rules = YAML::Load($yaml); };
2007         if ($@) {
2008             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
2009         }
2010         else {
2011             foreach my $key ( keys %$rules ) {
2012                 if ( $item->notforloan eq $key ) {
2013                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
2014                     $item->notforloan($rules->{$key})->store({ log_action => 0, skip_record_index => 1 });
2015                     last;
2016                 }
2017             }
2018         }
2019     }
2020
2021     # check if the return is allowed at this branch
2022     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
2023     unless ($returnallowed){
2024         $messages->{'Wrongbranch'} = {
2025             Wrongbranch => $branch,
2026             Rightbranch => $message
2027         };
2028         $doreturn = 0;
2029         my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2030         $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2031         return ( $doreturn, $messages, $issue, $patron_unblessed);
2032     }
2033
2034     if ( $item->withdrawn ) { # book has been cancelled
2035         $messages->{'withdrawn'} = 1;
2036         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
2037     }
2038
2039     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
2040         $doreturn = 0;
2041     }
2042
2043     # case of a return of document (deal with issues and holdingbranch)
2044     if ($doreturn) {
2045         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
2046         $patron or warn "AddReturn without current borrower";
2047
2048         if ($patron) {
2049             eval {
2050                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy, { skip_record_index => 1} );
2051             };
2052             unless ( $@ ) {
2053                 if (
2054                     (
2055                         C4::Context->preference('CalculateFinesOnReturn')
2056                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2057                     )
2058                     && !$item->itemlost
2059                   )
2060                 {
2061                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2062                 }
2063             } else {
2064                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
2065
2066                 my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2067                 $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2068
2069                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2070             }
2071
2072             # FIXME is the "= 1" right?  This could be the borrower hash.
2073             $messages->{'WasReturned'} = 1;
2074
2075         } else {
2076             $item->onloan(undef)->store({ log_action => 0 , skip_record_index => 1 });
2077         }
2078     }
2079
2080     # the holdingbranch is updated if the document is returned to another location.
2081     # this is always done regardless of whether the item was on loan or not
2082     if ($item->holdingbranch ne $branch) {
2083         $item->holdingbranch($branch)->store({ skip_record_index => 1 });
2084     }
2085
2086     my $item_was_lost = $item->itemlost;
2087     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2088     my $updated_item = ModDateLastSeen( $item->itemnumber, $leave_item_lost, { skip_record_index => 1 } ); # will unset itemlost if needed
2089
2090     # fix up the accounts.....
2091     if ($item_was_lost) {
2092         $messages->{'WasLost'} = 1;
2093         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2094             $messages->{'LostItemFeeRefunded'} = $updated_item->{_refunded};
2095             $messages->{'LostItemFeeRestored'} = $updated_item->{_restored};
2096
2097             if ( $updated_item->{_charge} ) {
2098                 $issue //= Koha::Old::Checkouts->search(
2099                     { itemnumber => $item->itemnumber },
2100                     { order_by   => { '-desc' => 'returndate' }, rows => 1 } )
2101                   ->single;
2102                 unless ( exists( $patron_unblessed->{branchcode} ) ) {
2103                     my $patron = $issue->patron;
2104                     $patron_unblessed = $patron->unblessed;
2105                 }
2106                 _CalculateAndUpdateFine(
2107                     {
2108                         issue       => $issue,
2109                         item        => $item->unblessed,
2110                         borrower    => $patron_unblessed,
2111                         return_date => $return_date
2112                     }
2113                 );
2114                 _FixOverduesOnReturn( $patron_unblessed->{borrowernumber},
2115                     $item->itemnumber, undef, 'RETURNED' );
2116                 $messages->{'LostItemFeeCharged'} = 1;
2117             }
2118         }
2119     }
2120
2121     # check if we have a transfer for this document
2122     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2123
2124     # if we have a transfer to complete, we update the line of transfers with the datearrived
2125     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2126     if ($datesent) {
2127         # At this point we will either fill the transfer or it is a wrong transfer
2128         # either way we should not now generate a new transfer
2129         $validTransfer = 0;
2130         if ( $tobranch eq $branch ) {
2131             my $sth = C4::Context->dbh->prepare(
2132                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2133             );
2134             $sth->execute( $item->itemnumber );
2135             $messages->{'TransferArrived'} = $frombranch;
2136         } else {
2137             $messages->{'WrongTransfer'}     = $tobranch;
2138             $messages->{'WrongTransferItem'} = $item->itemnumber;
2139         }
2140     }
2141
2142     # fix up the overdues in accounts...
2143     if ($borrowernumber) {
2144         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2145         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2146
2147         if ( $issue and $issue->is_overdue($return_date) ) {
2148         # fix fine days
2149             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2150             if ($reminder){
2151                 $messages->{'PrevDebarred'} = $debardate;
2152             } else {
2153                 $messages->{'Debarred'} = $debardate if $debardate;
2154             }
2155         # there's no overdue on the item but borrower had been previously debarred
2156         } elsif ( $issue->date_due and $patron->debarred ) {
2157              if ( $patron->debarred eq "9999-12-31") {
2158                 $messages->{'ForeverDebarred'} = $patron->debarred;
2159              } else {
2160                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2161                   $borrower_debar_dt->truncate(to => 'day');
2162                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2163                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2164                       $messages->{'PrevDebarred'} = $patron->debarred;
2165                   }
2166              }
2167         }
2168     }
2169
2170     # find reserves.....
2171     # launch the Checkreserves routine to find any holds
2172     my ($resfound, $resrec);
2173     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2174     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2175     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2176     if ( $resfound and $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2177         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2178         $resfound = 'Reserved';
2179         $resrec = $hold->unblessed;
2180     }
2181     if ($resfound) {
2182           $resrec->{'ResFound'} = $resfound;
2183         $messages->{'ResFound'} = $resrec;
2184     }
2185
2186     # Record the fact that this book was returned.
2187     UpdateStats({
2188         branch         => $branch,
2189         type           => $stat_type,
2190         itemnumber     => $itemnumber,
2191         itemtype       => $itemtype,
2192         location       => $item->location,
2193         borrowernumber => $borrowernumber,
2194         ccode          => $item->ccode,
2195     });
2196
2197     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2198     if ( $patron ) {
2199         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2200         my %conditions = (
2201             branchcode   => $branch,
2202             categorycode => $patron->categorycode,
2203             item_type    => $itemtype,
2204             notification => 'CHECKIN',
2205         );
2206         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2207             SendCirculationAlert({
2208                 type     => 'CHECKIN',
2209                 item     => $item->unblessed,
2210                 borrower => $patron->unblessed,
2211                 branch   => $branch,
2212             });
2213         }
2214
2215         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2216             if C4::Context->preference("ReturnLog");
2217         }
2218
2219     # Check if this item belongs to a biblio record that is attached to an
2220     # ILL request, if it is we need to update the ILL request's status
2221     if ( $doreturn and C4::Context->preference('CirculateILL')) {
2222         my $request = Koha::Illrequests->find(
2223             { biblio_id => $item->biblio->biblionumber }
2224         );
2225         $request->status('RET') if $request;
2226     }
2227
2228     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2229     if ($validTransfer && !$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) ){
2230         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2231         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2232             (C4::Context->preference("UseBranchTransferLimits") and
2233              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2234            )) {
2235             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2236             $debug and warn "item: " . Dumper($item->unblessed);
2237             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger, { skip_record_index => 1 });
2238             $messages->{'WasTransfered'} = 1;
2239         } else {
2240             $messages->{'NeedsTransfer'} = $returnbranch;
2241             $messages->{'TransferTrigger'} = $transfer_trigger;
2242         }
2243     }
2244
2245     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2246         my $claims = Koha::Checkouts::ReturnClaims->search(
2247            {
2248                itemnumber => $item->id,
2249                resolution => undef,
2250            }
2251         );
2252
2253         if ( $claims->count ) {
2254             $messages->{ReturnClaims} = $claims;
2255         }
2256     }
2257
2258     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
2259     $indexer->index_records( $item->biblionumber, "specialUpdate", "biblioserver" );
2260
2261     if ( $doreturn and $issue ) {
2262         my $checkin = Koha::Old::Checkouts->find($issue->id);
2263
2264         Koha::Plugins->call('after_circ_action', {
2265             action  => 'checkin',
2266             payload => {
2267                 checkout=> $checkin
2268             }
2269         });
2270     }
2271
2272     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2273 }
2274
2275 =head2 MarkIssueReturned
2276
2277   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy, [$params] );
2278
2279 Unconditionally marks an issue as being returned by
2280 moving the C<issues> row to C<old_issues> and
2281 setting C<returndate> to the current date.
2282
2283 if C<$returndate> is specified (in iso format), it is used as the date
2284 of the return.
2285
2286 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2287 the old_issue is immediately anonymised
2288
2289 Ideally, this function would be internal to C<C4::Circulation>,
2290 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2291 and offline_circ/process_koc.pl.
2292
2293 The last optional parameter allos passing skip_record_index to the item store call.
2294
2295 =cut
2296
2297 sub MarkIssueReturned {
2298     my ( $borrowernumber, $itemnumber, $returndate, $privacy, $params ) = @_;
2299
2300     # Retrieve the issue
2301     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2302
2303     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2304
2305     my $issue_id = $issue->issue_id;
2306
2307     my $anonymouspatron;
2308     if ( $privacy && $privacy == 2 ) {
2309         # The default of 0 will not work due to foreign key constraints
2310         # The anonymisation will fail if AnonymousPatron is not a valid entry
2311         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2312         # Note that a warning should appear on the about page (System information tab).
2313         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2314         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2315             unless Koha::Patrons->find( $anonymouspatron );
2316     }
2317
2318     my $schema = Koha::Database->schema;
2319
2320     # FIXME Improve the return value and handle it from callers
2321     $schema->txn_do(sub {
2322
2323         my $patron = Koha::Patrons->find( $borrowernumber );
2324
2325         # Update the returndate value
2326         if ( $returndate ) {
2327             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2328         }
2329         else {
2330             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2331         }
2332
2333         # Create the old_issues entry
2334         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2335
2336         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2337         if ( $privacy && $privacy == 2) {
2338             $old_checkout->borrowernumber($anonymouspatron)->store;
2339         }
2340
2341         # And finally delete the issue
2342         $issue->delete;
2343
2344         $issue->item->onloan(undef)->store({ log_action => 0, skip_record_index => $params->{skip_record_index} });
2345
2346         if ( C4::Context->preference('StoreLastBorrower') ) {
2347             my $item = Koha::Items->find( $itemnumber );
2348             $item->last_returned_by( $patron );
2349         }
2350
2351         # Remove any OVERDUES related debarment if the borrower has no overdues
2352         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2353           && $patron->debarred
2354           && !$patron->has_overdues
2355           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2356         ) {
2357             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2358         }
2359
2360     });
2361
2362     return $issue_id;
2363 }
2364
2365 =head2 _debar_user_on_return
2366
2367     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2368
2369 C<$borrower> borrower hashref
2370
2371 C<$item> item hashref
2372
2373 C<$datedue> date due DateTime object
2374
2375 C<$returndate> DateTime object representing the return time
2376
2377 Internal function, called only by AddReturn that calculates and updates
2378  the user fine days, and debars them if necessary.
2379
2380 Should only be called for overdue returns
2381
2382 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2383 to ease testing.
2384
2385 =cut
2386
2387 sub _calculate_new_debar_dt {
2388     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2389
2390     my $branchcode = _GetCircControlBranch( $item, $borrower );
2391     my $circcontrol = C4::Context->preference('CircControl');
2392     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2393         {   categorycode => $borrower->{categorycode},
2394             itemtype     => $item->{itype},
2395             branchcode   => $branchcode,
2396             rules => [
2397                 'finedays',
2398                 'lengthunit',
2399                 'firstremind',
2400                 'maxsuspensiondays',
2401                 'suspension_chargeperiod',
2402             ]
2403         }
2404     );
2405     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2406     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2407     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2408
2409     return unless $finedays;
2410
2411     # finedays is in days, so hourly loans must multiply by 24
2412     # thus 1 hour late equals 1 day suspension * finedays rate
2413     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2414
2415     # grace period is measured in the same units as the loan
2416     my $grace =
2417       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} // 0);
2418
2419     my $deltadays = DateTime::Duration->new(
2420         days => $chargeable_units
2421     );
2422
2423     if ( $deltadays->subtract($grace)->is_positive() ) {
2424         my $suspension_days = $deltadays * $finedays;
2425
2426         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2427             # No need to / 1 and do not consider / 0
2428             $suspension_days = DateTime::Duration->new(
2429                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2430             );
2431         }
2432
2433         # If the max suspension days is < than the suspension days
2434         # the suspension days is limited to this maximum period.
2435         my $max_sd = $issuing_rule->{maxsuspensiondays};
2436         if ( defined $max_sd && $max_sd ne '' ) {
2437             $max_sd = DateTime::Duration->new( days => $max_sd );
2438             $suspension_days = $max_sd
2439               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2440         }
2441
2442         my ( $has_been_extended );
2443         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2444             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2445             if ( $debarment ) {
2446                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2447                 $has_been_extended = 1;
2448             }
2449         }
2450
2451         my $new_debar_dt;
2452         # Use the calendar or not to calculate the debarment date
2453         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2454             my $calendar = Koha::Calendar->new(
2455                 branchcode => $branchcode,
2456                 days_mode  => 'Calendar'
2457             );
2458             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2459         }
2460         else {
2461             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2462         }
2463         return $new_debar_dt;
2464     }
2465     return;
2466 }
2467
2468 sub _debar_user_on_return {
2469     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2470
2471     $return_date //= dt_from_string();
2472
2473     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2474
2475     return unless $new_debar_dt;
2476
2477     Koha::Patron::Debarments::AddUniqueDebarment({
2478         borrowernumber => $borrower->{borrowernumber},
2479         expiration     => $new_debar_dt->ymd(),
2480         type           => 'SUSPENSION',
2481     });
2482     # if borrower was already debarred but does not get an extra debarment
2483     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2484     my ($new_debarment_str, $is_a_reminder);
2485     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2486         $is_a_reminder = 1;
2487         $new_debarment_str = $borrower->{debarred};
2488     } else {
2489         $new_debarment_str = $new_debar_dt->ymd();
2490     }
2491     # FIXME Should return a DateTime object
2492     return $new_debarment_str, $is_a_reminder;
2493 }
2494
2495 =head2 _FixOverduesOnReturn
2496
2497    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2498
2499 C<$borrowernumber> borrowernumber
2500
2501 C<$itemnumber> itemnumber
2502
2503 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2504
2505 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2506
2507 Internal function
2508
2509 =cut
2510
2511 sub _FixOverduesOnReturn {
2512     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2513     unless( $borrowernumber ) {
2514         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2515         return;
2516     }
2517     unless( $item ) {
2518         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2519         return;
2520     }
2521     unless( $status ) {
2522         warn "_FixOverduesOnReturn() not supplied valid status";
2523         return;
2524     }
2525
2526     my $schema = Koha::Database->schema;
2527
2528     my $result = $schema->txn_do(
2529         sub {
2530             # check for overdue fine
2531             my $accountlines = Koha::Account::Lines->search(
2532                 {
2533                     borrowernumber  => $borrowernumber,
2534                     itemnumber      => $item,
2535                     debit_type_code => 'OVERDUE',
2536                     status          => 'UNRETURNED'
2537                 }
2538             );
2539             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2540
2541             my $accountline = $accountlines->next;
2542             my $payments = $accountline->credits;
2543
2544             my $amountoutstanding = $accountline->amountoutstanding;
2545             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2546                 $accountline->delete;
2547                 return 0; # no warning, we've just removed a zero value fine (backdated return)
2548             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2549                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2550                 my $credit = $account->add_credit(
2551                     {
2552                         amount     => $amountoutstanding,
2553                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2554                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2555                         interface  => C4::Context->interface,
2556                         type       => 'FORGIVEN',
2557                         item_id    => $item
2558                     }
2559                 );
2560
2561                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2562
2563                 if (C4::Context->preference("FinesLog")) {
2564                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2565                 }
2566             }
2567
2568             $accountline->status($status);
2569             return $accountline->store();
2570         }
2571     );
2572
2573     return $result;
2574 }
2575
2576 =head2 _GetCircControlBranch
2577
2578    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2579
2580 Internal function :
2581
2582 Return the library code to be used to determine which circulation
2583 policy applies to a transaction.  Looks up the CircControl and
2584 HomeOrHoldingBranch system preferences.
2585
2586 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2587
2588 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2589
2590 =cut
2591
2592 sub _GetCircControlBranch {
2593     my ($item, $borrower) = @_;
2594     my $circcontrol = C4::Context->preference('CircControl');
2595     my $branch;
2596
2597     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2598         $branch= C4::Context->userenv->{'branch'};
2599     } elsif ($circcontrol eq 'PatronLibrary') {
2600         $branch=$borrower->{branchcode};
2601     } else {
2602         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2603         $branch = $item->{$branchfield};
2604         # default to item home branch if holdingbranch is used
2605         # and is not defined
2606         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2607             $branch = $item->{homebranch};
2608         }
2609     }
2610     return $branch;
2611 }
2612
2613 =head2 GetOpenIssue
2614
2615   $issue = GetOpenIssue( $itemnumber );
2616
2617 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2618
2619 C<$itemnumber> is the item's itemnumber
2620
2621 Returns a hashref
2622
2623 =cut
2624
2625 sub GetOpenIssue {
2626   my ( $itemnumber ) = @_;
2627   return unless $itemnumber;
2628   my $dbh = C4::Context->dbh;
2629   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2630   $sth->execute( $itemnumber );
2631   return $sth->fetchrow_hashref();
2632
2633 }
2634
2635 =head2 GetBiblioIssues
2636
2637   $issues = GetBiblioIssues($biblionumber);
2638
2639 this function get all issues from a biblionumber.
2640
2641 Return:
2642 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2643 tables issues and the firstname,surname & cardnumber from borrowers.
2644
2645 =cut
2646
2647 sub GetBiblioIssues {
2648     my $biblionumber = shift;
2649     return unless $biblionumber;
2650     my $dbh   = C4::Context->dbh;
2651     my $query = "
2652         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2653         FROM issues
2654             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2655             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2656             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2657             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2658         WHERE biblio.biblionumber = ?
2659         UNION ALL
2660         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2661         FROM old_issues
2662             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2663             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2664             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2665             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2666         WHERE biblio.biblionumber = ?
2667         ORDER BY timestamp
2668     ";
2669     my $sth = $dbh->prepare($query);
2670     $sth->execute($biblionumber, $biblionumber);
2671
2672     my @issues;
2673     while ( my $data = $sth->fetchrow_hashref ) {
2674         push @issues, $data;
2675     }
2676     return \@issues;
2677 }
2678
2679 =head2 GetUpcomingDueIssues
2680
2681   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2682
2683 =cut
2684
2685 sub GetUpcomingDueIssues {
2686     my $params = shift;
2687
2688     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2689     my $dbh = C4::Context->dbh;
2690
2691     my $statement = <<END_SQL;
2692 SELECT *
2693 FROM (
2694     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2695     FROM issues
2696     LEFT JOIN items USING (itemnumber)
2697     LEFT OUTER JOIN branches USING (branchcode)
2698     WHERE returndate is NULL
2699 ) tmp
2700 WHERE days_until_due >= 0 AND days_until_due <= ?
2701 END_SQL
2702
2703     my @bind_parameters = ( $params->{'days_in_advance'} );
2704
2705     my $sth = $dbh->prepare( $statement );
2706     $sth->execute( @bind_parameters );
2707     my $upcoming_dues = $sth->fetchall_arrayref({});
2708
2709     return $upcoming_dues;
2710 }
2711
2712 =head2 CanBookBeRenewed
2713
2714   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2715
2716 Find out whether a borrowed item may be renewed.
2717
2718 C<$borrowernumber> is the borrower number of the patron who currently
2719 has the item on loan.
2720
2721 C<$itemnumber> is the number of the item to renew.
2722
2723 C<$override_limit>, if supplied with a true value, causes
2724 the limit on the number of times that the loan can be renewed
2725 (as controlled by the item type) to be ignored. Overriding also allows
2726 to renew sooner than "No renewal before" and to manually renew loans
2727 that are automatically renewed.
2728
2729 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2730 item must currently be on loan to the specified borrower; renewals
2731 must be allowed for the item's type; and the borrower must not have
2732 already renewed the loan. $error will contain the reason the renewal can not proceed
2733
2734 =cut
2735
2736 sub CanBookBeRenewed {
2737     my ( $borrowernumber, $itemnumber, $override_limit, $cron ) = @_;
2738
2739     my $dbh    = C4::Context->dbh;
2740     my $renews = 1;
2741     my $auto_renew = "no";
2742
2743     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2744     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2745     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2746     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2747
2748     my $patron = $issue->patron or return;
2749
2750     # override_limit will override anything else except on_reserve
2751     unless ( $override_limit ){
2752         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2753         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2754             {
2755                 categorycode => $patron->categorycode,
2756                 itemtype     => $item->effective_itemtype,
2757                 branchcode   => $branchcode,
2758                 rules => [
2759                     'renewalsallowed',
2760                     'no_auto_renewal_after',
2761                     'no_auto_renewal_after_hard_limit',
2762                     'lengthunit',
2763                     'norenewalbefore',
2764                 ]
2765             }
2766         );
2767
2768         return ( 0, "too_many" )
2769           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2770
2771         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2772         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2773         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2774         my $restricted  = $patron->is_debarred;
2775         my $hasoverdues = $patron->has_overdues;
2776
2777         if ( $restricted and $restrictionblockrenewing ) {
2778             return ( 0, 'restriction');
2779         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2780             return ( 0, 'overdue');
2781         }
2782
2783         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2784
2785             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2786                 return ( 0, 'auto_account_expired' );
2787             }
2788
2789             if ( defined $issuing_rule->{no_auto_renewal_after}
2790                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2791                 # Get issue_date and add no_auto_renewal_after
2792                 # If this is greater than today, it's too late for renewal.
2793                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2794                 $maximum_renewal_date->add(
2795                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2796                 );
2797                 my $now = dt_from_string;
2798                 if ( $now >= $maximum_renewal_date ) {
2799                     return ( 0, "auto_too_late" );
2800                 }
2801             }
2802             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2803                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2804                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2805                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2806                     return ( 0, "auto_too_late" );
2807                 }
2808             }
2809
2810             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2811                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2812                 my $amountoutstanding =
2813                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2814                   ? $patron->account->balance
2815                   : $patron->account->outstanding_debits->total_outstanding;
2816                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2817                     return ( 0, "auto_too_much_oweing" );
2818                 }
2819             }
2820         }
2821
2822         if ( defined $issuing_rule->{norenewalbefore}
2823             and $issuing_rule->{norenewalbefore} ne "" )
2824         {
2825
2826             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2827             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2828                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2829
2830             # Depending on syspref reset the exact time, only check the date
2831             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2832                 and $issuing_rule->{lengthunit} eq 'days' )
2833             {
2834                 $soonestrenewal->truncate( to => 'day' );
2835             }
2836
2837             if ( $soonestrenewal > dt_from_string() )
2838             {
2839                 $auto_renew = ($issue->auto_renew && $patron->autorenew_checkouts) ? "auto_too_soon" : "too_soon";
2840             }
2841             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2842                 $auto_renew = "ok";
2843             }
2844         }
2845
2846         # Fallback for automatic renewals:
2847         # If norenewalbefore is undef, don't renew before due date.
2848         if ( $issue->auto_renew && $auto_renew eq "no" && $patron->autorenew_checkouts ) {
2849             my $now = dt_from_string;
2850             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2851                 $auto_renew = "ok";
2852             } else {
2853                 $auto_renew = "auto_too_soon";
2854             }
2855         }
2856     }
2857
2858     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2859
2860     # If next hold is non priority, then check if any hold with priority (non_priority = 0) exists for the same biblionumber.
2861     if ( $resfound && $resrec->{non_priority} ) {
2862         $resfound = Koha::Holds->search(
2863             { biblionumber => $resrec->{biblionumber}, non_priority => 0 } )
2864           ->count > 0;
2865     }
2866
2867
2868
2869     # This item can fill one or more unfilled reserve, can those unfilled reserves
2870     # all be filled by other available items?
2871     if ( $resfound
2872         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2873     {
2874         my $schema = Koha::Database->new()->schema();
2875
2876         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2877         if ($item_holds) {
2878             # There is an item level hold on this item, no other item can fill the hold
2879             $resfound = 1;
2880         }
2881         else {
2882
2883             # Get all other items that could possibly fill reserves
2884             my @itemnumbers = $schema->resultset('Item')->search(
2885                 {
2886                     biblionumber => $resrec->{biblionumber},
2887                     onloan       => undef,
2888                     notforloan   => 0,
2889                     -not         => { itemnumber => $itemnumber }
2890                 },
2891                 { columns => 'itemnumber' }
2892             )->get_column('itemnumber')->all();
2893
2894             # Get all other reserves that could have been filled by this item
2895             my @borrowernumbers;
2896             while (1) {
2897                 my ( $reserve_found, $reserve, undef ) =
2898                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2899
2900                 if ($reserve_found) {
2901                     push( @borrowernumbers, $reserve->{borrowernumber} );
2902                 }
2903                 else {
2904                     last;
2905                 }
2906             }
2907
2908             # If the count of the union of the lists of reservable items for each borrower
2909             # is equal or greater than the number of borrowers, we know that all reserves
2910             # can be filled with available items. We can get the union of the sets simply
2911             # by pushing all the elements onto an array and removing the duplicates.
2912             my @reservable;
2913             my %patrons;
2914             ITEM: foreach my $itemnumber (@itemnumbers) {
2915                 my $item = Koha::Items->find( $itemnumber );
2916                 next if IsItemOnHoldAndFound( $itemnumber );
2917                 for my $borrowernumber (@borrowernumbers) {
2918                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2919                     next unless IsAvailableForItemLevelRequest($item, $patron);
2920                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2921
2922                     push @reservable, $itemnumber;
2923                     if (@reservable >= @borrowernumbers) {
2924                         $resfound = 0;
2925                         last ITEM;
2926                     }
2927                     last;
2928                 }
2929             }
2930         }
2931     }
2932     if( $cron ) { #The cron wants to return 'too_soon' over 'on_reserve'
2933         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2934         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2935     } else { # For other purposes we want 'on_reserve' before 'too_soon'
2936         return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2937         return ( 0, $auto_renew  ) if $auto_renew =~ 'too_soon';#$auto_renew ne "no" && $auto_renew ne "ok";
2938     }
2939
2940     return ( 0, "auto_renew" ) if $auto_renew eq "ok" && !$override_limit; # 0 if auto-renewal should not succeed
2941
2942     return ( 1, undef );
2943 }
2944
2945 =head2 AddRenewal
2946
2947   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2948
2949 Renews a loan.
2950
2951 C<$borrowernumber> is the borrower number of the patron who currently
2952 has the item.
2953
2954 C<$itemnumber> is the number of the item to renew.
2955
2956 C<$branch> is the library where the renewal took place (if any).
2957            The library that controls the circ policies for the renewal is retrieved from the issues record.
2958
2959 C<$datedue> can be a DateTime object used to set the due date.
2960
2961 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2962 this parameter is not supplied, lastreneweddate is set to the current date.
2963
2964 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2965 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2966 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2967 syspref)
2968
2969 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2970 from the book's item type.
2971
2972 =cut
2973
2974 sub AddRenewal {
2975     my $borrowernumber  = shift;
2976     my $itemnumber      = shift or return;
2977     my $branch          = shift;
2978     my $datedue         = shift;
2979     my $lastreneweddate = shift || dt_from_string();
2980     my $skipfinecalc    = shift;
2981
2982     my $item_object   = Koha::Items->find($itemnumber) or return;
2983     my $biblio = $item_object->biblio;
2984     my $issue  = $item_object->checkout;
2985     my $item_unblessed = $item_object->unblessed;
2986
2987     my $dbh = C4::Context->dbh;
2988
2989     return unless $issue;
2990
2991     $borrowernumber ||= $issue->borrowernumber;
2992
2993     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2994         carp 'Invalid date passed to AddRenewal.';
2995         return;
2996     }
2997
2998     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
2999     my $patron_unblessed = $patron->unblessed;
3000
3001     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3002
3003     my $schema = Koha::Database->schema;
3004     $schema->txn_do(sub{
3005
3006         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3007             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3008         }
3009         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3010
3011         # If the due date wasn't specified, calculate it by adding the
3012         # book's loan length to today's date or the current due date
3013         # based on the value of the RenewalPeriodBase syspref.
3014         my $itemtype = $item_object->effective_itemtype;
3015         unless ($datedue) {
3016
3017             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3018                                             dt_from_string( $issue->date_due, 'sql' ) :
3019                                             dt_from_string();
3020             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3021         }
3022
3023         my $fees = Koha::Charges::Fees->new(
3024             {
3025                 patron    => $patron,
3026                 library   => $circ_library,
3027                 item      => $item_object,
3028                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3029                 to_date   => dt_from_string($datedue),
3030             }
3031         );
3032
3033         # Update the issues record to have the new due date, and a new count
3034         # of how many times it has been renewed.
3035         my $renews = ( $issue->renewals || 0 ) + 1;
3036         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
3037                                 WHERE borrowernumber=?
3038                                 AND itemnumber=?"
3039         );
3040
3041         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
3042
3043         # Update the renewal count on the item, and tell zebra to reindex
3044         $renews = ( $item_object->renewals || 0 ) + 1;
3045         $item_object->renewals($renews);
3046         $item_object->onloan($datedue);
3047         $item_object->store({ log_action => 0 });
3048
3049         # Charge a new rental fee, if applicable
3050         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3051         if ( $charge > 0 ) {
3052             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3053         }
3054
3055         # Charge a new accumulate rental fee, if applicable
3056         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3057         if ( $itemtype_object ) {
3058             my $accumulate_charge = $fees->accumulate_rentalcharge();
3059             if ( $accumulate_charge > 0 ) {
3060                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3061             }
3062             $charge += $accumulate_charge;
3063         }
3064
3065         # Send a renewal slip according to checkout alert preferencei
3066         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3067             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3068             my %conditions        = (
3069                 branchcode   => $branch,
3070                 categorycode => $patron->categorycode,
3071                 item_type    => $itemtype,
3072                 notification => 'CHECKOUT',
3073             );
3074             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3075                 SendCirculationAlert(
3076                     {
3077                         type     => 'RENEWAL',
3078                         item     => $item_unblessed,
3079                         borrower => $patron->unblessed,
3080                         branch   => $branch,
3081                     }
3082                 );
3083             }
3084         }
3085
3086         # Remove any OVERDUES related debarment if the borrower has no overdues
3087         if ( $patron
3088           && $patron->is_debarred
3089           && ! $patron->has_overdues
3090           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3091         ) {
3092             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3093         }
3094
3095         # Add the renewal to stats
3096         UpdateStats(
3097             {
3098                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3099                 type           => 'renew',
3100                 amount         => $charge,
3101                 itemnumber     => $itemnumber,
3102                 itemtype       => $itemtype,
3103                 location       => $item_object->location,
3104                 borrowernumber => $borrowernumber,
3105                 ccode          => $item_object->ccode,
3106             }
3107         );
3108
3109         #Log the renewal
3110         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3111
3112         Koha::Plugins->call('after_circ_action', {
3113             action  => 'renewal',
3114             payload => {
3115                 checkout  => $issue->get_from_storage
3116             }
3117         });
3118     });
3119
3120     return $datedue;
3121 }
3122
3123 sub GetRenewCount {
3124     # check renewal status
3125     my ( $bornum, $itemno ) = @_;
3126     my $dbh           = C4::Context->dbh;
3127     my $renewcount    = 0;
3128     my $renewsallowed = 0;
3129     my $renewsleft    = 0;
3130
3131     my $patron = Koha::Patrons->find( $bornum );
3132     my $item   = Koha::Items->find($itemno);
3133
3134     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3135
3136     # Look in the issues table for this item, lent to this borrower,
3137     # and not yet returned.
3138
3139     # FIXME - I think this function could be redone to use only one SQL call.
3140     my $sth = $dbh->prepare(
3141         "select * from issues
3142                                 where (borrowernumber = ?)
3143                                 and (itemnumber = ?)"
3144     );
3145     $sth->execute( $bornum, $itemno );
3146     my $data = $sth->fetchrow_hashref;
3147     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3148     # $item and $borrower should be calculated
3149     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3150
3151     my $rule = Koha::CirculationRules->get_effective_rule(
3152         {
3153             categorycode => $patron->categorycode,
3154             itemtype     => $item->effective_itemtype,
3155             branchcode   => $branchcode,
3156             rule_name    => 'renewalsallowed',
3157         }
3158     );
3159
3160     $renewsallowed = $rule ? $rule->rule_value : 0;
3161     $renewsleft    = $renewsallowed - $renewcount;
3162     if($renewsleft < 0){ $renewsleft = 0; }
3163     return ( $renewcount, $renewsallowed, $renewsleft );
3164 }
3165
3166 =head2 GetSoonestRenewDate
3167
3168   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3169
3170 Find out the soonest possible renew date of a borrowed item.
3171
3172 C<$borrowernumber> is the borrower number of the patron who currently
3173 has the item on loan.
3174
3175 C<$itemnumber> is the number of the item to renew.
3176
3177 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3178 renew date, based on the value "No renewal before" of the applicable
3179 issuing rule. Returns the current date if the item can already be
3180 renewed, and returns undefined if the borrower, loan, or item
3181 cannot be found.
3182
3183 =cut
3184
3185 sub GetSoonestRenewDate {
3186     my ( $borrowernumber, $itemnumber ) = @_;
3187
3188     my $dbh = C4::Context->dbh;
3189
3190     my $item      = Koha::Items->find($itemnumber)      or return;
3191     my $itemissue = $item->checkout or return;
3192
3193     $borrowernumber ||= $itemissue->borrowernumber;
3194     my $patron = Koha::Patrons->find( $borrowernumber )
3195       or return;
3196
3197     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3198     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3199         {   categorycode => $patron->categorycode,
3200             itemtype     => $item->effective_itemtype,
3201             branchcode   => $branchcode,
3202             rules => [
3203                 'norenewalbefore',
3204                 'lengthunit',
3205             ]
3206         }
3207     );
3208
3209     my $now = dt_from_string;
3210     return $now unless $issuing_rule;
3211
3212     if ( defined $issuing_rule->{norenewalbefore}
3213         and $issuing_rule->{norenewalbefore} ne "" )
3214     {
3215         my $soonestrenewal =
3216           dt_from_string( $itemissue->date_due )->subtract(
3217             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3218
3219         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3220             and $issuing_rule->{lengthunit} eq 'days' )
3221         {
3222             $soonestrenewal->truncate( to => 'day' );
3223         }
3224         return $soonestrenewal if $now < $soonestrenewal;
3225     }
3226     return $now;
3227 }
3228
3229 =head2 GetLatestAutoRenewDate
3230
3231   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3232
3233 Find out the latest possible auto renew date of a borrowed item.
3234
3235 C<$borrowernumber> is the borrower number of the patron who currently
3236 has the item on loan.
3237
3238 C<$itemnumber> is the number of the item to renew.
3239
3240 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3241 auto renew date, based on the value "No auto renewal after" and the "No auto
3242 renewal after (hard limit) of the applicable issuing rule.
3243 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3244 or item cannot be found.
3245
3246 =cut
3247
3248 sub GetLatestAutoRenewDate {
3249     my ( $borrowernumber, $itemnumber ) = @_;
3250
3251     my $dbh = C4::Context->dbh;
3252
3253     my $item      = Koha::Items->find($itemnumber)  or return;
3254     my $itemissue = $item->checkout                 or return;
3255
3256     $borrowernumber ||= $itemissue->borrowernumber;
3257     my $patron = Koha::Patrons->find( $borrowernumber )
3258       or return;
3259
3260     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3261     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3262         {
3263             categorycode => $patron->categorycode,
3264             itemtype     => $item->effective_itemtype,
3265             branchcode   => $branchcode,
3266             rules => [
3267                 'no_auto_renewal_after',
3268                 'no_auto_renewal_after_hard_limit',
3269                 'lengthunit',
3270             ]
3271         }
3272     );
3273
3274     return unless $circulation_rules;
3275     return
3276       if ( not $circulation_rules->{no_auto_renewal_after}
3277             or $circulation_rules->{no_auto_renewal_after} eq '' )
3278       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3279              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3280
3281     my $maximum_renewal_date;
3282     if ( $circulation_rules->{no_auto_renewal_after} ) {
3283         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3284         $maximum_renewal_date->add(
3285             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3286         );
3287     }
3288
3289     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3290         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3291         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3292     }
3293     return $maximum_renewal_date;
3294 }
3295
3296
3297 =head2 GetIssuingCharges
3298
3299   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3300
3301 Calculate how much it would cost for a given patron to borrow a given
3302 item, including any applicable discounts.
3303
3304 C<$itemnumber> is the item number of item the patron wishes to borrow.
3305
3306 C<$borrowernumber> is the patron's borrower number.
3307
3308 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3309 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3310 if it's a video).
3311
3312 =cut
3313
3314 sub GetIssuingCharges {
3315
3316     # calculate charges due
3317     my ( $itemnumber, $borrowernumber ) = @_;
3318     my $charge = 0;
3319     my $dbh    = C4::Context->dbh;
3320     my $item_type;
3321
3322     # Get the book's item type and rental charge (via its biblioitem).
3323     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3324         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3325     $charge_query .= (C4::Context->preference('item-level_itypes'))
3326         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3327         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3328
3329     $charge_query .= ' WHERE items.itemnumber =?';
3330
3331     my $sth = $dbh->prepare($charge_query);
3332     $sth->execute($itemnumber);
3333     if ( my $item_data = $sth->fetchrow_hashref ) {
3334         $item_type = $item_data->{itemtype};
3335         $charge    = $item_data->{rentalcharge};
3336         my $branch = C4::Context::mybranch();
3337         my $patron = Koha::Patrons->find( $borrowernumber );
3338         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3339         if ($discount) {
3340             # We may have multiple rules so get the most specific
3341             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3342         }
3343         if ($charge) {
3344             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3345         }
3346     }
3347
3348     return ( $charge, $item_type );
3349 }
3350
3351 # Select most appropriate discount rule from those returned
3352 sub _get_discount_from_rule {
3353     my ($categorycode, $branchcode, $itemtype) = @_;
3354
3355     # Set search precedences
3356     my @params = (
3357         {
3358             branchcode   => $branchcode,
3359             itemtype     => $itemtype,
3360             categorycode => $categorycode,
3361         },
3362         {
3363             branchcode   => undef,
3364             categorycode => $categorycode,
3365             itemtype     => $itemtype,
3366         },
3367         {
3368             branchcode   => $branchcode,
3369             categorycode => $categorycode,
3370             itemtype     => undef,
3371         },
3372         {
3373             branchcode   => undef,
3374             categorycode => $categorycode,
3375             itemtype     => undef,
3376         },
3377     );
3378
3379     foreach my $params (@params) {
3380         my $rule = Koha::CirculationRules->search(
3381             {
3382                 rule_name => 'rentaldiscount',
3383                 %$params,
3384             }
3385         )->next();
3386
3387         return $rule->rule_value if $rule;
3388     }
3389
3390     # none of the above
3391     return 0;
3392 }
3393
3394 =head2 AddIssuingCharge
3395
3396   &AddIssuingCharge( $checkout, $charge, $type )
3397
3398 =cut
3399
3400 sub AddIssuingCharge {
3401     my ( $checkout, $charge, $type ) = @_;
3402
3403     # FIXME What if checkout does not exist?
3404
3405     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3406     my $accountline = $account->add_debit(
3407         {
3408             amount      => $charge,
3409             note        => undef,
3410             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3411             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3412             interface   => C4::Context->interface,
3413             type        => $type,
3414             item_id     => $checkout->itemnumber,
3415             issue_id    => $checkout->issue_id,
3416         }
3417     );
3418 }
3419
3420 =head2 GetTransfers
3421
3422   GetTransfers($itemnumber);
3423
3424 =cut
3425
3426 sub GetTransfers {
3427     my ($itemnumber) = @_;
3428
3429     my $dbh = C4::Context->dbh;
3430
3431     my $query = '
3432         SELECT datesent,
3433                frombranch,
3434                tobranch,
3435                branchtransfer_id
3436         FROM branchtransfers
3437         WHERE itemnumber = ?
3438           AND datearrived IS NULL
3439         ';
3440     my $sth = $dbh->prepare($query);
3441     $sth->execute($itemnumber);
3442     my @row = $sth->fetchrow_array();
3443     return @row;
3444 }
3445
3446 =head2 GetTransfersFromTo
3447
3448   @results = GetTransfersFromTo($frombranch,$tobranch);
3449
3450 Returns the list of pending transfers between $from and $to branch
3451
3452 =cut
3453
3454 sub GetTransfersFromTo {
3455     my ( $frombranch, $tobranch ) = @_;
3456     return unless ( $frombranch && $tobranch );
3457     my $dbh   = C4::Context->dbh;
3458     my $query = "
3459         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3460         FROM   branchtransfers
3461         WHERE  frombranch=?
3462           AND  tobranch=?
3463           AND datearrived IS NULL
3464     ";
3465     my $sth = $dbh->prepare($query);
3466     $sth->execute( $frombranch, $tobranch );
3467     my @gettransfers;
3468
3469     while ( my $data = $sth->fetchrow_hashref ) {
3470         push @gettransfers, $data;
3471     }
3472     return (@gettransfers);
3473 }
3474
3475 =head2 DeleteTransfer
3476
3477   &DeleteTransfer($itemnumber);
3478
3479 =cut
3480
3481 sub DeleteTransfer {
3482     my ($itemnumber) = @_;
3483     return unless $itemnumber;
3484     my $dbh          = C4::Context->dbh;
3485     my $sth          = $dbh->prepare(
3486         "DELETE FROM branchtransfers
3487          WHERE itemnumber=?
3488          AND datearrived IS NULL "
3489     );
3490     return $sth->execute($itemnumber);
3491 }
3492
3493 =head2 SendCirculationAlert
3494
3495 Send out a C<check-in> or C<checkout> alert using the messaging system.
3496
3497 B<Parameters>:
3498
3499 =over 4
3500
3501 =item type
3502
3503 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3504
3505 =item item
3506
3507 Hashref of information about the item being checked in or out.
3508
3509 =item borrower
3510
3511 Hashref of information about the borrower of the item.
3512
3513 =item branch
3514
3515 The branchcode from where the checkout or check-in took place.
3516
3517 =back
3518
3519 B<Example>:
3520
3521     SendCirculationAlert({
3522         type     => 'CHECKOUT',
3523         item     => $item,
3524         borrower => $borrower,
3525         branch   => $branch,
3526     });
3527
3528 =cut
3529
3530 sub SendCirculationAlert {
3531     my ($opts) = @_;
3532     my ($type, $item, $borrower, $branch) =
3533         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3534     my %message_name = (
3535         CHECKIN  => 'Item_Check_in',
3536         CHECKOUT => 'Item_Checkout',
3537         RENEWAL  => 'Item_Checkout',
3538     );
3539     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3540         borrowernumber => $borrower->{borrowernumber},
3541         message_name   => $message_name{$type},
3542     });
3543     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3544
3545     my $schema = Koha::Database->new->schema;
3546     my @transports = keys %{ $borrower_preferences->{transports} };
3547
3548     # From the MySQL doc:
3549     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3550     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3551     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3552     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3553
3554     for my $mtt (@transports) {
3555         my $letter =  C4::Letters::GetPreparedLetter (
3556             module => 'circulation',
3557             letter_code => $type,
3558             branchcode => $branch,
3559             message_transport_type => $mtt,
3560             lang => $borrower->{lang},
3561             tables => {
3562                 $issues_table => $item->{itemnumber},
3563                 'items'       => $item->{itemnumber},
3564                 'biblio'      => $item->{biblionumber},
3565                 'biblioitems' => $item->{biblionumber},
3566                 'borrowers'   => $borrower,
3567                 'branches'    => $branch,
3568             }
3569         ) or next;
3570
3571         $schema->storage->txn_begin;
3572         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3573         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3574         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3575         unless ( $message ) {
3576             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3577             C4::Message->enqueue($letter, $borrower, $mtt);
3578         } else {
3579             $message->append($letter);
3580             $message->update;
3581         }
3582         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3583         $schema->storage->txn_commit;
3584     }
3585
3586     return;
3587 }
3588
3589 =head2 updateWrongTransfer
3590
3591   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3592
3593 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3594
3595 =cut
3596
3597 sub updateWrongTransfer {
3598         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3599         my $dbh = C4::Context->dbh;
3600 # first step validate the actual line of transfert .
3601         my $sth =
3602                 $dbh->prepare(
3603                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3604                 );
3605                 $sth->execute($FromLibrary,$itemNumber);
3606
3607 # second step create a new line of branchtransfer to the right location .
3608         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3609
3610 #third step changing holdingbranch of item
3611     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3612 }
3613
3614 =head2 CalcDateDue
3615
3616 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3617
3618 this function calculates the due date given the start date and configured circulation rules,
3619 checking against the holidays calendar as per the daysmode circulation rule.
3620 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3621 C<$itemtype>  = itemtype code of item in question
3622 C<$branch>  = location whose calendar to use
3623 C<$borrower> = Borrower object
3624 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3625
3626 =cut
3627
3628 sub CalcDateDue {
3629     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3630
3631     $isrenewal ||= 0;
3632
3633     # loanlength now a href
3634     my $loanlength =
3635             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3636
3637     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3638             ? qq{renewalperiod}
3639             : qq{issuelength};
3640
3641     my $datedue;
3642     if ( $startdate ) {
3643         if (ref $startdate ne 'DateTime' ) {
3644             $datedue = dt_from_string($datedue);
3645         } else {
3646             $datedue = $startdate->clone;
3647         }
3648     } else {
3649         $datedue = dt_from_string()->truncate( to => 'minute' );
3650     }
3651
3652
3653     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3654         {
3655             categorycode => $borrower->{categorycode},
3656             itemtype     => $itemtype,
3657             branchcode   => $branch,
3658         }
3659     );
3660
3661     # calculate the datedue as normal
3662     if ( $daysmode eq 'Days' )
3663     {    # ignoring calendar
3664         if ( $loanlength->{lengthunit} eq 'hours' ) {
3665             $datedue->add( hours => $loanlength->{$length_key} );
3666         } else {    # days
3667             $datedue->add( days => $loanlength->{$length_key} );
3668             $datedue->set_hour(23);
3669             $datedue->set_minute(59);
3670         }
3671     } else {
3672         my $dur;
3673         if ($loanlength->{lengthunit} eq 'hours') {
3674             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3675         }
3676         else { # days
3677             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3678         }
3679         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3680         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3681         if ($loanlength->{lengthunit} eq 'days') {
3682             $datedue->set_hour(23);
3683             $datedue->set_minute(59);
3684         }
3685     }
3686
3687     # if Hard Due Dates are used, retrieve them and apply as necessary
3688     my ( $hardduedate, $hardduedatecompare ) =
3689       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3690     if ($hardduedate) {    # hardduedates are currently dates
3691         $hardduedate->truncate( to => 'minute' );
3692         $hardduedate->set_hour(23);
3693         $hardduedate->set_minute(59);
3694         my $cmp = DateTime->compare( $hardduedate, $datedue );
3695
3696 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3697 # if the calculated date is before the 'after' Hard Due Date (floor), override
3698 # if the hard due date is set to 'exactly', overrride
3699         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3700             $datedue = $hardduedate->clone;
3701         }
3702
3703         # in all other cases, keep the date due as it is
3704
3705     }
3706
3707     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3708     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3709         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3710         if( $expiry_dt ) { #skip empty expiry date..
3711             $expiry_dt->set( hour => 23, minute => 59);
3712             my $d1= $datedue->clone->set_time_zone('floating');
3713             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3714                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3715             }
3716         }
3717         if ( $daysmode ne 'Days' ) {
3718           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3719           if ( $calendar->is_holiday($datedue) ) {
3720               # Don't return on a closed day
3721               $datedue = $calendar->prev_open_days( $datedue, 1 );
3722           }
3723         }
3724     }
3725
3726     return $datedue;
3727 }
3728
3729
3730 sub CheckValidBarcode{
3731 my ($barcode) = @_;
3732 my $dbh = C4::Context->dbh;
3733 my $query=qq|SELECT count(*)
3734              FROM items
3735              WHERE barcode=?
3736             |;
3737 my $sth = $dbh->prepare($query);
3738 $sth->execute($barcode);
3739 my $exist=$sth->fetchrow ;
3740 return $exist;
3741 }
3742
3743 =head2 IsBranchTransferAllowed
3744
3745   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3746
3747 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3748
3749 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3750 Koha::Item->can_be_transferred.
3751
3752 =cut
3753
3754 sub IsBranchTransferAllowed {
3755         my ( $toBranch, $fromBranch, $code ) = @_;
3756
3757         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3758
3759         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3760         my $dbh = C4::Context->dbh;
3761
3762         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3763         $sth->execute( $toBranch, $fromBranch, $code );
3764         my $limit = $sth->fetchrow_hashref();
3765
3766         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3767         if ( $limit->{'limitId'} ) {
3768                 return 0;
3769         } else {
3770                 return 1;
3771         }
3772 }
3773
3774 =head2 CreateBranchTransferLimit
3775
3776   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3777
3778 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3779
3780 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3781
3782 =cut
3783
3784 sub CreateBranchTransferLimit {
3785    my ( $toBranch, $fromBranch, $code ) = @_;
3786    return unless defined($toBranch) && defined($fromBranch);
3787    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3788
3789    my $dbh = C4::Context->dbh;
3790
3791    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3792    return $sth->execute( $code, $toBranch, $fromBranch );
3793 }
3794
3795 =head2 DeleteBranchTransferLimits
3796
3797     my $result = DeleteBranchTransferLimits($frombranch);
3798
3799 Deletes all the library transfer limits for one library.  Returns the
3800 number of limits deleted, 0e0 if no limits were deleted, or undef if
3801 no arguments are supplied.
3802
3803 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3804     fromBranch => $fromBranch
3805     })->delete.
3806
3807 =cut
3808
3809 sub DeleteBranchTransferLimits {
3810     my $branch = shift;
3811     return unless defined $branch;
3812     my $dbh    = C4::Context->dbh;
3813     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3814     return $sth->execute($branch);
3815 }
3816
3817 sub ReturnLostItem{
3818     my ( $borrowernumber, $itemnum ) = @_;
3819     MarkIssueReturned( $borrowernumber, $itemnum );
3820 }
3821
3822 =head2 LostItem
3823
3824   LostItem( $itemnumber, $mark_lost_from, $force_mark_returned, [$params] );
3825
3826 The final optional parameter, C<$params>, expected to contain
3827 'skip_record_index' key, which relayed down to Koha::Item/store,
3828 there it prevents calling of ModZebra index_records,
3829 which takes most of the time in batch adds/deletes: index_records better
3830 to be called later in C<additem.pl> after the whole loop.
3831
3832 $params:
3833     skip_record_index => 1|0
3834
3835 =cut
3836
3837 sub LostItem{
3838     my ($itemnumber, $mark_lost_from, $force_mark_returned, $params) = @_;
3839
3840     unless ( $mark_lost_from ) {
3841         # Temporary check to avoid regressions
3842         die q|LostItem called without $mark_lost_from, check the API.|;
3843     }
3844
3845     my $mark_returned;
3846     if ( $force_mark_returned ) {
3847         $mark_returned = 1;
3848     } else {
3849         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3850         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3851     }
3852
3853     my $dbh = C4::Context->dbh();
3854     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3855                            FROM issues
3856                            JOIN items USING (itemnumber)
3857                            JOIN biblio USING (biblionumber)
3858                            WHERE issues.itemnumber=?");
3859     $sth->execute($itemnumber);
3860     my $issues=$sth->fetchrow_hashref();
3861
3862     # If a borrower lost the item, add a replacement cost to the their record
3863     if ( my $borrowernumber = $issues->{borrowernumber} ){
3864         my $patron = Koha::Patrons->find( $borrowernumber );
3865
3866         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3867         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3868
3869         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3870             C4::Accounts::chargelostitem(
3871                 $borrowernumber,
3872                 $itemnumber,
3873                 $issues->{'replacementprice'},
3874                 sprintf( "%s %s %s",
3875                     $issues->{'title'}          || q{},
3876                     $issues->{'barcode'}        || q{},
3877                     $issues->{'itemcallnumber'} || q{},
3878                 ),
3879             );
3880             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3881             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3882         }
3883
3884         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3885     }
3886
3887     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3888     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3889         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store({ skip_record_index => $params->{skip_record_index} });
3890     }
3891     my $transferdeleted = DeleteTransfer($itemnumber);
3892 }
3893
3894 sub GetOfflineOperations {
3895     my $dbh = C4::Context->dbh;
3896     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3897     $sth->execute(C4::Context->userenv->{'branch'});
3898     my $results = $sth->fetchall_arrayref({});
3899     return $results;
3900 }
3901
3902 sub GetOfflineOperation {
3903     my $operationid = shift;
3904     return unless $operationid;
3905     my $dbh = C4::Context->dbh;
3906     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3907     $sth->execute( $operationid );
3908     return $sth->fetchrow_hashref;
3909 }
3910
3911 sub AddOfflineOperation {
3912     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3913     my $dbh = C4::Context->dbh;
3914     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3915     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3916     return "Added.";
3917 }
3918
3919 sub DeleteOfflineOperation {
3920     my $dbh = C4::Context->dbh;
3921     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3922     $sth->execute( shift );
3923     return "Deleted.";
3924 }
3925
3926 sub ProcessOfflineOperation {
3927     my $operation = shift;
3928
3929     my $report;
3930     if ( $operation->{action} eq 'return' ) {
3931         $report = ProcessOfflineReturn( $operation );
3932     } elsif ( $operation->{action} eq 'issue' ) {
3933         $report = ProcessOfflineIssue( $operation );
3934     } elsif ( $operation->{action} eq 'payment' ) {
3935         $report = ProcessOfflinePayment( $operation );
3936     }
3937
3938     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3939
3940     return $report;
3941 }
3942
3943 sub ProcessOfflineReturn {
3944     my $operation = shift;
3945
3946     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3947
3948     if ( $item ) {
3949         my $itemnumber = $item->itemnumber;
3950         my $issue = GetOpenIssue( $itemnumber );
3951         if ( $issue ) {
3952             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3953             ModDateLastSeen( $itemnumber, $leave_item_lost );
3954             MarkIssueReturned(
3955                 $issue->{borrowernumber},
3956                 $itemnumber,
3957                 $operation->{timestamp},
3958             );
3959             $item->renewals(0);
3960             $item->onloan(undef);
3961             $item->store({ log_action => 0 });
3962             return "Success.";
3963         } else {
3964             return "Item not issued.";
3965         }
3966     } else {
3967         return "Item not found.";
3968     }
3969 }
3970
3971 sub ProcessOfflineIssue {
3972     my $operation = shift;
3973
3974     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3975
3976     if ( $patron ) {
3977         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3978         unless ($item) {
3979             return "Barcode not found.";
3980         }
3981         my $itemnumber = $item->itemnumber;
3982         my $issue = GetOpenIssue( $itemnumber );
3983
3984         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3985             MarkIssueReturned(
3986                 $issue->{borrowernumber},
3987                 $itemnumber,
3988                 $operation->{timestamp},
3989             );
3990         }
3991         AddIssue(
3992             $patron->unblessed,
3993             $operation->{'barcode'},
3994             undef,
3995             1,
3996             $operation->{timestamp},
3997             undef,
3998         );
3999         return "Success.";
4000     } else {
4001         return "Borrower not found.";
4002     }
4003 }
4004
4005 sub ProcessOfflinePayment {
4006     my $operation = shift;
4007
4008     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4009
4010     $patron->account->pay(
4011         {
4012             amount     => $operation->{amount},
4013             library_id => $operation->{branchcode},
4014             interface  => 'koc'
4015         }
4016     );
4017
4018     return "Success.";
4019 }
4020
4021 =head2 TransferSlip
4022
4023   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4024
4025   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4026
4027 =cut
4028
4029 sub TransferSlip {
4030     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4031
4032     my $item =
4033       $itemnumber
4034       ? Koha::Items->find($itemnumber)
4035       : Koha::Items->find( { barcode => $barcode } );
4036
4037     $item or return;
4038
4039     return C4::Letters::GetPreparedLetter (
4040         module => 'circulation',
4041         letter_code => 'TRANSFERSLIP',
4042         branchcode => $branch,
4043         tables => {
4044             'branches'    => $to_branch,
4045             'biblio'      => $item->biblionumber,
4046             'items'       => $item->unblessed,
4047         },
4048     );
4049 }
4050
4051 =head2 CheckIfIssuedToPatron
4052
4053   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4054
4055   Return 1 if any record item is issued to patron, otherwise return 0
4056
4057 =cut
4058
4059 sub CheckIfIssuedToPatron {
4060     my ($borrowernumber, $biblionumber) = @_;
4061
4062     my $dbh = C4::Context->dbh;
4063     my $query = q|
4064         SELECT COUNT(*) FROM issues
4065         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4066         WHERE items.biblionumber = ?
4067         AND issues.borrowernumber = ?
4068     |;
4069     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4070     return 1 if $is_issued;
4071     return;
4072 }
4073
4074 =head2 IsItemIssued
4075
4076   IsItemIssued( $itemnumber )
4077
4078   Return 1 if the item is on loan, otherwise return 0
4079
4080 =cut
4081
4082 sub IsItemIssued {
4083     my $itemnumber = shift;
4084     my $dbh = C4::Context->dbh;
4085     my $sth = $dbh->prepare(q{
4086         SELECT COUNT(*)
4087         FROM issues
4088         WHERE itemnumber = ?
4089     });
4090     $sth->execute($itemnumber);
4091     return $sth->fetchrow;
4092 }
4093
4094 =head2 GetAgeRestriction
4095
4096   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4097   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4098
4099   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4100   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4101
4102 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4103 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4104 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4105          Negative days mean the borrower has gone past the age restriction age.
4106
4107 =cut
4108
4109 sub GetAgeRestriction {
4110     my ($record_restrictions, $borrower) = @_;
4111     my $markers = C4::Context->preference('AgeRestrictionMarker');
4112
4113     return unless $record_restrictions;
4114     # Split $record_restrictions to something like FSK 16 or PEGI 6
4115     my @values = split ' ', uc($record_restrictions);
4116     return unless @values;
4117
4118     # Search first occurrence of one of the markers
4119     my @markers = split /\|/, uc($markers);
4120     return unless @markers;
4121
4122     my $index            = 0;
4123     my $restriction_year = 0;
4124     for my $value (@values) {
4125         $index++;
4126         for my $marker (@markers) {
4127             $marker =~ s/^\s+//;    #remove leading spaces
4128             $marker =~ s/\s+$//;    #remove trailing spaces
4129             if ( $marker eq $value ) {
4130                 if ( $index <= $#values ) {
4131                     $restriction_year += $values[$index];
4132                 }
4133                 last;
4134             }
4135             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4136
4137                 # Perhaps it is something like "K16" (as in Finland)
4138                 $restriction_year += $1;
4139                 last;
4140             }
4141         }
4142         last if ( $restriction_year > 0 );
4143     }
4144
4145     #Check if the borrower is age restricted for this material and for how long.
4146     if ($restriction_year && $borrower) {
4147         if ( $borrower->{'dateofbirth'} ) {
4148             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4149             $alloweddate[0] += $restriction_year;
4150
4151             #Prevent runime eror on leap year (invalid date)
4152             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4153                 $alloweddate[2] = 28;
4154             }
4155
4156             #Get how many days the borrower has to reach the age restriction
4157             my @Today = split /-/, dt_from_string()->ymd();
4158             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4159             #Negative days means the borrower went past the age restriction age
4160             return ($restriction_year, $daysToAgeRestriction);
4161         }
4162     }
4163
4164     return ($restriction_year);
4165 }
4166
4167
4168 =head2 GetPendingOnSiteCheckouts
4169
4170 =cut
4171
4172 sub GetPendingOnSiteCheckouts {
4173     my $dbh = C4::Context->dbh;
4174     return $dbh->selectall_arrayref(q|
4175         SELECT
4176           items.barcode,
4177           items.biblionumber,
4178           items.itemnumber,
4179           items.itemnotes,
4180           items.itemcallnumber,
4181           items.location,
4182           issues.date_due,
4183           issues.branchcode,
4184           issues.date_due < NOW() AS is_overdue,
4185           biblio.author,
4186           biblio.title,
4187           borrowers.firstname,
4188           borrowers.surname,
4189           borrowers.cardnumber,
4190           borrowers.borrowernumber
4191         FROM items
4192         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4193         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4194         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4195         WHERE issues.onsite_checkout = 1
4196     |, { Slice => {} } );
4197 }
4198
4199 sub GetTopIssues {
4200     my ($params) = @_;
4201
4202     my ($count, $branch, $itemtype, $ccode, $newness)
4203         = @$params{qw(count branch itemtype ccode newness)};
4204
4205     my $dbh = C4::Context->dbh;
4206     my $query = q{
4207         SELECT * FROM (
4208         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4209           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4210           i.ccode, SUM(i.issues) AS count
4211         FROM biblio b
4212         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4213         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4214     };
4215
4216     my (@where_strs, @where_args);
4217
4218     if ($branch) {
4219         push @where_strs, 'i.homebranch = ?';
4220         push @where_args, $branch;
4221     }
4222     if ($itemtype) {
4223         if (C4::Context->preference('item-level_itypes')){
4224             push @where_strs, 'i.itype = ?';
4225             push @where_args, $itemtype;
4226         } else {
4227             push @where_strs, 'bi.itemtype = ?';
4228             push @where_args, $itemtype;
4229         }
4230     }
4231     if ($ccode) {
4232         push @where_strs, 'i.ccode = ?';
4233         push @where_args, $ccode;
4234     }
4235     if ($newness) {
4236         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4237         push @where_args, $newness;
4238     }
4239
4240     if (@where_strs) {
4241         $query .= 'WHERE ' . join(' AND ', @where_strs);
4242     }
4243
4244     $query .= q{
4245         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4246           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4247           i.ccode
4248         ORDER BY count DESC
4249     };
4250
4251     $query .= q{ ) xxx WHERE count > 0 };
4252     $count = int($count);
4253     if ($count > 0) {
4254         $query .= "LIMIT $count";
4255     }
4256
4257     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4258
4259     return @$rows;
4260 }
4261
4262 =head2 Internal methods
4263
4264 =cut
4265
4266 sub _CalculateAndUpdateFine {
4267     my ($params) = @_;
4268
4269     my $borrower    = $params->{borrower};
4270     my $item        = $params->{item};
4271     my $issue       = $params->{issue};
4272     my $return_date = $params->{return_date};
4273
4274     unless ($borrower) { carp "No borrower passed in!" && return; }
4275     unless ($item)     { carp "No item passed in!"     && return; }
4276     unless ($issue)    { carp "No issue passed in!"    && return; }
4277
4278     my $datedue = dt_from_string( $issue->date_due );
4279
4280     # we only need to calculate and change the fines if we want to do that on return
4281     # Should be on for hourly loans
4282     my $control = C4::Context->preference('CircControl');
4283     my $control_branchcode =
4284         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4285       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4286       :                                     $issue->branchcode;
4287
4288     my $date_returned = $return_date ? $return_date : dt_from_string();
4289
4290     my ( $amount, $unitcounttotal, $unitcount  ) =
4291       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4292
4293     if ( C4::Context->preference('finesMode') eq 'production' ) {
4294         if ( $amount > 0 ) {
4295             C4::Overdues::UpdateFine({
4296                 issue_id       => $issue->issue_id,
4297                 itemnumber     => $issue->itemnumber,
4298                 borrowernumber => $issue->borrowernumber,
4299                 amount         => $amount,
4300                 due            => output_pref($datedue),
4301             });
4302         }
4303         elsif ($return_date) {
4304
4305             # Backdated returns may have fines that shouldn't exist,
4306             # so in this case, we need to drop those fines to 0
4307
4308             C4::Overdues::UpdateFine({
4309                 issue_id       => $issue->issue_id,
4310                 itemnumber     => $issue->itemnumber,
4311                 borrowernumber => $issue->borrowernumber,
4312                 amount         => 0,
4313                 due            => output_pref($datedue),
4314             });
4315         }
4316     }
4317 }
4318
4319 sub _item_denied_renewal {
4320     my ($params) = @_;
4321
4322     my $item = $params->{item};
4323     return unless $item;
4324
4325     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4326     return unless $denyingrules;
4327     foreach my $field (keys %$denyingrules) {
4328         my $val = $item->$field;
4329         if( !defined $val) {
4330             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4331                 return 1;
4332             }
4333         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4334            # If the results matches the values in the syspref
4335            # We return true if match found
4336             return 1;
4337         }
4338     }
4339     return 0;
4340 }
4341
4342 1;
4343
4344 __END__
4345
4346 =head1 AUTHOR
4347
4348 Koha Development Team <http://koha-community.org/>
4349
4350 =cut