catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use strict;            # always use
 136 #use warnings; FIXME - Bug 2505
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth qw(:DEFAULT get_session);
 146 use C4::Search;
 147 use C4::Languages qw(getLanguages);
 148 use C4::Koha;
 149 use C4::Members qw(GetMember);
 150 use URI::Escape;
 151 use POSIX qw(ceil floor);
 152 use C4::Search::History;
 153
 154 use Koha::LibraryCategories;
 155 use Koha::Virtualshelves;
 156 use Koha::SearchEngine::Search;
 157 use Koha::SearchEngine::QueryBuilder;
 158
 159 use URI::Escape;
 160
 161 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 162 # create a new CGI object
 163 # FIXME: no_undef_params needs to be tested
 164 use CGI qw('-no_undef_params' -utf8 );
 165 my $cgi = new CGI;
 166
 167 # decide which template to use
 168 my $template_name;
 169 my $template_type;
 170 my @params = $cgi->multi_param("limit");
 171 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 172     $template_name = 'catalogue/results.tt';
 173 }
 174 else {
 175     $template_name = 'catalogue/advsearch.tt';
 176     $template_type = 'advsearch';
 177 }
 178 # load the template
 179 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 180     template_name => $template_name,
 181     query => $cgi,
 182     type => "intranet",
 183     authnotrequired => 0,
 184     flagsrequired   => { catalogue => 1 },
 185     }
 186 );
 187
 188 my $lang = C4::Languages::getlanguage($cgi);
 189
 190 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 191     $template->param('UNIMARC' => 1);
 192 }
 193 if (C4::Context->preference("IntranetNumbersPreferPhrase")) {
 194     $template->param('numbersphr' => 1);
 195 }
 196
 197 if($cgi->cookie("holdfor")){
 198     my $holdfor_patron = GetMember('borrowernumber' => $cgi->cookie("holdfor"));
 199     $template->param(
 200         holdfor => $cgi->cookie("holdfor"),
 201         holdfor_surname => $holdfor_patron->{'surname'},
 202         holdfor_firstname => $holdfor_patron->{'firstname'},
 203         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 204     );
 205 }
 206
 207 # get biblionumbers stored in the cart
 208 my @cart_list;
 209
 210 if($cgi->cookie("intranet_bib_list")){
 211     my $cart_list = $cgi->cookie("intranet_bib_list");
 212     @cart_list = split(/\//, $cart_list);
 213 }
 214
 215 # load the branches
 216 my $categories = Koha::LibraryCategories->search( { categorytype => 'searchdomain' }, { order_by => [ 'categorytype', 'categorycode' ] } );
 217
 218 $template->param(
 219     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 220     searchdomainloop => $categories
 221 );
 222
 223 # load the Type stuff
 224 my $itemtypes = GetItemTypes;
 225 # the index parameter is different for item-level itemtypes
 226 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 227 my @advancedsearchesloop;
 228 my $cnt;
 229 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 230 my @advanced_search_types = split(/\|/, $advanced_search_types);
 231
 232 foreach my $advanced_srch_type (@advanced_search_types) {
 233     $advanced_srch_type =~ s/^\s*//;
 234     $advanced_srch_type =~ s/\s*$//;
 235    if ($advanced_srch_type eq 'itemtypes') {
 236    # itemtype is a special case, since it's not defined in authorized values
 237         my @itypesloop;
 238         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 239             my %row =(  number=>$cnt++,
 240                 ccl => "$itype_or_itemtype,phr",
 241                 code => $thisitemtype,
 242                 description => $itemtypes->{$thisitemtype}->{translated_description},
 243                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 244             );
 245             push @itypesloop, \%row;
 246         }
 247         my %search_code = (  advanced_search_type => $advanced_srch_type,
 248                              code_loop => \@itypesloop );
 249         push @advancedsearchesloop, \%search_code;
 250     } else {
 251     # covers all the other cases: non-itemtype authorized values
 252        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 253         my @authvalueloop;
 254         for my $thisitemtype (@$advsearchtypes) {
 255                 my %row =(
 256                                 number=>$cnt++,
 257                                 ccl => $advanced_srch_type,
 258                 code => $thisitemtype->{authorised_value},
 259                 description => $thisitemtype->{'lib'},
 260                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 261                 );
 262                 push @authvalueloop, \%row;
 263         }
 264         my %search_code = (  advanced_search_type => $advanced_srch_type,
 265                              code_loop => \@authvalueloop );
 266         push @advancedsearchesloop, \%search_code;
 267     }
 268 }
 269 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 270 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 271 my $advancedsearchesloop = prepare_adv_search_types($types);
 272 $template->param(advancedsearchesloop => $advancedsearchesloop);
 273
 274 # The following should only be loaded if we're bringing up the advanced search template
 275 if ( $template_type eq 'advsearch' ) {
 276
 277     # load the servers (used for searching -- to do federated searching, etc.)
 278     my $primary_servers_loop;# = displayPrimaryServers();
 279     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 280
 281     my $secondary_servers_loop;
 282     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 283
 284     # set the default sorting
 285     if (   C4::Context->preference('OPACdefaultSortField')
 286         && C4::Context->preference('OPACdefaultSortOrder') ) {
 287         my $default_sort_by =
 288             C4::Context->preference('defaultSortField') . '_'
 289           . C4::Context->preference('defaultSortOrder');
 290         $template->param( sort_by => $default_sort_by  );
 291     }
 292
 293     # determine what to display next to the search boxes (ie, boolean option
 294     # shouldn't appear on the first one, scan indexes should, adding a new
 295     # box should only appear on the last, etc.
 296     my @search_boxes_array;
 297     my $search_boxes_count = 3; # begin whith 3 boxes
 298     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 299     for (my $i=1;$i<=$search_boxes_count;$i++) {
 300         # if it's the first one, don't display boolean option, but show scan indexes
 301         if ($i==1) {
 302             push @search_boxes_array, {scan_index => 1};
 303         }
 304         # if it's the last one, show the 'add field' box
 305         elsif ($i==$search_boxes_count) {
 306             push @search_boxes_array,
 307                 {
 308                 boolean => 1,
 309                 add_field => 1,
 310                 };
 311         }
 312         else {
 313             push @search_boxes_array,
 314                 {
 315                 boolean => 1,
 316                 };
 317         }
 318
 319     }
 320     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 321                       search_boxes_loop => \@search_boxes_array);
 322
 323     # load the language limits (for search)
 324     my $languages_limit_loop = getLanguages($lang, 1);
 325     $template->param(search_languages_loop => $languages_limit_loop,);
 326
 327     # Expanded search options in advanced search:
 328     # use the global setting by default, but let the user override it
 329     {
 330         my $expanded = $cgi->param('expanded_options');
 331         $expanded = C4::Context->preference("expandedSearchOption") || 0
 332             if !defined($expanded) || $expanded !~ /^0|1$/;
 333         $template->param( expanded_options => $expanded );
 334     }
 335
 336     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 337
 338     output_html_with_http_headers $cgi, $cookie, $template->output;
 339     exit;
 340 }
 341
 342 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 343
 344 # Fetch the paramater list as a hash in scalar context:
 345 #  * returns paramater list as tied hash ref
 346 #  * we can edit the values by changing the key
 347 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 348 my $params = $cgi->Vars;
 349
 350 # Params that can have more than one value
 351 # sort by is used to sort the query
 352 # in theory can have more than one but generally there's just one
 353 my @sort_by;
 354 my $default_sort_by;
 355 if (   C4::Context->preference('defaultSortField')
 356     && C4::Context->preference('defaultSortOrder') ) {
 357     $default_sort_by =
 358         C4::Context->preference('defaultSortField') . '_'
 359       . C4::Context->preference('defaultSortOrder');
 360 }
 361
 362 @sort_by = $cgi->multi_param('sort_by');
 363 $sort_by[0] = $default_sort_by unless $sort_by[0];
 364 foreach my $sort (@sort_by) {
 365     $template->param($sort => 1) if $sort;
 366 }
 367 $template->param('sort_by' => $sort_by[0]);
 368
 369 # Use the servers defined, or just search our local catalog(default)
 370 my @servers = $cgi->multi_param('server');
 371 unless (@servers) {
 372     #FIXME: this should be handled using Context.pm
 373     @servers = ("biblioserver");
 374     # @servers = C4::Context->config("biblioserver");
 375 }
 376 # operators include boolean and proximity operators and are used
 377 # to evaluate multiple operands
 378 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 379
 380 # indexes are query qualifiers, like 'title', 'author', etc. They
 381 # can be single or multiple parameters separated by comma: kw,right-Truncation
 382 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 383
 384 # if a simple index (only one)  display the index used in the top search box
 385 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 386     my $idx = "ms_".$indexes[0];
 387     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 388     $template->param($idx => 1);
 389 }
 390
 391 # an operand can be a single term, a phrase, or a complete ccl query
 392 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 393
 394 # limits are use to limit to results to a pre-defined category such as branch or language
 395 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 396 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 397 my %is_nolimit = map { $_ => 1 } @nolimits;
 398 @limits = grep { not $is_nolimit{$_} } @limits;
 399
 400 if($params->{'multibranchlimit'}) {
 401     my $library_category = Koha::LibraryCategories->find( $params->{multibranchlimit} );
 402     my @libraries = $library_category->libraries;
 403     my $multibranch = '('.join( " or ", map { 'branch: ' . $_->id } @libraries ) .')';
 404     push @limits, $multibranch if ($multibranch ne  '()');
 405 }
 406
 407 my $available;
 408 foreach my $limit(@limits) {
 409     if ($limit =~/available/) {
 410         $available = 1;
 411     }
 412 }
 413 $template->param(available => $available);
 414
 415 # append year limits if they exist
 416 my $limit_yr;
 417 my $limit_yr_value;
 418 if ($params->{'limit-yr'}) {
 419     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 420         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 421         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 422         $limit_yr_value = "$yr1-$yr2";
 423     }
 424     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 425         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 426         $limit_yr_value = $params->{'limit-yr'};
 427     }
 428     push @limits,$limit_yr;
 429     #FIXME: Should return a error to the user, incorect date format specified
 430 }
 431
 432 # convert indexes and operands to corresponding parameter names for the z3950 search
 433 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 434 my $z3950par;
 435 my $indexes2z3950 = {
 436     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 437     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 438     ti=>'title', 'ti,phr'=>'title', se=>'title'
 439 };
 440 for (my $ii = 0; $ii < @operands; ++$ii)
 441 {
 442     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 443     if (defined $name && defined $operands[$ii])
 444     {
 445         $z3950par ||= {};
 446         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 447     }
 448 }
 449
 450
 451 # Params that can only have one value
 452 my $scan = $params->{'scan'};
 453 my $count = C4::Context->preference('numSearchResults') || 20;
 454 my $results_per_page = $params->{'count'} || $count;
 455 my $offset = $params->{'offset'} || 0;
 456 my $page = $cgi->param('page') || 1;
 457 #my $offset = ($page-1)*$results_per_page;
 458 my $hits;
 459 my $expanded_facet = $params->{'expand'};
 460
 461 # Define some global variables
 462 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 463
 464 my $builder = Koha::SearchEngine::QueryBuilder->new(
 465     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 466 my $searcher = Koha::SearchEngine::Search->new(
 467     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 468
 469 ## I. BUILD THE QUERY
 470 (
 471     $error,             $query, $simple_query, $query_cgi,
 472     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 473     $query_type
 474   )
 475   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 476     \@sort_by, $scan, $lang );
 477
 478 ## parse the query_cgi string and put it into a form suitable for <input>s
 479 my @query_inputs;
 480 my $scan_index_to_use;
 481 my $scan_search_term_to_use;
 482
 483 for my $this_cgi ( split('&',$query_cgi) ) {
 484     next unless $this_cgi;
 485     $this_cgi =~ m/(.*?)=(.*)/;
 486     my $input_name = $1;
 487     my $input_value = $2;
 488     push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 489     if ($input_name eq 'idx') {
 490         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 491     }
 492     if ($input_name eq 'q') {
 493         $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 494     }
 495 }
 496 $template->param ( QUERY_INPUTS => \@query_inputs,
 497                    scan_index_to_use => $scan_index_to_use,
 498                    scan_search_term_to_use => $scan_search_term_to_use );
 499
 500 ## parse the limit_cgi string and put it into a form suitable for <input>s
 501 my @limit_inputs;
 502 for my $this_cgi ( split('&',$limit_cgi) ) {
 503     next unless $this_cgi;
 504     # handle special case limit-yr
 505     if ($this_cgi =~ /yr,st-numeric/) {
 506         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 507         next;
 508     }
 509     $this_cgi =~ m/(.*=)(.*)/;
 510     my $input_name = $1;
 511     my $input_value = $2;
 512     $input_name =~ s/=$//;
 513     push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 514 }
 515 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 516
 517 ## II. DO THE SEARCH AND GET THE RESULTS
 518 my $total; # the total results for the whole set
 519 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 520 my $results_hashref;
 521
 522 eval {
 523     my $itemtypes = GetItemTypes;
 524     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 525         $query,            $simple_query, \@sort_by,       \@servers,
 526         $results_per_page, $offset,       $expanded_facet, undef,
 527         $itemtypes,        $query_type,   $scan
 528     );
 529 };
 530
 531 if ($@ || $error) {
 532     $template->param(query_error => $error.$@);
 533     output_html_with_http_headers $cgi, $cookie, $template->output;
 534     exit;
 535 }
 536
 537 # At this point, each server has given us a result set
 538 # now we build that set for template display
 539 my @sup_results_array;
 540 for (my $i=0;$i<@servers;$i++) {
 541     my $server = $servers[$i];
 542     if ($server =~/biblioserver/) { # this is the local bibliographic server
 543         $hits = $results_hashref->{$server}->{"hits"};
 544         my $page = $cgi->param('page') || 0;
 545         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 546                                        $results_hashref->{$server}->{"RECORDS"});
 547         $total = $total + $results_hashref->{$server}->{"hits"};
 548
 549         # Search history
 550         if (C4::Context->preference('EnableSearchHistory')) {
 551             unless ( $offset ) {
 552                 my $path_info = $cgi->url(-path_info=>1);
 553                 my $query_cgi_history = $cgi->url(-query=>1);
 554                 $query_cgi_history =~ s/^$path_info\?//;
 555                 $query_cgi_history =~ s/;/&/g;
 556                 my $query_desc_history = $query_desc;
 557                 $query_desc_history .= ", $limit_desc"
 558                     if $limit_desc;
 559
 560                 C4::Search::History::add({
 561                     userid => $borrowernumber,
 562                     sessionid => $cgi->cookie("CGISESSID"),
 563                     query_desc => $query_desc_history,
 564                     query_cgi => $query_cgi_history,
 565                     total => $total,
 566                     type => "biblio",
 567                 });
 568             }
 569             $template->param( EnableSearchHistory => 1 );
 570         }
 571
 572         ## If there's just one result, redirect to the detail page
 573         if ($total == 1) {
 574             my $biblionumber = $newresults[0]->{biblionumber};
 575             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 576             my $views = { C4::Search::enabled_staff_search_views };
 577             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 578                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 579             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 580                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 581             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 582                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 583             } else {
 584                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 585             }
 586             exit;
 587         }
 588
 589         # set up parameters if user wishes to re-run the search
 590         # as a Z39.50 search
 591         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 592
 593         if ($hits) {
 594             $template->param(total => $hits);
 595             my $limit_cgi_not_availablity = $limit_cgi;
 596             $limit_cgi_not_availablity =~ s/&limit=available//g;
 597             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 598             $template->param(limit_cgi => $limit_cgi);
 599             $template->param(query_cgi => $query_cgi);
 600             $template->param(query_desc => $query_desc);
 601             $template->param(limit_desc => $limit_desc);
 602             $template->param(offset     => $offset);
 603             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 604             if ($query_desc || $limit_desc) {
 605                 $template->param(searchdesc => 1);
 606             }
 607             $template->param(results_per_page =>  $results_per_page);
 608             # must define a value for size if not present in DB
 609             # in order to avoid problems generated by the default size value in TT
 610             foreach my $line (@newresults) {
 611                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 612                 # while we're checking each line, see if item is in the cart
 613                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 614                     $line->{'incart'} = 1;
 615                 }
 616             }
 617             $template->param(SEARCH_RESULTS => \@newresults);
 618             ## FIXME: add a global function for this, it's better than the current global one
 619             ## Build the page numbers on the bottom of the page
 620             my @page_numbers;
 621             # total number of pages there will be
 622             my $pages = ceil($hits / $results_per_page);
 623             # default page number
 624             my $current_page_number = 1;
 625             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 626             my $previous_page_offset;
 627             if ( $offset >= $results_per_page ) {
 628                 $previous_page_offset = $offset - $results_per_page;
 629             }
 630             my $next_page_offset = $offset + $results_per_page;
 631             # If we're within the first 10 pages, keep it simple
 632             #warn "current page:".$current_page_number;
 633             if ($current_page_number < 10) {
 634                 # just show the first 10 pages
 635                 # Loop through the pages
 636                 my $pages_to_show = 10;
 637                 $pages_to_show = $pages if $pages<10;
 638                 for (my $i=1; $i<=$pages_to_show;$i++) {
 639                     # the offset for this page
 640                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 641                     # the page number for this page
 642                     my $this_page_number = $i;
 643                     # put it in the array
 644                     push @page_numbers,
 645                       { offset    => $this_offset,
 646                         pg        => $this_page_number,
 647                         # it should only be highlighted if it's the current page
 648                         highlight => $this_page_number == $current_page_number,
 649                         sort_by   => join ' ', @sort_by
 650                       };
 651
 652                 }
 653
 654             }
 655
 656             # now, show twenty pages, with the current one smack in the middle
 657             else {
 658                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 659                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 660                     my $this_page_number = $i-9;
 661                     if ( $this_page_number <= $pages ) {
 662                         push @page_numbers,
 663                           { offset    => $this_offset,
 664                             pg        => $this_page_number,
 665                             highlight => $this_page_number == $current_page_number,
 666                             sort_by   => join ' ', @sort_by
 667                           };
 668                     }
 669                 }
 670             }
 671             # FIXME: no previous_page_offset when pages < 2
 672             $template->param(   PAGE_NUMBERS => \@page_numbers,
 673                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 674             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 675         }
 676
 677
 678         # no hits
 679         else {
 680             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 681         }
 682
 683     } # end of the if local
 684
 685     # asynchronously search the authority server
 686     elsif ($server =~/authorityserver/) { # this is the local authority server
 687         my @inner_sup_results_array;
 688         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 689             my $marc_record_object = C4::Search::new_record_from_zebra(
 690                 'authorityserver',
 691                 $sup_record
 692             );
 693             # warn "Authority Found: ".$marc_record_object->as_formatted();
 694             push @inner_sup_results_array, {
 695                 'title' => $marc_record_object->field(100)->subfield('a'),
 696                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 697             };
 698         }
 699         push @sup_results_array, {  servername => $server,
 700                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 701     }
 702     # FIXME: can add support for other targets as needed here
 703     $template->param(           outer_sup_results_loop => \@sup_results_array);
 704 } #/end of the for loop
 705 #$template->param(FEDERATED_RESULTS => \@results_array);
 706
 707 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 708
 709 my $gotonumber = $cgi->param('gotoNumber');
 710 if ($gotonumber eq 'last' || $gotonumber eq 'first') {
 711     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 712 }
 713 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 714 my $gotopage = $cgi->param('gotoPage');
 715 $template->{'VARS'}->{'gotoPage'} = $gotopage
 716   if $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 717
 718 for my $facet ( @$facets ) {
 719     for my $entry ( @{ $facet->{facets} } ) {
 720         my $index = $entry->{type_link_value};
 721         my $value = $entry->{facet_link_value};
 722         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 723     }
 724 }
 725
 726 $template->param(
 727             #classlist => $classlist,
 728             total => $total,
 729             opacfacets => 1,
 730             facets_loop => $facets,
 731             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 732             scan => $scan,
 733             search_error => $error,
 734 );
 735
 736 if ($query_desc || $limit_desc) {
 737     $template->param(searchdesc => 1);
 738 }
 739
 740 # VI. BUILD THE TEMPLATE
 741
 742 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 743     {
 744         borrowernumber => $borrowernumber,
 745         add_allowed    => 1,
 746         category       => 1,
 747     }
 748 );
 749 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 750     {
 751         borrowernumber => $borrowernumber,
 752         add_allowed    => 1,
 753         category       => 2,
 754     }
 755 );
 756
 757
 758 $template->param(
 759     add_to_some_private_shelves => $some_private_shelves,
 760     add_to_some_public_shelves  => $some_public_shelves,
 761 );
 762
 763 output_html_with_http_headers $cgi, $cookie, $template->output;
 764
 765
 766 =head2 prepare_adv_search_types
 767
 768     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 769     my @advanced_search_types = prepare_adv_search_types($type);
 770
 771 Different types can be searched for in the advanced search. This takes the
 772 system preference that defines these types and parses it into an arrayref for
 773 the template.
 774
 775 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 776 It also accounts for the "item-level_itypes" system preference.
 777
 778 =cut
 779
 780 sub prepare_adv_search_types {
 781     my ($types) = @_;
 782
 783     my @advanced_search_types = split( /\|/, $types );
 784
 785     # the index parameter is different for item-level itemtypes
 786     my $itype_or_itemtype =
 787       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 788     my $itemtypes = GetItemTypes;
 789
 790     my ( $cnt, @result );
 791     foreach my $advanced_srch_type (@advanced_search_types) {
 792         $advanced_srch_type =~ s/^\s*//;
 793         $advanced_srch_type =~ s/\s*$//;
 794         if ( $advanced_srch_type eq 'itemtypes' ) {
 795
 796        # itemtype is a special case, since it's not defined in authorized values
 797             my @itypesloop;
 798             foreach my $thisitemtype (
 799                 sort {
 800                     $itemtypes->{$a}->{'translated_description'}
 801                       cmp $itemtypes->{$b}->{'translated_description'}
 802                 } keys %$itemtypes
 803               )
 804             {
 805                 my %row = (
 806                     number      => $cnt++,
 807                     ccl         => "$itype_or_itemtype,phr",
 808                     code        => $thisitemtype,
 809                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 810                     imageurl    => getitemtypeimagelocation(
 811                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 812                     ),
 813                 );
 814                 push @itypesloop, \%row;
 815             }
 816             my %search_code = (
 817                 advanced_search_type => $advanced_srch_type,
 818                 code_loop            => \@itypesloop
 819             );
 820             push @result, \%search_code;
 821         }
 822         else {
 823             # covers all the other cases: non-itemtype authorized values
 824             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 825             my @authvalueloop;
 826             for my $thisitemtype (@$advsearchtypes) {
 827                 my %row = (
 828                     number      => $cnt++,
 829                     ccl         => $advanced_srch_type,
 830                     code        => $thisitemtype->{authorised_value},
 831                     description => $thisitemtype->{'lib'},
 832                     imageurl    => getitemtypeimagelocation(
 833                         'intranet', $thisitemtype->{'imageurl'}
 834                     ),
 835                 );
 836                 push @authvalueloop, \%row;
 837             }
 838             my %search_code = (
 839                 advanced_search_type => $advanced_srch_type,
 840                 code_loop            => \@authvalueloop
 841             );
 842             push @result, \%search_code;
 843         }
 844     }
 845     return \@result;
 846 }