admin/currency.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2002 Paul Poulain
   5 # Copyright Koha Development Team
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24 use C4::Auth;
  25 use C4::Context;
  26 use C4::Output;
  27
  28 use Koha::Acquisition::Booksellers;
  29 use Koha::Acquisition::Currencies;
  30 use Koha::Acquisition::Orders;
  31
  32 my $input         = CGI->new;
  33 my $searchfield   = $input->param('searchfield') || $input->param('description') || q{};
  34 my $currency_code = $input->param('currency_code');
  35 my $op            = $input->param('op') || 'list';
  36 my @messages;
  37
  38 our ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => 'admin/currency.tt',
  40         query           => $input,
  41         type            => 'intranet',
  42         authnotrequired => 0,
  43         flagsrequired   => { parameters => 'parameters_remaining_permissions' },
  44     }
  45 );
  46
  47 if ( $op eq 'add_form' ) {
  48     my $currency;
  49     if ($currency_code) {
  50         $currency = Koha::Acquisition::Currencies->find($currency_code);
  51     }
  52
  53     $template->param( currency => $currency, );
  54 } elsif ( $op eq 'add_validate' ) {
  55     my $currency_code = $input->param('currency_code');
  56     my $symbol        = $input->param('symbol');
  57     my $isocode       = $input->param('isocode');
  58     my $rate          = $input->param('rate');
  59     my $active        = $input->param('active');
  60     my $p_sep_by_space = $input->param('p_sep_by_space');
  61     my $is_a_modif    = $input->param('is_a_modif');
  62
  63     if ($is_a_modif) {
  64         my $currency = Koha::Acquisition::Currencies->find($currency_code);
  65         $currency->symbol($symbol);
  66         $currency->isocode($isocode);
  67         $currency->rate($rate);
  68         $currency->active($active);
  69         $currency->p_sep_by_space($p_sep_by_space);
  70         eval { $currency->store; };
  71         if ($@) {
  72             push @messages, { type => 'error', code => 'error_on_update' };
  73         } else {
  74             push @messages, { type => 'message', code => 'success_on_update' };
  75         }
  76     } else {
  77         my $currency = Koha::Acquisition::Currency->new(
  78             {   currency => $currency_code,
  79                 symbol   => $symbol,
  80                 isocode  => $isocode,
  81                 rate     => $rate,
  82                 active   => $active,
  83                 p_sep_by_space => $p_sep_by_space,
  84             }
  85         );
  86         eval { $currency->store; };
  87         if ($@) {
  88             push @messages, { type => 'error', code => 'error_on_insert' };
  89         } else {
  90             push @messages, { type => 'message', code => 'success_on_insert' };
  91         }
  92     }
  93     $searchfield = q||;
  94     $op          = 'list';
  95 } elsif ( $op eq 'delete_confirm' ) {
  96     my $currency = Koha::Acquisition::Currencies->find($currency_code);
  97
  98     my $nb_of_orders = Koha::Acquisition::Orders->search( { currency => $currency->currency } )->count;
  99     my $nb_of_vendors = Koha::Acquisition::Booksellers->search( { -or => { listprice => $currency->currency, invoiceprice => $currency->currency } })->count;
 100     $template->param(
 101         currency     => $currency,
 102         nb_of_orders => $nb_of_orders,
 103         nb_of_vendors => $nb_of_vendors,
 104     );
 105 } elsif ( $op eq 'delete_confirmed' ) {
 106     my $currency = Koha::Acquisition::Currencies->find($currency_code);
 107     my $deleted = eval { $currency->delete; };
 108
 109     if ( $@ or not $deleted ) {
 110         push @messages, { type => 'error', code => 'error_on_delete' };
 111     } else {
 112         push @messages, { type => 'message', code => 'success_on_delete' };
 113     }
 114     $op = 'list';
 115 }
 116
 117 if ( $op eq 'list' ) {
 118     $searchfield =~ s/\,//g;
 119     my $currencies = Koha::Acquisition::Currencies->search( { currency => { -like => "$searchfield%" } } );
 120
 121     my $no_active_currency = not Koha::Acquisition::Currencies->search( { active => 1 } )->count;
 122     $template->param(
 123         currencies         => $currencies,
 124         no_active_currency => $no_active_currency,
 125     );
 126 }
 127
 128 $template->param(
 129     searchfield => $searchfield,
 130     messages    => \@messages,
 131     op          => $op,
 132 );
 133
 134 output_html_with_http_headers $input, $cookie, $template->output;