Koha/DateUtils.pm

   1 package Koha::DateUtils;
   2
   3 # Copyright (c) 2011 PTFS-Europe Ltd.
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use DateTime;
  21 use C4::Context;
  22 use Koha::Exceptions;
  23
  24 use base 'Exporter';
  25
  26 our @EXPORT = (
  27     qw( dt_from_string output_pref format_sqldatetime )
  28 );
  29
  30 =head1 DateUtils
  31
  32 Koha::DateUtils - Transitional wrappers to ease use of DateTime
  33
  34 =head1 DESCRIPTION
  35
  36 Koha has historically only used dates not datetimes and been content to
  37 handle these as strings. It also has confused formatting with actual dates
  38 this is a temporary module for wrappers to hide the complexity of switch to DateTime
  39
  40 =cut
  41
  42 =head2 dt_ftom_string
  43
  44 $dt = dt_from_string($date_string, [$format, $timezone ]);
  45
  46 Passed a date string returns a DateTime object format and timezone default
  47 to the system preferences. If the date string is empty DateTime->now is returned
  48
  49 =cut
  50
  51 sub dt_from_string {
  52     my ( $date_string, $date_format, $tz ) = @_;
  53
  54     return if $date_string and $date_string =~ m|^0000-0|;
  55
  56     $tz = C4::Context->tz unless $tz;;
  57
  58     return DateTime->now( time_zone => $tz ) unless $date_string;
  59
  60     $date_format = C4::Context->preference('dateformat') unless $date_format;
  61
  62     if ( ref($date_string) eq 'DateTime' ) {    # already a dt return it
  63         return $date_string;
  64     }
  65
  66     my $regex;
  67
  68     # The fallback format is sql/iso
  69     my $fallback_re = qr|
  70         (?<year>\d{4})
  71         -
  72         (?<month>\d{2})
  73         -
  74         (?<day>\d{2})
  75     |xms;
  76
  77     if ( $date_format eq 'metric' ) {
  78         # metric format is "dd/mm/yyyy[ hh:mm:ss]"
  79         $regex = qr|
  80             (?<day>\d{2})
  81             /
  82             (?<month>\d{2})
  83             /
  84             (?<year>\d{4})
  85         |xms;
  86     }
  87     elsif ( $date_format eq 'dmydot' ) {
  88         # dmydot format is "dd.mm.yyyy[ hh:mm:ss]"
  89         $regex = qr|
  90             (?<day>\d{2})
  91             .
  92             (?<month>\d{2})
  93             .
  94             (?<year>\d{4})
  95         |xms;
  96     }
  97     elsif ( $date_format eq 'us' ) {
  98         # us format is "mm/dd/yyyy[ hh:mm:ss]"
  99         $regex = qr|
 100             (?<month>\d{2})
 101             /
 102             (?<day>\d{2})
 103             /
 104             (?<year>\d{4})
 105         |xms;
 106     }
 107     elsif ( $date_format eq 'rfc3339' ) {
 108         $regex = qr/
 109             (?<year>\d{4})
 110             -
 111             (?<month>\d{2})
 112             -
 113             (?<day>\d{2})
 114             ([Tt\s])
 115             (?<hour>\d{2})
 116             :
 117             (?<minute>\d{2})
 118             :
 119             (?<second>\d{2})
 120             (\.\d{1,3})?(([Zz])|([\+|\-]([01][0-9]|2[0-3]):[0-5][0-9]))
 121         /xms;
 122     }
 123     elsif ( $date_format eq 'iso' or $date_format eq 'sql' ) {
 124         # iso or sql format are yyyy-dd-mm[ hh:mm:ss]"
 125         $regex = $fallback_re;
 126     }
 127     else {
 128         die "Invalid dateformat parameter ($date_format)";
 129     }
 130
 131     # Add the faculative time part [hh:mm[:ss]]
 132     my $time_re .= qr|
 133             (
 134                 \s*
 135                 (?<hour>\d{2})
 136                 :
 137                 (?<minute>\d{2})
 138                 (
 139                     :
 140                     (?<second>\d{2})
 141                 )?
 142                 (
 143                     \s
 144                     (?<ampm>\w{2})
 145                 )?
 146             )?
 147     |xms;
 148     $regex .= $time_re;
 149     $fallback_re .= $time_re;
 150
 151     my %dt_params;
 152     my $ampm;
 153     if ( $date_string =~ $regex ) {
 154         %dt_params = (
 155             year   => $+{year},
 156             month  => $+{month},
 157             day    => $+{day},
 158             hour   => $+{hour},
 159             minute => $+{minute},
 160             second => $+{second},
 161         );
 162         $ampm = $+{ampm};
 163     } elsif ( $date_string =~ $fallback_re ) {
 164         %dt_params = (
 165             year   => $+{year},
 166             month  => $+{month},
 167             day    => $+{day},
 168             hour   => $+{hour},
 169             minute => $+{minute},
 170             second => $+{second},
 171         );
 172         $ampm = $+{ampm};
 173     }
 174     else {
 175         die "The given date ($date_string) does not match the date format ($date_format)";
 176     }
 177
 178     # system allows the 0th of the month
 179     $dt_params{day} = '01' if $dt_params{day} eq '00';
 180
 181     # Set default hh:mm:ss to 00:00:00
 182     $dt_params{hour}   = 00 unless defined $dt_params{hour};
 183     $dt_params{minute} = 00 unless defined $dt_params{minute};
 184     $dt_params{second} = 00 unless defined $dt_params{second};
 185
 186     if ( $ampm ) {
 187         if ( $ampm eq 'AM' ) {
 188             $dt_params{hour} = 00 if $dt_params{hour} == 12;
 189         } elsif ( $dt_params{hour} != 12 ) { # PM
 190             $dt_params{hour} += 12;
 191             $dt_params{hour} = 00 if $dt_params{hour} == 24;
 192         }
 193     }
 194
 195     my $dt = eval {
 196         DateTime->new(
 197             %dt_params,
 198             # No TZ for dates 'infinite' => see bug 13242
 199             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 200         );
 201     };
 202     if ($@) {
 203         $tz = DateTime::TimeZone->new( name => 'floating' );
 204         $dt = DateTime->new(
 205             %dt_params,
 206             # No TZ for dates 'infinite' => see bug 13242
 207             ( $dt_params{year} < 9999 ? ( time_zone => $tz->name ) : () ),
 208         );
 209     }
 210     return $dt;
 211 }
 212
 213 =head2 output_pref
 214
 215 $date_string = output_pref({ dt => $dt [, dateformat => $date_format, timeformat => $time_format, dateonly => 0|1, as_due_date => 0|1 ] });
 216 $date_string = output_pref( $dt );
 217
 218 Returns a string containing the time & date formatted as per the C4::Context setting,
 219 or C<undef> if C<undef> was provided.
 220
 221 This routine can either be passed a DateTime object or or a hashref.  If it is
 222 passed a hashref, the expected keys are a mandatory 'dt' for the DateTime,
 223 an optional 'dateformat' to override the dateformat system preference, an
 224 optional 'timeformat' to override the TimeFormat system preference value,
 225 and an optional 'dateonly' to specify that only the formatted date string
 226 should be returned without the time.
 227
 228 =cut
 229
 230 sub output_pref {
 231     my $params = shift;
 232     my ( $dt, $str, $force_pref, $force_time, $dateonly, $as_due_date );
 233     if ( ref $params eq 'HASH' ) {
 234         $dt         = $params->{dt};
 235         $str        = $params->{str};
 236         $force_pref = $params->{dateformat};         # if testing we want to override Context
 237         $force_time = $params->{timeformat};
 238         $dateonly   = $params->{dateonly} || 0;    # if you don't want the hours and minutes
 239         $as_due_date = $params->{as_due_date} || 0; # don't display the hours and minutes if eq to 23:59 or 11:59 (depending the TimeFormat value)
 240     } else {
 241         $dt = $params;
 242     }
 243
 244     Koha::Exceptions::WrongParameter->throw( 'output_pref should not be called with both dt and str parameter' ) if $dt and $str;
 245
 246     if ( $str ) {
 247         local $@;
 248         $dt = eval { dt_from_string( $str ) };
 249         Koha::Exceptions::WrongParameter->throw("Invalid date '$str' passed to output_pref" ) if $@;
 250     }
 251
 252     return if !defined $dt; # NULL date
 253     Koha::Exceptions::WrongParameter->throw( "output_pref is called with '$dt' (ref ". ( ref($dt) ? ref($dt):'SCALAR')."), not a DateTime object")  if ref($dt) ne 'DateTime';
 254
 255     # FIXME: see bug 13242 => no TZ for dates 'infinite'
 256     if ( $dt->ymd !~ /^9999/ ) {
 257         my $tz = $dateonly ? DateTime::TimeZone->new(name => 'floating') : C4::Context->tz;
 258         $dt->set_time_zone( $tz );
 259     }
 260
 261     my $pref =
 262       defined $force_pref ? $force_pref : C4::Context->preference('dateformat');
 263
 264     my $time_format = $force_time || C4::Context->preference('TimeFormat') || q{};
 265     my $time = ( $time_format eq '12hr' ) ? '%I:%M %p' : '%H:%M';
 266     my $date;
 267     if ( $pref =~ m/^iso/ ) {
 268         $date = $dateonly
 269           ? $dt->strftime("%Y-%m-%d")
 270           : $dt->strftime("%Y-%m-%d $time");
 271     }
 272     elsif ( $pref =~ m/^rfc3339/ ) {
 273         if (!$dateonly) {
 274             $date = $dt->strftime('%FT%T%z');
 275             substr($date, -2, 0, ':'); # timezone "HHmm" => "HH:mm"
 276         }
 277         else {
 278             $date = $dt->strftime("%Y-%m-%d");
 279         }
 280     }
 281     elsif ( $pref =~ m/^metric/ ) {
 282         $date = $dateonly
 283           ? $dt->strftime("%d/%m/%Y")
 284           : $dt->strftime("%d/%m/%Y $time");
 285     }
 286     elsif ( $pref =~ m/^dmydot/ ) {
 287         $date = $dateonly
 288           ? $dt->strftime("%d.%m.%Y")
 289           : $dt->strftime("%d.%m.%Y $time");
 290     }
 291
 292     elsif ( $pref =~ m/^us/ ) {
 293         $date = $dateonly
 294           ? $dt->strftime("%m/%d/%Y")
 295           : $dt->strftime("%m/%d/%Y $time");
 296     }
 297     else {
 298         $date = $dateonly
 299           ? $dt->strftime("%Y-%m-%d")
 300           : $dt->strftime("%Y-%m-%d $time");
 301     }
 302
 303     if ( $as_due_date ) {
 304         $time_format eq '12hr'
 305             ? $date =~ s| 11:59 PM$||
 306             : $date =~ s| 23:59$||;
 307     }
 308
 309     return $date;
 310 }
 311
 312 =head2 format_sqldatetime
 313
 314 $string = format_sqldatetime( $string_as_returned_from_db );
 315
 316 a convenience routine for calling dt_from_string and formatting the result
 317 with output_pref as it is a frequent activity in scripts
 318
 319 =cut
 320
 321 sub format_sqldatetime {
 322     my $str        = shift;
 323     my $force_pref = shift;    # if testing we want to override Context
 324     my $force_time = shift;
 325     my $dateonly   = shift;
 326
 327     if ( defined $str && $str =~ m/^\d{4}-\d{2}-\d{2}/ ) {
 328         my $dt = dt_from_string( $str, 'sql' );
 329         return q{} unless $dt;
 330         $dt->truncate( to => 'minute' );
 331         return output_pref({
 332             dt => $dt,
 333             dateformat => $force_pref,
 334             timeformat => $force_time,
 335             dateonly => $dateonly
 336         });
 337     }
 338     return q{};
 339 }
 340
 341 1;