virtualshelves/downloadshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI;
  24 use Encode qw(encode);
  25
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Items;
  29 use C4::Output;
  30 use C4::VirtualShelves;
  31 use C4::Record;
  32 use C4::Ris;
  33 use C4::Csv;
  34 use utf8;
  35 my $query = new CGI;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  38     {
  39         template_name   => "virtualshelves/downloadshelf.tt",
  40         query           => $query,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { catalogue => 1 },
  44     }
  45 );
  46
  47 my $shelfid = $query->param('shelfid');
  48 my $format  = $query->param('format');
  49 my $dbh     = C4::Context->dbh;
  50
  51 if ($shelfid && $format) {
  52
  53     my ($items, $totitems)  = GetShelfContents($shelfid);
  54     my $marcflavour         = C4::Context->preference('marcflavour');
  55     my $output='';
  56
  57     # CSV
  58     if ($format =~ /^\d+$/) {
  59         my @biblios;
  60         foreach (@$items) {
  61             push @biblios, $_->{biblionumber};
  62         }
  63         $output = marc2csv(\@biblios, $format);
  64     }
  65     else { #Other formats
  66         foreach my $biblio (@$items) {
  67             my $biblionumber = $biblio->{biblionumber};
  68             my $record = GetMarcBiblio($biblionumber, 1);
  69             if ($format eq 'iso2709') {
  70                 $output .= $record->as_usmarc();
  71             }
  72             elsif ($format eq 'ris') {
  73                 $output .= marc2ris($record);
  74             }
  75             elsif ($format eq 'bibtex') {
  76                 $output .= marc2bibtex($record, $biblionumber);
  77             }
  78         }
  79     }
  80
  81     # If it was a CSV export we change the format after the export so the file extension is fine
  82     $format = "csv" if ($format =~ m/^\d+$/);
  83
  84     print $query->header(
  85         -type => 'application/octet-stream',
  86         -'Content-Transfer-Encoding' => 'binary',
  87         -attachment=>"shelf.$format");
  88     print $output;
  89 }
  90 else {
  91     $template->param(csv_profiles => GetCsvProfilesLoop('marc'));
  92     $template->param(shelfid => $shelfid);
  93     output_html_with_http_headers $query, $cookie, $template->output;
  94 }