opac/opac-downloadshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw(encode);
  25
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Items;
  29 use C4::Output;
  30 use C4::Record;
  31 use C4::Ris;
  32 use C4::Csv;
  33
  34 use Koha::Virtualshelves;
  35
  36 use utf8;
  37 my $query = new CGI;
  38
  39 # if virtualshelves is disabled, leave immediately
  40 if ( ! C4::Context->preference('virtualshelves') ) {
  41     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  42     exit;
  43 }
  44
  45 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  46     {
  47         template_name   => "opac-downloadshelf.tt",
  48         query           => $query,
  49         type            => "opac",
  50         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  51     }
  52 );
  53
  54 my $shelfnumber = $query->param('shelfnumber');
  55 my $format  = $query->param('format');
  56 my $context = $query->param('context');
  57 my $dbh     = C4::Context->dbh;
  58
  59 my $shelf = Koha::Virtualshelves->find( $shelfnumber );
  60 if ( $shelf and $shelf->can_be_viewed( $borrowernumber ) ) {
  61
  62     if ($shelfnumber && $format) {
  63
  64
  65         my $contents = $shelf->get_contents;
  66         my $marcflavour         = C4::Context->preference('marcflavour');
  67         my $output;
  68         my $extension;
  69         my $type;
  70
  71        # CSV
  72         if ($format =~ /^\d+$/) {
  73             my @biblios;
  74             while ( my $content = $contents->next ) {
  75                 push @biblios, $content->biblionumber->biblionumber;
  76             }
  77             $output = marc2csv(\@biblios, $format);
  78         # Other formats
  79         } else {
  80             while ( my $content = $contents->next ) {
  81                 my $biblionumber = $content->biblionumber->biblionumber;
  82
  83                 my $record = GetMarcBiblio($biblionumber, 1);
  84                 next unless $record;
  85
  86                 if ($format eq 'iso2709') {
  87                     $output .= $record->as_usmarc();
  88                 }
  89                 elsif ($format eq 'ris' ) {
  90                     $output .= marc2ris($record);
  91                 }
  92                 elsif ($format eq 'bibtex') {
  93                     $output .= marc2bibtex($record, $biblionumber);
  94                 }
  95                 elsif ( $format eq 'isbd' ) {
  96                     $output   .= GetISBDView($biblionumber, "opac");
  97                     $extension = "txt";
  98                     $type      = "text/plain";
  99                 }
 100             }
 101         }
 102
 103         # If it was a CSV export we change the format after the export so the file extension is fine
 104         $format = "csv" if ($format =~ m/^\d+$/);
 105
 106         print $query->header(
 107                                    -type => ($type) ? $type : 'application/octet-stream',
 108             -'Content-Transfer-Encoding' => 'binary',
 109                              -attachment => ($extension) ? "shelf.$format.$extension" : "shelf.$format"
 110         );
 111         print $output;
 112
 113     } else {
 114
 115         # if modal context is passed set a variable so that page markup can be different
 116         if($context eq "modal"){
 117             $template->param(modal => 1);
 118         } else {
 119             $template->param(fullpage => 1);
 120         }
 121         $template->param(csv_profiles => GetCsvProfilesLoop('marc'));
 122         $template->param( shelf => $shelf );
 123         output_html_with_http_headers $query, $cookie, $template->output;
 124     }
 125
 126 } else {
 127     $template->param(invalidlist => 1);
 128     output_html_with_http_headers $query, $cookie, $template->output;
 129 }