reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #writen 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it under the
  10 # terms of the GNU General Public License as published by the Free Software
  11 # Foundation; either version 2 of the License, or (at your option) any later
  12 # version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  15 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  16 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License along with
  19 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  20 # Suite 330, Boston, MA  02111-1307 USA
  21
  22 =head1 request.pl
  23
  24 script to place reserves/requests
  25
  26 =cut
  27
  28 use strict;
  29 use warnings;
  30 use C4::Branch; # GetBranches get_branchinfos_of
  31 use CGI;
  32 use List::MoreUtils qw/uniq/;
  33 use Date::Calc qw/Date_to_Days/;
  34 use C4::Output;
  35 use C4::Auth;
  36 use C4::Reserves;
  37 use C4::Biblio;
  38 use C4::Items;
  39 use C4::Koha;
  40 use C4::Circulation;
  41 use C4::Dates qw/format_date/;
  42 use C4::Members;
  43 use C4::Search;         # enabled_staff_search_views
  44
  45 my $dbh = C4::Context->dbh;
  46 my $sth;
  47 my $input = new CGI;
  48 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  49     {
  50         template_name   => "reserve/request.tmpl",
  51         query           => $input,
  52         type            => "intranet",
  53         authnotrequired => 0,
  54         flagsrequired   => { reserveforothers => 1 },
  55     }
  56 );
  57
  58 my $multihold = $input->param('multi_hold');
  59 $template->param(multi_hold => $multihold);
  60
  61 # get Branches and Itemtypes
  62 my $branches = GetBranches();
  63 my $itemtypes = GetItemTypes();
  64
  65 my $default = C4::Context->userenv->{branch};
  66 my @values;
  67 my %label_of;
  68
  69 foreach my $branchcode (sort keys %{$branches} ) {
  70     push @values, $branchcode;
  71     $label_of{$branchcode} = $branches->{$branchcode}->{branchname};
  72 }
  73 my $CGIbranch = CGI::scrolling_list(
  74                                     -name     => 'pickup',
  75                                     -id          => 'pickup',
  76                                     -values   => \@values,
  77                                     -default  => $default,
  78                                     -labels   => \%label_of,
  79                                     -size     => 1,
  80                                     -multiple => 0,
  81                                    );
  82
  83 # Select borrowers infos
  84 my $findborrower = $input->param('findborrower');
  85 $findborrower = '' unless defined $findborrower;
  86 $findborrower =~ s|,| |g;
  87 my $cardnumber = $input->param('cardnumber') || '';
  88 my $borrowerslist;
  89 my $messageborrower;
  90 my $warnings;
  91 my $messages;
  92
  93 my $date = C4::Dates->today('iso');
  94
  95 if ($findborrower) {
  96     my ( $count, $borrowers ) =
  97       SearchMember($findborrower, 'cardnumber', 'web' );
  98
  99     my @borrowers = @$borrowers;
 100
 101     if ( $#borrowers == -1 ) {
 102         $input->param( 'findborrower', '' );
 103         $messageborrower = "'$findborrower'";
 104     }
 105     elsif ( $#borrowers == 0 ) {
 106         $input->param( 'cardnumber', $borrowers[0]->{'cardnumber'} );
 107         $cardnumber = $borrowers[0]->{'cardnumber'};
 108     }
 109     else {
 110         $borrowerslist = \@borrowers;
 111     }
 112 }
 113
 114 if ($cardnumber) {
 115     my $borrowerinfo = GetMemberDetails( 0, $cardnumber );
 116     my $diffbranch;
 117     my @getreservloop;
 118     my $count_reserv = 0;
 119     my $maxreserves;
 120
 121 #   we check the reserves of the borrower, and if he can reserv a document
 122 # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 123
 124     my $number_reserves =
 125       GetReserveCount( $borrowerinfo->{'borrowernumber'} );
 126
 127     if ( $number_reserves > C4::Context->preference('maxreserves') ) {
 128                 $warnings = 1;
 129         $maxreserves = 1;
 130     }
 131
 132     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 133     my $expiry_date = $borrowerinfo->{dateexpiry};
 134     my $expiry = 0; # flag set if patron account has expired
 135     if ($expiry_date and $expiry_date ne '0000-00-00' and
 136             Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 137                 $messages = $expiry = 1;
 138     }
 139
 140
 141     # check if the borrower make the reserv in a different branch
 142     if ( $borrowerinfo->{'branchcode'} ne C4::Context->userenv->{'branch'} ) {
 143                 $messages = 1;
 144         $diffbranch = 1;
 145     }
 146
 147     $template->param(
 148                 borrowernumber => $borrowerinfo->{'borrowernumber'},
 149                 borrowersurname   => $borrowerinfo->{'surname'},
 150                 borrowerfirstname => $borrowerinfo->{'firstname'},
 151                 borrowerstreetaddress => $borrowerinfo->{'address'},
 152                 borrowercity => $borrowerinfo->{'city'},
 153                 borrowerphone => $borrowerinfo->{'phone'},
 154                 borrowermobile => $borrowerinfo->{'mobile'},
 155                 borrowerfax => $borrowerinfo->{'fax'},
 156                 borrowerphonepro => $borrowerinfo->{'phonepro'},
 157                 borroweremail => $borrowerinfo->{'email'},
 158                 borroweremailpro => $borrowerinfo->{'emailpro'},
 159                 borrowercategory => $borrowerinfo->{'category'},
 160                 borrowerreservs   => $count_reserv,
 161                 maxreserves       => $maxreserves,
 162                 expiry            => $expiry,
 163                 diffbranch        => $diffbranch,
 164                                 messages => $messages,
 165                                 warnings => $warnings
 166     );
 167 }
 168
 169 $template->param( messageborrower => $messageborrower );
 170
 171 my $CGIselectborrower;
 172 if ($borrowerslist) {
 173     my @values;
 174     my %labels;
 175
 176     foreach my $borrower (
 177         sort {
 178                 $a->{surname}
 179               . $a->{firstname} cmp $b->{surname}
 180               . $b->{firstname}
 181         } @{$borrowerslist}
 182       )
 183     {
 184         push @values, $borrower->{cardnumber};
 185
 186         $labels{ $borrower->{cardnumber} } = sprintf(
 187             '%s, %s ... (%s - %s) ... %s',
 188             $borrower->{surname},    $borrower->{firstname},
 189             $borrower->{cardnumber}, $borrower->{categorycode},
 190             $borrower->{address},
 191         );
 192     }
 193
 194     $CGIselectborrower = CGI::scrolling_list(
 195         -name     => 'cardnumber',
 196         -values   => \@values,
 197         -labels   => \%labels,
 198         -size     => 7,
 199         -multiple => 0,
 200     );
 201 }
 202
 203 # FIXME launch another time GetMemberDetails perhaps until
 204 my $borrowerinfo = GetMemberDetails( 0, $cardnumber );
 205
 206 my @biblionumbers = ();
 207 my $biblionumbers = $input->param('biblionumbers');
 208 if ($multihold) {
 209     @biblionumbers = split '/', $biblionumbers;
 210 } else {
 211     push @biblionumbers, $input->param('biblionumber');
 212 }
 213
 214 my @biblioloop = ();
 215 foreach my $biblionumber (@biblionumbers) {
 216
 217     my %biblioloopiter = ();
 218         my $maxreserves;
 219
 220     my $dat          = GetBiblioData($biblionumber);
 221
 222     if ( not CanBookBeReserved($borrowerinfo->{borrowernumber}, $biblionumber) ) {
 223                 $warnings = 1;
 224         $maxreserves = 1;
 225     }
 226     # get existing reserves .....
 227     my ( $count, $reserves ) = GetReservesFromBiblionumber($biblionumber,1);
 228     my $totalcount = $count;
 229     my $alreadyreserved;
 230
 231     foreach my $res (@$reserves) {
 232         if ( defined $res->{found} && $res->{found} eq 'W' ) {
 233             $count--;
 234         }
 235
 236         if ( defined $borrowerinfo && ($borrowerinfo->{borrowernumber} eq $res->{borrowernumber}) ) {
 237             $warnings = 1;
 238             $alreadyreserved = 1;
 239             $biblioloopiter{warn} = 1;
 240             $biblioloopiter{alreadyres} = 1;
 241         }
 242     }
 243
 244     $template->param( alreadyreserved => $alreadyreserved,
 245                       messages => $messages,
 246                       warnings => $warnings,
 247                                           maxreserves=>$maxreserves
 248                                           );
 249
 250
 251     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 252     # make priorities options
 253
 254     my @optionloop;
 255     for ( 1 .. $count + 1 ) {
 256         push(
 257              @optionloop,
 258              {
 259               num      => $_,
 260               selected => ( $_ == $count + 1 ),
 261              }
 262             );
 263     }
 264     # adding a fixed value for priority options
 265     my $fixedRank = $count+1;
 266
 267     my @branchcodes;
 268     my %itemnumbers_of_biblioitem;
 269     my @itemnumbers;
 270
 271     ## $items is array of 'item' table numbers
 272     if (my $items = get_itemnumbers_of($biblionumber)->{$biblionumber}){
 273         @itemnumbers  = @$items;
 274     }
 275     else {
 276         $template->param('noitems' => 1);
 277         $biblioloopiter{noitems} = 1;
 278     }
 279
 280     ## Hash of item number to 'item' table fields
 281     my $iteminfos_of = GetItemInfosOf(@itemnumbers);
 282
 283     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 284     ## when by definition all of the itemnumber have the same biblioitemnumber
 285     foreach my $itemnumber (@itemnumbers) {
 286         my $biblioitemnumber = $iteminfos_of->{$itemnumber}->{biblioitemnumber};
 287         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 288     }
 289
 290     ## Should be same as biblionumber
 291     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 292
 293     my $notforloan_label_of = get_notforloan_label_of();
 294
 295     ## Hash of biblioitemnumber to 'biblioitem' table records
 296     my $biblioiteminfos_of  = GetBiblioItemInfosOf(@biblioitemnumbers);
 297
 298     my @bibitemloop;
 299
 300     foreach my $biblioitemnumber (@biblioitemnumbers) {
 301         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 302         my $num_available = 0;
 303         my $num_override  = 0;
 304
 305         $biblioitem->{description} =
 306           $itemtypes->{ $biblioitem->{itemtype} }{description};
 307         $biblioloopiter{description} = $biblioitem->{description};
 308         $biblioloopiter{itypename} = $biblioitem->{description};
 309         $biblioloopiter{imageurl} =
 310           getitemtypeimagelocation('intranet', $itemtypes->{$biblioitem->{itemtype}}{imageurl});
 311
 312         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 313             my $item = $iteminfos_of->{$itemnumber};
 314
 315             unless (C4::Context->preference('item-level_itypes')) {
 316                 $item->{itype} = $biblioitem->{itemtype};
 317             }
 318
 319             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 320             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 321             $item->{homebranchname} = $branches->{ $item->{homebranch} }{branchname};
 322
 323             # if the holdingbranch is different than the homebranch, we show the
 324             # holdingbranch of the document too
 325             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 326                 $item->{holdingbranchname} =
 327                   $branches->{ $item->{holdingbranch} }{branchname};
 328             }
 329
 330             #   add information
 331             $item->{itemcallnumber} = $item->{itemcallnumber};
 332
 333             # if the item is currently on loan, we display its return date and
 334             # change the background color
 335             my $issues= GetItemIssue($itemnumber);
 336             if ( $issues->{'date_due'} ) {
 337                 $item->{date_due} = format_date($issues->{'date_due'});
 338                 $item->{backgroundcolor} = 'onloan';
 339             }
 340
 341             # checking reserve
 342             my ($reservedate,$reservedfor,$expectedAt) = GetReservesFromItemnumber($itemnumber);
 343             my $ItemBorrowerReserveInfo = GetMemberDetails( $reservedfor, 0);
 344
 345             if ( defined $reservedate ) {
 346                 $item->{backgroundcolor} = 'reserved';
 347                 $item->{reservedate}     = format_date($reservedate);
 348                 $item->{ReservedForBorrowernumber}     = $reservedfor;
 349                 $item->{ReservedForSurname}     = $ItemBorrowerReserveInfo->{'surname'};
 350                 $item->{ReservedForFirstname}     = $ItemBorrowerReserveInfo->{'firstname'};
 351                 $item->{ExpectedAtLibrary}     = $branches->{$expectedAt}{branchname};
 352
 353             }
 354
 355             # Management of the notforloan document
 356             if ( $item->{notforloan} ) {
 357                 $item->{backgroundcolor} = 'other';
 358                 $item->{notforloanvalue} =
 359                   $notforloan_label_of->{ $item->{notforloan} };
 360             }
 361
 362             # Management of lost or long overdue items
 363             if ( $item->{itemlost} ) {
 364
 365                 # FIXME localized strings should never be in Perl code
 366                 $item->{message} =
 367                   $item->{itemlost} == 1 ? "(lost)"
 368                     : $item->{itemlost} == 2 ? "(long overdue)"
 369                       : "";
 370                 $item->{backgroundcolor} = 'other';
 371             }
 372
 373             # Check the transit status
 374             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 375               GetTransfers($itemnumber);
 376
 377             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 378                 $item->{transfertwhen} = format_date($transfertwhen);
 379                 $item->{transfertfrom} =
 380                   $branches->{$transfertfrom}{branchname};
 381                 $item->{transfertto} = $branches->{$transfertto}{branchname};
 382                 $item->{nocancel} = 1;
 383             }
 384
 385             # If there is no loan, return and transfer, we show a checkbox.
 386             $item->{notforloan} = $item->{notforloan} || 0;
 387
 388             # if independent branches is on we need to check if the person can reserve
 389             # for branches they arent logged in to
 390             if ( C4::Context->preference("IndependantBranches") ) {
 391                 if (! C4::Context->preference("canreservefromotherbranches")){
 392                     # cant reserve items so need to check if item homebranch and userenv branch match if not we cant reserve
 393                     my $userenv = C4::Context->userenv;
 394                     if ( ($userenv) && ( $userenv->{flags} % 2 != 1 ) ) {
 395                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 396                     }
 397                 }
 398             }
 399
 400             my $branch = C4::Circulation::_GetCircControlBranch($item, $borrowerinfo);
 401
 402             my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 403             my $policy_holdallowed = 1;
 404
 405             $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 406
 407             if ( $branchitemrule->{'holdallowed'} == 0 ||
 408                  ( $branchitemrule->{'holdallowed'} == 1 && $borrowerinfo->{'branchcode'} ne $item->{'homebranch'} ) ) {
 409                 $policy_holdallowed = 0;
 410             }
 411
 412             if (IsAvailableForItemLevelRequest($itemnumber) and not $item->{cantreserve} and CanItemBeReserved($borrowerinfo->{borrowernumber}, $itemnumber) ) {
 413                 if ( not $policy_holdallowed and C4::Context->preference( 'AllowHoldPolicyOverride' ) ) {
 414                     $item->{override} = 1;
 415                     $num_override++;
 416                 } elsif ( $policy_holdallowed ) {
 417                     $item->{available} = 1;
 418                     $num_available++;
 419                 }
 420             }
 421             # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 422
 423             # FIXME: move this to a pm
 424             my $sth2 = $dbh->prepare("SELECT * FROM reserves WHERE borrowernumber=? AND itemnumber=? AND found='W'");
 425             $sth2->execute($item->{ReservedForBorrowernumber},$item->{itemnumber});
 426             while (my $wait_hashref = $sth2->fetchrow_hashref) {
 427                 $item->{waitingdate} = format_date($wait_hashref->{waitingdate});
 428             }
 429             push @{ $biblioitem->{itemloop} }, $item;
 430         }
 431
 432         if ( $num_override == scalar( @{ $biblioitem->{itemloop} } ) ) { # That is, if all items require an override
 433             $template->param( override_required => 1 );
 434         } elsif ( $num_available == 0 ) {
 435             $template->param( none_available => 1 );
 436             $template->param( warnings => 1 );
 437             $biblioloopiter{warn} = 1;
 438             $biblioloopiter{none_avail} = 1;
 439         }
 440
 441         push @bibitemloop, $biblioitem;
 442     }
 443
 444     # existingreserves building
 445     my @reserveloop;
 446     ( $count, $reserves ) = GetReservesFromBiblionumber($biblionumber,1);
 447     foreach my $res ( sort {
 448             my $a_found = $a->{found} || '';
 449             my $b_found = $a->{found} || '';
 450             $a_found cmp $b_found;
 451         } @$reserves ) {
 452         my %reserve;
 453         my @optionloop;
 454         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 455             push(
 456                  @optionloop,
 457                  {
 458                   num      => $i,
 459                   selected => ( $i == $res->{priority} ),
 460                  }
 461                 );
 462         }
 463
 464         if ( defined $res->{'found'} && $res->{'found'} eq 'W' ) {
 465             my $item = $res->{'itemnumber'};
 466             $item = GetBiblioFromItemNumber($item,undef);
 467             $reserve{'wait'}= 1;
 468             $reserve{'holdingbranch'}=$item->{'holdingbranch'};
 469             $reserve{'biblionumber'}=$item->{'biblionumber'};
 470             $reserve{'barcodenumber'}   = $item->{'barcode'};
 471             $reserve{'wbrcode'} = $res->{'branchcode'};
 472             $reserve{'itemnumber'}  = $res->{'itemnumber'};
 473             $reserve{'wbrname'} = $branches->{$res->{'branchcode'}}->{'branchname'};
 474             if($reserve{'holdingbranch'} eq $reserve{'wbrcode'}){
 475                 $reserve{'atdestination'} = 1;
 476             }
 477             # set found to 1 if reserve is waiting for patron pickup
 478             $reserve{'found'} = 1 if $res->{'found'} eq 'W';
 479         } elsif ($res->{priority} > 0) {
 480             if (defined($res->{itemnumber})) {
 481                 my $item = GetItem($res->{itemnumber});
 482                 $reserve{'itemnumber'}  = $res->{'itemnumber'};
 483                 $reserve{'barcodenumber'}   = $item->{'barcode'};
 484                 $reserve{'item_level_hold'} = 1;
 485             }
 486         }
 487
 488         #     get borrowers reserve info
 489         my $reserveborrowerinfo = GetMemberDetails( $res->{'borrowernumber'}, 0);
 490         if (C4::Context->preference('HidePatronName')){
 491             $reserve{'hidename'} = 1;
 492             $reserve{'cardnumber'} = $reserveborrowerinfo->{'cardnumber'};
 493         }
 494         $reserve{'date'}           = format_date( $res->{'reservedate'} );
 495         $reserve{'borrowernumber'} = $res->{'borrowernumber'};
 496         $reserve{'biblionumber'}   = $res->{'biblionumber'};
 497         $reserve{'borrowernumber'} = $res->{'borrowernumber'};
 498         $reserve{'firstname'}      = $reserveborrowerinfo->{'firstname'};
 499         $reserve{'surname'}        = $reserveborrowerinfo->{'surname'};
 500         $reserve{'notes'}          = $res->{'reservenotes'};
 501         $reserve{'wait'}           =
 502           ( ( defined $res->{'found'} and $res->{'found'} eq 'W' ) or ( $res->{'priority'} eq '0' ) );
 503         $reserve{'constrainttypea'} = ( $res->{'constrainttype'} eq 'a' );
 504         $reserve{'constrainttypeo'} = ( $res->{'constrainttype'} eq 'o' );
 505         $reserve{'voldesc'}         = $res->{'volumeddesc'};
 506         $reserve{'ccode'}           = $res->{'ccode'};
 507         $reserve{'barcode'}         = $res->{'barcode'};
 508         $reserve{'priority'}    = $res->{'priority'};
 509         $reserve{'branchloop'} = GetBranchesLoop($res->{'branchcode'});
 510         $reserve{'optionloop'} = \@optionloop;
 511
 512         push( @reserveloop, \%reserve );
 513     }
 514
 515     # get the time for the form name...
 516     my $time = time();
 517
 518     $template->param(
 519                      CGIbranch   => $CGIbranch,
 520
 521                      time        => $time,
 522                      fixedRank   => $fixedRank,
 523                     );
 524
 525     # display infos
 526     $template->param(
 527                      optionloop        => \@optionloop,
 528                      bibitemloop       => \@bibitemloop,
 529                      date              => $date,
 530                      biblionumber      => $biblionumber,
 531                      findborrower      => $findborrower,
 532                      cardnumber        => $cardnumber,
 533                      title             => $dat->{title},
 534                      author            => $dat->{author},
 535                      holdsview => 1,
 536                      C4::Search::enabled_staff_search_views,
 537                     );
 538     if (defined $borrowerinfo && exists $borrowerinfo->{'branchcode'}) {
 539         $template->param(
 540                      borrower_branchname => $branches->{$borrowerinfo->{'branchcode'}}->{'branchname'},
 541                      borrower_branchcode => $borrowerinfo->{'branchcode'},
 542         );
 543     }
 544     $template->param(CGIselectborrower => $CGIselectborrower) if defined $CGIselectborrower;
 545
 546     $biblioloopiter{biblionumber} = $biblionumber;
 547     $biblioloopiter{title} = $dat->{title};
 548     $biblioloopiter{rank} = $fixedRank;
 549     $biblioloopiter{reserveloop} = \@reserveloop;
 550
 551     if (@reserveloop) {
 552         $template->param( reserveloop => \@reserveloop );
 553     }
 554
 555
 556     push @biblioloop, \%biblioloopiter;
 557 }
 558
 559 $template->param( biblioloop => \@biblioloop );
 560 $template->param( biblionumbers => $biblionumbers );
 561
 562 if ($multihold) {
 563     $template->param( multi_hold => 1 );
 564 }
 565
 566 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 567     $template->param(
 568         reserve_in_future         => 1,
 569         DHTMLcalendar_dateformat  => C4::Dates->DHTMLcalendar(),
 570         );
 571 }
 572
 573 # printout the page
 574 output_html_with_http_headers $input, $cookie, $template->output;