virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw( encode );
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use Koha::Email;
  35 use Koha::Virtualshelves;
  36
  37 my $query = new CGI;
  38
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name   => "virtualshelves/sendshelfform.tt",
  42         query           => $query,
  43         type            => "intranet",
  44         authnotrequired => 0,
  45         flagsrequired   => { catalogue => 1 },
  46     }
  47 );
  48
  49 my $shelfid = $query->param('shelfid');
  50 my $email   = $query->param('email');
  51
  52 my $dbh = C4::Context->dbh;
  53
  54 if ($email) {
  55     my $comment = $query->param('comment');
  56     my $message = Koha::Email->new();
  57     my %mail    = $message->create_message_headers(
  58         {
  59             to => $email
  60         }
  61     );
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65         template_name   => "virtualshelves/sendshelf.tt",
  66         query           => $query,
  67         type            => "intranet",
  68         authnotrequired => 0,
  69         flagsrequired   => { catalogue => 1 },
  70         }
  71     );
  72
  73     my $shelf = Koha::Virtualshelves->find( $shelfid );
  74     my $contents = $shelf->get_contents;
  75     my $marcflavour = C4::Context->preference('marcflavour');
  76     my $iso2709;
  77     my @results;
  78
  79     while ( my $content = $contents->next ) {
  80         my $biblionumber     = $content->biblionumber;
  81         my $fw               = GetFrameworkCode($biblionumber);
  82         my $dat              = GetBiblioData($biblionumber);
  83         my $record           = GetMarcBiblio($biblionumber, 1);
  84         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  85         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  86         my $subtitle         = GetRecordValue( 'subtitle', $record, $fw );
  87
  88         my @items = GetItemsInfo($biblionumber);
  89
  90         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  91         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  92         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  93         $dat->{'biblionumber'} = $biblionumber;
  94         $dat->{ITEM_RESULTS}   = \@items;
  95         $dat->{subtitle}       = $subtitle;
  96         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
  97
  98         $iso2709 .= $record->as_usmarc();
  99
 100         push( @results, $dat );
 101     }
 102
 103     $template2->param(
 104         BIBLIO_RESULTS => \@results,
 105         comment        => $comment,
 106         shelfname      => $shelf->shelfname,
 107     );
 108
 109     # Getting template result
 110     my $template_res = $template2->output();
 111     my $body;
 112
 113     # Analysing information and getting mail properties
 114     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 115         $mail{'subject'} = Encode::encode("UTF-8", $1);
 116         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 117     }
 118     else { $mail{'subject'} = "no subject"; }
 119
 120     my $email_header = "";
 121     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 122         $email_header = $1;
 123         $email_header =~ s|\n?(.*)\n?|$1|;
 124         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 125     }
 126
 127     my $email_file = "list.txt";
 128     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 129         $email_file = $1;
 130         $email_file =~ s|\n?(.*)\n?|$1|;
 131     }
 132
 133     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 134         $body = $1;
 135         $body =~ s|\n?(.*)\n?|$1|;
 136         $body = encode_qp(Encode::encode("UTF-8", $body));
 137     }
 138
 139     my $boundary = "====" . time() . "====";
 140
 141     # We set and put the multipart content
 142     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 143
 144     my $isofile = encode_base64( encode( "UTF-8", $iso2709 ) );
 145     $boundary = '--' . $boundary;
 146
 147     $mail{body} = <<END_OF_BODY;
 148 $boundary
 149 Content-Type: text/plain; charset="utf-8"
 150 Content-Transfer-Encoding: quoted-printable
 151
 152 $email_header
 153 $body
 154 $boundary
 155 Content-Type: application/octet-stream; name="shelf.iso2709"
 156 Content-Transfer-Encoding: base64
 157 Content-Disposition: attachment; filename="shelf.iso2709"
 158
 159 $isofile
 160 $boundary--
 161 END_OF_BODY
 162
 163     # Sending mail
 164     if ( sendmail %mail ) {
 165
 166         # do something if it works....
 167         $template->param( SENT => "1" );
 168     }
 169     else {
 170         # do something if it doesn't work....
 171         carp "Error sending mail: $Mail::Sendmail::error \n";
 172         $template->param( error => 1 );
 173     }
 174
 175     $template->param( email => $email );
 176     output_html_with_http_headers $query, $cookie, $template->output;
 177
 178 }
 179 else {
 180     $template->param(
 181         shelfid => $shelfid,
 182         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 183     );
 184     output_html_with_http_headers $query, $cookie, $template->output;
 185 }