circ/returns.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN-OP
   5 #           2007-2010 BibLibre, Paul POULAIN
   6 #           2010 Catalyst IT
   7 #           2011 PTFS-Europe Ltd.
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it under the
  12 # terms of the GNU General Public License as published by the Free Software
  13 # Foundation; either version 2 of the License, or (at your option) any later
  14 # version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  17 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  18 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License along
  21 # with Koha; if not, write to the Free Software Foundation, Inc.,
  22 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  23
  24 =head1 returns.pl
  25
  26 script to execute returns of books
  27
  28 =cut
  29
  30 use strict;
  31 use warnings;
  32
  33 use CGI;
  34 use DateTime;
  35 use C4::Context;
  36 use C4::Auth qw/:DEFAULT get_session/;
  37 use C4::Output;
  38 use C4::Circulation;
  39 use C4::Print;
  40 use C4::Reserves;
  41 use C4::Biblio;
  42 use C4::Items;
  43 use C4::Members;
  44 use C4::Branch; # GetBranches GetBranchName
  45 use C4::Koha;   # FIXME : is it still useful ?
  46 use C4::RotatingCollections;
  47 use Koha::DateUtils;
  48 use Koha::Calendar;
  49
  50 my $query = new CGI;
  51
  52 #getting the template
  53 my ( $template, $librarian, $cookie ) = get_template_and_user(
  54     {
  55         template_name   => "circ/returns.tt",
  56         query           => $query,
  57         type            => "intranet",
  58         authnotrequired => 0,
  59         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  60     }
  61 );
  62
  63 my $sessionID = $query->cookie("CGISESSID");
  64 my $session = get_session($sessionID);
  65 if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  66     # no branch set we can't return
  67     print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  68     exit;
  69 }
  70
  71 #####################
  72 #Global vars
  73 my $branches = GetBranches();
  74 my $printers = GetPrinters();
  75 my $userenv = C4::Context->userenv;
  76 my $userenv_branch = $userenv->{'branch'} // '';
  77 my $printer = $userenv->{'branchprinter'} // '';
  78
  79 my $overduecharges = (C4::Context->preference('finesMode') && C4::Context->preference('finesMode') ne 'off');
  80 #
  81 # Some code to handle the error if there is no branch or printer setting.....
  82 #
  83
  84 # Set up the item stack ....
  85 my %returneditems;
  86 my %riduedate;
  87 my %riborrowernumber;
  88 my @inputloop;
  89 foreach ( $query->param ) {
  90     my $counter;
  91     if (/ri-(\d*)/) {
  92         $counter = $1;
  93         if ($counter > 20) {
  94             next;
  95         }
  96     }
  97     else {
  98         next;
  99     }
 100
 101     my %input;
 102     my $barcode        = $query->param("ri-$counter");
 103     my $duedate        = $query->param("dd-$counter");
 104     my $borrowernumber = $query->param("bn-$counter");
 105     $counter++;
 106
 107     # decode barcode    ## Didn't we already decode them before passing them back last time??
 108     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 109     $barcode = barcodedecode($barcode) if(C4::Context->preference('itemBarcodeInputFilter'));
 110
 111     ######################
 112     #Are these lines still useful ?
 113     $returneditems{$counter}    = $barcode;
 114     $riduedate{$counter}        = $duedate;
 115     $riborrowernumber{$counter} = $borrowernumber;
 116
 117     #######################
 118     $input{counter}        = $counter;
 119     $input{barcode}        = $barcode;
 120     $input{duedate}        = $duedate;
 121     $input{borrowernumber} = $borrowernumber;
 122     push( @inputloop, \%input );
 123 }
 124
 125 ############
 126 # Deal with the requests....
 127
 128 if ($query->param('WT-itemNumber')){
 129         updateWrongTransfer ($query->param('WT-itemNumber'),$query->param('WT-waitingAt'),$query->param('WT-From'));
 130 }
 131
 132 if ( $query->param('resbarcode') ) {
 133     my $item           = $query->param('itemnumber');
 134     my $borrowernumber = $query->param('borrowernumber');
 135     my $resbarcode     = $query->param('resbarcode');
 136     my $diffBranchReturned = $query->param('diffBranch');
 137     my $iteminfo   = GetBiblioFromItemNumber($item);
 138     # fix up item type for display
 139     $iteminfo->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $iteminfo->{'itype'} : $iteminfo->{'itemtype'};
 140     my $diffBranchSend = ($userenv_branch ne $diffBranchReturned) ? $diffBranchReturned : undef;
 141 # diffBranchSend tells ModReserveAffect whether document is expected in this library or not,
 142 # i.e., whether to apply waiting status
 143     ModReserveAffect( $item, $borrowernumber, $diffBranchSend);
 144 #   check if we have other reserves for this document, if we have a return send the message of transfer
 145     my ( $messages, $nextreservinfo ) = GetOtherReserves($item);
 146
 147     my ($borr) = GetMemberDetails( $nextreservinfo, 0 );
 148     my $name   = $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'};
 149     if ( $messages->{'transfert'} ) {
 150         $template->param(
 151             itemtitle      => $iteminfo->{'title'},
 152             itemnumber     => $iteminfo->{'itemnumber'},
 153             itembiblionumber => $iteminfo->{'biblionumber'},
 154             iteminfo       => $iteminfo->{'author'},
 155             tobranchname   => GetBranchName($messages->{'transfert'}),
 156             name           => $name,
 157             borrowernumber => $borrowernumber,
 158             borcnum        => $borr->{'cardnumber'},
 159             borfirstname   => $borr->{'firstname'},
 160             borsurname     => $borr->{'surname'},
 161             diffbranch     => 1,
 162         );
 163     }
 164 }
 165
 166 my $borrower;
 167 my $returned = 0;
 168 my $messages;
 169 my $issueinformation;
 170 my $itemnumber;
 171 my $barcode     = $query->param('barcode');
 172 my $exemptfine  = $query->param('exemptfine');
 173 if (
 174   $exemptfine &&
 175   !C4::Auth::haspermission(C4::Context->userenv->{'id'}, {'updatecharges' => 'writeoff'})
 176 ) {
 177     # silently prevent unauthorized operator from forgiving overdue
 178     # fines by manually tweaking form parameters
 179     undef $exemptfine;
 180 }
 181 my $dropboxmode = $query->param('dropboxmode');
 182 my $dotransfer  = $query->param('dotransfer');
 183 my $canceltransfer = $query->param('canceltransfer');
 184 my $dest = $query->param('dest');
 185 my $calendar    = Koha::Calendar->new( branchcode => $userenv_branch );
 186 #dropbox: get last open day (today - 1)
 187 my $today       = DateTime->now( time_zone => C4::Context->tz());
 188 my $dropboxdate = $calendar->addDate($today, -1);
 189
 190 my $return_date_override = $query->param('return_date_override');
 191 my $return_date_override_remember =
 192   $query->param('return_date_override_remember');
 193 if ($return_date_override) {
 194     if ( C4::Context->preference('SpecifyReturnDate') ) {
 195         # FIXME we really need to stop adding more uses of C4::Dates
 196         if ( $return_date_override =~ C4::Dates->regexp('syspref') ) {
 197
 198             # note that we've overriden the return date
 199             $template->param( return_date_was_overriden => 1);
 200             # Save the original format if we are remembering for this series
 201             $template->param(
 202                 return_date_override          => $return_date_override,
 203                 return_date_override_remember => 1
 204             ) if ($return_date_override_remember);
 205
 206             my $dt = dt_from_string($return_date_override);
 207             $return_date_override =
 208               DateTime::Format::MySQL->format_datetime($dt);
 209         }
 210     }
 211     else {
 212         $return_date_override = q{};
 213     }
 214 }
 215
 216 if ($dotransfer){
 217 # An item has been returned to a branch other than the homebranch, and the librarian has chosen to initiate a transfer
 218     my $transferitem = $query->param('transferitem');
 219     my $tobranch     = $query->param('tobranch');
 220     ModItemTransfer($transferitem, $userenv_branch, $tobranch);
 221 }
 222
 223 if ($canceltransfer){
 224     $itemnumber=$query->param('itemnumber');
 225     DeleteTransfer($itemnumber);
 226     if($dest eq "ttr"){
 227         print $query->redirect("/cgi-bin/koha/circ/transferstoreceive.pl");
 228         exit;
 229     } else {
 230         $template->param( transfercancelled => 1);
 231     }
 232 }
 233
 234 # actually return book and prepare item table.....
 235 if ($barcode) {
 236     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 237     $barcode = barcodedecode($barcode) if C4::Context->preference('itemBarcodeInputFilter');
 238     $itemnumber = GetItemnumberFromBarcode($barcode);
 239
 240 #
 241 # save the return
 242 #
 243     ( $returned, $messages, $issueinformation, $borrower ) =
 244       AddReturn( $barcode, $userenv_branch, $exemptfine, $dropboxmode, $return_date_override, $dropboxdate );
 245     my $homeorholdingbranchreturn = C4::Context->preference('HomeOrHoldingBranchReturn');
 246     $homeorholdingbranchreturn ||= 'homebranch';
 247
 248     # get biblio description
 249     my $biblio = GetBiblioFromItemNumber($itemnumber);
 250     # fix up item type for display
 251     $biblio->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $biblio->{'itype'} : $biblio->{'itemtype'};
 252
 253     # Check if we should display a checkin message, based on the the item
 254     # type of the checked in item
 255     my $itemtype = C4::ItemType->get( $biblio->{'itemtype'} );
 256     if ( $itemtype->{'checkinmsg'} ) {
 257         $template->param(
 258             checkinmsg     => $itemtype->{'checkinmsg'},
 259             checkinmsgtype => $itemtype->{'checkinmsgtype'},
 260         );
 261     }
 262
 263     $template->param(
 264         title            => $biblio->{'title'},
 265         homebranch       => $biblio->{'homebranch'},
 266         homebranchname   => GetBranchName( $biblio->{$homeorholdingbranchreturn} ),
 267         author           => $biblio->{'author'},
 268         itembarcode      => $biblio->{'barcode'},
 269         itemtype         => $biblio->{'itemtype'},
 270         ccode            => $biblio->{'ccode'},
 271         itembiblionumber => $biblio->{'biblionumber'},
 272         borrower         => $borrower,
 273         additional_materials => $biblio->{'materials'},
 274     );
 275
 276     my %input = (
 277         counter => 0,
 278         first   => 1,
 279         barcode => $barcode,
 280     );
 281
 282     if ($returned) {
 283         my $time_now = DateTime->now( time_zone => C4::Context->tz )->truncate( to => 'minute');
 284         my $duedate = $issueinformation->{date_due}->strftime('%Y-%m-%d %H:%M');
 285         $returneditems{0}      = $barcode;
 286         $riborrowernumber{0}   = $borrower->{'borrowernumber'};
 287         $riduedate{0}          = $duedate;
 288         $input{borrowernumber} = $borrower->{'borrowernumber'};
 289         $input{duedate}        = $duedate;
 290         unless ( $dropboxmode ) {
 291             $input{return_overdue} = 1 if (DateTime->compare($issueinformation->{date_due}, DateTime->now()) == -1);
 292         } else {
 293             $input{return_overdue} = 1 if (DateTime->compare($issueinformation->{date_due}, $dropboxdate) == -1);
 294         }
 295         push( @inputloop, \%input );
 296
 297         if ( C4::Context->preference("FineNotifyAtCheckin") ) {
 298             my ( $od, $issue, $fines ) = GetMemberIssuesAndFines( $borrower->{'borrowernumber'} );
 299             if ($fines && $fines > 0) {
 300                 $template->param( fines => sprintf("%.2f",$fines) );
 301                 $template->param( fineborrowernumber => $borrower->{'borrowernumber'} );
 302             }
 303         }
 304
 305         if (C4::Context->preference("WaitingNotifyAtCheckin") ) {
 306             #Check for waiting holds
 307             my @reserves = GetReservesFromBorrowernumber($borrower->{'borrowernumber'});
 308             my $waiting_holds = 0;
 309             foreach my $num_res (@reserves) {
 310                 if ( $num_res->{'found'} eq 'W' && $num_res->{'branchcode'} eq $userenv_branch) {
 311                     $waiting_holds++;
 312                 }
 313             }
 314             if ($waiting_holds > 0) {
 315                 $template->param(
 316                     waiting_holds       => $waiting_holds,
 317                     holdsborrowernumber => $borrower->{'borrowernumber'},
 318                     holdsfirstname => $borrower->{'firstname'},
 319                     holdssurname => $borrower->{'surname'},
 320                 );
 321             }
 322         }
 323     }
 324     elsif ( !$messages->{'BadBarcode'} ) {
 325         $input{duedate}   = 0;
 326         $returneditems{0} = $barcode;
 327         $riduedate{0}     = 0;
 328         push( @inputloop, \%input );
 329     }
 330 }
 331 $template->param( inputloop => \@inputloop );
 332
 333 my $found    = 0;
 334 my $waiting  = 0;
 335 my $reserved = 0;
 336
 337 # new op dev : we check if the document must be returned to his homebranch directly,
 338 #  if the document is transfered, we have warning message .
 339
 340 if ( $messages->{'WasTransfered'} ) {
 341     $template->param(
 342         found          => 1,
 343         transfer       => 1,
 344         itemnumber     => $itemnumber,
 345     );
 346 }
 347
 348 if ( $messages->{'NeedsTransfer'} ){
 349     $template->param(
 350         found          => 1,
 351         needstransfer  => 1,
 352         itemnumber     => $itemnumber,
 353     );
 354 }
 355
 356 if ( $messages->{'Wrongbranch'} ){
 357     $template->param(
 358         wrongbranch => 1,
 359     );
 360 }
 361
 362 # case of wrong transfert, if the document wasn't transfered to the right library (according to branchtransfer (tobranch) BDD)
 363
 364 if ( $messages->{'WrongTransfer'} and not $messages->{'WasTransfered'}) {
 365     $template->param(
 366         WrongTransfer  => 1,
 367         TransferWaitingAt => $messages->{'WrongTransfer'},
 368         WrongTransferItem => $messages->{'WrongTransferItem'},
 369         itemnumber => $itemnumber,
 370     );
 371
 372     my $reserve    = $messages->{'ResFound'};
 373     my $branchname = $branches->{ $reserve->{'branchcode'} }->{'branchname'};
 374     my ($borr) = GetMemberDetails( $reserve->{'borrowernumber'}, 0 );
 375     my $name = $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'};
 376     $template->param(
 377             wname           => $name,
 378             wborfirstname   => $borr->{'firstname'},
 379             wborsurname     => $borr->{'surname'},
 380             wbortitle       => $borr->{'title'},
 381             wborphone       => $borr->{'phone'},
 382             wboremail       => $borr->{'email'},
 383             wborstnum       => $borr->{streetnumber},
 384             wboraddress     => $borr->{'address'},
 385             wboraddress2    => $borr->{'address2'},
 386             wborcity        => $borr->{'city'},
 387             wborzip         => $borr->{'zipcode'},
 388             wborrowernumber => $reserve->{'borrowernumber'},
 389             wborcnum        => $borr->{'cardnumber'},
 390             wtransfertFrom  => $userenv_branch,
 391     );
 392 }
 393
 394 #
 395 # reserve found and item arrived at the expected branch
 396 #
 397 if ( $messages->{'ResFound'}) {
 398     my $reserve    = $messages->{'ResFound'};
 399     my $branchname = $branches->{ $reserve->{'branchcode'} }->{'branchname'};
 400     my ($borr) = GetMemberDetails( $reserve->{'borrowernumber'}, 0 );
 401
 402     if ( $reserve->{'ResFound'} eq "Waiting" or $reserve->{'ResFound'} eq "Reserved" ) {
 403         if ( $reserve->{'ResFound'} eq "Waiting" ) {
 404             $template->param(
 405                 waiting      => ($userenv_branch eq $reserve->{'branchcode'} ? 1 : 0 ),
 406             );
 407         } elsif ( $reserve->{'ResFound'} eq "Reserved" ) {
 408             $template->param(
 409                 intransit    => ($userenv_branch eq $reserve->{'branchcode'} ? 0 : 1 ),
 410                 transfertodo => ($userenv_branch eq $reserve->{'branchcode'} ? 0 : 1 ),
 411                 resbarcode   => $barcode,
 412                 reserved     => 1,
 413             );
 414         }
 415
 416         # same params for Waiting or Reserved
 417         $template->param(
 418             found          => 1,
 419             currentbranch  => $branches->{$userenv_branch}->{'branchname'},
 420             destbranchname => $branches->{ $reserve->{'branchcode'} }->{'branchname'},
 421             name           => $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'},
 422             borfirstname   => $borr->{'firstname'},
 423             borsurname     => $borr->{'surname'},
 424             bortitle       => $borr->{'title'},
 425             borphone       => $borr->{'phone'},
 426             boremail       => $borr->{'email'},
 427             boraddress     => $borr->{'address'},
 428             boraddress2    => $borr->{'address2'},
 429             borstnum       => $borr->{streetnumber},
 430             borcity        => $borr->{'city'},
 431             borzip         => $borr->{'zipcode'},
 432             borcnum        => $borr->{'cardnumber'},
 433             debarred       => $borr->{'debarred'},
 434             gonenoaddress  => $borr->{'gonenoaddress'},
 435             barcode        => $barcode,
 436             destbranch     => $reserve->{'branchcode'},
 437             borrowernumber => $reserve->{'borrowernumber'},
 438             itemnumber     => $reserve->{'itemnumber'},
 439             reservenotes   => $reserve->{'reservenotes'},
 440         );
 441     } # else { ; }  # error?
 442 }
 443
 444 # Error Messages
 445 my @errmsgloop;
 446 foreach my $code ( keys %$messages ) {
 447     my %err;
 448     my $exit_required_p = 0;
 449     if ( $code eq 'BadBarcode' ) {
 450         $err{badbarcode} = 1;
 451         $err{msg}        = $messages->{'BadBarcode'};
 452     }
 453     elsif ( $code eq 'NotIssued' ) {
 454         $err{notissued} = 1;
 455         $err{msg} = $branches->{ $messages->{'IsPermanent'} }->{'branchname'};
 456     }
 457     elsif ( $code eq 'LocalUse' ) {
 458         $err{localuse} = 1;
 459     }
 460     elsif ( $code eq 'WasLost' ) {
 461         $err{waslost} = 1;
 462     }
 463     elsif ( $code eq 'LostItemFeeRefunded' ) {
 464         $template->param( LostItemFeeRefunded => 1 );
 465     }
 466     elsif ( $code eq 'ResFound' ) {
 467         ;    # FIXME... anything to do here?
 468     }
 469     elsif ( $code eq 'WasReturned' ) {
 470         ;    # FIXME... anything to do here?
 471     }
 472     elsif ( $code eq 'WasTransfered' ) {
 473         ;    # FIXME... anything to do here?
 474     }
 475     elsif ( $code eq 'withdrawn' ) {
 476         $err{withdrawn} = 1;
 477         $exit_required_p = 1 if C4::Context->preference("BlockReturnOfWithdrawnItems");
 478     }
 479     elsif ( ( $code eq 'IsPermanent' ) && ( not $messages->{'ResFound'} ) ) {
 480         if ( $messages->{'IsPermanent'} ne $userenv_branch ) {
 481             $err{ispermanent} = 1;
 482             $err{msg}         =
 483               $branches->{ $messages->{'IsPermanent'} }->{'branchname'};
 484         }
 485     }
 486     elsif ( $code eq 'WrongTransfer' ) {
 487         ;    # FIXME... anything to do here?
 488     }
 489     elsif ( $code eq 'WrongTransferItem' ) {
 490         ;    # FIXME... anything to do here?
 491     }
 492     elsif ( $code eq 'NeedsTransfer' ) {
 493     }
 494     elsif ( $code eq 'Wrongbranch' ) {
 495     }
 496     elsif ( $code eq 'Debarred' ) {
 497         $err{debarred}            = $messages->{'Debarred'};
 498         $err{debarcardnumber}     = $borrower->{cardnumber};
 499         $err{debarborrowernumber} = $borrower->{borrowernumber};
 500         $err{debarname}           = "$borrower->{firstname} $borrower->{surname}";
 501     }
 502     elsif ( $code eq 'PrevDebarred' ) {
 503         $err{prevdebarred}        = $messages->{'PrevDebarred'};
 504     }
 505     elsif ( $code eq 'ForeverDebarred' ) {
 506         $err{foreverdebarred}        = $messages->{'ForeverDebarred'};
 507     }
 508     elsif ( $code eq 'NotForLoanStatusUpdated' ) {
 509         $err{NotForLoanStatusUpdated} = $messages->{NotForLoanStatusUpdated};
 510     }
 511     else {
 512         die "Unknown error code $code";    # note we need all the (empty) elsif's above, or we die.
 513         # This forces the issue of staying in sync w/ Circulation.pm
 514     }
 515     if (%err) {
 516         push( @errmsgloop, \%err );
 517     }
 518     last if $exit_required_p;
 519 }
 520 $template->param( errmsgloop => \@errmsgloop );
 521
 522 #set up so only the last 8 returned items display (make for faster loading pages)
 523 my $returned_counter = ( C4::Context->preference('numReturnedItemsToShow') ) ? C4::Context->preference('numReturnedItemsToShow') : 8;
 524 my $count = 0;
 525 my @riloop;
 526 my $shelflocations = GetKohaAuthorisedValues('items.location','');
 527 foreach ( sort { $a <=> $b } keys %returneditems ) {
 528     my %ri;
 529     if ( $count++ < $returned_counter ) {
 530         my $bar_code = $returneditems{$_};
 531         if ($riduedate{$_}) {
 532             my $duedate = dt_from_string( $riduedate{$_}, 'sql');
 533             $ri{year}  = $duedate->year();
 534             $ri{month} = $duedate->month();
 535             $ri{day}   = $duedate->day();
 536             $ri{hour}   = $duedate->hour();
 537             $ri{minute}   = $duedate->minute();
 538             $ri{duedate} = output_pref($duedate);
 539             my ($b)      = GetMemberDetails( $riborrowernumber{$_}, 0 );
 540             unless ( $dropboxmode ) {
 541                 $ri{return_overdue} = 1 if (DateTime->compare($duedate, DateTime->now()) == -1);
 542             } else {
 543                 $ri{return_overdue} = 1 if (DateTime->compare($duedate, $dropboxdate) == -1);
 544             }
 545             $ri{borrowernumber} = $b->{'borrowernumber'};
 546             $ri{borcnum}        = $b->{'cardnumber'};
 547             $ri{borfirstname}   = $b->{'firstname'};
 548             $ri{borsurname}     = $b->{'surname'};
 549             $ri{bortitle}       = $b->{'title'};
 550             $ri{bornote}        = $b->{'borrowernotes'};
 551             $ri{borcategorycode}= $b->{'categorycode'};
 552         }
 553         else {
 554             $ri{borrowernumber} = $riborrowernumber{$_};
 555         }
 556
 557         #        my %ri;
 558         my $biblio = GetBiblioFromItemNumber(GetItemnumberFromBarcode($bar_code));
 559         my $item   = GetItem( GetItemnumberFromBarcode($bar_code) );
 560         # fix up item type for display
 561         $biblio->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $biblio->{'itype'} : $biblio->{'itemtype'};
 562         $ri{itembiblionumber} = $biblio->{'biblionumber'};
 563         $ri{itemtitle}        = $biblio->{'title'};
 564         $ri{itemauthor}       = $biblio->{'author'};
 565         $ri{itemcallnumber}   = $biblio->{'itemcallnumber'};
 566         $ri{itemtype}         = $biblio->{'itemtype'};
 567         $ri{itemnote}         = $biblio->{'itemnotes'};
 568         $ri{ccode}            = $biblio->{'ccode'};
 569         $ri{itemnumber}       = $biblio->{'itemnumber'};
 570         $ri{barcode}          = $bar_code;
 571         $ri{homebranch}       = $item->{'homebranch'};
 572         $ri{holdingbranch}    = $item->{'holdingbranch'};
 573
 574         $ri{location}         = $biblio->{'location'};
 575         my $shelfcode = $ri{'location'};
 576         $ri{'location'} = $shelflocations->{$shelfcode} if ( defined( $shelfcode ) && defined($shelflocations) && exists( $shelflocations->{$shelfcode} ) );
 577
 578     }
 579     else {
 580         last;
 581     }
 582     push @riloop, \%ri;
 583 }
 584 my ($genbrname, $genprname);
 585 if (my $b = $branches->{$userenv_branch}) {
 586     $genbrname = $b->{'branchname'};
 587 }
 588 if (my $p = $printers->{$printer}) {
 589     $genprname = $p->{'printername'};
 590 }
 591 $template->param(
 592     riloop         => \@riloop,
 593     genbrname      => $genbrname,
 594     genprname      => $genprname,
 595     branchname     => $genbrname,
 596     printer        => $printer,
 597     errmsgloop     => \@errmsgloop,
 598     exemptfine     => $exemptfine,
 599     dropboxmode    => $dropboxmode,
 600     dropboxdate    => output_pref($dropboxdate),
 601     overduecharges => $overduecharges,
 602     soundon        => C4::Context->preference("SoundOn"),
 603     BlockReturnOfWithdrawnItems => C4::Context->preference("BlockReturnOfWithdrawnItems"),
 604 );
 605
 606 $itemnumber = GetItemnumberFromBarcode( $query->param('barcode') );
 607 if ( $itemnumber ) {
 608    my ( $holdingBranch, $collectionBranch ) = GetCollectionItemBranches( $itemnumber );
 609     if ( ! ( $holdingBranch eq $collectionBranch ) ) {
 610         $template->param(
 611           collectionItemNeedsTransferred => 1,
 612           collectionBranch => GetBranchName($collectionBranch),
 613         );
 614     }
 615 }
 616
 617 # actually print the page!
 618 output_html_with_http_headers $query, $cookie, $template->output;