C4/ItemType.pm

   1 package C4::ItemType;
   2
   3 # Copyright Liblime 2009
   4 # Parts Copyright Tamil 2011
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it under the
   9 # terms of the GNU General Public License as published by the Free Software
  10 # Foundation; either version 2 of the License, or (at your option) any later
  11 # version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  14 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  15 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License along
  18 # with Koha; if not, write to the Free Software Foundation, Inc.,
  19 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  20
  21 use strict;
  22 use warnings;
  23 use C4::Context;
  24 use Encode qw( encode );
  25
  26 our $AUTOLOAD;
  27
  28
  29
  30
  31 =head1 NAME
  32
  33 C4::ItemType - objects from the itemtypes table
  34
  35 =head1 SYNOPSIS
  36
  37     use C4::ItemType;
  38     my @itemtypes = C4::ItemType->all;
  39     print join("\n", map { $_->description } @itemtypes), "\n";
  40
  41 =head1 DESCRIPTION
  42
  43 Objects of this class represent a row in the C<itemtypes> table.
  44
  45 Currently, the bare minimum for using this as a read-only data source has
  46 been implemented.  The API was designed to make it easy to transition to
  47 an ORM later on.
  48
  49 =head1 API
  50
  51 =head2 Class Methods
  52
  53 =cut
  54
  55 =head3 C4::ItemType->new(\%opts)
  56
  57 Given a hashref, a new (in-memory) C4::ItemType object will be instantiated.
  58 The database is not touched.
  59
  60 =cut
  61
  62 sub new {
  63     my ($class, $opts) = @_;
  64     bless $opts => $class;
  65 }
  66
  67
  68
  69
  70 =head3 C4::ItemType->all
  71
  72 This returns all the itemtypes as objects.  By default they're ordered by
  73 C<description>.
  74
  75 =cut
  76
  77 sub all {
  78     my ($class) = @_;
  79     my $dbh = C4::Context->dbh;
  80
  81     my @itypes;
  82     for ( @{$dbh->selectall_arrayref(
  83         "SELECT * FROM itemtypes ORDER BY description", { Slice => {} })} )
  84     {
  85         push @itypes, $class->new($_);
  86     }
  87     return @itypes;
  88 }
  89
  90
  91
  92
  93 =head3 C4::ItemType->get
  94
  95 Return the itemtype indicated by the itemtype given as argument, as
  96 an object.
  97
  98 =cut
  99
 100 sub get {
 101     my ($class, $itemtype) = @_;
 102     my $dbh = C4::Context->dbh;
 103
 104     my $data = $dbh->selectrow_hashref(
 105         "SELECT * FROM itemtypes WHERE itemtype = ?", undef, $itemtype
 106     );
 107     return $class->new($data);
 108 }
 109
 110
 111
 112
 113 =head2 Object Methods
 114
 115 These are read-only accessors for attributes of a C4::ItemType object.
 116
 117 =head3 $itemtype->itemtype
 118
 119 =cut
 120
 121 =head3 $itemtype->description
 122
 123 =cut
 124
 125 =head3 $itemtype->renewalsallowed
 126
 127 =cut
 128
 129 =head3 $itemtype->rentalcharge
 130
 131 =cut
 132
 133 =head3 $itemtype->notforloan
 134
 135 =cut
 136
 137 =head3 $itemtype->imageurl
 138
 139 =cut
 140
 141 =head3 $itemtype->checkinmsg
 142
 143 =cut
 144
 145 =head3 $itemtype->summary
 146
 147 =cut
 148
 149 sub AUTOLOAD {
 150     my $self = shift;
 151     my $attr = $AUTOLOAD;
 152     $attr =~ s/.*://;
 153     if (exists $self->{$attr}) {
 154         return $self->{$attr};
 155     } else {
 156         return undef;
 157     }
 158 }
 159
 160 sub DESTROY { }
 161
 162
 163
 164 # ack itemtypes | grep '\.pm' | awk '{ print $1 }' | sed 's/:.*$//' | sort | uniq | sed -e 's,/,::,g' -e 's/\.pm//' -e 's/^/L<C4::/' -e 's/$/>,/'
 165
 166 =head1 SEE ALSO
 167
 168 The following modules make reference to the C<itemtypes> table.
 169
 170 L<C4::Biblio>,
 171 L<C4::Circulation>,
 172 L<C4::Context>,
 173 L<C4::Items>,
 174 L<C4::Koha>,
 175 L<C4::Labels>,
 176 L<C4::Overdues>,
 177 L<C4::Reserves>,
 178 L<C4::Search>,
 179 L<C4::VirtualShelves::Page>,
 180 L<C4::VirtualShelves>,
 181 L<C4::XSLT>
 182
 183
 184
 185 =head1 AUTHOR
 186
 187 John Beppu <john.beppu@liblime.com>
 188
 189 =cut
 190
 191 1;