misc/cronjobs/edi_cron.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2013,2014,2015 PTFS Europe Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use warnings;
  21 use strict;
  22 use utf8;
  23
  24 # Handles all the edi processing for a site
  25 # loops through the vendor_edifact records and uploads and downloads
  26 # edifact files if the appropriate type is enabled
  27 # downloaded quotes, invoices and responses are processed here
  28 # if orders are enabled and present they are generated and sent
  29 # can be run as frequently as required
  30 # log messages are appended to logdir/editrace.log
  31
  32 use Koha::Script -cron;
  33 use C4::Context;
  34 use Log::Log4perl qw(:easy);
  35 use Koha::Database;
  36 use Koha::EDI qw( process_quote process_invoice process_ordrsp);
  37 use Koha::Edifact::Transport;
  38 use Koha::Plugins::Handler;
  39 use Fcntl qw( :DEFAULT :flock :seek );
  40
  41 my $logdir = C4::Context->config('logdir');
  42
  43 # logging set to trace as this may be what you
  44 # want on implementation
  45 Log::Log4perl->easy_init(
  46     {
  47         level => $TRACE,
  48         file  => ">>$logdir/editrace.log",
  49     }
  50 );
  51
  52 # we dont have a lock dir in context so use the logdir
  53 my $pidfile = "$logdir/edicron.pid";
  54
  55 my $pid_handle = check_pidfile();
  56
  57 my $schema = Koha::Database->new()->schema();
  58
  59 my @edi_accts = $schema->resultset('VendorEdiAccount')->all();
  60
  61 my $logger = Log::Log4perl->get_logger();
  62
  63 for my $acct (@edi_accts) {
  64     if ( $acct->quotes_enabled ) {
  65         my $downloader = Koha::Edifact::Transport->new( $acct->id );
  66         $downloader->download_messages('QUOTE');
  67
  68     }
  69
  70     if ( $acct->invoices_enabled ) {
  71         my $downloader;
  72
  73         if ( $acct->plugin ) {
  74             $downloader = Koha::Plugins::Handler->run(
  75                 {
  76                     class  => $acct->plugin,
  77                     method => 'edifact_transport',
  78                     params => {
  79                         vendor_edi_account_id => $acct->id,
  80                     }
  81                 }
  82             );
  83         }
  84
  85         $downloader ||= Koha::Edifact::Transport->new( $acct->id );
  86
  87         $downloader->download_messages('INVOICE');
  88
  89     }
  90     if ( $acct->orders_enabled ) {
  91
  92         # select pending messages
  93         my @pending_orders = $schema->resultset('EdifactMessage')->search(
  94             {
  95                 message_type => 'ORDERS',
  96                 vendor_id    => $acct->vendor_id,
  97                 status       => 'Pending',
  98             }
  99         );
 100         my $uploader = Koha::Edifact::Transport->new( $acct->id );
 101         $uploader->upload_messages(@pending_orders);
 102     }
 103     if ( $acct->responses_enabled ) {
 104         my $downloader = Koha::Edifact::Transport->new( $acct->id );
 105         $downloader->download_messages('ORDRSP');
 106     }
 107 }
 108
 109 # process any downloaded quotes
 110
 111 my @downloaded_quotes = $schema->resultset('EdifactMessage')->search(
 112     {
 113         message_type => 'QUOTE',
 114         status       => 'new',
 115     }
 116 )->all;
 117
 118 foreach my $quote_file (@downloaded_quotes) {
 119     my $filename = $quote_file->filename;
 120     $logger->trace("Processing quote $filename");
 121     process_quote($quote_file);
 122 }
 123
 124 # process any downloaded invoices
 125 if ( C4::Context->preference('EdifactInvoiceImport') eq 'automatic' ) {
 126     my @downloaded_invoices = $schema->resultset('EdifactMessage')->search(
 127         {
 128             message_type => 'INVOICE',
 129             status       => 'new',
 130         }
 131     )->all;
 132
 133     foreach my $invoice (@downloaded_invoices) {
 134         my $filename = $invoice->filename();
 135         $logger->trace("Processing invoice $filename");
 136         process_invoice($invoice);
 137     }
 138 }
 139
 140 my @downloaded_responses = $schema->resultset('EdifactMessage')->search(
 141     {
 142         message_type => 'ORDRSP',
 143         status       => 'new',
 144     }
 145 )->all;
 146
 147 foreach my $response (@downloaded_responses) {
 148     my $filename = $response->filename();
 149     $logger->trace("Processing order response $filename");
 150     process_ordrsp($response);
 151 }
 152
 153 if ( close $pid_handle ) {
 154     unlink $pidfile;
 155     exit 0;
 156 }
 157 else {
 158     $logger->error("Error on pidfile close: $!");
 159     exit 1;
 160 }
 161
 162 sub check_pidfile {
 163
 164     # sysopen my $fh, $pidfile, O_EXCL | O_RDWR or log_exit "$0 already running"
 165     sysopen my $fh, $pidfile, O_RDWR | O_CREAT
 166       or log_exit("$0: open $pidfile: $!");
 167     flock $fh => LOCK_EX or log_exit("$0: flock $pidfile: $!");
 168
 169     sysseek $fh, 0, SEEK_SET or log_exit("$0: sysseek $pidfile: $!");
 170     truncate $fh, 0 or log_exit("$0: truncate $pidfile: $!");
 171     print $fh "$$\n" or log_exit("$0: print $pidfile: $!");
 172
 173     return $fh;
 174 }
 175
 176 sub log_exit {
 177     my $error = shift;
 178     $logger->error($error);
 179
 180     exit 1;
 181 }