course_reserves/add_items.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # Copyright 2012 Bywater Solutions
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Koha;
  28 use C4::Biblio;
  29 use Koha::Items;
  30
  31 use C4::CourseReserves qw(GetCourse GetCourseItem GetCourseReserve ModCourseItem ModCourseReserve);
  32
  33 use Koha::ItemTypes;
  34
  35 my $cgi = new CGI;
  36
  37 my $action       = $cgi->param('action')       || '';
  38 my $course_id    = $cgi->param('course_id')    || '';
  39 my $barcode      = $cgi->param('barcode')      || '';
  40 my $return       = $cgi->param('return')       || '';
  41 my $itemnumber   = ($cgi->param('itemnumber') && $action eq 'lookup') ? $cgi->param('itemnumber') : '';
  42
  43 my $item = Koha::Items->find( { ( $itemnumber ? ( itemnumber => $itemnumber ) : ( barcode => $barcode ) ) } );
  44 my $title = ($item) ? $item->biblio->title : undef;
  45
  46 my $step = ( $action eq 'lookup' && $item ) ? '2' : '1';
  47
  48 my $tmpl = ($course_id) ? "add_items-step$step.tt" : "invalid-course.tt";
  49 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  50     {   template_name   => "course_reserves/$tmpl",
  51         query           => $cgi,
  52         type            => "intranet",
  53         authnotrequired => 0,
  54         flagsrequired   => { coursereserves => 'add_reserves' },
  55     }
  56 );
  57
  58 if ( !$item && $action eq 'lookup' ){
  59     $template->param( ERROR_ITEM_NOT_FOUND => 1 );
  60     $template->param( UNKNOWN_BARCODE => $barcode ) if $barcode;
  61 }
  62
  63 $template->param( course => GetCourse($course_id) );
  64
  65 if ( $action eq 'lookup' ) {
  66     my $course_item = GetCourseItem( itemnumber => $item->{'itemnumber'} );
  67     my $course_reserve =
  68       ($course_item)
  69       ? GetCourseReserve(
  70         course_id => $course_id,
  71         ci_id     => $course_item->{'ci_id'}
  72       )
  73       : undef;
  74
  75     my $itemtypes = Koha::ItemTypes->search;
  76     $template->param(
  77         item           => $item,
  78         title          => $title,
  79         course_item    => $course_item,
  80         course_reserve => $course_reserve,
  81
  82         ccodes    => GetAuthorisedValues('CCODE'),
  83         locations => GetAuthorisedValues('LOC'),
  84         itypes    => $itemtypes, # FIXME We certainly want to display the translated_description in the template
  85         return    => $return,
  86     );
  87
  88 } elsif ( $action eq 'add' ) {
  89     my $ci_id = ModCourseItem(
  90         itemnumber    => scalar $cgi->param('itemnumber'),
  91         itype         => scalar $cgi->param('itype'),
  92         ccode         => scalar $cgi->param('ccode'),
  93         holdingbranch => scalar $cgi->param('holdingbranch'),
  94         location      => scalar $cgi->param('location'),
  95     );
  96
  97     my $cr_id = ModCourseReserve(
  98         course_id   => $course_id,
  99         ci_id       => $ci_id,
 100         staff_note  => scalar $cgi->param('staff_note'),
 101         public_note => scalar $cgi->param('public_note'),
 102     );
 103
 104     if ( $return ) {
 105         print $cgi->redirect("/cgi-bin/koha/course_reserves/course-details.pl?course_id=$return");
 106         exit;
 107     }
 108 }
 109
 110 output_html_with_http_headers $cgi, $cookie, $template->output;