misc/cronjobs/delete_patrons.pl

   1 #!/usr/bin/perl
   2
   3 use Modern::Perl;
   4
   5 use Pod::Usage;
   6 use Getopt::Long;
   7
   8 use C4::Members;
   9 use Koha::DateUtils;
  10 use Koha::Patrons;
  11 use C4::Log;
  12
  13 my ( $help, $verbose, $not_borrowed_since, $expired_before, $last_seen,
  14     $category_code, $branchcode, $confirm );
  15 GetOptions(
  16     'h|help'                 => \$help,
  17     'v|verbose'              => \$verbose,
  18     'not_borrowed_since:s'   => \$not_borrowed_since,
  19     'expired_before:s'       => \$expired_before,
  20     'last_seen:s'            => \$last_seen,
  21     'category_code:s'        => \$category_code,
  22     'library:s'              => \$branchcode,
  23     'c|confirm'              => \$confirm,
  24 ) || pod2usage(1);
  25
  26 if ($help) {
  27     pod2usage(1);
  28 }
  29
  30 $not_borrowed_since = dt_from_string( $not_borrowed_since, 'iso' )
  31   if $not_borrowed_since;
  32
  33 $expired_before = dt_from_string( $expired_before, 'iso' )
  34   if $expired_before;
  35
  36 if ( $last_seen and not C4::Context->preference('TrackLastPatronActivity') ) {
  37     pod2usage(q{The --last_seen option cannot be used with TrackLastPatronActivity turned off});
  38 }
  39
  40 unless ( $not_borrowed_since or $expired_before or $last_seen or $category_code or $branchcode ) {
  41     pod2usage(q{At least one filter is mandatory});
  42 }
  43
  44 cronlogaction();
  45
  46 my $members = GetBorrowersToExpunge(
  47     {
  48         not_borrowed_since => $not_borrowed_since,
  49         expired_before       => $expired_before,
  50         last_seen            => $last_seen,
  51         category_code        => $category_code,
  52         branchcode           => $branchcode,
  53     }
  54 );
  55
  56 unless ($confirm) {
  57     say "Doing a dry run; no patron records will actually be deleted.";
  58     say "Run again with --confirm to delete the records.";
  59 }
  60
  61 say scalar(@$members) . " patrons to delete";
  62
  63 my $deleted = 0;
  64 for my $member (@$members) {
  65     print "Trying to delete patron $member->{borrowernumber}... "
  66       if $verbose;
  67
  68     my $borrowernumber = $member->{borrowernumber};
  69     my $flags = C4::Members::patronflags( $member );
  70     if ( my $charges = $flags->{CHARGES}{amount} ) {
  71         say "Failed to delete patron $borrowernumber: patron has $charges in fines";
  72         next;
  73     }
  74
  75     if ( $confirm ) {
  76         my $patron = Koha::Patrons->find( $borrowernumber );
  77         my $deleted = eval { $patron->move_to_deleted; };
  78         if ($@ or not $deleted) {
  79             say "Failed to delete patron $borrowernumber, cannot move it" . ( $@ ? ": ($@)" : "" );
  80             next;
  81         }
  82
  83         eval { $patron->delete };
  84         if ($@) {
  85             say "Failed to delete patron $borrowernumber: $@)";
  86             next;
  87         }
  88     }
  89     $deleted++;
  90     say "OK" if $verbose;
  91 }
  92
  93 say "$deleted patrons deleted";
  94
  95 =head1 NAME
  96
  97 delete_patrons - This script deletes patrons
  98
  99 =head1 SYNOPSIS
 100
 101 delete_patrons.pl [-h|--help] [-v|--verbose] [-c|--confirm] [--not_borrowed_since=DATE] [--expired_before=DATE] [--last-seen=DATE] [--category_code=CAT] [--library=LIBRARY]
 102
 103 Dates should be in ISO format, e.g., 2013-07-19, and can be generated
 104 with `date -d '-3 month' "+%Y-%m-%d"`.
 105
 106 The options to select the patron records to delete are cumulative.  For
 107 example, supplying both --expired_before and --library specifies that
 108 that patron records must meet both conditions to be selected for deletion.
 109
 110 =head1 OPTIONS
 111
 112 =over
 113
 114 =item B<-h|--help>
 115
 116 Print a brief help message
 117
 118 =item B<--not_borrowed_since>
 119
 120 Delete patrons who have not borrowed since this date.
 121
 122 =item B<--expired_before>
 123
 124 Delete patrons with an account expired before this date.
 125
 126 =item B<--last_seen>
 127
 128 Delete patrons who have not been connected since this date.
 129
 130 The system preference TrackLastPatronActivity must be enabled to use this option.
 131
 132 =item B<--category_code>
 133
 134 Delete patrons who have this category code.
 135
 136 =item B<--library>
 137
 138 Delete patrons in this library.
 139
 140 =item B<-c|--confirm>
 141
 142 This flag must be provided in order for the script to actually
 143 delete patron records.  If it is not supplied, the script will
 144 only report on the patron records it would have deleted.
 145
 146 =item B<-v|--verbose>
 147
 148 Verbose mode.
 149
 150 =back
 151
 152 =head1 AUTHOR
 153
 154 Jonathan Druart <jonathan.druart@biblibre.com>
 155
 156 =head1 COPYRIGHT
 157
 158 Copyright 2013 BibLibre
 159
 160 =head1 LICENSE
 161
 162 This file is part of Koha.
 163
 164 Koha is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software
 165 Foundation; either version 3 of the License, or (at your option) any later version.
 166
 167 You should have received a copy of the GNU General Public License along
 168 with Koha; if not, write to the Free Software Foundation, Inc.,
 169 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
 170
 171 =cut