Koha/REST/Plugin/Pagination.pm

   1 package Koha::REST::Plugin::Pagination;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Plugin';
  21
  22 =head1 NAME
  23
  24 Koha::REST::Plugin::Pagination
  25
  26 =head1 API
  27
  28 =head2 Mojolicious::Plugin methods
  29
  30 =head3 register
  31
  32 =cut
  33
  34 sub register {
  35     my ( $self, $app ) = @_;
  36
  37 =head2 Helper methods
  38
  39 =head3 add_pagination_headers
  40
  41     my $patrons = Koha::Patrons->search( ... );
  42     $c->add_pagination_headers({
  43         total  => $patrons->count,
  44         params => {
  45             _page     => ...
  46             _per_page => ...
  47             ...
  48         }
  49     });
  50
  51 Adds a Link header to the response message $c carries, following RFC5988, including
  52 the following relation types: 'prev', 'next', 'first' and 'last'.
  53 It also adds X-Total-Count, containing the total results count.
  54
  55 If page size is omitted, it defaults to the value of the RESTdefaultPageSize syspref.
  56
  57 =cut
  58
  59     $app->helper(
  60         'add_pagination_headers' => sub {
  61             my ( $c, $args ) = @_;
  62
  63             my $total    = $args->{total};
  64             my $req_page = $args->{params}->{_page} // 1;
  65             my $per_page = $args->{params}->{_per_page} //
  66                             C4::Context->preference('RESTdefaultPageSize') // 20;
  67
  68             my $pages;
  69             if ( $per_page == -1 ) {
  70                 $req_page = 1;
  71                 $pages    = 1;
  72             }
  73             else {
  74                 $pages = int $total / $per_page;
  75                 $pages++
  76                     if $total % $per_page > 0;
  77             }
  78
  79             my @links;
  80
  81             if ( $per_page != -1 and $pages > 1 and $req_page > 1 ) {    # Previous exists?
  82                 push @links,
  83                     _build_link(
  84                     $c,
  85                     {   page     => $req_page - 1,
  86                         per_page => $per_page,
  87                         rel      => 'prev',
  88                         params   => $args->{params}
  89                     }
  90                     );
  91             }
  92
  93             if ( $per_page != -1 and $pages > 1 and $req_page < $pages ) {    # Next exists?
  94                 push @links,
  95                     _build_link(
  96                     $c,
  97                     {   page     => $req_page + 1,
  98                         per_page => $per_page,
  99                         rel      => 'next',
 100                         params   => $args->{params}
 101                     }
 102                     );
 103             }
 104
 105             push @links,
 106                 _build_link( $c,
 107                 { page => 1, per_page => $per_page, rel => 'first', params => $args->{params} } );
 108             push @links,
 109                 _build_link( $c,
 110                 { page => $pages, per_page => $per_page, rel => 'last', params => $args->{params} } );
 111
 112             # Add Link header
 113             $c->res->headers->add( 'Link' => join( ',', @links ) );
 114
 115             # Add X-Total-Count header
 116             $c->res->headers->add( 'X-Total-Count' => $total );
 117             return $c;
 118         }
 119     );
 120
 121 =head3 dbic_merge_pagination
 122
 123     $filter = $c->dbic_merge_pagination({
 124         filter => $filter,
 125         params => {
 126             page     => $params->{_page},
 127             per_page => $params->{_per_page}
 128         }
 129     });
 130
 131 Adds I<page> and I<rows> elements to the filter parameter.
 132
 133 =cut
 134
 135     $app->helper(
 136         'dbic_merge_pagination' => sub {
 137             my ( $c, $args ) = @_;
 138             my $filter = $args->{filter};
 139
 140             $filter->{page} = $args->{params}->{_page};
 141             $filter->{rows} = $args->{params}->{_per_page};
 142
 143             return $filter;
 144         }
 145     );
 146 }
 147
 148 =head2 Internal methods
 149
 150 =head3 _build_link
 151
 152     my $link = _build_link( $c, { page => 1, per_page => 5, rel => 'prev' });
 153
 154 Returns a string, suitable for using in Link headers following RFC5988.
 155
 156 =cut
 157
 158 sub _build_link {
 159     my ( $c, $args ) = @_;
 160
 161     my $params = $args->{params};
 162
 163     $params->{_page}     = $args->{page};
 164     $params->{_per_page} = $args->{per_page};
 165
 166     my $link = '<'
 167         . $c->req->url->clone->query(
 168             $params
 169         )->to_abs
 170         . '>; rel="'
 171         . $args->{rel} . '"';
 172
 173     # TODO: Find a better solution for this horrible (but needed) fix
 174     $link =~ s|api/v1/app\.pl/||;
 175
 176     return $link;
 177 }
 178
 179 1;