tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49
  50 use Koha::Patron::Attribute::Types;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $redirect    = $input->param('redirect');
  70 my $section     = $input->param('section');
  71
  72 my $dbh = C4::Context->dbh;
  73
  74 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  75     {
  76         template_name   => 'tools/letter.tt',
  77         query           => $input,
  78         type            => 'intranet',
  79         authnotrequired => 0,
  80         flagsrequired   => { tools => 'edit_notices' },
  81         debug           => 1,
  82     }
  83 );
  84
  85 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  86   ?  C4::Context->userenv()->{'branch'}
  87   : undef;
  88 # we show only the TMPL_VAR names $op
  89
  90 $template->param(
  91     independant_branch => $my_branch,
  92         script_name => $script_name,
  93   searchfield => $searchfield,
  94     branchcode => $branchcode,
  95     section => $section,
  96         action => $script_name
  97 );
  98
  99 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
 100     add_validate();
 101     if( $redirect eq "just_save" ){
 102         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done&section=$section");
 103         exit;
 104     } else {
 105         $op = q{}; # we return to the default screen for the next operation
 106     }
 107 }
 108 if ($op eq 'copy_form') {
 109     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 110     my $branchcode = $input->param('branchcode');
 111     add_form($oldbranchcode, $module, $code);
 112     $template->param(
 113         oldbranchcode => $oldbranchcode,
 114         branchcode => $branchcode,
 115         copying => 1,
 116         modify => 0,
 117     );
 118 }
 119 elsif ( $op eq 'add_form' ) {
 120     add_form($branchcode, $module, $code);
 121 }
 122 elsif ( $op eq 'delete_confirm' ) {
 123     delete_confirm($branchcode, $module, $code);
 124 }
 125 elsif ( $op eq 'delete_confirmed' ) {
 126     delete_confirmed($branchcode, $module, $code);
 127     $op = q{}; # next operation is to return to default screen
 128 }
 129 else {
 130     default_display($branchcode,$searchfield);
 131 }
 132
 133 # Do this last as delete_confirmed resets
 134 if ($op) {
 135     $template->param($op  => 1);
 136 } else {
 137     $template->param(no_op_set => 1);
 138 }
 139
 140 output_html_with_http_headers $input, $cookie, $template->output;
 141
 142 sub add_form {
 143     my ( $branchcode,$module, $code ) = @_;
 144
 145     my $letters;
 146     # if code has been passed we can identify letter and its an update action
 147     if ($code) {
 148         $letters = C4::Letters::GetLetterTemplates(
 149             {
 150                 branchcode => $branchcode,
 151                 module     => $module,
 152                 code       => $code,
 153             }
 154         );
 155     }
 156
 157     my $message_transport_types = GetMessageTransportTypes();
 158     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 159     my %letters = ( default => { templates => $templates } );
 160
 161     if ( C4::Context->preference('TranslateNotices') ) {
 162         my $translated_languages =
 163           C4::Languages::getTranslatedLanguages( 'opac',
 164             C4::Context->preference('template') );
 165         for my $language (@$translated_languages) {
 166             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 167                 if ( $language->{plural} ) {
 168                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 169                         description => $sublanguage->{native_description}
 170                           . ' '
 171                           . $sublanguage->{region_description} . ' ('
 172                           . $sublanguage->{rfc4646_subtag} . ')',
 173                         templates => { %$templates },
 174                     };
 175                 }
 176                 else {
 177                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 178                         description => $sublanguage->{native_description}
 179                           . ' ('
 180                           . $sublanguage->{rfc4646_subtag} . ')',
 181                         templates => { %$templates },
 182                     };
 183                 }
 184             }
 185         }
 186         $template->param( languages => $translated_languages );
 187     }
 188     if ($letters) {
 189         $template->param(
 190             modify     => 1,
 191             code       => $code,
 192         );
 193         my $first_flag_name = 1;
 194         my ( $lang, @templates );
 195         # The letter name is contained into each mtt row.
 196         # So we can only sent the first one to the template.
 197         for my $letter ( @$letters ) {
 198             # The letter_name
 199             if ( $first_flag_name and $letter->{name} ) {
 200                 $template->param(
 201                     letter_name=> $letter->{name},
 202                 );
 203                 $first_flag_name = 0;
 204             }
 205
 206             my $lang = $letter->{lang};
 207             my $mtt = $letter->{message_transport_type};
 208             $letters{ $lang }{templates}{$mtt} = {
 209                 message_transport_type => $letter->{message_transport_type},
 210                 is_html    => $letter->{is_html},
 211                 title      => $letter->{title},
 212                 content    => $letter->{content} // '',
 213             };
 214         }
 215     }
 216     else {
 217         $template->param( adding => 1 );
 218     }
 219
 220     $template->param(
 221         letters => \%letters,
 222     );
 223
 224     my $field_selection;
 225     push @{$field_selection}, add_fields('branches');
 226     if ($module eq 'reserves') {
 227         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 228     }
 229     elsif ( $module eq 'acquisition' ) {
 230         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 231     }
 232     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 233         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 234     }
 235     elsif ($module eq 'claimissues') {
 236         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription', 'biblio', 'biblioitems');
 237     }
 238     elsif ($module eq 'serial') {
 239         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 240     }
 241     elsif ($module eq 'suggestions') {
 242         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 243     }
 244     else {
 245         push @{$field_selection}, add_fields('biblio','biblioitems'),
 246             add_fields('items'),
 247             {value => 'items.content', text => 'items.content'},
 248             {value => 'items.fine',    text => 'items.fine'},
 249             add_fields('borrowers');
 250         if ($module eq 'circulation') {
 251             push @{$field_selection}, add_fields('opac_news');
 252
 253         }
 254
 255         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 256             push @{$field_selection}, add_fields('old_issues');
 257         } else {
 258             push @{$field_selection}, add_fields('issues');
 259         }
 260
 261         if ( $module eq 'circulation' and $code and $code =~ /^AR_/  ) {
 262             push @{$field_selection}, add_fields('article_requests');
 263         }
 264     }
 265
 266     my $preview_is_available = 0;
 267
 268     if ($code) {
 269         $preview_is_available = grep {/^$code$/} qw( CHECKIN CHECKOUT HOLD_SLIP );
 270     }
 271
 272     $template->param(
 273         module     => $module,
 274         SQLfieldnames => $field_selection,
 275         branchcode => $branchcode,
 276         preview_is_available => $preview_is_available,
 277     );
 278     return;
 279 }
 280
 281 sub add_validate {
 282     my $dbh        = C4::Context->dbh;
 283     my $branchcode    = $input->param('branchcode');
 284     my $module        = $input->param('module');
 285     my $oldmodule     = $input->param('oldmodule');
 286     my $code          = $input->param('code');
 287     my $name          = $input->param('name');
 288     my @mtt           = $input->multi_param('message_transport_type');
 289     my @title         = $input->multi_param('title');
 290     my @content       = $input->multi_param('content');
 291     my @lang          = $input->multi_param('lang');
 292     for my $mtt ( @mtt ) {
 293         my $is_html = $input->param("is_html_$mtt");
 294         my $title   = shift @title;
 295         my $content = shift @content;
 296         my $lang = shift @lang;
 297         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 298
 299         # getletter can return the default letter even if we pass a branchcode
 300         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 301         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 302             $letter = undef;
 303         }
 304         unless ( $title and $content ) {
 305             # Delete this mtt if no title or content given
 306             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 307             next;
 308         }
 309         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 310             $dbh->do(
 311                 q{
 312                     UPDATE letter
 313                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 314                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 315                 },
 316                 undef,
 317                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 318                 $branchcode, $oldmodule, $code, $mtt, $lang
 319             );
 320         } else {
 321             $dbh->do(
 322                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 323                 undef,
 324                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 325             );
 326         }
 327     }
 328     # set up default display
 329     default_display($branchcode);
 330     return 1;
 331 }
 332
 333 sub delete_confirm {
 334     my ($branchcode, $module, $code) = @_;
 335     my $dbh = C4::Context->dbh;
 336     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 337     my @values = values %$letter;
 338     $template->param(
 339         letter => $letter,
 340     );
 341     return;
 342 }
 343
 344 sub delete_confirmed {
 345     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 346     C4::Letters::DelLetter(
 347         {
 348             branchcode => $branchcode || '',
 349             module     => $module,
 350             code       => $code,
 351             mtt        => $mtt,
 352             lang       => $lang,
 353         }
 354     );
 355     # setup default display for screen
 356     default_display($branchcode);
 357     return;
 358 }
 359
 360 sub retrieve_letters {
 361     my ($branchcode, $searchstring) = @_;
 362
 363     $branchcode = $my_branch if $branchcode && $my_branch;
 364
 365     my $dbh = C4::Context->dbh;
 366     my ($sql, @where, @args);
 367     $sql = "SELECT branchcode, module, code, name, branchname
 368             FROM letter
 369             LEFT OUTER JOIN branches USING (branchcode)
 370     ";
 371     if ($searchstring && $searchstring=~m/(\S+)/) {
 372         $searchstring = $1 . q{%};
 373         push @where, 'code LIKE ?';
 374         push @args, $searchstring;
 375     }
 376     elsif ($branchcode) {
 377         push @where, 'branchcode = ?';
 378         push @args, $branchcode || '';
 379     }
 380     elsif ($my_branch) {
 381         push @where, "(branchcode = ? OR branchcode = '')";
 382         push @args, $my_branch;
 383     }
 384
 385     $sql .= " WHERE ".join(" AND ", @where) if @where;
 386     $sql .= " GROUP BY branchcode,module,code,name,branchname";
 387
 388     $sql .= " ORDER BY module, code, branchcode";
 389
 390     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 391 }
 392
 393 sub default_display {
 394     my ($branchcode, $searchfield) = @_;
 395
 396     unless ( defined $branchcode ) {
 397         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 398             $branchcode = C4::Context::mybranch();
 399         }
 400     }
 401
 402     if ( $searchfield  ) {
 403         $template->param( search      => 1 );
 404     }
 405     my $results = retrieve_letters($branchcode,$searchfield);
 406
 407     my $loop_data = [];
 408     my $protected_letters = protected_letters();
 409     foreach my $row (@{$results}) {
 410         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 411         push @{$loop_data}, $row;
 412
 413     }
 414
 415     $template->param(
 416         letter => $loop_data,
 417         branchcode => $branchcode,
 418     );
 419 }
 420
 421 sub add_fields {
 422     my @tables = @_;
 423     my @fields = ();
 424
 425     for my $table (@tables) {
 426         push @fields, get_columns_for($table);
 427
 428     }
 429     return @fields;
 430 }
 431
 432 sub get_columns_for {
 433     my $table = shift;
 434 # FIXME untranslatable
 435     my %column_map = (
 436         aqbooksellers => '---BOOKSELLERS---',
 437         aqorders      => '---ORDERS---',
 438         serial        => '---SERIALS---',
 439         reserves      => '---HOLDS---',
 440         suggestions   => '---SUGGESTIONS---',
 441     );
 442     my @fields = ();
 443     if (exists $column_map{$table} ) {
 444         push @fields, {
 445             value => q{},
 446             text  => $column_map{$table} ,
 447         };
 448     }
 449     else {
 450         my $tlabel = '---' . uc $table;
 451         $tlabel.= '---';
 452         push @fields, {
 453             value => q{},
 454             text  => $tlabel,
 455         };
 456     }
 457
 458     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 459     my $table_prefix = $table . q|.|;
 460     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 461     for my $row (@{$rows}) {
 462         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 463         push @fields, {
 464             value => $table_prefix . $row->{Field},
 465             text  => $table_prefix . $row->{Field},
 466         }
 467     }
 468     if ($table eq 'borrowers') {
 469         my $attribute_types = Koha::Patron::Attribute::Types->search(
 470             {},
 471             { order_by => 'code' },
 472         );
 473         while ( my $at = $attribute_types->next ) {
 474             push @fields, {
 475                 value => "borrower-attribute:" . $at->code,
 476                 text  => "attribute:" . $at->code,
 477             }
 478         }
 479     }
 480     return @fields;
 481 }