opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along
  15 # with Koha; if not, write to the Free Software Foundation, Inc.,
  16 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  17
  18 use Modern::Perl;
  19
  20 use CGI;
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use String::Random qw( random_string );
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use C4::Members;
  27 use Koha::Borrower::Modifications;
  28 use C4::Branch qw(GetBranchesLoop);
  29 use C4::Scrubber;
  30
  31 my $cgi = new CGI;
  32 my $dbh = C4::Context->dbh;
  33
  34 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  35     {
  36         template_name   => "opac-memberentry.tt",
  37         type            => "opac",
  38         query           => $cgi,
  39         authnotrequired => 1,
  40     }
  41 );
  42
  43 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  44 {
  45     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  46     exit;
  47 }
  48
  49 my $action = $cgi->param('action') || q{};
  50 if ( $action eq q{} ) {
  51     if ($borrowernumber) {
  52         $action = 'edit';
  53     }
  54     else {
  55         $action = 'new';
  56     }
  57 }
  58
  59 $template->param(
  60     action            => $action,
  61     hidden            => GetHiddenFields(),
  62     mandatory         => GetMandatoryFields($action),
  63     member_titles     => GetTitles() || undef,
  64     branches          => GetBranchesLoop(),
  65     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  66 );
  67
  68 if ( $action eq 'create' ) {
  69
  70     my %borrower = ParseCgiForBorrower($cgi);
  71
  72     %borrower = DelEmptyFields(%borrower);
  73
  74     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
  75
  76     if (@empty_mandatory_fields) {
  77         $template->param(
  78             empty_mandatory_fields => \@empty_mandatory_fields,
  79             borrower               => \%borrower
  80         );
  81     }
  82     elsif (
  83         md5_base64( $cgi->param('captcha') ) ne $cgi->param('captcha_digest') )
  84     {
  85         $template->param(
  86             failed_captcha => 1,
  87             borrower       => \%borrower
  88         );
  89     }
  90     else {
  91         if (
  92             C4::Context->boolean_preference(
  93                 'PatronSelfRegistrationVerifyByEmail')
  94           )
  95         {
  96             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  97                 {
  98                     template_name   => "opac-registration-email-sent.tt",
  99                     type            => "opac",
 100                     query           => $cgi,
 101                     authnotrequired => 1,
 102                 }
 103             );
 104             $template->param( 'email' => $borrower{'email'} );
 105
 106             my $verification_token = md5_hex( \%borrower );
 107             $borrower{'password'} = random_string("..........");
 108
 109             Koha::Borrower::Modifications->new(
 110                 verification_token => $verification_token )
 111               ->AddModifications(\%borrower);
 112
 113             #Send verification email
 114             my $letter = C4::Letters::GetPreparedLetter(
 115                 module      => 'members',
 116                 letter_code => 'OPAC_REG_VERIFY',
 117                 tables      => {
 118                     borrower_modifications =>
 119                       [ $verification_token, $verification_token ],
 120                 },
 121             );
 122
 123             C4::Letters::EnqueueLetter(
 124                 {
 125                     letter                 => $letter,
 126                     message_transport_type => 'email',
 127                     to_address             => $borrower{'email'},
 128                     from_address =>
 129                       C4::Context->preference('KohaAdminEmailAddress'),
 130                 }
 131             );
 132         }
 133         else {
 134             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 135                 {
 136                     template_name   => "opac-registration-confirmation.tt",
 137                     type            => "opac",
 138                     query           => $cgi,
 139                     authnotrequired => 1,
 140                 }
 141             );
 142
 143             $template->param( OpacPasswordChange =>
 144                   C4::Context->preference('OpacPasswordChange') );
 145
 146             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 147
 148             $template->param( password_cleartext => $password );
 149             $template->param(
 150                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 151             $template->param(
 152                 PatronSelfRegistrationAdditionalInstructions =>
 153                   C4::Context->preference(
 154                     'PatronSelfRegistrationAdditionalInstructions')
 155             );
 156         }
 157     }
 158 }
 159 elsif ( $action eq 'update' ) {
 160
 161     my %borrower = ParseCgiForBorrower($cgi);
 162
 163     my %borrower_changes = DelEmptyFields(%borrower);
 164     my @empty_mandatory_fields =
 165       CheckMandatoryFields( \%borrower_changes, $action );
 166
 167     if (@empty_mandatory_fields) {
 168         $template->param(
 169             empty_mandatory_fields => \@empty_mandatory_fields,
 170             borrower               => \%borrower
 171         );
 172
 173         $template->param( action => 'edit' );
 174     }
 175     else {
 176         ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 177             {
 178                 template_name   => "opac-memberentry-update-submitted.tt",
 179                 type            => "opac",
 180                 query           => $cgi,
 181                 authnotrequired => 1,
 182             }
 183         );
 184
 185         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 186
 187         my $m =
 188           Koha::Borrower::Modifications->new(
 189             borrowernumber => $borrowernumber );
 190
 191         $m->DelModifications;
 192         $m->AddModifications(\%borrower_changes);
 193         $template->param(
 194             borrower => GetMember( borrowernumber => $borrowernumber ),
 195         );
 196     }
 197 }
 198 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 199     my $borrower = GetMember( borrowernumber => $borrowernumber );
 200
 201     if (C4::Context->preference('ExtendedPatronAttributes')) {
 202         my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber, 'opac');
 203         if (scalar(@$attributes) > 0) {
 204             $borrower->{ExtendedPatronAttributes} = 1;
 205             $borrower->{patron_attributes} = $attributes;
 206         }
 207     }
 208
 209     $template->param(
 210         borrower => $borrower, );
 211
 212     if (C4::Context->preference('OPACpatronimages')) {
 213         my ($image, $dberror) = GetPatronImage($borrower->{borrowernumber});
 214         if ($image) {
 215             $template->param(
 216                 display_patron_image => 1
 217             );
 218         }
 219     }
 220
 221 }
 222
 223 my $captcha = random_string("CCCCC");
 224
 225 $template->param(
 226     captcha        => $captcha,
 227     captcha_digest => md5_base64($captcha)
 228 );
 229
 230 output_html_with_http_headers $cgi, $cookie, $template->output;
 231
 232 sub GetHiddenFields {
 233     my %hidden_fields;
 234
 235     my $BorrowerUnwantedField =
 236       C4::Context->preference("PatronSelfRegistrationBorrowerUnwantedField");
 237
 238     my @fields = split( /\|/, $BorrowerUnwantedField );
 239     foreach (@fields) {
 240         next unless m/\w/o;
 241         $hidden_fields{$_} = 1;
 242     }
 243
 244     return \%hidden_fields;
 245 }
 246
 247 sub GetMandatoryFields {
 248     my ($action) = @_;
 249
 250     my %mandatory_fields;
 251
 252     my $BorrowerMandatoryField =
 253       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 254
 255     my @fields = split( /\|/, $BorrowerMandatoryField );
 256
 257     foreach (@fields) {
 258         $mandatory_fields{$_} = 1;
 259     }
 260
 261     if ( $action eq 'create' || $action eq 'new' ) {
 262         $mandatory_fields{'email'} = 1
 263           if C4::Context->boolean_preference(
 264             'PatronSelfRegistrationVerifyByEmail');
 265     }
 266
 267     return \%mandatory_fields;
 268 }
 269
 270 sub CheckMandatoryFields {
 271     my ( $borrower, $action ) = @_;
 272
 273     my @empty_mandatory_fields;
 274
 275     my $mandatory_fields = GetMandatoryFields($action);
 276     delete $mandatory_fields->{'cardnumber'};
 277
 278     foreach my $key ( keys %$mandatory_fields ) {
 279         push( @empty_mandatory_fields, $key )
 280           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 281     }
 282
 283     return @empty_mandatory_fields;
 284 }
 285
 286 sub ParseCgiForBorrower {
 287     my ($cgi) = @_;
 288
 289     my $scrubber = C4::Scrubber->new();
 290     my %borrower;
 291
 292     foreach ( $cgi->param ) {
 293         if ( $_ =~ '^borrower_' ) {
 294             my ($key) = substr( $_, 9 );
 295             $borrower{$key} = $scrubber->scrub( $cgi->param($_) );
 296         }
 297     }
 298
 299     $borrower{'dateofbirth'} =
 300       C4::Dates->new( $borrower{'dateofbirth'} )->output("iso")
 301       if ( defined( $borrower{'dateofbirth'} ) );
 302
 303     return %borrower;
 304 }
 305
 306 sub DelUnchangedFields {
 307     my ( $borrowernumber, %new_data ) = @_;
 308
 309     my $current_data = GetMember( borrowernumber => $borrowernumber );
 310
 311     foreach my $key ( keys %new_data ) {
 312         if ( $current_data->{$key} eq $new_data{$key} ) {
 313             delete $new_data{$key};
 314         }
 315     }
 316
 317     return %new_data;
 318 }
 319
 320 sub DelEmptyFields {
 321     my (%borrower) = @_;
 322
 323     foreach my $key ( keys %borrower ) {
 324         delete $borrower{$key} unless $borrower{$key};
 325     }
 326
 327     return %borrower;
 328 }