about.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Pat Eyler 2003
   4 # Copyright Biblibre 2006
   5 # Parts Copyright Liblime 2008
   6 # Parts Copyright Chris Nighswonger 2010
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24
  25 use CGI qw ( -utf8 );
  26 use DateTime::TimeZone;
  27 use File::Spec;
  28 use List::MoreUtils qw/ any /;
  29 use LWP::Simple;
  30 use Module::Load::Conditional qw(can_load);
  31 use XML::Simple;
  32 use Config;
  33 use Search::Elasticsearch;
  34 use Try::Tiny;
  35 use YAML qw/LoadFile/;
  36
  37 use C4::Output;
  38 use C4::Auth;
  39 use C4::Context;
  40 use C4::Installer;
  41
  42 use Koha;
  43 use Koha::DateUtils qw(dt_from_string output_pref);
  44 use Koha::Acquisition::Currencies;
  45 use Koha::Patron::Categories;
  46 use Koha::Patrons;
  47 use Koha::Caches;
  48 use Koha::Config::SysPrefs;
  49 use Koha::Illrequest::Config;
  50 use Koha::SearchEngine::Elasticsearch;
  51
  52 use C4::Members::Statistics;
  53
  54
  55 #use Smart::Comments '####';
  56
  57 my $query = new CGI;
  58 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  59     {
  60         template_name   => "about.tt",
  61         query           => $query,
  62         type            => "intranet",
  63         authnotrequired => 0,
  64         flagsrequired   => { catalogue => 1 },
  65         debug           => 1,
  66     }
  67 );
  68
  69 my $config_timezone = C4::Context->config('timezone') // '';
  70 my $config_invalid  = !DateTime::TimeZone->is_valid_name( $config_timezone );
  71 my $env_timezone    = $ENV{TZ} // '';
  72 my $env_invalid     = !DateTime::TimeZone->is_valid_name( $env_timezone );
  73 my $actual_bad_tz_fallback = 0;
  74
  75 if ( $config_timezone ne '' &&
  76      $config_invalid ) {
  77     # Bad config
  78     $actual_bad_tz_fallback = 1;
  79 }
  80 elsif ( $config_timezone eq '' &&
  81         $env_timezone    ne '' &&
  82         $env_invalid ) {
  83     # No config, but bad ENV{TZ}
  84     $actual_bad_tz_fallback = 1;
  85 }
  86
  87 my $time_zone = {
  88     actual                 => C4::Context->tz->name,
  89     actual_bad_tz_fallback => $actual_bad_tz_fallback,
  90     config                 => $config_timezone,
  91     config_invalid         => $config_invalid,
  92     environment            => $env_timezone,
  93     environment_invalid    => $env_invalid
  94 };
  95
  96 $template->param(
  97     time_zone              => $time_zone,
  98     current_date_and_time  => output_pref({ dt => dt_from_string(), dateformat => 'iso' })
  99 );
 100
 101 my $perl_path = $^X;
 102 if ($^O ne 'VMS') {
 103     $perl_path .= $Config{_exe} unless $perl_path =~ m/$Config{_exe}$/i;
 104 }
 105
 106 my $zebraVersion = `zebraidx -V`;
 107
 108 # Check running PSGI env
 109 if ( any { /(^psgi\.|^plack\.)/i } keys %ENV ) {
 110     $template->param(
 111         is_psgi => 1,
 112         psgi_server => ($ENV{ PLACK_ENV }) ? "Plack ($ENV{PLACK_ENV})" :
 113                        ($ENV{ MOD_PERL })  ? "mod_perl ($ENV{MOD_PERL})" :
 114                                              'Unknown'
 115     );
 116 }
 117
 118 # Memcached configuration
 119 my $memcached_servers   = $ENV{MEMCACHED_SERVERS} || C4::Context->config('memcached_servers');
 120 my $memcached_namespace = $ENV{MEMCACHED_NAMESPACE} || C4::Context->config('memcached_namespace') // 'koha';
 121
 122 my $cache = Koha::Caches->get_instance;
 123 my $effective_caching_method = ref($cache->cache);
 124 # Memcached may have been running when plack has been initialized but could have been stopped since
 125 # FIXME What are the consequences of that??
 126 my $is_memcached_still_active = $cache->set_in_cache('test_for_about_page', "just a simple value");
 127
 128 my $where_is_memcached_config = 'nowhere';
 129 if ( $ENV{MEMCACHED_SERVERS} and C4::Context->config('memcached_servers') ) {
 130     $where_is_memcached_config = 'both';
 131 } elsif ( $ENV{MEMCACHED_SERVERS} and not C4::Context->config('memcached_servers') ) {
 132     $where_is_memcached_config = 'ENV_only';
 133 } elsif ( C4::Context->config('memcached_servers') ) {
 134     $where_is_memcached_config = 'config_only';
 135 }
 136
 137 $template->param(
 138     effective_caching_method => $effective_caching_method,
 139     memcached_servers   => $memcached_servers,
 140     memcached_namespace => $memcached_namespace,
 141     is_memcached_still_active => $is_memcached_still_active,
 142     where_is_memcached_config => $where_is_memcached_config,
 143     memcached_running   => Koha::Caches->get_instance->memcached_cache,
 144 );
 145
 146 # Additional system information for warnings
 147
 148 my $warnStatisticsFieldsError;
 149 my $prefStatisticsFields = C4::Context->preference('StatisticsFields');
 150 if ($prefStatisticsFields) {
 151     $warnStatisticsFieldsError = $prefStatisticsFields
 152         unless ( $prefStatisticsFields eq C4::Members::Statistics->get_fields() );
 153 }
 154
 155 my $prefAutoCreateAuthorities = C4::Context->preference('AutoCreateAuthorities');
 156 my $prefBiblioAddsAuthorities = C4::Context->preference('BiblioAddsAuthorities');
 157 my $warnPrefBiblioAddsAuthorities = ( $prefAutoCreateAuthorities && ( !$prefBiblioAddsAuthorities) );
 158
 159 my $prefEasyAnalyticalRecords  = C4::Context->preference('EasyAnalyticalRecords');
 160 my $prefUseControlNumber  = C4::Context->preference('UseControlNumber');
 161 my $warnPrefEasyAnalyticalRecords  = ( $prefEasyAnalyticalRecords  && $prefUseControlNumber );
 162
 163 my $AnonymousPatron = C4::Context->preference('AnonymousPatron');
 164 my $warnPrefAnonymousPatronOPACPrivacy = (
 165     C4::Context->preference('OPACPrivacy')
 166         and not $AnonymousPatron
 167 );
 168 my $warnPrefAnonymousPatronAnonSuggestions = (
 169     C4::Context->preference('AnonSuggestions')
 170         and not $AnonymousPatron
 171 );
 172
 173 my $anonymous_patron = Koha::Patrons->find( $AnonymousPatron );
 174 my $warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist = ( $AnonymousPatron && C4::Context->preference('AnonSuggestions') && not $anonymous_patron );
 175
 176 my $warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist = ( not $anonymous_patron and Koha::Patrons->search({ privacy => 2 })->count );
 177
 178 my $errZebraConnection = C4::Context->Zconn("biblioserver",0)->errcode();
 179
 180 my $warnIsRootUser   = (! $loggedinuser);
 181
 182 my $warnNoActiveCurrency = (! defined Koha::Acquisition::Currencies->get_active);
 183
 184 my @xml_config_warnings;
 185
 186 my $context = new C4::Context;
 187
 188 if (    C4::Context->config('zebra_bib_index_mode')
 189     and C4::Context->config('zebra_bib_index_mode') eq 'grs1' )
 190 {
 191     push @xml_config_warnings, { error => 'zebra_bib_index_mode_is_grs1' };
 192 }
 193
 194 if (    C4::Context->config('zebra_auth_index_mode')
 195     and C4::Context->config('zebra_auth_index_mode') eq 'grs1' )
 196 {
 197     push @xml_config_warnings, { error => 'zebra_auth_index_mode_is_grs1' };
 198 }
 199
 200 if ( (C4::Context->config('zebra_auth_index_mode') eq 'dom') && ($context->{'server'}->{'authorityserver'}->{'config'} !~ /zebra-authorities-dom.cfg/) ) {
 201     push @xml_config_warnings, {
 202         error => 'zebra_auth_index_mode_mismatch_warn'
 203     };
 204 }
 205
 206 if ( ! defined C4::Context->config('log4perl_conf') ) {
 207     push @xml_config_warnings, {
 208         error => 'log4perl_entry_missing'
 209     }
 210 }
 211
 212 if ( ! defined C4::Context->config('upload_path') ) {
 213     if ( Koha::Config::SysPrefs->find('OPACBaseURL')->value ) {
 214         # OPACBaseURL seems to be set
 215         push @xml_config_warnings, {
 216             error => 'uploadpath_entry_missing'
 217         }
 218     } else {
 219         push @xml_config_warnings, {
 220             error => 'uploadpath_and_opacbaseurl_entry_missing'
 221         }
 222     }
 223 }
 224
 225 if ( ! C4::Context->config('tmp_path') ) {
 226     my $temporary_directory = C4::Context::temporary_directory;
 227     push @xml_config_warnings, {
 228         error             => 'tmp_path_missing',
 229         effective_tmp_dir => $temporary_directory,
 230     }
 231 }
 232
 233 # Test QueryParser configuration sanity
 234 if ( C4::Context->preference( 'UseQueryParser' ) ) {
 235     # Get the QueryParser configuration file name
 236     my $queryparser_file          = C4::Context->config( 'queryparser_config' );
 237     my $queryparser_fallback_file = '/etc/koha/searchengine/queryparser.yaml';
 238     # Check QueryParser is functional
 239     my $QParser = C4::Context->queryparser();
 240     my $queryparser_error = {};
 241     if ( ! defined $QParser || ref($QParser) ne 'Koha::QueryParser::Driver::PQF' ) {
 242         # Error initializing the QueryParser object
 243         # Get the used queryparser.yaml file path to report the user
 244         $queryparser_error->{ fallback } = ( defined $queryparser_file ) ? 0 : 1;
 245         $queryparser_error->{ file }     = ( defined $queryparser_file )
 246                                                 ? $queryparser_file
 247                                                 : $queryparser_fallback_file;
 248         # Report error data to the template
 249         $template->param( QueryParserError => $queryparser_error );
 250     } else {
 251         # Check for an absent queryparser_config entry in koha-conf.xml
 252         if ( ! defined $queryparser_file ) {
 253             # Not an error but a warning for the missing entry in koha-conf-xml
 254             push @xml_config_warnings, {
 255                     error => 'queryparser_entry_missing',
 256                     file  => $queryparser_fallback_file
 257             };
 258         }
 259     }
 260 }
 261
 262 # Test Zebra facets configuration
 263 if ( !defined C4::Context->config('use_zebra_facets') ) {
 264     push @xml_config_warnings, { error => 'use_zebra_facets_entry_missing' };
 265 }
 266
 267 # ILL module checks
 268 if ( C4::Context->preference('ILLModule') ) {
 269     my $warnILLConfiguration = 0;
 270     my $ill_config_from_file = C4::Context->config("interlibrary_loans");
 271     my $ill_config = Koha::Illrequest::Config->new;
 272
 273     my $available_ill_backends =
 274       ( scalar @{ $ill_config->available_backends } > 0 );
 275
 276     # Check backends
 277     if ( !$available_ill_backends ) {
 278         $template->param( no_ill_backends => 1 );
 279         $warnILLConfiguration = 1;
 280     }
 281
 282     # Check partner_code
 283     if ( !Koha::Patron::Categories->find($ill_config->partner_code) ) {
 284         $template->param( ill_partner_code_doesnt_exist => $ill_config->partner_code );
 285         $warnILLConfiguration = 1;
 286     }
 287
 288     if ( !$ill_config_from_file->{partner_code} ) {
 289         # partner code not defined
 290         $template->param( ill_partner_code_not_defined => 1 );
 291         $warnILLConfiguration = 1;
 292     }
 293
 294
 295     if ( !$ill_config_from_file->{branch} ) {
 296         # branch not defined
 297         $template->param( ill_branch_not_defined => 1 );
 298         $warnILLConfiguration = 1;
 299     }
 300
 301     $template->param( warnILLConfiguration => $warnILLConfiguration );
 302 }
 303
 304 if ( C4::Context->preference('SearchEngine') eq 'Elasticsearch' ) {
 305     # Check ES configuration health and runtime status
 306
 307     my $es_status;
 308     my $es_config_error;
 309     my $es_running = 1;
 310
 311     my $es_conf;
 312     try {
 313         $es_conf = Koha::SearchEngine::Elasticsearch::_read_configuration();
 314     }
 315     catch {
 316         if ( ref($_) eq 'Koha::Exceptions::Config::MissingEntry' ) {
 317             $template->param( elasticsearch_fatal_config_error => $_->message );
 318             $es_config_error = 1;
 319         }
 320     };
 321     if ( !$es_config_error ) {
 322
 323         my $biblios_index_name     = $es_conf->{index_name} . "_" . $Koha::SearchEngine::BIBLIOS_INDEX;
 324         my $authorities_index_name = $es_conf->{index_name} . "_" . $Koha::SearchEngine::AUTHORITIES_INDEX;
 325
 326         my @indexes = ($biblios_index_name, $authorities_index_name);
 327         # TODO: When new indexes get added, we could have other ways to
 328         #       fetch the list of available indexes (e.g. plugins, etc)
 329         $es_status->{nodes} = $es_conf->{nodes};
 330         my $es = Search::Elasticsearch->new({ nodes => $es_conf->{nodes} });
 331
 332         foreach my $index ( @indexes ) {
 333             my $count;
 334             try {
 335                 $count = $es->indices->stats( index => $index )
 336                       ->{_all}{primaries}{docs}{count};
 337             }
 338             catch {
 339                 if ( ref($_) eq 'Search::Elasticsearch::Error::Missing' ) {
 340                     push @{ $es_status->{errors} }, "Index not found ($index)";
 341                     $count = -1;
 342                 }
 343                 elsif ( ref($_) eq 'Search::Elasticsearch::Error::NoNodes' ) {
 344                     $es_running = 0;
 345                 }
 346                 else {
 347                     # TODO: when time comes, we will cover more use cases
 348                     die $_;
 349                 }
 350             };
 351
 352             push @{ $es_status->{indexes} },
 353               {
 354                 index_name => $index,
 355                 count      => $count
 356               };
 357         }
 358         $es_status->{running} = $es_running;
 359
 360         $template->param( elasticsearch_status => $es_status );
 361     }
 362 }
 363
 364 if ( C4::Context->preference('RESTOAuth2ClientCredentials') ) {
 365     # Do we have the required deps?
 366     unless ( can_load( modules => { 'Net::OAuth2::AuthorizationServer' => undef }) ) {
 367         $template->param( oauth2_missing_deps => 1 );
 368     }
 369 }
 370
 371 # Sco Patron should not contain any other perms than circulate => self_checkout
 372 if (  C4::Context->preference('WebBasedSelfCheck')
 373       and C4::Context->preference('AutoSelfCheckAllowed')
 374 ) {
 375     my $userid = C4::Context->preference('AutoSelfCheckID');
 376     my $all_permissions = C4::Auth::get_user_subpermissions( $userid );
 377     my ( $has_self_checkout_perm, $has_other_permissions );
 378     while ( my ( $module, $permissions ) = each %$all_permissions ) {
 379         if ( $module eq 'self_check' ) {
 380             while ( my ( $permission, $flag ) = each %$permissions ) {
 381                 if ( $permission eq 'self_checkout_module' ) {
 382                     $has_self_checkout_perm = 1;
 383                 } else {
 384                     $has_other_permissions = 1;
 385                 }
 386             }
 387         } else {
 388             $has_other_permissions = 1;
 389         }
 390     }
 391     $template->param(
 392         AutoSelfCheckPatronDoesNotHaveSelfCheckPerm => not ( $has_self_checkout_perm ),
 393         AutoSelfCheckPatronHasTooManyPerm => $has_other_permissions,
 394     );
 395 }
 396
 397 # Test YAML system preferences
 398 # FIXME: This is list of current YAML formatted prefs, should by type of preference
 399 my @yaml_prefs = (
 400     "UpdateNotForLoanStatusOnCheckin",
 401     "OpacHiddenItems",
 402     "BibtexExportAdditionalFields",
 403     "RisExportAdditionalFields",
 404     "UpdateItemWhenLostFromHoldList",
 405     "MarcFieldsToOrder",
 406     "MarcItemFieldsToOrder",
 407     "UpdateitemLocationOnCheckin",
 408     "ItemsDeniedRenewal"
 409 );
 410 my @bad_yaml_prefs;
 411 foreach my $syspref (@yaml_prefs) {
 412     my $yaml = C4::Context->preference( $syspref );
 413     if ( $yaml ) {
 414         eval { YAML::Load( "$yaml\n\n" ); };
 415         if ($@) {
 416             push @bad_yaml_prefs, $syspref;
 417         }
 418     }
 419 }
 420 $template->param( 'bad_yaml_prefs' => \@bad_yaml_prefs ) if @bad_yaml_prefs;
 421
 422 {
 423     my $dbh       = C4::Context->dbh;
 424     my $patrons = $dbh->selectall_arrayref(
 425         q|select b.borrowernumber from borrowers b join deletedborrowers db on b.borrowernumber=db.borrowernumber|,
 426         { Slice => {} }
 427     );
 428     my $biblios = $dbh->selectall_arrayref(
 429         q|select b.biblionumber from biblio b join deletedbiblio db on b.biblionumber=db.biblionumber|,
 430         { Slice => {} }
 431     );
 432     my $items = $dbh->selectall_arrayref(
 433         q|select i.itemnumber from items i join deleteditems di on i.itemnumber=di.itemnumber|,
 434         { Slice => {} }
 435     );
 436     my $checkouts = $dbh->selectall_arrayref(
 437         q|select i.issue_id from issues i join old_issues oi on i.issue_id=oi.issue_id|,
 438         { Slice => {} }
 439     );
 440     my $holds = $dbh->selectall_arrayref(
 441         q|select r.reserve_id from reserves r join old_reserves o on r.reserve_id=o.reserve_id|,
 442         { Slice => {} }
 443     );
 444     if ( @$patrons or @$biblios or @$items or @$checkouts or @$holds ) {
 445         $template->param(
 446             has_ai_issues => 1,
 447             ai_patrons    => $patrons,
 448             ai_biblios    => $biblios,
 449             ai_items      => $items,
 450             ai_checkouts  => $checkouts,
 451             ai_holds      => $holds,
 452         );
 453     }
 454 }
 455
 456 # Circ rule warnings
 457 {
 458     my $dbh   = C4::Context->dbh;
 459     my $units = $dbh->selectall_arrayref(
 460         q|SELECT branchcode, categorycode, itemtype, lengthunit FROM issuingrules WHERE lengthunit NOT IN ( 'days', 'hours' ); |,
 461         { Slice => {} }
 462     );
 463
 464     if (@$units) {
 465         $template->param(
 466             warnIssuingRules => 1,
 467             ir_units         => $units,
 468         );
 469     }
 470 }
 471
 472 # Guarantor relationships warnings
 473 {
 474     my $dbh   = C4::Context->dbh;
 475     my ($bad_relationships_count) = $dbh->selectall_arrayref(q{
 476         SELECT COUNT(*)
 477         FROM (
 478             SELECT relationship FROM borrower_relationships WHERE relationship='_bad_data'
 479             UNION ALL
 480             SELECT relationship FROM borrowers WHERE relationship='_bad_data') a
 481     });
 482
 483     $bad_relationships_count = $bad_relationships_count->[0]->[0];
 484
 485     my $existing_relationships = $dbh->selectall_arrayref(q{
 486           SELECT DISTINCT(relationship)
 487           FROM (
 488               SELECT relationship FROM borrower_relationships WHERE relationship IS NOT NULL
 489               UNION ALL
 490               SELECT relationship FROM borrowers WHERE relationship IS NOT NULL) a
 491     });
 492
 493     my %valid_relationships = map { $_ => 1 } split( /,|\|/, C4::Context->preference('borrowerRelationship') );
 494     $valid_relationships{ _bad_data } = 1; # we handle this case in another way
 495
 496     my $wrong_relationships = [ grep { !$valid_relationships{ $_->[0] } } @{$existing_relationships} ];
 497     if ( @$wrong_relationships or $bad_relationships_count ) {
 498
 499         $template->param(
 500             warnRelationships => 1,
 501         );
 502
 503         if ( $wrong_relationships ) {
 504             $template->param(
 505                 wrong_relationships => $wrong_relationships
 506             );
 507         }
 508         if ($bad_relationships_count) {
 509             $template->param(
 510                 bad_relationships_count => $bad_relationships_count,
 511             );
 512         }
 513     }
 514 }
 515
 516 my %versions = C4::Context::get_versions();
 517
 518 $template->param(
 519     kohaVersion   => $versions{'kohaVersion'},
 520     osVersion     => $versions{'osVersion'},
 521     perlPath      => $perl_path,
 522     perlVersion   => $versions{'perlVersion'},
 523     perlIncPath   => [ map { perlinc => $_ }, @INC ],
 524     mysqlVersion  => $versions{'mysqlVersion'},
 525     apacheVersion => $versions{'apacheVersion'},
 526     zebraVersion  => $zebraVersion,
 527     prefBiblioAddsAuthorities => $prefBiblioAddsAuthorities,
 528     prefAutoCreateAuthorities => $prefAutoCreateAuthorities,
 529     warnPrefBiblioAddsAuthorities => $warnPrefBiblioAddsAuthorities,
 530     warnPrefEasyAnalyticalRecords  => $warnPrefEasyAnalyticalRecords,
 531     warnPrefAnonymousPatronOPACPrivacy        => $warnPrefAnonymousPatronOPACPrivacy,
 532     warnPrefAnonymousPatronAnonSuggestions    => $warnPrefAnonymousPatronAnonSuggestions,
 533     warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist     => $warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist,
 534     warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist => $warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist,
 535     errZebraConnection => $errZebraConnection,
 536     warnIsRootUser => $warnIsRootUser,
 537     warnNoActiveCurrency => $warnNoActiveCurrency,
 538     warnNoTemplateCaching => ( C4::Context->config('template_cache_dir') ? 0 : 1 ),
 539     xml_config_warnings => \@xml_config_warnings,
 540     warnStatisticsFieldsError => $warnStatisticsFieldsError,
 541 );
 542
 543 my @components = ();
 544
 545 my $perl_modules = C4::Installer::PerlModules->new;
 546 $perl_modules->versions_info;
 547
 548 my @pm_types = qw(missing_pm upgrade_pm current_pm);
 549
 550 foreach my $pm_type(@pm_types) {
 551     my $modules = $perl_modules->get_attr($pm_type);
 552     foreach (@$modules) {
 553         my ($module, $stats) = each %$_;
 554         push(
 555             @components,
 556             {
 557                 name    => $module,
 558                 version => $stats->{'cur_ver'},
 559                 missing => ($pm_type eq 'missing_pm' ? 1 : 0),
 560                 upgrade => ($pm_type eq 'upgrade_pm' ? 1 : 0),
 561                 current => ($pm_type eq 'current_pm' ? 1 : 0),
 562                 require => $stats->{'required'},
 563                 reqversion => $stats->{'min_ver'},
 564             }
 565         );
 566     }
 567 }
 568
 569 @components = sort {$a->{'name'} cmp $b->{'name'}} @components;
 570
 571 my $counter=0;
 572 my $row = [];
 573 my $table = [];
 574 foreach (@components) {
 575     push (@$row, $_);
 576     unless (++$counter % 4) {
 577         push (@$table, {row => $row});
 578         $row = [];
 579     }
 580 }
 581 # Processing the last line (if there are any modules left)
 582 if (scalar(@$row) > 0) {
 583     # Extending $row to the table size
 584     $$row[3] = '';
 585     # Pushing the last line
 586     push (@$table, {row => $row});
 587 }
 588 ## ## $table
 589
 590 $template->param( table => $table );
 591
 592
 593 ## ------------------------------------------
 594 ## Koha contributions
 595 my $docdir;
 596 if ( defined C4::Context->config('docdir') ) {
 597     $docdir = C4::Context->config('docdir');
 598 } else {
 599     # if no <docdir> is defined in koha-conf.xml, use the default location
 600     # this is a work-around to stop breakage on upgraded Kohas, bug 8911
 601     $docdir = C4::Context->config('intranetdir') . '/docs';
 602 }
 603
 604 ## Release teams
 605 my $teams =
 606   -e "$docdir" . "/teams.yaml"
 607   ? LoadFile( "$docdir" . "/teams.yaml" )
 608   : {};
 609 my $dev_team = (sort {$b <=> $a} (keys %{$teams->{team}}))[0];
 610 my $short_version = substr($versions{'kohaVersion'},0,5);
 611 my $minor = substr($versions{'kohaVersion'},3,2);
 612 my $development_version = ( $minor eq '05' || $minor eq '11' ) ? 0 : 1;
 613 $template->param( short_version => $short_version );
 614 $template->param( development_version => $development_version );
 615
 616 ## Contributors
 617 my $contributors =
 618   -e "$docdir" . "/contributors.yaml"
 619   ? LoadFile( "$docdir" . "/contributors.yaml" )
 620   : {};
 621 for my $version ( sort { $a <=> $b } keys %{$teams->{team}} ) {
 622     for my $role ( keys %{ $teams->{team}->{$version} } ) {
 623         my $normalized_role = "$role";
 624         $normalized_role =~ s/s$//;
 625         if ( ref( $teams->{team}->{$version}->{$role} ) eq 'ARRAY' ) {
 626             for my $contributor ( @{ $teams->{team}->{$version}->{$role} } ) {
 627                 my $name = $contributor->{name};
 628                 # Add role to contributors
 629                 push @{ $contributors->{$name}->{roles}->{$normalized_role} },
 630                   $version;
 631                 # Add openhub to teams
 632                 if ( exists( $contributors->{$name}->{openhub} ) ) {
 633                     $contributor->{openhub} = $contributors->{$name}->{openhub};
 634                 }
 635             }
 636         }
 637         elsif ( $role ne 'release_date' ) {
 638             my $name = $teams->{team}->{$version}->{$role}->{name};
 639             # Add role to contributors
 640             push @{ $contributors->{$name}->{roles}->{$normalized_role} },
 641               $version;
 642             # Add openhub to teams
 643             if ( exists( $contributors->{$name}->{openhub} ) ) {
 644                 $teams->{team}->{$version}->{$role}->{openhub} =
 645                   $contributors->{$name}->{openhub};
 646             }
 647         }
 648         else {
 649             $teams->{team}->{$version}->{$role} = DateTime->from_epoch( epoch => $teams->{team}->{$version}->{$role});
 650         }
 651     }
 652 }
 653
 654 ## Create last name ordered array of people from contributors
 655 my @people = map {
 656     { name => $_, ( $contributors->{$_} ? %{ $contributors->{$_} } : () ) }
 657 } sort {
 658     my ($alast) = ( split( /\s/, $a ) )[-1];
 659     my ($blast) = ( split( /\s/, $b ) )[-1];
 660     lc($alast) cmp lc($blast)
 661 } keys %{$contributors};
 662
 663 $template->param( contributors => \@people );
 664 $template->param( maintenance_team => $teams->{team}->{$dev_team} );
 665 $template->param( release_team => $teams->{team}->{$short_version} );
 666
 667 ## Timeline
 668 if ( open( my $file, "<:encoding(UTF-8)", "$docdir" . "/history.txt" ) ) {
 669
 670     my $i = 0;
 671
 672     my @rows2 = ();
 673     my $row2  = [];
 674
 675     my @lines = <$file>;
 676     close($file);
 677
 678     shift @lines; #remove header row
 679
 680     foreach (@lines) {
 681         my ( $epoch, $date, $desc, $tag ) = split(/\t/);
 682         if(!$desc && $date=~ /(?<=\d{4})\s+/) {
 683             ($date, $desc)= ($`, $');
 684         }
 685         push(
 686             @rows2,
 687             {
 688                 date => $date,
 689                 desc => $desc,
 690             }
 691         );
 692     }
 693
 694     my $table2 = [];
 695     #foreach my $row2 (@rows2) {
 696     foreach  (@rows2) {
 697         push (@$row2, $_);
 698         push( @$table2, { row2 => $row2 } );
 699         $row2 = [];
 700     }
 701
 702     $template->param( table2 => $table2 );
 703 } else {
 704     $template->param( timeline_read_error => 1 );
 705 }
 706
 707 output_html_with_http_headers $query, $cookie, $template->output;