opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::Reserves;
  28 use C4::Members;
  29 use C4::Members::AttributeTypes;
  30 use C4::Members::Attributes qw/GetBorrowerAttributeValue/;
  31 use C4::Output;
  32 use C4::Biblio;
  33 use C4::Items;
  34 use C4::Letters;
  35 use Koha::Account::Lines;
  36 use Koha::Libraries;
  37 use Koha::DateUtils;
  38 use Koha::Holds;
  39 use Koha::Database;
  40 use Koha::ItemTypes;
  41 use Koha::Patron::Attribute::Types;
  42 use Koha::Patron::Messages;
  43 use Koha::Patron::Discharge;
  44 use Koha::Patrons;
  45
  46 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  47
  48 use Scalar::Util qw(looks_like_number);
  49 use Date::Calc qw(
  50   Today
  51   Add_Delta_Days
  52   Date_to_Days
  53 );
  54
  55 my $query = new CGI;
  56
  57 BEGIN {
  58     if (C4::Context->preference('BakerTaylorEnabled')) {
  59         require C4::External::BakerTaylor;
  60         import C4::External::BakerTaylor qw(&image_url &link_url);
  61     }
  62 }
  63
  64 # CAS single logout handling
  65 # Will print header and exit
  66 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  67
  68 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  69     {
  70         template_name   => "opac-user.tt",
  71         query           => $query,
  72         type            => "opac",
  73         authnotrequired => 0,
  74         debug           => 1,
  75     }
  76 );
  77
  78 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  79
  80 my $show_priority;
  81 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  82     m/priority/ and $show_priority = 1;
  83 }
  84
  85 my $patronupdate = $query->param('patronupdate');
  86 my $canrenew = 1;
  87
  88 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  89
  90 # get borrower information ....
  91 my $patron = Koha::Patrons->find( $borrowernumber );
  92 my $borr = $patron->unblessed;
  93 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
  94 my $borcat = $borr ? $borr->{categorycode} : q{};
  95
  96 my (  $today_year,   $today_month,   $today_day) = Today();
  97 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
  98
  99 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
 100 my $userdebarred;
 101
 102 if ($debar) {
 103     $userdebarred = 1;
 104     $template->param( 'userdebarred' => $userdebarred );
 105     if ( $debar ne "9999-12-31" ) {
 106         $borr->{'userdebarreddate'} = $debar;
 107     }
 108     # FIXME looks like $available is not needed
 109     # If a user is discharged they have a validated discharge available
 110     my $available = Koha::Patron::Discharge::count({
 111         borrowernumber => $borrowernumber,
 112         validated      => 1,
 113     });
 114     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 115 }
 116
 117 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 118     $borr->{'flagged'} = 1;
 119     $canrenew = 0;
 120 }
 121
 122 my $amountoutstanding = $patron->account->balance;
 123 if ( $amountoutstanding > 5 ) {
 124     $borr->{'amountoverfive'} = 1;
 125 }
 126 if ( 5 >= $amountoutstanding && $amountoutstanding > 0 ) {
 127     $borr->{'amountoverzero'} = 1;
 128 }
 129 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 130 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 131
 132 if (   C4::Context->preference('OpacRenewalAllowed')
 133     && defined($no_renewal_amt)
 134     && $amountoutstanding > $no_renewal_amt )
 135 {
 136     $borr->{'flagged'} = 1;
 137     $canrenew = 0;
 138     $template->param(
 139         renewal_blocked_fines => $no_renewal_amt,
 140         renewal_blocked_fines_amountoutstanding => $amountoutstanding,
 141     );
 142 }
 143
 144 if ( $amountoutstanding < 0 ) {
 145     $borr->{'amountlessthanzero'} = 1;
 146     $amountoutstanding = -1 * ( $amountoutstanding );
 147 }
 148
 149 # Warningdate is the date that the warning starts appearing
 150 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 151     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 152     if ( $days_to_expiry < 0 ) {
 153         #borrower card has expired, warn the borrower
 154         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 155     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 156         # borrower card soon to expire, warn the borrower
 157         $borr->{'warndeparture'} = $borr->{dateexpiry};
 158         if (C4::Context->preference('ReturnBeforeExpiry')){
 159             $borr->{'returnbeforeexpiry'} = 1;
 160         }
 161     }
 162 }
 163
 164 # pass on any renew errors to the template for displaying
 165 my $renew_error = $query->param('renew_error');
 166
 167 $template->param(
 168                     amountoutstanding => $amountoutstanding,
 169                     borrowernumber    => $borrowernumber,
 170                     patron_flagged    => $borr->{flagged},
 171                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 172                     surname           => $borr->{surname},
 173                     RENEW_ERROR       => $renew_error,
 174                     borrower          => $borr,
 175                 );
 176
 177 #get issued items ....
 178
 179 my $count          = 0;
 180 my $overdues_count = 0;
 181 my @overdues;
 182 my @issuedat;
 183 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 184 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 185 if ( $pending_checkouts->count ) { # Useless test
 186     while ( my $c = $pending_checkouts->next ) {
 187         my $issue = $c->unblessed_all_relateds;
 188         # check for reserves
 189         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 190         if ( $restype ) {
 191             $issue->{'reserved'} = 1;
 192         }
 193
 194         # Must be moved in a module if reused
 195         my $charges = Koha::Account::Lines->search(
 196             {
 197                 borrowernumber    => $patron->borrowernumber,
 198                 amountoutstanding => { '>' => 0 },
 199                 accounttype       => [ 'F', 'FU', 'L' ],
 200                 itemnumber        => $issue->{itemnumber}
 201             },
 202         );
 203         $issue->{charges} = $charges->total_outstanding;
 204
 205         my $rental_fines = Koha::Account::Lines->search(
 206             {
 207                 borrowernumber    => $patron->borrowernumber,
 208                 amountoutstanding => { '>' => 0 },
 209                 accounttype       => 'Rent',
 210                 itemnumber        => $issue->{itemnumber}
 211             }
 212         );
 213         $issue->{rentalfines} = $rental_fines->total_outstanding;
 214
 215         my $marcrecord = GetMarcBiblio({
 216             biblionumber => $issue->{'biblionumber'},
 217             embed_items  => 1,
 218             opac         => 1,
 219             borcat       => $borcat });
 220         $issue->{'subtitle'} = GetRecordValue('subtitle', $marcrecord, GetFrameworkCode($issue->{'biblionumber'}));
 221         # check if item is renewable
 222         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 223         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 224         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 225         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 226         if($status && C4::Context->preference("OpacRenewalAllowed")){
 227             $issue->{'status'} = $status;
 228         }
 229
 230         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 231
 232         if ($renewerror) {
 233             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 234             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 235             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 236             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 237             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 238             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 239             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 240             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 241
 242             if ( $renewerror eq 'too_soon' ) {
 243                 $issue->{'too_soon'}         = 1;
 244                 $issue->{'soonestrenewdate'} = output_pref(
 245                     C4::Circulation::GetSoonestRenewDate(
 246                         $issue->{borrowernumber},
 247                         $issue->{itemnumber}
 248                     )
 249                 );
 250             }
 251         }
 252
 253         if ( $c->is_overdue ) {
 254             push @overdues, $issue;
 255             $overdues_count++;
 256             $issue->{'overdue'} = 1;
 257         }
 258         else {
 259             $issue->{'issued'} = 1;
 260         }
 261         # imageurl:
 262         my $itemtype = $issue->{'itemtype'};
 263         if ( $itemtype ) {
 264             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 265             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 266         }
 267         push @issuedat, $issue;
 268         $count++;
 269
 270         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 271         $issue->{normalized_isbn} = $isbn;
 272         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 273
 274                 # My Summary HTML
 275                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 276                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 277                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 278                     $issue->{title} =~ s/\s+$//; # remove trailing space
 279                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 280                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 281                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 282                     $issue->{MySummaryHTML} = $my_summary_html;
 283                 }
 284     }
 285 }
 286 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 287 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 288
 289 $template->param( ISSUES       => \@issuedat );
 290 $template->param( issues_count => $count );
 291 $template->param( canrenew     => $canrenew );
 292 $template->param( OVERDUES       => \@overdues );
 293 $template->param( overdues_count => $overdues_count );
 294
 295 my $show_barcode = Koha::Patron::Attribute::Types->search(
 296     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 297 if ($show_barcode) {
 298     my $patron_show_barcode = GetBorrowerAttributeValue($borrowernumber, ATTRIBUTE_SHOW_BARCODE);
 299     undef $show_barcode if defined($patron_show_barcode) && !$patron_show_barcode;
 300 }
 301 $template->param( show_barcode => 1 ) if $show_barcode;
 302
 303 # now the reserved items....
 304 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 305
 306 $template->param(
 307     RESERVES       => $reserves,
 308     showpriority   => $show_priority,
 309 );
 310
 311 if (C4::Context->preference('BakerTaylorEnabled')) {
 312     $template->param(
 313         BakerTaylorEnabled  => 1,
 314         BakerTaylorImageURL => &image_url(),
 315         BakerTaylorLinkURL  => &link_url(),
 316         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 317     );
 318 }
 319
 320 if (C4::Context->preference("OPACAmazonCoverImages") or
 321     C4::Context->preference("GoogleJackets") or
 322     C4::Context->preference("BakerTaylorEnabled") or
 323     C4::Context->preference("SyndeticsCoverImages")) {
 324         $template->param(JacketImages=>1);
 325 }
 326
 327 $template->param(
 328     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 329     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 330     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 331     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 332 );
 333
 334 my $patron_messages = Koha::Patron::Messages->search(
 335     {
 336         borrowernumber => $borrowernumber,
 337         message_type => 'B',
 338     }
 339 );
 340
 341 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 342     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 343 {
 344     my @relatives =
 345       Koha::Database->new()->schema()->resultset("Borrower")->search(
 346         {
 347             privacy_guarantor_checkouts => 1,
 348             'me.guarantorid'           => $borrowernumber
 349         },
 350         { prefetch => [ { 'issues' => { 'item' => 'biblio' } } ] }
 351       );
 352     $template->param( relatives => \@relatives );
 353 }
 354
 355 $template->param(
 356     patron_messages          => $patron_messages,
 357     opacnote                 => $borr->{opacnote},
 358     patronupdate             => $patronupdate,
 359     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 360     userview                 => 1,
 361     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 362     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 363     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 364     failed_holds             => scalar $query->param('failed_holds'),
 365 );
 366
 367 # if not an empty string this indicates to return
 368 # back to the opac-results page
 369 my $search_query = $query->param('has-search-query');
 370
 371 if ($search_query) {
 372
 373     print $query->redirect(
 374         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 375         -cookie => $cookie,
 376     );
 377 }
 378
 379 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };