Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 # Copyright 2016 PTFS Europe
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18 #
  19 # Current maintainer MJR http://mjr.towers.org.uk/
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27 use Getopt::Long qw/HelpMessage/;
  28 use FindBin; # we need to enforce which C4::Installer::PerlModule is used in case more than one is installed
  29
  30 use lib $FindBin::Bin;
  31
  32 use C4::Installer::PerlModules;
  33
  34 my $koha_pm = C4::Installer::PerlModules->new;
  35
  36 my $DEBUG = 0;
  37 die "perl 5.10 or later required" unless ($] >= 5.010000);
  38
  39 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  40
  41 my $dirtree = hashdir('.');
  42 my %result = ();
  43
  44 =head1 NAME
  45
  46 Makefile.PL - Koha packager and installer
  47
  48 =head1 SYNOPSIS
  49
  50 =head2 BASIC INSTALLATION
  51
  52     perl Makefile.PL
  53     make
  54     make test
  55     sudo make install
  56
  57 =head2 UPGRADE INSTALLATION
  58
  59     NOTE: This option is only available if koha-install-log exists.
  60
  61     perl Makefile.PL --prev-install-log /path/to/koha-install-log
  62
  63     make
  64     make test
  65     sudo make upgrade
  66
  67 =head2 PACKAGING RELEASE TARBALLS
  68
  69     make manifest tardist
  70     make manifest zipdist
  71
  72 =head2 CLEANING UP
  73
  74         make clean
  75
  76 =head2 CLI PARAMETERS
  77
  78     --prev-install-log           Read configuration from previous installation
  79     --install_mode               Installation mode (dev, standard, single)
  80     --db_type                    Database (mysql, Pg)
  81     --db_host                    Database host (e.g. localhost)
  82     --db_port                    Database port (e.g. 3306)
  83     --db_name                    Database name (e.g. koha)
  84     --db_user                    Database user (e.g. kohaadmin)
  85     --db_pass                    Database password (e.g. katikoan)
  86     --zebra_marc_format          Zebra MARC format (marc21, normarc, unimarc)
  87     --zebra_language             Zebra language (e.g. en)
  88     --zebra_tokenizer            Zebra tokenizer (chr, icu)
  89     --zebra_user                 Zebra user (e.g. kohauser)
  90     --zebra_pass                 Zebra password (e.g. zebrastripes)
  91     --zebra_sru_host             Zebra SRU servername (e.g. localhost)
  92     --zebra_sru_biblios_port     Zebra SRU biblios port (e.g. 9998)
  93     --zebra_sru_authorities_port Zebra SRU biblios port (e.g. 9999)
  94     --koha_user                  Koha Unix user (e.g. koha)
  95     --koha_group                 Koha Unix group (e.g. koha)
  96     --install_sru                Install the SRU server (yes, no)
  97     --install_pazpar2            Install PazPar2 (yes, no)
  98     --use_memcached              Use Memcached (yes, no)
  99     --font_dir                   Location of fonts (e.g. /usr/share/fonts/truetype/dejavu)
 100     --run_database_tests         Run database dependent tests (yes, no)
 101     --install_base               Base directory of installation (e.g. /usr/share/koha)
 102     --template-cache-dir         Specify a template cache directory (e.g. /var/cache/koha)
 103     --help                       Display this help message
 104
 105 =head1 DESCRIPTION
 106
 107 This is a packager and installer that uses
 108 ExtUtils::MakeMaker, which is fairly common
 109 on perl systems.
 110 As well as building tar or zip files
 111 and installing with the above commands,
 112 it allows us to check pre-requisites
 113 and generate configuration files.
 114
 115 =head1 VARIABLES
 116
 117 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
 118
 119 Basic metadata about this software.
 120
 121 =head2 NO_META
 122
 123 Suppress generation of META.yml file.
 124
 125 =head2 PREREQ_PM
 126
 127 Hash of perl modules and versions required.
 128
 129 =head2 PM
 130
 131 Hash of file mappings
 132
 133 =head2 PL_FILES
 134
 135 This is a hash of PL scripts to run after installation and
 136 the files to ask them to generate.
 137 Maybe use the values from CONFIGURE
 138 to generate initial configuration files in future.
 139
 140 =cut
 141
 142 =head2 target_map
 143
 144 This is a hash mapping directories and files in the
 145 source tree to installation target directories.  The rules
 146 for this mapping are:
 147
 148 =over 4
 149
 150 =item If a directory or file is specified, it and its
 151 contents will be copied to the installation target directory.
 152
 153 =item If a subdirectory of a mapped directory is specified,
 154 its target overrides the parent's target for that subdirectory.
 155
 156 =item The value of each map entry may either be a scalar containing
 157 one target or a reference to a hash containing 'target' and 'trimdir'
 158 keys.
 159
 160 =item Any files at the top level of the source tree that are
 161 not included in the map will not be installed.
 162
 163 =item Any directories at the top level of the source tree
 164 that are not included in the map will be installed in
 165 INTRANET_CGI_DIR.  This is a sensible default given the
 166 current organization of the source tree, but (FIXME) it
 167 would be better to reorganize the source tree to better
 168 match the installation system, to allow adding new directories
 169 without having to adjust Makefile.PL each time.  The idea
 170 is to make the C<$target_map> hash as minimal as possible.
 171
 172 =back
 173
 174 The permitted installation targets are:
 175
 176 =over 4
 177
 178 =item INTRANET_CGI_DIR
 179
 180 CGI scripts for intranet (staff) interface.
 181
 182 =item INTRANET_TMPL_DIR
 183
 184 HTML templates for the intranet interface.
 185
 186 =item INTRANET_WWW_DIR
 187
 188 HTML files, images, etc. for DocumentRoot for the intranet interface.
 189
 190 =item OPAC_CGI_DIR
 191
 192 CGI scripts for OPAC (public) interface.
 193
 194 =item OPAC_TMPL_DIR
 195
 196 HTML templates for the OPAC interface.
 197
 198 =item OPAC_WWW_DIR
 199
 200 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 201
 202 =item PERL_MODULE_DIR
 203
 204 Perl modules (at present just the C4 modules) that are intimately
 205 tied to Koha.  Depending on the installation options, these
 206 may or may not be installed one of the standard directories
 207 in Perl's default @LIB.
 208
 209 =item KOHA_CONF_DIR
 210
 211 Directory for Koha configuration files.
 212
 213 =item ZEBRA_CONF_DIR
 214
 215 Directory for Zebra configuration files.
 216
 217 =item ZEBRA_LOCK_DIR
 218
 219 Directory for Zebra's lock files.  This includes subdirs for authorities,
 220 biblios, and the zebra rebuild function.  Any activity to reindex
 221 zebra from koha should interlock here with rebuild_zebra.pl.
 222
 223 =item ZEBRA_DATA_DIR
 224
 225 Directory for Zebra's data files.
 226
 227 =item ZEBRA_RUN_DIR
 228
 229 Directory for Zebra's UNIX-domain sockets.
 230
 231 =item ELASTICSEARCH_SERVERS
 232
 233 Server:port of the Elasticsearch server to use, as a comma separated list:
 234 eg. 192.168.0.100:9200, localhost:9200
 235
 236 =item ELASTICSEARCH_INDEX
 237
 238 Unique index in Elasticsearch, for this Koha-instance
 239 eg. koha-mykoha  or just  koha
 240
 241 =item MISC_DIR
 242
 243 Directory for for miscellaenous scripts, among other
 244 things the translation toolkit and RSS feed tools.
 245
 246 =item SCRIPT_DIR
 247
 248 Directory for command-line scripts and daemons to
 249 be set up all for installation modes.
 250
 251 =item SCRIPT_NONDEV_DIR
 252
 253 Directory for command-line scripts that should
 254 be installed in the same directory as the
 255 SCRIPT_DIR target except 'dev' installs.
 256
 257 =item MAN_DIR
 258
 259 Directory for man pages created from POD -- will mostly
 260 contain information of interest to Koha developers.
 261
 262 =item DOC_DIR
 263
 264 Directory for Koha documentation accessed from the
 265 command-line, e.g., READMEs.
 266
 267 =item LOCK_DIR
 268
 269 Directory for Koha scripts to put their locks.
 270
 271 =item LOG_DIR
 272
 273 Directory for Apache and Zebra logs produced by Koha.
 274
 275 =item BACKUP_DIR
 276
 277 Directory for backup files produced by Koha.
 278
 279 =item PLUGINS_DIR
 280
 281 Directory for external Koha plugins.
 282
 283 =item PAZPAR2_CONF_DIR
 284
 285 Directory for PazPar2 configuration files.
 286
 287 =item FONT_DIR
 288
 289 Directory where DejaVu fonts are installed.
 290
 291 =item NONE
 292
 293 This is a dummy target used to explicitly state
 294 that a given file or directory is not to be installed.
 295 This is used either for parts of the installer itself
 296 or for development tools that are not applicable to a
 297 production installation.
 298
 299 =back
 300
 301 =cut
 302
 303 my $target_map = {
 304   './about.pl'                  => 'INTRANET_CGI_DIR',
 305   './acqui'                     => 'INTRANET_CGI_DIR',
 306   './admin'                     => 'INTRANET_CGI_DIR',
 307   './api'                       => { target => 'API_CGI_DIR', trimdir => -1 },
 308   './authorities'               => 'INTRANET_CGI_DIR',
 309   './basket'                    => 'INTRANET_CGI_DIR',
 310   './C4'                        => 'PERL_MODULE_DIR',
 311   './C4/SIP/t'                  => 'NONE',
 312   './C4/SIP/koha_test'          => 'NONE',
 313   './C4/tests'                  => 'NONE',
 314   './catalogue'                 => 'INTRANET_CGI_DIR',
 315   './cataloguing'               => 'INTRANET_CGI_DIR',
 316   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 317   './check_sysprefs.pl'         => 'NONE',
 318   './circ'                      => 'INTRANET_CGI_DIR',
 319   './clubs'                     => 'INTRANET_CGI_DIR',
 320   './course_reserves'           => 'INTRANET_CGI_DIR',
 321   './cpanfile'                  => 'PERL_MODULE_DIR',
 322   './docs/history.txt'          => { target => 'DOC_DIR', trimdir => -1 },
 323   './docs/contributors.yaml'    => { target => 'DOC_DIR', trimdir => -1 },
 324   './docs/teams.yaml'           => { target => 'DOC_DIR', trimdir => -1 },
 325   './offline_circ'              => 'INTRANET_CGI_DIR',
 326   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 327   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 328   './etc/z3950'                 => { target => 'Z3950_CONF_DIR', trimdir => -1 },
 329   './etc/pazpar2'               => { target => 'PAZPAR2_CONF_DIR', trimdir => -1 },
 330   './help.pl'                   => 'INTRANET_CGI_DIR',
 331   './ill'                       => 'INTRANET_CGI_DIR',
 332   './installer-CPAN.pl'         => 'NONE',
 333   './installer'                 => 'INTRANET_CGI_DIR',
 334   './errors'                    => {target => 'INTRANET_CGI_DIR'},
 335   './Koha'                      => 'PERL_MODULE_DIR',
 336   './Koha.pm'                   => 'PERL_MODULE_DIR',
 337   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 338   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 339   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 340   './labels'                    => 'INTRANET_CGI_DIR',
 341   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 342   './Makefile.PL'               => 'NONE',
 343   './MANIFEST.SKIP'             => 'NONE',
 344   './members'                   => 'INTRANET_CGI_DIR',
 345   './misc'                      => { target => 'SCRIPT_NONDEV_DIR', trimdir => -1 },
 346   './misc/bin'                  => { target => 'SCRIPT_DIR', trimdir => -1 },
 347   './misc/release_notes'        => { target => 'DOC_DIR', trimdir => 2 },
 348   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 349   './misc/koha-install-log'     => { target => 'MISC_DIR', trimdir => -1 },
 350   './misc/installer_devel_notes' => 'NONE',
 351   './opac'                      => 'OPAC_CGI_DIR',
 352   './OpenILS'                   => 'PERL_MODULE_DIR',
 353   './README.txt'                => 'NONE',
 354   './patroncards'               => 'INTRANET_CGI_DIR',
 355   './patron_lists'              => 'INTRANET_CGI_DIR',
 356   './plugins'                   => 'INTRANET_CGI_DIR',
 357   './reports'                   => 'INTRANET_CGI_DIR',
 358   './reserve'                   => 'INTRANET_CGI_DIR',
 359   './reviews'                   => 'INTRANET_CGI_DIR',
 360   './rewrite-config.PL'         => 'NONE',
 361   './reviews'                   => 'INTRANET_CGI_DIR',
 362   './rotating_collections'      => 'INTRANET_CGI_DIR',
 363   './serials'                   => 'INTRANET_CGI_DIR',
 364   './services'                  => 'INTRANET_CGI_DIR',
 365   './skel'                      => 'NONE',
 366   './skel/var/lock/koha'        => { target => 'LOCK_DIR', trimdir => -1 },
 367   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 368   './skel/var/spool/koha'       => { target => 'BACKUP_DIR', trimdir => -1 },
 369   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 370   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 371   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 372   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 373   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 374   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 375   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 376   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 377   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 378   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 379   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 380   './skel/var/lock/koha/zebradb/rebuild' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 381   './skel/var/lib/koha/plugins' => { target => 'PLUGINS_DIR', trimdir => 6 },
 382   './sms'                       => 'INTRANET_CGI_DIR',
 383   './suggestion'                => 'INTRANET_CGI_DIR',
 384   './svc'                       => 'INTRANET_CGI_DIR',
 385   './t'                         => 'NONE',
 386   './tags'                      => 'INTRANET_CGI_DIR',
 387   './tmp'                       => 'NONE', # FIXME need to determine whether
 388                                            # Koha generates any persistent temp files
 389                                            # that should go in /var/tmp/koha
 390   './tools'                     => 'INTRANET_CGI_DIR',
 391   './virtualshelves'            => 'INTRANET_CGI_DIR',
 392   # ignore files and directories created by the install itself
 393   './pm_to_blib'                => 'NONE',
 394   './blib'                      => 'NONE',
 395   '.sass-lint.yml'              => 'NONE',
 396   '.scss-lint.yml'              => 'NONE',
 397   '.eslintrc.json'              => 'NONE',
 398   'gulpfile.js'                 => 'NONE',
 399   'package.json'                => 'NONE',
 400   'yarn.lock'                   => 'NONE',
 401 };
 402
 403 =head1 CONFIGURATION OPTIONS
 404
 405 The following configuration options are used by the installer.
 406
 407 =over 4
 408
 409 =item INSTALL_MODE
 410
 411 Specifies whether installation will be FHS-compliant (default,
 412 assumes user has root), put everything under
 413 a single directory (for users installing on a web host
 414 that allows CGI scripts and a MySQL database but not root
 415 access), or development (for a developer who wants to run
 416 Koha from a git clone with no fuss).
 417
 418 =item INSTALL_BASE
 419
 420 Directory under which most components will go.  Default
 421 value will vary depending on INSTALL_MODE.
 422
 423 =item DB_TYPE
 424
 425 Type of DBMS (e.g., mysql or Pg).
 426
 427 =item DB_HOST
 428
 429 Name of DBMS server.
 430
 431 =item DB_PORT
 432
 433 Port that DBMS server is listening on.
 434
 435 =item DB_NAME
 436
 437 Name of the DBMS database for Koha.
 438
 439 =item DB_USER
 440
 441 Name of DBMS user account for Koha's database.
 442
 443 =item DB_PASS
 444
 445 Pasword of DMBS user account for Koha's database.
 446
 447 =item ZEBRA_MARC_FORMAT
 448
 449 Specifies format of MARC records to be indexed by Zebra.
 450
 451 =item ZEBRA_LANGUAGE
 452
 453 Specifies primary language of records that will be
 454 indexed by Zebra.
 455
 456 =item ZEBRA_USER
 457
 458 Internal Zebra user account for the index.
 459
 460 =item ZEBRA_PASS
 461
 462 Internal Zebra user account's password.
 463
 464 =item KOHA_USER
 465
 466 System user account that will own Koha's files.
 467
 468 =item KOHA_GROUP
 469
 470 System group that will own Koha's files.
 471
 472 =back
 473
 474 =cut
 475
 476 # default configuration options
 477 my %config_defaults = (
 478   'DB_TYPE'           => 'mysql',
 479   'DB_HOST'           => 'localhost',
 480   'DB_NAME'           => 'koha',
 481   'DB_USER'           => 'kohaadmin',
 482   'DB_PASS'           => 'katikoan',
 483   'DB_USE_TLS'        => 'no',
 484   'DB_TLS_CA_CERTIFICATE'  => '/etc/mysql-ssl/server-ca.pem',
 485   'DB_TLS_CLIENT_CERTIFICATE'  => '/etc/mysql-ssl/client-cert.pem',
 486   'DB_TLS_CLIENT_KEY' => '/etc/mysql-ssl/client-key.pem',
 487   'INSTALL_SRU'       => 'yes',
 488   'INSTALL_PAZPAR2'   => 'no',
 489   'ZEBRA_MARC_FORMAT' => 'marc21',
 490   'ZEBRA_LANGUAGE'    => 'en',
 491   'ZEBRA_TOKENIZER'   => 'chr',
 492   'ZEBRA_USER'        => 'kohauser',
 493   'ZEBRA_PASS'        => 'zebrastripes',
 494   'ZEBRA_SRU_HOST'    => 'localhost',
 495   'ZEBRA_SRU_BIBLIOS_PORT'    => '9998',
 496   'ZEBRA_SRU_AUTHORITIES_PORT'    => '9999',
 497   'KOHA_USER'         => 'koha',
 498   'KOHA_GROUP'        => 'koha',
 499   'MERGE_SERVER_HOST' => 'localhost',
 500   'MERGE_SERVER_PORT' => '11001',
 501   'PAZPAR2_HOST' => 'localhost',
 502   'PAZPAR2_PORT' => '11002',
 503   'RUN_DATABASE_TESTS' => 'no',
 504   'PATH_TO_ZEBRA' => '',
 505   'USE_MEMCACHED'     => 'yes',
 506   'MEMCACHED_SERVERS' => '127.0.0.1:11211',
 507   'MEMCACHED_NAMESPACE' => 'KOHA',
 508   'TEMPLATE_CACHE_DIR' => '/tmp/koha',
 509   'USE_ELASTICSEARCH'     => 'no',
 510   'ELASTICSEARCH_SERVERS' => 'localhost:9200',
 511   'ELASTICSEARCH_INDEX'  => 'koha',
 512   'FONT_DIR'          => '/usr/share/fonts/truetype/dejavu'
 513 );
 514
 515 # set some default configuration options based on OS
 516 # more conditions need to be added for other OS's
 517
 518 warn "Your platform appears to be $^O.\n" if $DEBUG;
 519
 520 if ( $^O eq 'cygwin' ) {
 521         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 522         # this could be changed to put some files (ie. libraries) into system32, etc.
 523         $config_defaults{'INSTALL_MODE'} = 'single';
 524         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 525 }
 526 else {
 527         $config_defaults{'INSTALL_MODE'} = 'standard';
 528         $config_defaults{'INSTALL_BASE'} = '/usr/share/koha';
 529 }
 530
 531 # valid values for certain configuration options
 532 my %valid_config_values = (
 533   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 534   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 535   'DB_USE_TLS' => {'yes', 'no'},
 536   'INSTALL_SRU' => { 'yes' => 1, 'no' => 1 },
 537   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'normarc' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 538   'ZEBRA_LANGUAGE'    => { 'cs' => 1, 'el' => 1, 'en' => 1, 'es' => 1, 'fr' => 1, 'nb' => 1, 'ru' => 1, 'uk' => 1 }, # FIXME should generate from contents of distribution
 539   'ZEBRA_TOKENIZER' => { chr => 1, icu => 1 },
 540   'RUN_DATABASE_TESTS' => { 'yes' => 1, 'no' => 1 },
 541   'USE_MEMCACHED'      => { 'yes' => 1, 'no' => 1 },
 542   'USE_ELASTICSEARCH'  => { 'yes' => 1, 'no' => 1 },
 543 );
 544
 545 # get settings from command-line
 546 my $koha_install_log = "";
 547 my $cli_koha_install_mode = "";
 548 my $cli_koha_db_type = "";
 549 my $cli_koha_db_host = "";
 550 my $cli_koha_db_port = "";
 551 my $cli_koha_db_name = "";
 552 my $cli_koha_db_user = "";
 553 my $cli_koha_db_pass = "";
 554 my $cli_zebra_marc_format = "";
 555 my $cli_zebra_language = "",
 556 my $cli_zebra_tokenizer = "";
 557 my $cli_zebra_user = "";
 558 my $cli_zebra_pass = "";
 559 my $cli_zebra_sru_host = "";
 560 my $cli_zebra_sru_bib_port = "";
 561 my $cli_zebra_sru_auth_port = "";
 562 my $cli_koha_user = "";
 563 my $cli_koha_group = "";
 564 my $cli_koha_install_sru = "";
 565 my $cli_koha_install_pazpar2 = "";
 566 my $cli_koha_use_memcached = "";
 567 my $cli_koha_font_dir = "";
 568 my $cli_koha_run_database_tests = "";
 569 my $cli_koha_install_base = "";
 570 my $cli_koha_template_cache_dir = "";
 571 Getopt::Long::Configure('pass_through');
 572 my $results = GetOptions(
 573     "prev-install-log=s"           => \$koha_install_log,
 574     "install_mode=s"               => \$cli_koha_install_mode,
 575     "db_type=s"                    => \$cli_koha_db_type,
 576     "db_host=s"                    => \$cli_koha_db_host,
 577     "db_port=s"                    => \$cli_koha_db_port,
 578     "db_name=s"                    => \$cli_koha_db_name,
 579     "db_user=s"                    => \$cli_koha_db_user,
 580     "db_pass=s"                    => \$cli_koha_db_pass,
 581     "zebra_marc_format=s"          => \$cli_zebra_marc_format,
 582     "zebra_language=s"             => \$cli_zebra_language,
 583     "zebra_tokenizer=s"            => \$cli_zebra_tokenizer,
 584     "zebra_user=s"                 => \$cli_zebra_user,
 585     "zebra_pass=s"                 => \$cli_zebra_pass,
 586     "zebra_sru_host=s"             => \$cli_zebra_sru_host,
 587     "zebra_sru_biblios_port=s"     => \$cli_zebra_sru_bib_port,
 588     "zebra_sru_authorities_port=s" => \$cli_zebra_sru_auth_port,
 589     "koha_user=s"                  => \$cli_koha_user,
 590     "koha_group=s"                 => \$cli_koha_group,
 591     "install_sru=s"                => \$cli_koha_install_sru,
 592     "install_pazpar2=s"            => \$cli_koha_install_pazpar2,
 593     "use_memcached=s"              => \$cli_koha_use_memcached,
 594     "font_dir=s"                   => \$cli_koha_font_dir,
 595     "run_database_tests=s"         => \$cli_koha_run_database_tests,
 596     "install_base=s"               => \$cli_koha_install_base,
 597     "template-cache-dir=s"         => \$cli_koha_template_cache_dir,
 598     "help"                         => sub { HelpMessage(0) },
 599 ) or HelpMessage(1);
 600
 601 my %install_log_values = ();
 602 if ($koha_install_log ne "") {
 603     get_install_log_values($koha_install_log, \%install_log_values);
 604 } else {
 605     # Try to set install_log_values for provided values;
 606     get_cli_values(\%install_log_values);
 607 }
 608
 609 my %config = get_configuration(\%config_defaults, \%valid_config_values, \%install_log_values);
 610 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 611 display_configuration(\%config, $target_directories);
 612 my $file_map = {};
 613 get_file_map($target_map, $dirtree, $file_map);
 614
 615 my $pl_files = {
 616       'rewrite-config.PL' => [
 617          'blib/KOHA_CONF_DIR/koha-conf.xml',
 618          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 619          'blib/KOHA_CONF_DIR/log4perl.conf',
 620          'blib/ZEBRA_CONF_DIR/etc/default.idx',
 621          'blib/MISC_DIR/koha-install-log'
 622          ],
 623           'fix-perl-path.PL' => [       # this script ensures the correct shebang line for the platform installed on...
 624                  'blib'
 625                  ],
 626 };
 627
 628 push @{ $pl_files->{'rewrite-config.PL'} }, (
 629     'blib/ZEBRA_CONF_DIR/etc/passwd',
 630     'blib/ZEBRA_CONF_DIR/zebra-biblios-dom.cfg',
 631     'blib/ZEBRA_CONF_DIR/zebra-authorities-dom.cfg',
 632     'blib/ZEBRA_CONF_DIR/explain-authorities.xml',
 633     'blib/ZEBRA_CONF_DIR/explain-biblios.xml',
 634     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-dom.xml',
 635     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-dom.xml',
 636 );
 637 push @{ $pl_files->{'rewrite-config.PL'} }, (
 638     'blib/SCRIPT_DIR/koha-zebra-ctl.sh',
 639     'blib/SCRIPT_DIR/koha-pazpar2-ctl.sh',
 640     'blib/SCRIPT_DIR/koha-index-daemon-ctl.sh',
 641 );
 642 if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
 643     push @{ $pl_files->{'rewrite-config.PL'} }, (
 644         'blib/PAZPAR2_CONF_DIR/koha-biblios.xml',
 645         'blib/PAZPAR2_CONF_DIR/pazpar2.xml'
 646     );
 647 }
 648 $config{'ZEBRA_AUTH_CFG'} = 'zebra-authorities-dom.cfg';
 649 $config{'ZEBRA_BIB_CFG'}  = 'zebra-biblios-dom.cfg';
 650 $config{'AUTH_RETRIEVAL_CFG'} = 'retrieval-info-auth-dom.xml';
 651 $config{'BIB_RETRIEVAL_CFG'}  = 'retrieval-info-bib-dom.xml';
 652
 653 if ($config{'INSTALL_MODE'} ne "dev") {
 654     push @{ $pl_files->{'rewrite-config.PL'} }, (
 655         'blib/PERL_MODULE_DIR/C4/Context.pm',
 656         'blib/SCRIPT_NONDEV_DIR/kohalib.pl'
 657     );
 658 }
 659
 660 $config{ZEBRA_TOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 661     ? 'icuchain words-icu.xml'
 662     : 'charmap word-phrase-utf.chr';
 663
 664 $config{ZEBRA_PTOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 665     ? 'icuchain phrases-icu.xml'
 666     : 'charmap word-phrase-utf.chr';
 667
 668 my %test_suite_override_dirs = (
 669     KOHA_CONF_DIR  => ['etc'],
 670     ZEBRA_CONF_DIR => ['etc', 'zebradb'],
 671     Z3950_CONF_DIR => ['etc', 'z3950'],
 672     LOCK_DIR       => ['var', 'lock'],
 673     LOG_DIR        => ['var', 'log'],
 674     BACKUP_DIR     => ['var', 'spool'],
 675     SCRIPT_DIR     => ['bin'],
 676     ZEBRA_LOCK_DIR => ['var', 'lock', 'zebradb'],
 677     ZEBRA_DATA_DIR => ['var', 'lib', 'zebradb'],
 678     ZEBRA_RUN_DIR  => ['var', 'run', 'zebradb'],
 679 );
 680
 681 WriteMakefile(
 682               NAME         => 'koha',
 683               #VERSION     => strftime('2.9.%Y%m%d%H',gmtime),
 684               VERSION_FROM => 'kohaversion.pl',
 685               ABSTRACT     => 'Award-winning integrated library system (ILS) and Web OPAC',
 686               AUTHOR       => 'Koha Contributors <http://koha-community.org/>',
 687               NO_META      => 1,
 688               PREREQ_PM    => $koha_pm->prereq_pm,
 689
 690               # File tree mapping
 691               PM => $file_map,
 692
 693               # Man pages generated from POD
 694               # ExtUtils::MakeMaker already manage $(DESTDIR)
 695               INSTALLMAN1DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man1'),
 696               INSTALLMAN3DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man3'),
 697
 698               PL_FILES => $pl_files,
 699 );
 700
 701 =head1 FUNCTIONS
 702
 703 =head2 hashdir
 704
 705 This function recurses through the directory structure and builds
 706 a hash of hashes containing the structure with arrays holding filenames.
 707 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 708
 709 =cut
 710
 711 sub hashdir{
 712     my $dir = shift;
 713     opendir my $dh, $dir or die $!;
 714     my $tree = {}->{$dir} = {};
 715     while( my $file = readdir($dh) ) {
 716         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 717         my $path = $dir .'/' . $file;
 718         $tree->{$file} = hashdir($path), next if -d $path;
 719         push @{$tree->{'.'}}, $file;
 720     }
 721     return $tree;
 722 }
 723
 724 =head2 get_file_map
 725
 726 This function combines the target_map and file hash to
 727 map each source file to its destination relative to
 728 the set of installation targets.
 729
 730 Output will be a hash mapping from each source file
 731 to its destination value, like this:
 732
 733 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 734
 735 =cut
 736
 737 sub get_file_map {
 738     my $target_map = shift;
 739     my $dirtree = shift;
 740     my $file_map = shift;
 741     my $curr_path = @_ ? shift : ['.'];
 742
 743     # Traverse the directory tree.
 744     # For each file or directory, identify the
 745     # most specific match in the target_map
 746     foreach my $dir (sort keys %{ $dirtree }) {
 747         if ($dir eq '.') {
 748             # deal with files in directory
 749             foreach my $file (sort @{ $dirtree->{$dir} }) {
 750                 my $targetdir = undef;
 751                 my $matchlevel = undef;
 752                 # first, see if there is a match on this specific
 753                 # file in the target map
 754                 my $filepath = join("/", @$curr_path, $file);
 755                 if (exists $target_map->{$filepath}) {
 756                     $targetdir = $target_map->{$filepath};
 757                     $matchlevel = scalar(@$curr_path) + 1;
 758                 } else {
 759                     # no match on the specific file; look for
 760                     # a directory match
 761                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 762                         my $dirpath = join("/", @$curr_path[0..$i]);
 763                         if (exists $target_map->{$dirpath}) {
 764                             $targetdir = $target_map->{$dirpath};
 765                             $matchlevel = $i + 1;
 766                             last;
 767                         }
 768                     }
 769                 }
 770                 if (defined $targetdir) {
 771                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel);
 772                 } else {
 773                     my $path = join("/", @$curr_path);
 774                     print "failed to map: $path/$file\n" if $DEBUG;
 775                 }
 776             }
 777         } else {
 778             # dealing with subdirectory
 779             push @$curr_path, $dir;
 780             get_file_map($target_map, $dirtree->{$dir}, $file_map, $curr_path);
 781             pop @$curr_path;
 782         }
 783     }
 784 }
 785
 786 sub _add_to_file_map {
 787     my $file_map = shift;
 788     my $targetdir = shift;
 789     my $curr_path = shift;
 790     my $file = shift;
 791     my $matchlevel = shift;
 792     my $dest_path = @_ ? shift : $curr_path;
 793
 794     # The target can be one of the following:
 795     # 1. scalar representing target symbol
 796     # 2. hash ref containing target and trimdir keys
 797     #
 798     # Consequently, this routine traverses this structure,
 799     # calling itself recursively, until it deals with
 800     # all of the scalar target symbols.
 801     if (ref $targetdir eq 'HASH') {
 802         my $subtarget = $targetdir->{target};
 803         if (exists $targetdir->{trimdir}) {
 804             # if we get here, we've specified that
 805             # rather than installing the file to
 806             # $(TARGET)/matching/dirs/subdirs/file,
 807             # we want to install it to
 808             # $(TARGET)/subdirs/file
 809             #
 810             # Note that this the only place where
 811             # $matchlevel is used.
 812             my @new_dest_path = @$dest_path;
 813             if ($targetdir->{trimdir} == -1)  {
 814                 splice @new_dest_path, 0, $matchlevel;
 815             } else {
 816                 splice @new_dest_path, 0, $targetdir->{trimdir};
 817             }
 818             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, \@new_dest_path);
 819         } else {
 820             # actually getting here means that the
 821             # target was unnecessarily listed
 822             # as a hash, but we'll forgive that
 823             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel);
 824         }
 825     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 826         my $source = File::Spec->catfile(@$curr_path, $file);
 827         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 828         #print "$source => $destination\n"; # DEBUG
 829         # quote spaces in file names
 830         # FIXME: this is of questionable portability and
 831         # probably depends on user's make recognizing this
 832         # quoting syntax -- probably better to remove
 833         # spaces and shell metacharacters from all file names
 834         $source =~ s/ /\\ /g;
 835         $destination =~ s/ /\\ /g;
 836
 837         $file_map->{$source} = $destination;
 838     }
 839 }
 840
 841 =head2 get_cli_values
 842
 843 Reads values provided on cli for configuration values
 844
 845 =cut
 846
 847 sub get_cli_values {
 848     my $values = shift;
 849     my $map = {
 850         INSTALL_MODE               => $cli_koha_install_mode,
 851         DB_TYPE                    => $cli_koha_db_type,
 852         DB_HOST                    => $cli_koha_db_host,
 853         DB_PORT                    => $cli_koha_db_port,
 854         DB_NAME                    => $cli_koha_db_name,
 855         DB_USER                    => $cli_koha_db_user,
 856         DB_PASS                    => $cli_koha_db_pass,
 857         ZEBRA_MARC_FORMAT          => $cli_zebra_marc_format,
 858         ZEBRA_LANGUAGE             => $cli_zebra_language,
 859         ZEBRA_TOKENIZER            => $cli_zebra_tokenizer,
 860         ZEBRA_USER                 => $cli_zebra_user,
 861         ZEBRA_PASS                 => $cli_zebra_pass,
 862         ZEBRA_SRU_HOST             => $cli_zebra_sru_host,
 863         ZEBRA_SRU_BIBLIOS_PORT     => $cli_zebra_sru_bib_port,
 864         ZEBRA_SRU_AUTHORITIES_PORT => $cli_zebra_sru_auth_port,
 865         KOHA_USER                  => $cli_koha_user,
 866         KOHA_GROUP                 => $cli_koha_group,
 867         INSTALL_SRU                => $cli_koha_install_sru,
 868         INSTALL_PAZPAR2            => $cli_koha_install_pazpar2,
 869         USE_MEMCACHED              => $cli_koha_use_memcached,
 870         FONT_DIR                   => $cli_koha_font_dir,
 871         RUN_DATABASE_TESTS         => $cli_koha_run_database_tests,
 872         INSTALL_BASE               => $cli_koha_install_base,
 873         TEMPLATE_CACHE_DIR         => $cli_koha_template_cache_dir
 874     };
 875     foreach my $key (keys %{$map}) {
 876         $values->{$key} = $map->{$key} if ($map->{$key});
 877     }
 878 }
 879
 880 =head2 get_install_log_values
 881
 882 Reads value from the Koha install log specified by
 883 --prev-install-log
 884
 885 =cut
 886
 887 sub get_install_log_values {
 888     my $install_log = shift;
 889     my $values = shift;
 890
 891     open my $log, '<', $install_log or die "Cannot open install log $install_log: $!\n";
 892     while (<$log>) {
 893         chomp;
 894         next if /^#/ or /^\s*$/;
 895         next if /^=/;
 896         next unless m/=/;
 897         s/\s+$//g;
 898         my ($key, $value) = split /=/, $_, 2;
 899         $values->{$key} = $value;
 900     }
 901     close $log;
 902
 903     print <<_EXPLAIN_INSTALL_LOG_;
 904 Reading values from install log $install_log.  You
 905 will be prompted only for settings that have been
 906 added since the last time you installed Koha.  To
 907 be prompted for all settings, run 'perl Makefile.PL'
 908 without the --prev-install-log option.
 909 _EXPLAIN_INSTALL_LOG_
 910 }
 911
 912 =head2 get_configuration
 913
 914 This prompts the user for various configuration options.
 915
 916 =cut
 917
 918 sub get_configuration {
 919   my $defaults = shift;
 920   my $valid_values = shift;
 921   my $install_log_values = shift;
 922   my %config = ();
 923
 924   my $msg = q(
 925 By default, Koha can be installed in one of three ways:
 926
 927 standard: Install files in conformance with the Filesystem
 928           Hierarchy Standard (FHS).  This is the default mode
 929           and should be used when installing a production
 930           Koha system.  On Unix systems, root access is
 931           needed to complete a standard installation.
 932
 933 single:   Install files under a single directory.  This option
 934           is useful for installing Koha without root access, e.g.,
 935           on a web host that allows CGI scripts and MySQL databases
 936           but requires the user to keep all files under the user's
 937           HOME directory.
 938
 939 dev:      Create a set of symbolic links and configuration files to
 940           allow Koha to run directly from the source distribution.
 941           This mode is useful for developers who want to run
 942           Koha from a git clone.
 943
 944 Installation mode);
 945     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 946     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values, $install_log_values);
 947
 948     # set message and default value for INSTALL_BASE
 949     # depending on value of INSTALL_MODE
 950     my $install_base_default = $defaults->{'INSTALL_BASE'};
 951     if ($config{'INSTALL_MODE'} eq 'dev') {
 952         $msg = q(
 953 Please specify the directory in which to install Koha's
 954 active configuration files and (if applicable) the
 955 Zebra database.  Koha's CGI scripts and templates will
 956 be run from the current directory.
 957
 958 Configuration directory:);
 959         # FIXME - home directory portability consideration apply
 960         $install_base_default =
 961             $ENV{DESTDIR}
 962             || ( exists $ENV{HOME} ? "$ENV{HOME}/koha-dev" : "$defaults->{'INSTALL_BASE'}-dev" )
 963         ;
 964     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 965         $msg = "\nPlease specify the directory in which to install Koha";
 966         # FIXME -- we're assuming under a 'single' mode install
 967         # that user will likely want to install under the home
 968         # directory.  This is OK in and of itself, but we should
 969         # use File::HomeDir to locate the home directory portably.
 970         # This is deferred for now because File::HomeDir is not yet
 971         # core.
 972                 # --we must also keep this portable to the major OS's -fbcit
 973         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : $defaults->{'INSTALL_BASE'};
 974     } else {
 975         # must be standard
 976         $msg = q(
 977 Please specify the directory under which most Koha files
 978 will be installed.
 979
 980 Note that if you are planning in installing more than
 981 one instance of Koha, you may want to modify the last
 982 component of the directory path, which will be used
 983 as the package name in the FHS layout.
 984
 985 Base installation directory);
 986     }
 987     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values, $install_log_values);
 988
 989     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 990         print "INSTALL_BASE=$config{'INSTALL_BASE'}\r\n" if $DEBUG;
 991     if ($config{'INSTALL_MODE'} eq "standard") {
 992         $msg = q(
 993 Since you are using the 'standard' install
 994 mode, you should run 'make install' as root.
 995 However, it is recommended that a non-root
 996 user (on Unix and Linux platforms) have
 997 ownership of Koha's files, including the
 998 Zebra indexes if applicable.
 999
1000 Please specify a user account.  This
1001 user account does not need to exist
1002 right now, but it needs to exist
1003 before you run 'make install'.  Please
1004 note that for security reasons, this
1005 user should not be the same as the user
1006 account Apache runs under.
1007
1008 User account);
1009         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values, $install_log_values);
1010
1011         $msg = q(
1012 Please specify the group that should own
1013 Koha's files.  As above, this group need
1014 not exist right now, but should be created
1015 before you run 'make install'.
1016
1017 Group);
1018         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values, $install_log_values);
1019     }
1020
1021     $msg = q(
1022 Please specify which database engine you will use
1023 to store data in Koha.  The choices are MySQL and
1024 PostgreSQL; please note that at the moment
1025 PostgreSQL support is highly experimental.
1026
1027 DBMS to use);
1028     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
1029     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values, $install_log_values);
1030
1031     $msg = q(
1032 Please specify the name or address of your
1033 database server.  Note that the database
1034 does not have to exist at this point, it
1035 can be created after running 'make install'
1036 and before you try using Koha for the first time.
1037
1038 Database server);
1039     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values, $install_log_values);
1040
1041     $msg = q(
1042 Please specify the port used to connect to the
1043 DMBS);
1044     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
1045     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values, $install_log_values);
1046
1047     $msg = q(
1048 Please specify the name of the database to be
1049 used by Koha);
1050     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values, $install_log_values);
1051     if ($config{'DB_TYPE'} eq 'mysql'){
1052         $msg = q(
1053 Please specify whether the connection to MySQL will use TLS
1054         );
1055         $config{'DB_USE_TLS'} = _get_value('DB_USE_TLS', $msg, $defaults->{'DB_USE_TLS'}, $valid_values, $install_log_values);
1056     }
1057     if ($config{'DB_USE_TLS'} eq 'yes'){
1058         $msg = q(
1059 Please enter the path to the CA certificate for TLS
1060         );
1061         $config{'DB_TLS_CA_CERTIFICATE'} = _get_value('DB_TLS_CA_CERTIFICATE', $msg, $defaults->{'DB_TLS_CA_CERTIFICATE'}, $valid_values, $install_log_values);
1062
1063         $msg = q(
1064 Please enter the path to the client certificate for TLS
1065         );
1066         $config{'DB_TLS_CLIENT_CERTIFICATE'} = _get_value('DB_TLS_CLIENT_CERTIFICATE', $msg, $defaults->{'DB_TLS_CLIENT_CERTIFICATE'}, $valid_values, $install_log_values);
1067         $msg = q(
1068 Please enter the path to the client key for TLS
1069         );
1070         $config{'DB_TLS_CLIENT_KEY'} = _get_value('DB_TLS_CLIENT_KEY', $msg, $defaults->{'DB_TLS_CLIENT_KEY'}, $valid_values, $install_log_values);
1071     }
1072
1073     $msg = q(
1074 Please specify the user that owns the database to be
1075 used by Koha);
1076     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values, $install_log_values);
1077
1078     $msg = q(
1079 Please specify the password of the user that owns the
1080 database to be used by Koha);
1081     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values, $install_log_values);
1082
1083     print q(
1084 Koha uses the Zebra search engine for high-performance
1085 searching of bibliographic and authority records.  Checking
1086 to see if you have installed the Zebra software...
1087 );
1088
1089     if (defined(my $zebra_path = find_zebra())) {
1090         $config{'PATH_TO_ZEBRA'} = $zebra_path;
1091         print qq(
1092 Found 'zebrasrv' and 'zebraidx' in $zebra_path.
1093 );
1094     } else {
1095         print q(
1096 Unable to find the Zebra programs 'zebrasrv' and 'zebraidx'
1097 in your PATH or in some of the usual places.  If you haven't
1098 installed Zebra yet, please do so and run Makefile.PL again.
1099
1100 );
1101     }
1102
1103     $msg = q(
1104 You must specify the primary MARC format of the
1105 records to be indexed by Zebra.
1106
1107 Koha provides Zebra configuration files for MARC21,
1108 NORMARC and UNIMARC.
1109
1110 MARC format for Zebra indexing);
1111     $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
1112     $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values, $install_log_values);
1113     $msg = q(
1114 Koha supplies Zebra configuration files tuned for
1115 searching either English (en) or French (fr) MARC
1116 records.
1117
1118 Primary language for Zebra indexing);
1119     $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
1120     $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values, $install_log_values);
1121
1122     $msg = q(
1123 Zebra has two methods to perform records tokenization
1124 and characters normalization: CHR and ICU. ICU is
1125 recommended for catalogs containing non-Latin
1126 characters.);
1127
1128     $msg .= _add_valid_values_disp('ZEBRA_TOKENIZER', $valid_values);
1129     $config{'ZEBRA_TOKENIZER'} = _get_value('ZEBRA_TOKENIZER', $msg, $defaults->{'ZEBRA_TOKENIZER'}, $valid_values, $install_log_values);
1130
1131     $msg = q(
1132 Please specify Zebra database user);
1133     $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values, $install_log_values);
1134
1135     $msg = q(
1136 Please specify the Zebra database password);
1137     $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values, $install_log_values);
1138
1139     $msg = q(
1140 Since you've chosen to use Zebra, you can enable the SRU/
1141 Z39.50 Server if you so choose, but you must specify a
1142 few configuration options for it.
1143
1144 Please note that if you choose *NOT* to configure SRU,
1145 koha-conf.xml will still contain some references to SRU
1146 settings.  Those references will be ignored by Koha.
1147
1148 Install the SRU configuration files?);
1149     $msg .= _add_valid_values_disp('INSTALL_SRU', $valid_values);
1150     $config{'INSTALL_SRU'} = _get_value('INSTALL_SRU', $msg, $defaults->{'INSTALL_SRU'}, $valid_values, $install_log_values);
1151
1152     if ($config{'INSTALL_SRU'} eq 'yes') {
1153         $msg = q(
1154 Since you've chosen to configure SRU, you must
1155 specify the host and port(s) that the SRU
1156 Servers (bibliographic and authority) should run on.
1157 );
1158         $msg = q(
1159 SRU Database host?);
1160         $config{'ZEBRA_SRU_HOST'} = _get_value('ZEBRA_SRU_HOST', $msg, $defaults->{'ZEBRA_SRU_HOST'}, $valid_values, $install_log_values);
1161
1162         $msg = q(
1163 SRU port for bibliographic data?);
1164         $config{'ZEBRA_SRU_BIBLIOS_PORT'} = _get_value('ZEBRA_SRU_BIBLIOS_PORT', $msg, $defaults->{'ZEBRA_SRU_BIBLIOS_PORT'}, $valid_values, $install_log_values);
1165
1166         $msg = q(
1167 SRU port for authority data?);
1168         $config{'ZEBRA_SRU_AUTHORITIES_PORT'} = _get_value('ZEBRA_SRU_AUTHORITIES_PORT', $msg, $defaults->{'ZEBRA_SRU_AUTHORITIES_PORT'}, $valid_values, $install_log_values);
1169
1170     }
1171
1172     $msg = q(
1173 Along with Zebra, you can also choose to install PazPar2,
1174 which is a metasearch tool.  With PazPar2,
1175 Koha can perform on-the-fly merging of bibliographic
1176 records during searching, allowing for FRBRization of
1177 the results list.
1178
1179 Install the PazPar2 configuration files?);
1180     $msg .= _add_valid_values_disp('INSTALL_PAZPAR2', $valid_values);
1181     $config{'INSTALL_PAZPAR2'} = _get_value('INSTALL_PAZPAR2', $msg, $defaults->{'INSTALL_PAZPAR2'}, $valid_values, $install_log_values);
1182
1183     if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
1184         $msg = q(
1185 Since you've chosen to configure PazPar2, you must
1186 specify the host and port(s) that PazPar2
1187 uses:
1188 );
1189         $msg = q(
1190 Zebra bibliographic server host?);
1191         $config{'MERGE_SERVER_HOST'} = _get_value('MERGE_SERVER_HOST', $msg, $defaults->{'MERGE_SERVER_HOST'}, $valid_values, $install_log_values);
1192
1193         $msg = q(
1194 Zebra bibliographic port for PazPar2 to use?);
1195         $config{'MERGE_SERVER_PORT'} = _get_value('MERGE_SERVER_PORT', $msg, $defaults->{'MERGE_SERVER_PORT'}, $valid_values, $install_log_values);
1196
1197         $msg = q(
1198 PazPar2 host?);
1199         $config{'PAZPAR2_HOST'} = _get_value('PAZPAR2_HOST', $msg, $defaults->{'PAZPAR2_HOST'}, $valid_values, $install_log_values);
1200
1201         $msg = q(
1202 PazPar2 port?);
1203         $config{'PAZPAR2_PORT'} = _get_value('PAZPAR2_PORT', $msg, $defaults->{'PAZPAR2_PORT'}, $valid_values, $install_log_values);
1204
1205     }
1206
1207   $msg = q(
1208 Use memcached to cache the results of some function calls?
1209 This provides a significant performance improvement.
1210 You will need a Memcached server running.);
1211   $msg .= _add_valid_values_disp('USE_MEMCACHED', $valid_values);
1212   $config{'USE_MEMCACHED'} = _get_value('USE_MEMCACHED', $msg, $defaults->{'USE_MEMCACHED'}, $valid_values, $install_log_values);
1213   if ($config{'USE_MEMCACHED'} eq 'yes'){
1214       $msg = q(
1215 Since you've chosen to use caching, you must specify the memcached servers and the namespace to use:
1216 );
1217       $msg = q(
1218 Memcached server address?);
1219       $config{'MEMCACHED_SERVERS'} = _get_value('MEMCACHED_SERVERS', $msg, $defaults->{'MEMCACHED_SERVERS'}, $valid_values, $install_log_values);
1220
1221       $msg = q(
1222 Memcached namespace?);
1223       $config{'MEMCACHED_NAMESPACE'} = _get_value('MEMCACHED_NAMESPACE', $msg, $defaults->{'MEMCACHED_NAMESPACE'}, $valid_values, $install_log_values);
1224   }
1225
1226
1227   $msg = q(
1228 Use Elasticsearch to serve search results?
1229 You will need a Elasticsearch server running.);
1230   $msg .= _add_valid_values_disp('USE_ELASTICSEARCH', $valid_values);
1231   $config{'USE_ELASTICSEARCH'} = _get_value('USE_ELASTICSEARCH', $msg, $defaults->{'USE_ELASTICSEARCH'}, $valid_values, $install_log_values);
1232   if ($config{'USE_ELASTICSEARCH'} eq 'yes'){
1233       $msg = q(
1234 Define the ELASTICSEARCH_SERVERS with a comma-separated list. Eg
1235 localhost:9200, 192.168.0.100:9200
1236 );
1237       $msg = q(
1238 Elasticsearch server addresses?);
1239       $config{'ELASTICSEARCH_SERVERS'} = _get_value('ELASTICSEARCH_SERVERS', $msg, $defaults->{'ELASTICSEARCH_SERVERS'}, $valid_values, $install_log_values);
1240
1241       $msg = q(
1242 What index name to use for this Koha-instance? It must be unique for each Koha
1243 sharing the same Elasticsearch-cluster
1244
1245 Elasticsearch index?);
1246       $config{'ELASTICSEARCH_INDEX'} = _get_value('ELASTICSEARCH_INDEX', $msg, $defaults->{'ELASTICSEARCH_INDEX'}, $valid_values, $install_log_values);
1247   }
1248
1249   $msg = q(
1250 Template cache directory?);
1251   $config{'TEMPLATE_CACHE_DIR'} = _get_value('TEMPLATE_CACHE_DIR', $msg, $defaults->{'TEMPLATE_CACHE_DIR'}, $valid_values, $install_log_values);
1252
1253   $msg = q(
1254 Path to DejaVu fonts?);
1255   $config{'FONT_DIR'} = _get_value('FONT_DIR', $msg, $defaults->{'FONT_DIR'}, $valid_values, $install_log_values);
1256
1257
1258   $msg = q(
1259 Would you like to run the database-dependent test suite?);
1260   $msg .= _add_valid_values_disp( 'RUN_DATABASE_TESTS', $valid_values );
1261     $config{'RUN_DATABASE_TESTS'} = _get_value( 'RUN_DATABASE_TESTS', $msg, $defaults->{'RUN_DATABASE_TESTS'}, $valid_values, $install_log_values );
1262
1263   if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1264       $config{'TEST_DB_TYPE'} = $config{'DB_TYPE'};
1265       $config{'TEST_DB_HOST'} = $config{'DB_HOST'};
1266       $msg = q(TEST DATABASE
1267
1268 THE DATA IN THIS DATABASE WILL BE DESTROYED during the process of
1269 testing. Please don't do this on your production database. It is not
1270 reversible.
1271
1272 YOU WILL SUFFER DATA LOSS if you run this test suite on your test
1273 database. You are better off not running this optional test suite than
1274 doing it in a database that you don't want to lose.
1275
1276 Please specify the name of the test database to be
1277 used by Koha);
1278
1279       $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1280       while ( $config{'TEST_DB_NAME'} eq $config{'DB_NAME'} ) {
1281           $msg = q(Please do not use the same database for testing as you do for production. You run the severe risk of data loss.);
1282           $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1283       }
1284
1285       $msg = q(
1286 Please specify the user that owns the database to be
1287 used by Koha);
1288     $config{'TEST_DB_USER'} = _get_value('TEST_DB_USER', $msg, $defaults->{'TEST_DB_USER'}, $valid_values, $install_log_values);
1289
1290       $msg = q(
1291 Please specify the password of the user that owns the
1292 database to be used by Koha);
1293       $config{'TEST_DB_PASS'} = _get_value('TEST_DB_PASS', $msg, $defaults->{'TEST_DB_PASS'}, $valid_values, $install_log_values);
1294   }
1295
1296     print "\n\n";
1297
1298     # add version number
1299     my $version = "no_version_found";
1300     eval {
1301         require 'kohaversion.pl';
1302         $version = kohaversion();
1303     };
1304     $config{'KOHA_INSTALLED_VERSION'} = $version;
1305
1306     return %config;
1307 }
1308
1309 sub _add_valid_values_disp {
1310     my $key = shift;
1311     my $valid_values = shift;
1312
1313     my $disp = "";
1314     if (exists $valid_values->{$key}) {
1315         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
1316     }
1317     return $disp;
1318 }
1319
1320 sub _get_value {
1321     my $key = shift;
1322     my $msg = shift;
1323     my $default = shift;
1324     my $valid_values = shift;
1325     my $install_log_values = shift;
1326
1327     # take value from install log if present
1328     if (exists $install_log_values{$key}) {
1329         $install_log_values{$key} =~ s/\$/\$\$/g;
1330         return $install_log_values{$key};
1331     }
1332
1333     # override default value from environment
1334     if (exists $ENV{$key}) {
1335         $default = $ENV{$key};
1336         $msg .= " (default from environment)";
1337     }
1338
1339     my $val = prompt($msg, $default);
1340
1341     while (exists $valid_values->{$key} and
1342            $val ne $default and
1343            not exists $valid_values->{$key}->{$val}) {
1344         my $retry_msg = "Value '$val' is not a valid option.\n";
1345         $retry_msg .= "Please enter a value";
1346         $retry_msg .= _add_valid_values_disp($key, $valid_values);
1347         $val = prompt($retry_msg, $default);
1348     }
1349     $val =~ s/\$/\$\$/g;
1350     return $val;
1351 }
1352
1353 =head2 get_target_directories
1354
1355 Creates a hash mapping from symbols for installation target
1356 directories to actual directory paths.
1357
1358 Also returns a hash indicating targets for which
1359 files need not be copied -- this is used for the 'dev'
1360 mode installation, where some files are installed in place.
1361
1362 =cut
1363
1364 sub get_target_directories {
1365     my $config = shift;
1366
1367     my $base = $config->{'INSTALL_BASE'};
1368     my $mode = $config->{'INSTALL_MODE'};
1369
1370     # get last component of install base directory
1371     # to treat as package name
1372     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
1373
1374     my @basedir = File::Spec->splitdir($directories);
1375
1376     if ( $^O eq 'cygwin' ) { shift @basedir; unshift @basedir, 'c:'; }   # in a cygwin environment, $volume is returned empty
1377
1378     my $package = pop @basedir;
1379
1380
1381     my %dirmap = ();
1382     my %skipdirs = ();
1383     if ($mode eq 'single') {
1384         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1385         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1386         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1387         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1388         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1389         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1390         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1391         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1392         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1393         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1394         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'z3950');
1395         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1396         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1397         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1398         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1399         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1400         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1401         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1402         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lock');
1403         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1404         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1405         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'koha', 'plugins');
1406         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1407         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1408     } elsif ($mode eq 'dev') {
1409         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
1410         $dirmap{'API_CGI_DIR'} = File::Spec->catdir($curdir, 'api');
1411         $skipdirs{'API_CGI_DIR'} = 1;
1412         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
1413         $skipdirs{'INTRANET_CGI_DIR'} = 1;
1414         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
1415         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
1416         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1417         $skipdirs{'INTRANET_WWW_DIR'} = 1;
1418         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir);
1419         $skipdirs{'OPAC_CGI_DIR'} = 1;
1420         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
1421         $skipdirs{'OPAC_TMPL_DIR'} = 1;
1422         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1423         $skipdirs{'OPAC_WWW_DIR'} = 1;
1424         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
1425         $skipdirs{'PERL_MODULE_DIR'} = 1;
1426         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1427         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1428         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'z3950');
1429         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1430         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1431         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1432         #For dev install, point NONDEV_DIR to misc in current dir (not base)
1433         #Used by supportdir in koha-conf.xml (BZ 12031)
1434         $dirmap{'SCRIPT_NONDEV_DIR'} = File::Spec->catdir($curdir, 'misc');
1435         $skipdirs{'SCRIPT_NONDEV_DIR'} = 1;
1436         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1437         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1438         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1439         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lock');
1440         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1441         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1442         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'plugins');
1443         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1444         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1445     } else {
1446         # mode is standard, i.e., 'fhs'
1447         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1448         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1449         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1450         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1451         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1452         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1453         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1454         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1455         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
1456         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
1457         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'z3950');
1458         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'pazpar2');
1459         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1460         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1461         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1462         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1463         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1464         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
1465         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package);
1466         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
1467         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'spool', $package);
1468         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'plugins');
1469         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
1470         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
1471     }
1472
1473     _get_env_overrides(\%dirmap);
1474     _get_argv_overrides(\%dirmap);
1475     _add_destdir(\%dirmap);
1476
1477     return \%dirmap, \%skipdirs;
1478 }
1479
1480 =head2 get_test_dir
1481
1482 Map a directory target to the corresponding path for
1483 the test suite.
1484
1485 =cut
1486
1487 sub get_test_dir {
1488     my ($dirname) = @_;
1489
1490     my @basedir = (File::Spec->rel2abs(File::Spec->curdir()), 't', 'run');
1491     if (exists $test_suite_override_dirs{$dirname}) {
1492         return File::Spec->catdir(@basedir, @{ $test_suite_override_dirs{$dirname} });
1493     } else {
1494         return;
1495     }
1496
1497 }
1498
1499 sub _get_env_overrides {
1500     my $dirmap = shift;
1501
1502     foreach my $key (keys %$dirmap) {
1503         if (exists $ENV{$key}) {
1504             $dirmap->{$key} = $ENV{$key};
1505             print "Setting $key from environment\n";
1506         }
1507     }
1508 }
1509
1510 sub _get_argv_overrides {
1511     my $dirmap = shift;
1512
1513     my @new_argv = ();
1514     for (my $i = 0; $i <= $#ARGV; $i++) {
1515         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
1516             $dirmap->{$1} = $2;
1517         } else {
1518             push @new_argv, $ARGV[$i];
1519         }
1520     }
1521     @ARGV = @new_argv;
1522 }
1523
1524 sub _strip_destdir {
1525     my $dir = shift;
1526     $dir =~ s/^\$\(DESTDIR\)//;
1527     return $dir;
1528 }
1529
1530 sub _add_destdir {
1531     my $dirmap = shift;
1532
1533     foreach my $key (keys %$dirmap) {
1534         $dirmap->{$key} = '$(DESTDIR)'.$dirmap->{$key};
1535     }
1536 }
1537
1538 sub display_configuration {
1539     my $config = shift;
1540     my $dirmap = shift;
1541     my @version = grep /\/usr\/share\/perl\//, @INC;
1542     push @version, ('/usr/share/perl/5.10') if !$version[0];
1543     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1544     foreach my $key (sort keys %$config) {
1545         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1546     }
1547
1548     print "\nand in the following directories:\n\n";
1549     foreach my $key (sort keys %$dirmap) {
1550         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1551     }
1552     print "\n\nTo change any configuration setting, please run\n";
1553     print "perl Makefile.PL again.  To override one of the target\n";
1554     print "directories, you can do so on the command line like this:\n";
1555     print "\nperl Makefile.PL PERL_MODULE_DIR=$version[0]\n\n";
1556     print "You can also set different default values for parameters\n";
1557     print "or override directory locations by using environment variables.\n";
1558     print "\nFor example:\n\n";
1559     print "export DB_USER=my_koha\n";
1560     print "perl Makefile.PL\n";
1561     print "\nor\n\n";
1562     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1563 }
1564
1565 =head2 find_zebra
1566
1567 Attempt to find Zebra - check user's PATH and
1568 a few other directories for zebrasrv and zebraidx.
1569
1570 =cut
1571
1572 sub find_zebra {
1573     my @search_dirs = map {
1574                             my $abs = File::Spec->rel2abs($_);
1575                             my ($toss, $directories);
1576                             ($toss, $directories, $toss) = File::Spec->splitpath($abs, 1);
1577                             $directories;
1578                         }  split /:/, $ENV{PATH};
1579     push @search_dirs, qw(/usr/local/bin /opt/local/bin /usr/bin);
1580     my @zebrasrv_dirs = grep { -x File::Spec->catpath('', $_, 'zebrasrv') } @search_dirs;
1581     return unless @zebrasrv_dirs;
1582     # verify that directory that contains zebrasrv also contains zebraidx
1583     foreach my $dir (@zebrasrv_dirs) {
1584         return $dir if -x File::Spec->catpath('', $dir, 'zebraidx');
1585     }
1586     return;
1587 }
1588
1589 package MY;
1590
1591 sub test {
1592     my $self = shift;
1593     my $test = $self->SUPER::test(@_);
1594     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1595
1596     # set KOHA_CONF
1597     $test =~ s!\$\(FULLPERLRUN\)!KOHA_CONF=blib/KOHA_CONF_DIR/koha-conf.xml \$(FULLPERLRUN)!g;
1598     return $test;
1599 }
1600
1601 sub install {
1602     my $self = shift;
1603     my $install = "";
1604     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1605     # This means that we're completely overriding EU::MM's default
1606     # installation and uninstallation targets.
1607
1608 # If installation is on Win32, we need to do permissions different from *nix
1609     if ( $^O =~ /darwin|linux|cygwin|freebsd|solaris/ ) { # this value needs to be verified for each platform and modified accordingly
1610             foreach my $key (sort keys %$target_directories) {
1611                     $install .= qq(
1612 KOHA_INST_$key = blib/$key
1613 KOHA_DEST_$key = $target_directories->{$key}
1614 ) unless exists $skip_directories->{$key};
1615                 }
1616                 $install .= qq(
1617 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1618 \t\$(NOECHO) \$(NOOP)
1619 );
1620                         $install .= "install_koha ::\n";
1621                         $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1622                         foreach my $key (sort keys %$target_directories) {
1623                                 $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1624           unless exists $skip_directories->{$key};
1625                         }
1626                         $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1627                         $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1628
1629                         $install .= "\n";
1630                         $install .= "set_koha_ownership ::\n";
1631 # Do not try to change ownership if DESTDIR is set
1632                         if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1633                                 foreach my $key (sort keys %$target_directories) {
1634             $install .= "\t\$(NOECHO) if test -z \"\$(DESTDIR)\"; then chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key); fi\n"
1635             unless exists $skip_directories->{$key};
1636                                 }
1637                         } else {
1638                                 $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1639                         }
1640
1641                         $install .= "\n";
1642                         $install .= "set_koha_permissions ::\n";
1643                         # This is necessary because EU::MM installs files
1644                         # as either 0444 or 0555, and we want the owner
1645                         # of Koha's files to have write permission by default.
1646                         foreach my $key (sort keys %$target_directories) {
1647                                 $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1648           unless exists $skip_directories->{$key};
1649                         }
1650         }
1651
1652         $install .= "\n";
1653
1654     $install .= "warn_koha_env_vars ::\n";
1655     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1656     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1657     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1658     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1659     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1660     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1661     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1662     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1663     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1664     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1665     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1666
1667     $install .= _update_zebra_conf_target();
1668
1669     $install .= upgrade();
1670
1671     return $install;
1672 }
1673
1674 =head2 _update_zebra_conf_target
1675
1676 Add an installation target for updating
1677 Zebra's configuration files.
1678
1679 =cut
1680
1681 sub _update_zebra_conf_target {
1682
1683     my $target = "\nupdate_zebra_conf ::\n";
1684     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1685     $target .= "\t\t\$(KOHA_INST_ZEBRA_CONF_DIR) \$(KOHA_DEST_ZEBRA_CONF_DIR) \n";
1686     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_ZEBRA_CONF_DIR)\n";
1687     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1688     $target .= "\t\t\$(KOHA_INST_PAZPAR2_CONF_DIR) \$(KOHA_DEST_PAZPAR2_CONF_DIR) \n";
1689     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_PAZPAR2_CONF_DIR)\n";
1690
1691     return $target;
1692 }
1693
1694 sub upgrade {
1695     my $upgrade = "";
1696
1697     my $backup_suffix;
1698     if (exists $install_log_values{'KOHA_INSTALLED_VERSION'}) {
1699         my $version = $install_log_values{'KOHA_INSTALLED_VERSION'};
1700         $version =~ s/\./_/g;
1701         $backup_suffix = "_koha_$version";
1702     } else {
1703         $backup_suffix = "_upgrade_backup";
1704     }
1705
1706     $upgrade .= qq/
1707 MOD_BACKUP = \$(ABSPERLRUN) -MC4::Installer::UpgradeBackup -e 'backup_changed_files({\@ARGV}, '$backup_suffix', '\''\$(VERBINST)'\'', '\''\$(UNINST)'\'');' --
1708
1709 upgrade :: make_upgrade_backup install
1710 \t\$(NOECHO) \$(NOOP)
1711 make_upgrade_backup ::
1712 \t\$(NOECHO) umask 022; \$(MOD_BACKUP) \\
1713 /;
1714     foreach my $key (qw/KOHA_CONF_DIR INTRANET_TMPL_DIR INTRANET_WWW_DIR OPAC_TMPL_DIR OPAC_WWW_DIR
1715                      PAZPAR2_CONF_DIR ZEBRA_CONF_DIR PLUGINS_DIR/) {
1716         $upgrade .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1717             unless exists $skip_directories->{$key} or
1718                    not exists $target_directories->{$key};
1719     }
1720     $upgrade =~ s/\\\n$/\n/;
1721
1722     return $upgrade;
1723 }
1724 sub postamble {
1725     # put directory mappings into Makefile
1726     # so that Make will export as environment
1727     # variables -- this is for the use of
1728     # rewrite-confg.PL
1729
1730     my $env;
1731         # Hereagain, we must alter syntax per platform...
1732         {
1733                 $env = join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1734                 $env .= "\n\n";
1735                 $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1736         }
1737
1738     return "$env\n";
1739 }
1740
1741
1742 __END__
1743
1744
1745 =head1 SEE ALSO
1746
1747 ExtUtils::MakeMaker(3)
1748
1749 =head1 AUTHORS
1750
1751 MJ Ray mjr at phonecoop.coop
1752 Galen Charlton galen.charlton at liblime.com
1753
1754 =cut
1755
1756 FIXME: deal with .htaccess