t/db_dependent/DecreaseLoanHighHolds.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use DateTime;
  20
  21 use C4::Circulation;
  22 use Koha::Database;
  23 use Koha::DateUtils;
  24 use Koha::Patrons;
  25 use Koha::Biblio;
  26 use Koha::Item;
  27 use Koha::Holds;
  28 use Koha::Hold;
  29 use Koha::CirculationRules;
  30 use t::lib::TestBuilder;
  31 use t::lib::Mocks;
  32
  33 use Test::More tests => 19;
  34
  35 my $dbh    = C4::Context->dbh;
  36 my $schema = Koha::Database->new()->schema();
  37 my $builder = t::lib::TestBuilder->new;
  38
  39 $schema->storage->txn_begin();
  40
  41 my $now_value       = dt_from_string();
  42 my $mocked_datetime = Test::MockModule->new('DateTime');
  43 $mocked_datetime->mock( 'now', sub { return $now_value->clone; } );
  44
  45 my $library  = $builder->build( { source => 'Branch' } );
  46 my $category = $builder->build( { source => 'Category' } );
  47 my $itemtype = $builder->build( { source => 'Itemtype' } )->{itemtype};
  48
  49 t::lib::Mocks::mock_userenv({ branchcode => $library->{branchcode} });
  50 is( C4::Context->userenv->{branch}, $library->{branchcode}, 'userenv set' );
  51
  52 my $patron_category = $builder->build({
  53     source => 'Category',
  54     value => {
  55         category_type => 'P',
  56         enrolmentfee => 0
  57     }
  58 });
  59
  60 my @patrons;
  61 for my $i ( 1 .. 20 ) {
  62     my $patron = Koha::Patron->new({
  63         firstname => 'Kyle',
  64         surname => 'Hall',
  65         categorycode => $category->{categorycode},
  66         branchcode => $library->{branchcode},
  67         categorycode => $patron_category->{categorycode},
  68     })->store();
  69     push( @patrons, $patron );
  70 }
  71
  72 my $biblio = $builder->build_sample_biblio();
  73
  74 # The biblio gets 10 items
  75 my @items;
  76 for my $i ( 1 .. 10 ) {
  77     my $item = $builder->build_sample_item(
  78         {
  79             biblionumber     => $biblio->id(),
  80             itype            => $itemtype
  81         }
  82     );
  83     push( @items, $item );
  84 }
  85
  86 # Place 6 holds, patrons 0,1,2,3,4,5
  87 for my $i ( 0 .. 5 ) {
  88     my $patron = $patrons[$i];
  89     my $hold   = Koha::Hold->new(
  90         {
  91             borrowernumber => $patron->id,
  92             biblionumber   => $biblio->id,
  93             branchcode     => $library->{branchcode},
  94         }
  95     )->store();
  96 }
  97
  98 my $item   = shift(@items);
  99 my $patron = shift(@patrons);
 100 my $patron_hold = Koha::Holds->find({ borrowernumber => $patron->borrowernumber, biblionumber => $item->biblionumber });
 101
 102 Koha::CirculationRules->set_rules(
 103     {
 104         branchcode   => undef,
 105         categorycode => undef,
 106         itemtype     => $item->itype,
 107         rules        => {
 108             issuelength     => '14',
 109             lengthunit      => 'days',
 110             reservesallowed => '99',
 111             holds_per_record => '99',
 112         }
 113     }
 114 );
 115
 116
 117 my $orig_due = C4::Circulation::CalcDateDue(
 118     dt_from_string(),
 119     $item->effective_itemtype,
 120     $patron->branchcode,
 121     $patron->unblessed
 122 );
 123
 124 t::lib::Mocks::mock_preference( 'decreaseLoanHighHolds',               1 );
 125 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsDuration',       1 );
 126 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsValue',          1 );
 127 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsControl',        'static' );
 128 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsIgnoreStatuses', 'damaged,itemlost,notforloan,withdrawn' );
 129
 130 my $item_hr = { itemnumber => $item->id, biblionumber => $biblio->id, homebranch => $library->{branchcode}, holdingbranch => $library->{branchcode}, barcode => $item->barcode };
 131 my $patron_hr = { borrowernumber => $patron->id, branchcode => $library->{branchcode} };
 132
 133 my $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 134 is( $data->{exceeded},        1,          "Static mode should exceed threshold" );
 135 is( $data->{outstanding},     6,          "Should have 6 outstanding holds" );
 136 is( $data->{duration},        1,          "Should have duration of 1" );
 137 is( ref( $data->{due_date} ), 'DateTime', "due_date should be a DateTime object" );
 138
 139 my $duedate = $data->{due_date};
 140 is($duedate->hour, $orig_due->hour, 'New due hour is equal to original due hour.');
 141 is($duedate->min, $orig_due->min, 'New due minute is equal to original due minute.');
 142 is($duedate->sec, 0, 'New due date second is zero.');
 143
 144 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsControl', 'dynamic' );
 145 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 146 is( $data->{exceeded}, 0, "Should not exceed threshold" );
 147
 148
 149 # Place 6 more holds - patrons 5,6,7,8,9,10
 150 for my $i ( 5 .. 10 ) {
 151     my $patron = $patrons[$i];
 152     my $hold   = Koha::Hold->new(
 153         {
 154             borrowernumber => $patron->id,
 155             biblionumber   => $biblio->id,
 156             branchcode     => $library->{branchcode},
 157         }
 158     )->store();
 159 }
 160
 161 # 12 holds, threshold is 1 over 10 holdable items = 11
 162 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 163 is( $data->{exceeded}, 1, "Should exceed threshold of 1" );
 164 is( $data->{outstanding}, 12, "Should exceed threshold of 1" );
 165
 166 # 12 holds, threshold is 2 over 10 holdable items = 12 (equal is okay)
 167 t::lib::Mocks::mock_preference( 'decreaseLoanHighHoldsValue', 2 );
 168 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 169 is( $data->{exceeded}, 0, "Should not exceed threshold of 2" );
 170
 171 my $unholdable = pop(@items);
 172 $unholdable->damaged(-1);
 173 $unholdable->store();
 174
 175 # 12 holds, threshold is 2 over 9 holdable items = 11
 176 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 177 is( $data->{exceeded}, 1, "Should exceed threshold with one damaged item" );
 178
 179 $unholdable->damaged(0);
 180 $unholdable->itemlost(-1);
 181 $unholdable->store();
 182
 183 # 12 holds, threshold is 2 over 9 holdable items = 11
 184 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 185 is( $data->{exceeded}, 1, "Should exceed threshold with one lost item" );
 186
 187 $unholdable->itemlost(0);
 188 $unholdable->notforloan(-1);
 189 $unholdable->store();
 190
 191 # 12 holds, threshold is 2 over 9 holdable items = 11
 192 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 193 is( $data->{exceeded}, 1, "Should exceed threshold with one notforloan item" );
 194
 195 $unholdable->notforloan(0);
 196 $unholdable->withdrawn(-1);
 197 $unholdable->store();
 198
 199 # 12 holds, threshold is 2 over 9 holdable items = 11
 200 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 201 is( $data->{exceeded}, 1, "Should exceed threshold with one withdrawn item" );
 202
 203 $patron_hold->found('F')->store;
 204 # 11 holds, threshold is 2 over 9 holdable items = 11
 205 $data = C4::Circulation::checkHighHolds( $item_hr, $patron_hr );
 206 is( $data->{exceeded}, 1, "Should exceed threshold with one withdrawn item" );
 207 $patron_hold->found(undef)->store;
 208
 209 t::lib::Mocks::mock_preference('CircControl', 'PatronLibrary');
 210
 211 my $patron_object = Koha::Patrons->find( $patron_hr->{borrowernumber} );
 212 my ( undef, $needsconfirmation ) = CanBookBeIssued( $patron_object, $item->barcode );
 213 ok( $needsconfirmation->{HIGHHOLDS}, "High holds checkout needs confirmation" );
 214
 215 ( undef, $needsconfirmation ) = CanBookBeIssued( $patron_object, $item->barcode, undef, undef, undef, { override_high_holds => 1 } );
 216 ok( !$needsconfirmation->{HIGHHOLDS}, "High holds checkout does not need confirmation" );
 217
 218 $schema->storage->txn_rollback();