opac/opac-memberentry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw ( -utf8 );
  21 use Digest::MD5 qw( md5_base64 md5_hex );
  22 use JSON;
  23 use List::MoreUtils qw( any each_array uniq );
  24 use String::Random qw( random_string );
  25
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::Members;
  29 use C4::Members::Attributes qw( GetBorrowerAttributes );
  30 use C4::Form::MessagingPreferences;
  31 use C4::Scrubber;
  32 use Email::Valid;
  33 use Koha::DateUtils;
  34 use Koha::Libraries;
  35 use Koha::Patron::Attribute::Types;
  36 use Koha::Patron::Attributes;
  37 use Koha::Patron::Images;
  38 use Koha::Patron::Modification;
  39 use Koha::Patron::Modifications;
  40 use Koha::Patrons;
  41 use Koha::Token;
  42
  43 my $cgi = new CGI;
  44 my $dbh = C4::Context->dbh;
  45
  46 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  47     {
  48         template_name   => "opac-memberentry.tt",
  49         type            => "opac",
  50         query           => $cgi,
  51         authnotrequired => 1,
  52     }
  53 );
  54
  55 unless ( C4::Context->preference('PatronSelfRegistration') || $borrowernumber )
  56 {
  57     print $cgi->redirect("/cgi-bin/koha/opac-main.pl");
  58     exit;
  59 }
  60
  61 my $action = $cgi->param('action') || q{};
  62 if ( $action eq q{} ) {
  63     if ($borrowernumber) {
  64         $action = 'edit';
  65     }
  66     else {
  67         $action = 'new';
  68     }
  69 }
  70
  71 my $mandatory = GetMandatoryFields($action);
  72
  73 my @libraries = Koha::Libraries->search;
  74 if ( my @libraries_to_display = split '\|', C4::Context->preference('PatronSelfRegistrationLibraryList') ) {
  75     @libraries = map { my $b = $_; my $branchcode = $_->branchcode; grep( /^$branchcode$/, @libraries_to_display ) ? $b : () } @libraries;
  76 }
  77 my ( $min, $max ) = C4::Members::get_cardnumber_length();
  78 if ( defined $min ) {
  79      $template->param(
  80          minlength_cardnumber => $min,
  81          maxlength_cardnumber => $max
  82      );
  83  }
  84
  85 $template->param(
  86     action            => $action,
  87     hidden            => GetHiddenFields( $mandatory, 'registration' ),
  88     mandatory         => $mandatory,
  89     libraries         => \@libraries,
  90     OPACPatronDetails => C4::Context->preference('OPACPatronDetails'),
  91 );
  92
  93 my $attributes = ParsePatronAttributes($borrowernumber,$cgi);
  94 my $conflicting_attribute = 0;
  95
  96 foreach my $attr (@$attributes) {
  97     unless ( C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber) ) {
  98         my $attr_info = C4::Members::AttributeTypes->fetch($attr->{code});
  99         $template->param(
 100             extended_unique_id_failed_code => $attr->{code},
 101             extended_unique_id_failed_value => $attr->{value},
 102             extended_unique_id_failed_description => $attr_info->description()
 103         );
 104         $conflicting_attribute = 1;
 105     }
 106 }
 107
 108 if ( $action eq 'create' ) {
 109
 110     my %borrower = ParseCgiForBorrower($cgi);
 111
 112     %borrower = DelEmptyFields(%borrower);
 113
 114     my @empty_mandatory_fields = CheckMandatoryFields( \%borrower, $action );
 115     my $invalidformfields = CheckForInvalidFields(\%borrower);
 116     delete $borrower{'password2'};
 117     my $cardnumber_error_code;
 118     if ( !grep { $_ eq 'cardnumber' } @empty_mandatory_fields ) {
 119         # No point in checking the cardnumber if it's missing and mandatory, it'll just generate a
 120         # spurious length warning.
 121         $cardnumber_error_code = checkcardnumber( $borrower{cardnumber}, $borrower{borrowernumber} );
 122     }
 123
 124     if ( @empty_mandatory_fields || @$invalidformfields || $cardnumber_error_code || $conflicting_attribute ) {
 125         if ( $cardnumber_error_code == 1 ) {
 126             $template->param( cardnumber_already_exists => 1 );
 127         } elsif ( $cardnumber_error_code == 2 ) {
 128             $template->param( cardnumber_wrong_length => 1 );
 129         }
 130
 131         $template->param(
 132             empty_mandatory_fields => \@empty_mandatory_fields,
 133             invalid_form_fields    => $invalidformfields,
 134             borrower               => \%borrower
 135         );
 136         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 137     }
 138     elsif (
 139         md5_base64( uc( $cgi->param('captcha') ) ) ne $cgi->param('captcha_digest') )
 140     {
 141         $template->param(
 142             failed_captcha => 1,
 143             borrower       => \%borrower
 144         );
 145         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( undef, $attributes ) );
 146     }
 147     else {
 148         if (
 149             C4::Context->boolean_preference(
 150                 'PatronSelfRegistrationVerifyByEmail')
 151           )
 152         {
 153             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 154                 {
 155                     template_name   => "opac-registration-email-sent.tt",
 156                     type            => "opac",
 157                     query           => $cgi,
 158                     authnotrequired => 1,
 159                 }
 160             );
 161             $template->param( 'email' => $borrower{'email'} );
 162
 163             my $verification_token = md5_hex( time().{}.rand().{}.$$ );
 164             while ( Koha::Patron::Modifications->search( { verification_token => $verification_token } )->count() ) {
 165                 $verification_token = md5_hex( time().{}.rand().{}.$$ );
 166             }
 167
 168             $borrower{password}           = random_string("..........");
 169             $borrower{verification_token} = $verification_token;
 170
 171             Koha::Patron::Modification->new( \%borrower )->store();
 172
 173             #Send verification email
 174             my $letter = C4::Letters::GetPreparedLetter(
 175                 module      => 'members',
 176                 letter_code => 'OPAC_REG_VERIFY',
 177                 tables      => {
 178                     borrower_modifications => $verification_token,
 179                 },
 180             );
 181
 182             C4::Letters::EnqueueLetter(
 183                 {
 184                     letter                 => $letter,
 185                     message_transport_type => 'email',
 186                     to_address             => $borrower{'email'},
 187                     from_address =>
 188                       C4::Context->preference('KohaAdminEmailAddress'),
 189                 }
 190             );
 191         }
 192         else {
 193             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 194                 {
 195                     template_name   => "opac-registration-confirmation.tt",
 196                     type            => "opac",
 197                     query           => $cgi,
 198                     authnotrequired => 1,
 199                 }
 200             );
 201
 202             $template->param( OpacPasswordChange =>
 203                   C4::Context->preference('OpacPasswordChange') );
 204
 205             my ( $borrowernumber, $password ) = AddMember_Opac(%borrower);
 206             C4::Members::Attributes::SetBorrowerAttributes( $borrowernumber, $attributes );
 207             C4::Form::MessagingPreferences::handle_form_action($cgi, { borrowernumber => $borrowernumber }, $template, 1, C4::Context->preference('PatronSelfRegistrationDefaultCategory') ) if $borrowernumber && C4::Context->preference('EnhancedMessagingPreferences');
 208
 209             $template->param( password_cleartext => $password );
 210             $template->param(
 211                 borrower => GetMember( borrowernumber => $borrowernumber ) );
 212             $template->param(
 213                 PatronSelfRegistrationAdditionalInstructions =>
 214                   C4::Context->preference(
 215                     'PatronSelfRegistrationAdditionalInstructions')
 216             );
 217         }
 218     }
 219 }
 220 elsif ( $action eq 'update' ) {
 221
 222     my $borrower = GetMember( borrowernumber => $borrowernumber );
 223     die "Wrong CSRF token"
 224         unless Koha::Token->new->check_csrf({
 225             session_id => scalar $cgi->cookie('CGISESSID'),
 226             token  => scalar $cgi->param('csrf_token'),
 227         });
 228
 229     my %borrower = ParseCgiForBorrower($cgi);
 230
 231     my %borrower_changes = DelEmptyFields(%borrower);
 232     my @empty_mandatory_fields =
 233       CheckMandatoryFields( \%borrower_changes, $action );
 234     my $invalidformfields = CheckForInvalidFields(\%borrower);
 235
 236     # Send back the data to the template
 237     %borrower = ( %$borrower, %borrower );
 238
 239     if (@empty_mandatory_fields || @$invalidformfields) {
 240         $template->param(
 241             empty_mandatory_fields => \@empty_mandatory_fields,
 242             invalid_form_fields    => $invalidformfields,
 243             borrower               => \%borrower,
 244             csrf_token             => Koha::Token->new->generate_csrf({
 245                 session_id => scalar $cgi->cookie('CGISESSID'),
 246             }),
 247         );
 248         $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ) );
 249
 250         $template->param( action => 'edit' );
 251     }
 252     else {
 253         my %borrower_changes = DelUnchangedFields( $borrowernumber, %borrower );
 254         my $extended_attributes_changes = FilterUnchangedAttributes( $borrowernumber, $attributes );
 255
 256         if ( %borrower_changes || scalar @{$extended_attributes_changes} > 0 ) {
 257             ( $template, $borrowernumber, $cookie ) = get_template_and_user(
 258                 {
 259                     template_name   => "opac-memberentry-update-submitted.tt",
 260                     type            => "opac",
 261                     query           => $cgi,
 262                     authnotrequired => 1,
 263                 }
 264             );
 265
 266             $borrower_changes{borrowernumber} = $borrowernumber;
 267             $borrower_changes{extended_attributes} = to_json($extended_attributes_changes);
 268
 269             # FIXME update the following with
 270             # Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber })->delete;
 271             # when bug 17091 will be pushed
 272             my $patron_modifications = Koha::Patron::Modifications->search({ borrowernumber => $borrowernumber });
 273             while ( my $patron_modification = $patron_modifications->next ) {
 274                 $patron_modification->delete;
 275             }
 276
 277             my $m = Koha::Patron::Modification->new( \%borrower_changes )->store();
 278
 279             $template->param(
 280                 borrower => GetMember( borrowernumber => $borrowernumber ),
 281             );
 282         }
 283         else {
 284             $template->param(
 285                 action => 'edit',
 286                 nochanges => 1,
 287                 borrower => GetMember( borrowernumber => $borrowernumber ),
 288                 patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber, $attributes ),
 289                 csrf_token => Koha::Token->new->generate_csrf({
 290                     session_id => scalar $cgi->cookie('CGISESSID'),
 291                 }),
 292             );
 293         }
 294     }
 295 }
 296 elsif ( $action eq 'edit' ) {    #Display logged in borrower's data
 297     my $borrower = GetMember( borrowernumber => $borrowernumber );
 298
 299     $template->param(
 300         borrower  => $borrower,
 301         guarantor => scalar Koha::Patrons->find($borrowernumber)->guarantor(),
 302         hidden => GetHiddenFields( $mandatory, 'modification' ),
 303         csrf_token => Koha::Token->new->generate_csrf({
 304             session_id => scalar $cgi->cookie('CGISESSID'),
 305         }),
 306     );
 307
 308     if (C4::Context->preference('OPACpatronimages')) {
 309         my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
 310         $template->param( display_patron_image => 1 ) if $patron_image;
 311     }
 312
 313     $template->param( patron_attribute_classes => GeneratePatronAttributesForm( $borrowernumber ) );
 314 } else {
 315     # Render self-registration page
 316     $template->param( patron_attribute_classes => GeneratePatronAttributesForm() );
 317 }
 318
 319 my $captcha = random_string("CCCCC");
 320
 321 $template->param(
 322     captcha        => $captcha,
 323     captcha_digest => md5_base64($captcha)
 324 );
 325
 326 output_html_with_http_headers $cgi, $cookie, $template->output, undef, { force_no_caching => 1 };
 327
 328 sub GetHiddenFields {
 329     my ( $mandatory, $action ) = @_;
 330     my %hidden_fields;
 331
 332     my $BorrowerUnwantedField = $action eq 'modification' ?
 333       C4::Context->preference( "PatronSelfModificationBorrowerUnwantedField" ) :
 334       C4::Context->preference( "PatronSelfRegistrationBorrowerUnwantedField" );
 335
 336     my @fields = split( /\|/, $BorrowerUnwantedField || q|| );
 337     foreach (@fields) {
 338         next unless m/\w/o;
 339         #Don't hide mandatory fields
 340         next if $mandatory->{$_};
 341         $hidden_fields{$_} = 1;
 342     }
 343
 344     return \%hidden_fields;
 345 }
 346
 347 sub GetMandatoryFields {
 348     my ($action) = @_;
 349
 350     my %mandatory_fields;
 351
 352     my $BorrowerMandatoryField =
 353       C4::Context->preference("PatronSelfRegistrationBorrowerMandatoryField");
 354
 355     my @fields = split( /\|/, $BorrowerMandatoryField );
 356
 357     foreach (@fields) {
 358         $mandatory_fields{$_} = 1;
 359     }
 360
 361     if ( $action eq 'create' || $action eq 'new' ) {
 362         $mandatory_fields{'email'} = 1
 363           if C4::Context->boolean_preference(
 364             'PatronSelfRegistrationVerifyByEmail');
 365     }
 366
 367     return \%mandatory_fields;
 368 }
 369
 370 sub CheckMandatoryFields {
 371     my ( $borrower, $action ) = @_;
 372
 373     my @empty_mandatory_fields;
 374
 375     my $mandatory_fields = GetMandatoryFields($action);
 376     delete $mandatory_fields->{'cardnumber'};
 377
 378     foreach my $key ( keys %$mandatory_fields ) {
 379         push( @empty_mandatory_fields, $key )
 380           unless ( defined( $borrower->{$key} ) && $borrower->{$key} );
 381     }
 382
 383     return @empty_mandatory_fields;
 384 }
 385
 386 sub CheckForInvalidFields {
 387     my $minpw = C4::Context->preference('minPasswordLength');
 388     my $borrower = shift;
 389     my @invalidFields;
 390     if ($borrower->{'email'}) {
 391         unless ( Email::Valid->address($borrower->{'email'}) ) {
 392             push(@invalidFields, "email");
 393         } elsif ( C4::Context->preference("PatronSelfRegistrationEmailMustBeUnique") ) {
 394             my $patrons_with_same_email = Koha::Patrons->search( { email => $borrower->{email} })->count;
 395             if ( $patrons_with_same_email ) {
 396                 push @invalidFields, "duplicate_email";
 397             }
 398         }
 399     }
 400     if ($borrower->{'emailpro'}) {
 401         push(@invalidFields, "emailpro") if (!Email::Valid->address($borrower->{'emailpro'}));
 402     }
 403     if ($borrower->{'B_email'}) {
 404         push(@invalidFields, "B_email") if (!Email::Valid->address($borrower->{'B_email'}));
 405     }
 406     if ( defined $borrower->{'password'}
 407         and $borrower->{'password'} ne $borrower->{'password2'} )
 408     {
 409         push( @invalidFields, "password_match" );
 410     }
 411     if ( $borrower->{'password'}  && $minpw && (length($borrower->{'password'}) < $minpw) ) {
 412        push(@invalidFields, "password_invalid");
 413     }
 414     if ( $borrower->{'password'} ) {
 415        push(@invalidFields, "password_spaces") if ($borrower->{'password'} =~ /^\s/ or $borrower->{'password'} =~ /\s$/);
 416     }
 417
 418     return \@invalidFields;
 419 }
 420
 421 sub ParseCgiForBorrower {
 422     my ($cgi) = @_;
 423
 424     my $scrubber = C4::Scrubber->new();
 425     my %borrower;
 426
 427     foreach ( $cgi->param ) {
 428         if ( $_ =~ '^borrower_' ) {
 429             my ($key) = substr( $_, 9 );
 430             $borrower{$key} = $scrubber->scrub( scalar $cgi->param($_) );
 431         }
 432     }
 433
 434     my $dob_dt;
 435     $dob_dt = eval { dt_from_string( $borrower{'dateofbirth'} ); }
 436         if ( $borrower{'dateofbirth'} );
 437
 438     if ( $dob_dt ) {
 439         $borrower{'dateofbirth'} = output_pref ( { dt => $dob_dt, dateonly => 1, dateformat => 'iso' } );
 440     }
 441     else {
 442         # Trigger validation
 443         $borrower{'dateofbirth'} = undef;
 444     }
 445
 446     return %borrower;
 447 }
 448
 449 sub DelUnchangedFields {
 450     my ( $borrowernumber, %new_data ) = @_;
 451
 452     my $current_data = GetMember( borrowernumber => $borrowernumber );
 453
 454     foreach my $key ( keys %new_data ) {
 455         if ( $current_data->{$key} eq $new_data{$key} ) {
 456             delete $new_data{$key};
 457         }
 458     }
 459
 460     return %new_data;
 461 }
 462
 463 sub DelEmptyFields {
 464     my (%borrower) = @_;
 465
 466     foreach my $key ( keys %borrower ) {
 467         delete $borrower{$key} unless $borrower{$key};
 468     }
 469
 470     return %borrower;
 471 }
 472
 473 sub FilterUnchangedAttributes {
 474     my ( $borrowernumber, $entered_attributes ) = @_;
 475
 476     my @patron_attributes = grep {$_->opac_editable} Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 477
 478     my $patron_attribute_types;
 479     foreach my $attr (@patron_attributes) {
 480         $patron_attribute_types->{ $attr->code } += 1;
 481     }
 482
 483     my $passed_attribute_types;
 484     foreach my $attr (@{ $entered_attributes }) {
 485         $passed_attribute_types->{ $attr->{ code } } += 1;
 486     }
 487
 488     my @changed_attributes;
 489
 490     # Loop through the current patron attributes
 491     foreach my $attribute_type ( keys %{ $patron_attribute_types } ) {
 492         if ( $patron_attribute_types->{ $attribute_type } !=  $passed_attribute_types->{ $attribute_type } ) {
 493             # count differs, overwrite all attributes for given type
 494             foreach my $attr (@{ $entered_attributes }) {
 495                 push @changed_attributes, $attr
 496                     if $attr->{ code } eq $attribute_type;
 497             }
 498         } else {
 499             # count matches, check values
 500             my $changes = 0;
 501             foreach my $attr (grep { $_->code eq $attribute_type } @patron_attributes) {
 502                 $changes = 1
 503                     unless any { $_->{ value } eq $attr->attribute } @{ $entered_attributes };
 504                 last if $changes;
 505             }
 506
 507             if ( $changes ) {
 508                 foreach my $attr (@{ $entered_attributes }) {
 509                     push @changed_attributes, $attr
 510                         if $attr->{ code } eq $attribute_type;
 511                 }
 512             }
 513         }
 514     }
 515
 516     # Loop through passed attributes, looking for new ones
 517     foreach my $attribute_type ( keys %{ $passed_attribute_types } ) {
 518         if ( !defined $patron_attribute_types->{ $attribute_type } ) {
 519             # YAY, new stuff
 520             foreach my $attr (grep { $_->{code} eq $attribute_type } @{ $entered_attributes }) {
 521                 push @changed_attributes, $attr;
 522             }
 523         }
 524     }
 525
 526     return \@changed_attributes;
 527 }
 528
 529 sub GeneratePatronAttributesForm {
 530     my ( $borrowernumber, $entered_attributes ) = @_;
 531
 532     # Get all attribute types and the values for this patron (if applicable)
 533     my @types = grep { $_->opac_editable() or $_->opac_display }
 534         Koha::Patron::Attribute::Types->search()->as_list();
 535     if ( scalar(@types) == 0 ) {
 536         return [];
 537     }
 538
 539     my @displayable_attributes = grep { $_->opac_display }
 540         Koha::Patron::Attributes->search({ borrowernumber => $borrowernumber })->as_list;
 541
 542     my %attr_values = ();
 543
 544     # Build the attribute values list either from the passed values
 545     # or taken from the patron itself
 546     if ( defined $entered_attributes ) {
 547         foreach my $attr (@$entered_attributes) {
 548             push @{ $attr_values{ $attr->{code} } }, $attr->{value};
 549         }
 550     }
 551     elsif ( defined $borrowernumber ) {
 552         my @editable_attributes = grep { $_->opac_editable } @displayable_attributes;
 553         foreach my $attr (@editable_attributes) {
 554             push @{ $attr_values{ $attr->code } }, $attr->attribute;
 555         }
 556     }
 557
 558     # Add the non-editable attributes (that don't come from the form)
 559     foreach my $attr ( grep { !$_->opac_editable } @displayable_attributes ) {
 560         push @{ $attr_values{ $attr->code } }, $attr->attribute;
 561     }
 562
 563     # Find all existing classes
 564     my @classes = sort( uniq( map { $_->class } @types ) );
 565     my %items_by_class;
 566
 567     foreach my $attr_type (@types) {
 568         push @{ $items_by_class{ $attr_type->class() } }, {
 569             type => $attr_type,
 570             # If editable, make sure there's at least one empty entry,
 571             # to make the template's job easier
 572             values => $attr_values{ $attr_type->code() } || ['']
 573         }
 574             unless !defined $attr_values{ $attr_type->code() }
 575                     and !$attr_type->opac_editable;
 576     }
 577
 578     # Finally, build a list of containing classes
 579     my @class_loop;
 580     foreach my $class (@classes) {
 581         next unless ( $items_by_class{$class} );
 582
 583         my $av = Koha::AuthorisedValues->search(
 584             { category => 'PA_CLASS', authorised_value => $class } );
 585
 586         my $lib = $av->count ? $av->next->opac_description : $class;
 587
 588         push @class_loop,
 589             {
 590             class => $class,
 591             items => $items_by_class{$class},
 592             lib   => $lib,
 593             };
 594     }
 595
 596     return \@class_loop;
 597 }
 598
 599 sub ParsePatronAttributes {
 600     my ( $borrowernumber, $cgi ) = @_;
 601
 602     my @codes  = $cgi->multi_param('patron_attribute_code');
 603     my @values = $cgi->multi_param('patron_attribute_value');
 604
 605     my @editable_attribute_types
 606         = map { $_->code } Koha::Patron::Attribute::Types->search({ opac_editable => 1 });
 607
 608     my $ea = each_array( @codes, @values );
 609     my @attributes;
 610
 611     my $delete_candidates = {};
 612
 613     while ( my ( $code, $value ) = $ea->() ) {
 614         if ( any { $_ eq $code } @editable_attribute_types ) {
 615             # It is an editable attribute
 616             if ( !defined($value) or $value eq '' ) {
 617                 $delete_candidates->{$code} = 1
 618                     unless $delete_candidates->{$code};
 619             }
 620             else {
 621                 # we've got a value
 622                 push @attributes, { code => $code, value => $value };
 623
 624                 # 'code' is no longer a delete candidate
 625                 delete $delete_candidates->{$code}
 626                     if defined $delete_candidates->{$code};
 627             }
 628         }
 629     }
 630
 631     foreach my $code ( keys %{$delete_candidates} ) {
 632         if ( Koha::Patron::Attributes->search({
 633                 borrowernumber => $borrowernumber, code => $code })->count > 0 )
 634         {
 635             push @attributes, { code => $code, value => '' }
 636                 unless any { $_->{code} eq $code } @attributes;
 637         }
 638     }
 639
 640     return \@attributes;
 641 }
 642
 643
 644 1;