C4/Languages.pm

   1 package C4::Languages;
   2
   3 # Copyright 2006 (C) LibLime
   4 # Joshua Ferraro <jmf@liblime.com>
   5 # Portions Copyright 2009 Chris Cormack and the Koha Dev Team
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use CGI;
  27 use List::MoreUtils qw( any );
  28 use C4::Context;
  29 use Koha::Cache::Memory::Lite;
  30 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $DEBUG);
  31
  32 BEGIN {
  33     require Exporter;
  34     @ISA    = qw(Exporter);
  35     @EXPORT = qw(
  36         &getFrameworkLanguages
  37         &getTranslatedLanguages
  38         &getLanguages
  39         &getAllLanguages
  40     );
  41     @EXPORT_OK = qw(getFrameworkLanguages getTranslatedLanguages getAllLanguages getLanguages get_bidi regex_lang_subtags language_get_description accept_language getlanguage);
  42     $DEBUG = 0;
  43 }
  44
  45 =head1 NAME
  46
  47 C4::Languages - Perl Module containing language list functions for Koha
  48
  49 =head1 SYNOPSIS
  50
  51 use C4::Languages;
  52
  53 =head1 DESCRIPTION
  54
  55 =cut
  56
  57 =head1 FUNCTIONS
  58
  59 =head2 getFrameworkLanguages
  60
  61 Returns a reference to an array of hashes:
  62
  63  my $languages = getFrameworkLanguages();
  64  for my $language(@$languages) {
  65     print "$language->{language_code}\n"; # language code in iso 639-2
  66     print "$language->{language_name}\n"; # language name in native script
  67     print "$language->{language_locale_name}\n"; # language name in current locale
  68  }
  69
  70 =cut
  71
  72 sub getFrameworkLanguages {
  73     # get a hash with all language codes, names, and locale names
  74     my $all_languages = getAllLanguages();
  75     my @languages;
  76
  77     # find the available directory names
  78     my $dir=C4::Context->config('intranetdir')."/installer/data/";
  79     opendir (MYDIR,$dir);
  80     my @listdir= grep { !/^\.|CVS/ && -d "$dir/$_"} readdir(MYDIR);
  81     closedir MYDIR;
  82
  83     # pull out all data for the dir names that exist
  84     for my $dirname (@listdir) {
  85         for my $language_set (@$all_languages) {
  86
  87             if ($dirname eq $language_set->{language_code}) {
  88                 push @languages, {
  89                     'language_code'=>$dirname,
  90                     'language_description'=>$language_set->{language_description},
  91                     'native_descrition'=>$language_set->{language_native_description} }
  92             }
  93         }
  94     }
  95     return \@languages;
  96 }
  97
  98 =head2 getTranslatedLanguages
  99
 100 Returns a reference to an array of hashes:
 101
 102  my $languages = getTranslatedLanguages();
 103  print "Available translated languages:\n";
 104  for my $language(@$trlanguages) {
 105     print "$language->{language_code}\n"; # language code in iso 639-2
 106     print "$language->{language_name}\n"; # language name in native script
 107     print "$language->{language_locale_name}\n"; # language name in current locale
 108  }
 109
 110 =cut
 111
 112 sub getTranslatedLanguages {
 113     my ($interface, $theme, $current_language, $which) = @_;
 114     my $htdocs;
 115     my @languages;
 116     my @enabled_languages;
 117
 118     if ($interface && $interface eq 'opac' ) {
 119         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 120         $htdocs = C4::Context->config('opachtdocs');
 121         if ( $theme and -d "$htdocs/$theme" ) {
 122             (@languages) = _get_language_dirs($htdocs,$theme);
 123         }
 124         else {
 125             for my $theme ( _get_themes('opac') ) {
 126                 push @languages, _get_language_dirs($htdocs,$theme);
 127             }
 128         }
 129     }
 130     elsif ($interface && $interface eq 'intranet' ) {
 131         @enabled_languages = split ",", C4::Context->preference('language');
 132         $htdocs = C4::Context->config('intrahtdocs');
 133         if ( $theme and -d "$htdocs/$theme" ) {
 134             @languages = _get_language_dirs($htdocs,$theme);
 135         }
 136         else {
 137             foreach my $theme ( _get_themes('intranet') ) {
 138                 push @languages, _get_language_dirs($htdocs,$theme);
 139             }
 140         }
 141     }
 142     else {
 143         @enabled_languages = split ",", C4::Context->preference('opaclanguages');
 144         my $htdocs = C4::Context->config('intrahtdocs');
 145         foreach my $theme ( _get_themes('intranet') ) {
 146             push @languages, _get_language_dirs($htdocs,$theme);
 147         }
 148         $htdocs = C4::Context->config('opachtdocs');
 149         foreach my $theme ( _get_themes('opac') ) {
 150             push @languages, _get_language_dirs($htdocs,$theme);
 151         }
 152         my %seen;
 153         $seen{$_}++ for @languages;
 154         @languages = keys %seen;
 155     }
 156     return _build_languages_arrayref(\@languages,$current_language,\@enabled_languages);
 157 }
 158
 159 =head2 getAllLanguages
 160
 161 Returns a reference to an array of hashes:
 162
 163  my $alllanguages = getAllLanguages();
 164  print "Available translated languages:\n";
 165  for my $language(@$alllanguages) {
 166     print "$language->{language_code}\n";
 167     print "$language->{language_name}\n";
 168     print "$language->{language_locale_name}\n";
 169  }
 170
 171 This routine is a wrapper for getLanguages().
 172
 173 =cut
 174
 175 sub getAllLanguages {
 176     return getLanguages(shift);
 177 }
 178
 179 =head2 getLanguages
 180
 181     my $lang_arrayref = getLanguages([$lang[, $isFiltered]]);
 182
 183 Returns a reference to an array of hashes of languages.
 184
 185 - If no parameter is passed to the function, it returns english languages names
 186 - If a $lang parameter conforming to RFC4646 syntax is passed, the function returns languages names translated in $lang
 187   If a language name is not translated in $lang in database, the function returns english language name
 188 - If $isFiltered is set to true, only the detail of the languages selected in system preferences AdvanceSearchLanguages is returned.
 189
 190 =cut
 191
 192 sub getLanguages {
 193     my $lang = shift;
 194     my $isFiltered = shift;
 195
 196     my @languages_loop;
 197     my $dbh=C4::Context->dbh;
 198     my $default_language = 'en';
 199     my $current_language = $default_language;
 200     my $language_list = $isFiltered ? C4::Context->preference("AdvancedSearchLanguages") : undef;
 201     if ($lang) {
 202         $current_language = regex_lang_subtags($lang)->{'language'};
 203     }
 204     my $sth = $dbh->prepare('SELECT * FROM language_subtag_registry WHERE type=\'language\'');
 205     $sth->execute();
 206     while (my $language_subtag_registry = $sth->fetchrow_hashref) {
 207         my $desc;
 208         # check if language name is stored in current language
 209         my $sth4= $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag =? AND lang = ?");
 210         $sth4->execute($language_subtag_registry->{subtag},$current_language);
 211         while (my $language_desc = $sth4->fetchrow_hashref) {
 212              $desc=$language_desc->{description};
 213         }
 214         my $sth2= $dbh->prepare("SELECT * FROM language_descriptions LEFT JOIN language_rfc4646_to_iso639 on language_rfc4646_to_iso639.rfc4646_subtag = language_descriptions.subtag WHERE type='language' AND subtag =? AND language_descriptions.lang = ?");
 215         if ($desc) {
 216             $sth2->execute($language_subtag_registry->{subtag},$current_language);
 217         }
 218         else {
 219             $sth2->execute($language_subtag_registry->{subtag},$default_language);
 220         }
 221         my $sth3 = $dbh->prepare("SELECT description FROM language_descriptions WHERE type='language' AND subtag=? AND lang=?");
 222         # add the correct description info
 223         while (my $language_descriptions = $sth2->fetchrow_hashref) {
 224             $sth3->execute($language_subtag_registry->{subtag},$language_subtag_registry->{subtag});
 225             my $native_description;
 226             while (my $description = $sth3->fetchrow_hashref) {
 227                 $native_description = $description->{description};
 228             }
 229
 230             # fill in the ISO6329 code
 231             $language_subtag_registry->{iso639_2_code} = $language_descriptions->{iso639_2_code};
 232             # fill in the native description of the language, as well as the current language's translation of that if it exists
 233             if ($native_description) {
 234                 $language_subtag_registry->{language_description} = $native_description;
 235                 $language_subtag_registry->{language_description}.=" ($language_descriptions->{description})" if $language_descriptions->{description};
 236             }
 237             else {
 238                 $language_subtag_registry->{language_description} = $language_descriptions->{description};
 239             }
 240         }
 241         # Do not push unless valid iso639-2 code
 242         if ( $language_subtag_registry->{ iso639_2_code } and ( !$language_list || index (  $language_list, $language_subtag_registry->{ iso639_2_code } ) >= 0) ) {
 243             push @languages_loop, $language_subtag_registry;
 244         }
 245     }
 246     return \@languages_loop;
 247 }
 248
 249 =head2 _get_themes
 250
 251 Internal function, returns an array of all available themes.
 252
 253   (@themes) = &_get_themes('opac');
 254   (@themes) = &_get_themes('intranet');
 255
 256 =cut
 257
 258 sub _get_themes {
 259     my $interface = shift;
 260     my $htdocs;
 261     my @themes;
 262     if ( $interface && $interface eq 'intranet' ) {
 263         $htdocs = C4::Context->config('intrahtdocs');
 264     }
 265     else {
 266         $htdocs = C4::Context->config('opachtdocs');
 267     }
 268     opendir D, "$htdocs";
 269     my @dirlist = readdir D;
 270     foreach my $directory (@dirlist) {
 271         # if there's an en dir, it's a valid theme
 272         -d "$htdocs/$directory/en" and push @themes, $directory;
 273     }
 274     return @themes;
 275 }
 276
 277 =head2 _get_language_dirs
 278
 279 Internal function, returns an array of directory names, excluding non-language directories
 280
 281 =cut
 282
 283 sub _get_language_dirs {
 284     my ($htdocs,$theme) = @_;
 285     $htdocs //= '';
 286     $theme //= '';
 287     my @lang_strings;
 288     opendir D, "$htdocs/$theme";
 289     for my $lang_string ( readdir D ) {
 290         next if $lang_string =~/^\./;
 291         next if $lang_string eq 'all';
 292         next if $lang_string =~/png$/;
 293         next if $lang_string =~/js$/;
 294         next if $lang_string =~/css$/;
 295         next if $lang_string =~/CVS$/;
 296         next if $lang_string =~/\.txt$/i;     #Don't read the readme.txt !
 297         next if $lang_string =~/img|images|famfam|js|less|lib|sound|pdf/;
 298         push @lang_strings, $lang_string;
 299     }
 300         return (@lang_strings);
 301 }
 302
 303 =head2 _build_languages_arrayref
 304
 305 Internal function for building the ref to array of hashes
 306
 307 FIXME: this could be rewritten and simplified using map
 308
 309 =cut
 310
 311 sub _build_languages_arrayref {
 312         my ($translated_languages,$current_language,$enabled_languages) = @_;
 313         $current_language //= '';
 314         my @translated_languages = @$translated_languages;
 315         my @languages_loop; # the final reference to an array of hashrefs
 316         my @enabled_languages = @$enabled_languages;
 317         # how many languages are enabled, if one, take note, some contexts won't need to display it
 318         my %seen_languages; # the language tags we've seen
 319         my %found_languages;
 320         my $language_groups;
 321         my $track_language_groups;
 322         my $current_language_regex = regex_lang_subtags($current_language);
 323         # Loop through the translated languages
 324         for my $translated_language (@translated_languages) {
 325             # separate the language string into its subtag types
 326             my $language_subtags_hashref = regex_lang_subtags($translated_language);
 327
 328             # is this language string 'enabled'?
 329             for my $enabled_language (@enabled_languages) {
 330                 #warn "Checking out if $translated_language eq $enabled_language";
 331                 $language_subtags_hashref->{'enabled'} = 1 if $translated_language eq $enabled_language;
 332             }
 333
 334             # group this language, key by langtag
 335             $language_subtags_hashref->{'sublanguage_current'} = 1 if $translated_language eq $current_language;
 336             $language_subtags_hashref->{'rfc4646_subtag'} = $translated_language;
 337             $language_subtags_hashref->{'native_description'} = language_get_description($language_subtags_hashref->{language},$language_subtags_hashref->{language},'language');
 338             $language_subtags_hashref->{'script_description'} = language_get_description($language_subtags_hashref->{script},$language_subtags_hashref->{'language'},'script');
 339             $language_subtags_hashref->{'region_description'} = language_get_description($language_subtags_hashref->{region},$language_subtags_hashref->{'language'},'region');
 340             $language_subtags_hashref->{'variant_description'} = language_get_description($language_subtags_hashref->{variant},$language_subtags_hashref->{'language'},'variant');
 341             $track_language_groups->{$language_subtags_hashref->{'language'}}++;
 342             push ( @{ $language_groups->{$language_subtags_hashref->{language}} }, $language_subtags_hashref );
 343         }
 344         # $key is a language subtag like 'en'
 345         while( my ($key, $value) = each %$language_groups) {
 346
 347             # is this language group enabled? are any of the languages within it enabled?
 348             my $enabled;
 349             for my $enabled_language (@enabled_languages) {
 350                 my $regex_enabled_language = regex_lang_subtags($enabled_language);
 351                 $enabled = 1 if $key eq ($regex_enabled_language->{language} // '');
 352             }
 353             push @languages_loop,  {
 354                             # this is only use if there is one
 355                             rfc4646_subtag => @$value[0]->{rfc4646_subtag},
 356                             native_description => language_get_description($key,$key,'language'),
 357                             language => $key,
 358                             sublanguages_loop => $value,
 359                             plural => $track_language_groups->{$key} >1 ? 1 : 0,
 360                             current => ($current_language_regex->{language} // '') eq $key ? 1 : 0,
 361                             group_enabled => $enabled,
 362                            };
 363         }
 364         return \@languages_loop;
 365 }
 366
 367 sub language_get_description {
 368     my ($script,$lang,$type) = @_;
 369     my $dbh = C4::Context->dbh;
 370     my $desc;
 371     my $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 372     #warn "QUERY: SELECT description FROM language_descriptions WHERE subtag=$script AND lang=$lang AND type=$type";
 373     $sth->execute($script,$lang,$type);
 374     while (my $descriptions = $sth->fetchrow_hashref) {
 375         $desc = $descriptions->{'description'};
 376     }
 377     unless ($desc) {
 378         $sth = $dbh->prepare("SELECT description FROM language_descriptions WHERE subtag=? AND lang=? AND type=?");
 379         $sth->execute($script,'en',$type);
 380         while (my $descriptions = $sth->fetchrow_hashref) {
 381             $desc = $descriptions->{'description'};
 382         }
 383     }
 384     return $desc;
 385 }
 386 =head2 regex_lang_subtags
 387
 388 This internal sub takes a string composed according to RFC 4646 as
 389 an input and returns a reference to a hash containing keys and values
 390 for ( language, script, region, variant, extension, privateuse )
 391
 392 =cut
 393
 394 sub regex_lang_subtags {
 395     my $string = shift;
 396
 397     # Regex for recognizing RFC 4646 well-formed tags
 398     # http://www.rfc-editor.org/rfc/rfc4646.txt
 399
 400     # regexes based on : http://unicode.org/cldr/data/tools/java/org/unicode/cldr/util/data/langtagRegex.txt
 401     # The structure requires no forward references, so it reverses the order.
 402     # The uppercase comments are fragments copied from RFC 4646
 403     #
 404     # Note: the tool requires that any real "=" or "#" or ";" in the regex be escaped.
 405
 406     my $alpha   = qr/[a-zA-Z]/ ;    # ALPHA
 407     my $digit   = qr/[0-9]/ ;   # DIGIT
 408     my $alphanum    = qr/[a-zA-Z0-9]/ ; # ALPHA / DIGIT
 409     my $x   = qr/[xX]/ ;    # private use singleton
 410     my $singleton = qr/[a-w y-z A-W Y-Z]/ ; # other singleton
 411     my $s   = qr/[-]/ ; # separator -- lenient parsers will use [-_]
 412
 413     # Now do the components. The structure is slightly different to allow for capturing the right components.
 414     # The notation (?:....) is a non-capturing version of (...): so the "?:" can be deleted if someone doesn't care about capturing.
 415
 416     my $extlang = qr{(?: $s $alpha{3} )}x ; # *3("-" 3ALPHA)
 417     my $language    = qr{(?: $alpha{2,3} | $alpha{4,8} )}x ;
 418     #my $language   = qr{(?: $alpha{2,3}$extlang{0,3} | $alpha{4,8} )}x ;   # (2*3ALPHA [ extlang ]) / 4ALPHA / 5*8ALPHA
 419
 420     my $script  = qr{(?: $alpha{4} )}x ;    # 4ALPHA
 421
 422     my $region  = qr{(?: $alpha{2} | $digit{3} )}x ;     # 2ALPHA / 3DIGIT
 423
 424     my $variantSub  = qr{(?: $digit$alphanum{3} | $alphanum{5,8} )}x ;  # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 425     my $variant = qr{(?: $variantSub (?: $s$variantSub )* )}x ; # *("-" variant), 5*8alphanum / (DIGIT 3alphanum)
 426
 427     my $extensionSub    = qr{(?: $singleton (?: $s$alphanum{2,8} )+ )}x ;   # singleton 1*("-" (2*8alphanum))
 428     my $extension   = qr{(?: $extensionSub (?: $s$extensionSub )* )}x ; # singleton 1*("-" (2*8alphanum))
 429
 430     my $privateuse  = qr{(?: $x (?: $s$alphanum{1,8} )+ )}x ;   # ("x"/"X") 1*("-" (1*8alphanum))
 431
 432     # Define certain grandfathered codes, since otherwise the regex is pretty useless.
 433     # Since these are limited, this is safe even later changes to the registry --
 434     # the only oddity is that it might change the type of the tag, and thus
 435     # the results from the capturing groups.
 436     # http://www.iana.org/assignments/language-subtag-registry
 437     # Note that these have to be compared case insensitively, requiring (?i) below.
 438
 439     my $grandfathered   = qr{(?: (?i)
 440         en $s GB $s oed
 441     |   i $s (?: ami | bnn | default | enochian | hak | klingon | lux | mingo | navajo | pwn | tao | tay | tsu )
 442     |   sgn $s (?: BE $s fr | BE $s nl | CH $s de)
 443 )}x;
 444
 445     # For well-formedness, we don't need the ones that would otherwise pass, so they are commented out here
 446
 447     #   |   art $s lojban
 448     #   |   cel $s gaulish
 449     #   |   en $s (?: boont | GB $s oed | scouse )
 450     #   |   no $s (?: bok | nyn)
 451     #   |   zh $s (?: cmn | cmn $s Hans | cmn $s Hant | gan | guoyu | hakka | min | min $s nan | wuu | xiang | yue)
 452
 453     # Here is the final breakdown, with capturing groups for each of these components
 454     # The language, variants, extensions, grandfathered, and private-use may have interior '-'
 455
 456     #my $root = qr{(?: ($language) (?: $s ($script) )? 40% (?: $s ($region) )? 40% (?: $s ($variant) )? 10% (?: $s ($extension) )? 5% (?: $s ($privateuse) )? 5% ) 90% | ($grandfathered) 5% | ($privateuse) 5% };
 457
 458     $string =~  qr{^ (?:($language)) (?:$s($script))? (?:$s($region))?  (?:$s($variant))?  (?:$s($extension))?  (?:$s($privateuse))? $}xi;  # |($grandfathered) | ($privateuse) $}xi;
 459     my %subtag = (
 460         'rfc4646_subtag' => $string,
 461         'language' => $1,
 462         'script' => $2,
 463         'region' => $3,
 464         'variant' => $4,
 465         'extension' => $5,
 466         'privateuse' => $6,
 467     );
 468     return \%subtag;
 469 }
 470
 471 # Script Direction Resources:
 472 # http://www.w3.org/International/questions/qa-scripts
 473 sub get_bidi {
 474     my ($language_script)= @_;
 475     my $dbh = C4::Context->dbh;
 476     my $bidi;
 477     my $sth = $dbh->prepare('SELECT bidi FROM language_script_bidi WHERE rfc4646_subtag=?');
 478     $sth->execute($language_script);
 479     while (my $result = $sth->fetchrow_hashref) {
 480         $bidi = $result->{'bidi'};
 481     }
 482     return $bidi;
 483 };
 484
 485 sub accept_language {
 486     # referenced http://search.cpan.org/src/CGILMORE/I18N-AcceptLanguage-1.04/lib/I18N/AcceptLanguage.pm
 487     my ($clientPreferences,$supportedLanguages) = @_;
 488     my @languages = ();
 489     if ($clientPreferences) {
 490         # There should be no whitespace anways, but a cleanliness/sanity check
 491         $clientPreferences =~ s/\s//g;
 492         # Prepare the list of client-acceptable languages
 493         foreach my $tag (split(/,/, $clientPreferences)) {
 494             my ($language, $quality) = split(/\;/, $tag);
 495             $quality =~ s/^q=//i if $quality;
 496             $quality = 1 unless $quality;
 497             next if $quality <= 0;
 498             # We want to force the wildcard to be last
 499             $quality = 0 if ($language eq '*');
 500             # Pushing lowercase language here saves processing later
 501             push(@languages, { quality => $quality,
 502                language => $language,
 503                lclanguage => lc($language) });
 504         }
 505     } else {
 506         carp "accept_language(x,y) called with no clientPreferences (x).";
 507     }
 508     # Prepare the list of server-supported languages
 509     my %supportedLanguages = ();
 510     my %secondaryLanguages = ();
 511     foreach my $language (@$supportedLanguages) {
 512         # warn "Language supported: " . $language->{language};
 513         my $subtag = $language->{rfc4646_subtag};
 514         $supportedLanguages{lc($subtag)} = $subtag;
 515         if ( $subtag =~ /^([^-]+)-?/ ) {
 516             $secondaryLanguages{lc($1)} = $subtag;
 517         }
 518     }
 519
 520     # Reverse sort the list, making best quality at the front of the array
 521     @languages = sort { $b->{quality} <=> $a->{quality} } @languages;
 522     my $secondaryMatch = '';
 523     foreach my $tag (@languages) {
 524         if (exists($supportedLanguages{$tag->{lclanguage}})) {
 525             # Client en-us eq server en-us
 526             return $supportedLanguages{$tag->{language}} if exists($supportedLanguages{$tag->{language}});
 527             return $supportedLanguages{$tag->{lclanguage}};
 528         } elsif (exists($secondaryLanguages{$tag->{lclanguage}})) {
 529             # Client en eq server en-us
 530             return $secondaryLanguages{$tag->{language}} if exists($secondaryLanguages{$tag->{language}});
 531             return $supportedLanguages{$tag->{lclanguage}};
 532         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 533             # Client en-gb eq server en-us
 534             $secondaryMatch = $secondaryLanguages{$1};
 535         } elsif ($tag->{lclanguage} =~ /^([^-]+)-/ && exists($secondaryLanguages{$1}) && $secondaryMatch eq '') {
 536             # FIXME: We just checked the exact same conditional!
 537             # Client en-us eq server en
 538             $secondaryMatch = $supportedLanguages{$1};
 539         } elsif ($tag->{lclanguage} eq '*') {
 540         # * matches every language not already specified.
 541         # It doesn't care which we pick, so let's pick the default,
 542         # if available, then the first in the array.
 543         #return $acceptor->defaultLanguage() if $acceptor->defaultLanguage();
 544         return $supportedLanguages->[0];
 545         }
 546     }
 547     # No primary matches. Secondary? (ie, en-us requested and en supported)
 548     return $secondaryMatch if $secondaryMatch;
 549     return undef;   # else, we got nothing.
 550 }
 551
 552 =head2 getlanguage
 553
 554     Select a language based on the URL parameter 'language', a cookie,
 555     syspref available languages & browser
 556
 557 =cut
 558
 559 sub getlanguage {
 560     my ($cgi) = @_;
 561
 562     my $memory_cache = Koha::Cache::Memory::Lite->get_instance();
 563     my $cache_key = "getlanguage";
 564     unless ( $cgi and $cgi->param('language') ) {
 565         my $cached = $memory_cache->get_from_cache($cache_key);
 566         return $cached if $cached;
 567     }
 568
 569     $cgi //= new CGI;
 570     my $interface = C4::Context->interface;
 571     my $theme = C4::Context->preference( ( $interface eq 'opac' ) ? 'opacthemes' : 'template' );
 572     my $language;
 573
 574     my $preference_to_check =
 575       $interface eq 'intranet' ? 'language' : 'opaclanguages';
 576     # Get the available/valid languages list
 577     my @languages;
 578     my $preference_value = C4::Context->preference($preference_to_check);
 579     if ($preference_value) {
 580         @languages = split /,/, $preference_value;
 581     }
 582
 583     # Chose language from the URL
 584     my $cgi_param_language = $cgi->param( 'language' );
 585     if ( defined $cgi_param_language && any { $_ eq $cgi_param_language } @languages) {
 586         $language = $cgi_param_language;
 587     }
 588
 589     # cookie
 590     if (not $language and my $cgi_cookie_language = $cgi->cookie('KohaOpacLanguage') ) {
 591         ( $language = $cgi_cookie_language ) =~ s/[^a-zA-Z_-]*//; # sanitize cookie
 592     }
 593
 594     # HTTP_ACCEPT_LANGUAGE
 595     if ( !$language && $ENV{HTTP_ACCEPT_LANGUAGE} ) {
 596         $language = accept_language( $ENV{HTTP_ACCEPT_LANGUAGE},
 597             getTranslatedLanguages( $interface, $theme ) );
 598     }
 599
 600     # Ignore a lang not selected in sysprefs
 601     if ( $language && not any { $_ eq $language } @languages ) {
 602         $language = undef;
 603     }
 604
 605     # Pick the first selected syspref language
 606     $language = shift @languages unless $language;
 607
 608     # Fall back to English if necessary
 609     $language ||= 'en';
 610
 611     $memory_cache->set_in_cache( $cache_key, $language );
 612     return $language;
 613 }
 614
 615 1;
 616
 617 __END__
 618
 619 =head1 AUTHOR
 620
 621 Joshua Ferraro
 622
 623 =cut