opac/opac-downloadcart.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw(encode);
  24
  25 use C4::Auth;
  26 use C4::Biblio;
  27 use C4::Items;
  28 use C4::Output;
  29 use C4::Record;
  30 use C4::Ris;
  31
  32 use Koha::CsvProfiles;
  33
  34 use utf8;
  35 my $query = new CGI;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  38     {
  39         template_name   => "opac-downloadcart.tt",
  40         query           => $query,
  41         type            => "opac",
  42         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  43     }
  44 );
  45
  46 my $bib_list = $query->param('bib_list');
  47 my $format  = $query->param('format');
  48 my $dbh     = C4::Context->dbh;
  49
  50 if ($bib_list && $format) {
  51
  52     my @bibs = split( /\//, $bib_list );
  53
  54     my $marcflavour = C4::Context->preference('marcflavour');
  55     my $output;
  56     my $extension;
  57     my $type;
  58
  59     # CSV
  60     if ($format =~ /^\d+$/) {
  61
  62         $output = marc2csv(\@bibs, $format);
  63
  64         # Other formats
  65     } else {
  66         foreach my $biblio (@bibs) {
  67
  68             my $record = GetMarcBiblio($biblio, 1);
  69             next unless $record;
  70
  71             if ($format eq 'iso2709') {
  72                 $output .= $record->as_usmarc();
  73             }
  74             elsif ($format eq 'ris') {
  75                 $output .= marc2ris($record);
  76             }
  77             elsif ($format eq 'bibtex') {
  78                 $output .= marc2bibtex($record, $biblio);
  79             }
  80             elsif ( $format eq 'isbd' ) {
  81                 $output   .= GetISBDView($biblio, "opac");
  82                 $extension = "txt";
  83                 $type      = "text/plain";
  84             }
  85         }
  86     }
  87
  88     # If it was a CSV export we change the format after the export so the file extension is fine
  89     $format = "csv" if ($format =~ m/^\d+$/);
  90
  91     print $query->header(
  92                                -type => ($type) ? $type : 'application/octet-stream',
  93         -'Content-Transfer-Encoding' => 'binary',
  94                          -attachment => ($extension) ? "cart.$format.$extension" : "cart.$format"
  95     );
  96     print $output;
  97
  98 } else {
  99     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc' }) ]);
 100     $template->param(bib_list => $bib_list);
 101     output_html_with_http_headers $query, $cookie, $template->output;
 102 }