opac/opac-user.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 # parts copyright 2010 BibLibre
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Circulation;
  27 use C4::External::BakerTaylor qw( image_url link_url );
  28 use C4::Reserves;
  29 use C4::Members;
  30 use C4::Output;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Letters;
  34 use Koha::Account::Lines;
  35 use Koha::Biblios;
  36 use Koha::Libraries;
  37 use Koha::DateUtils;
  38 use Koha::Holds;
  39 use Koha::Database;
  40 use Koha::ItemTypes;
  41 use Koha::Patron::Attribute::Types;
  42 use Koha::Patrons;
  43 use Koha::Patron::Messages;
  44 use Koha::Patron::Discharge;
  45 use Koha::Patrons;
  46 use Koha::Token;
  47
  48 use constant ATTRIBUTE_SHOW_BARCODE => 'SHOW_BCODE';
  49
  50 use Scalar::Util qw(looks_like_number);
  51 use Date::Calc qw(
  52   Today
  53   Add_Delta_Days
  54   Date_to_Days
  55 );
  56
  57 my $query = new CGI;
  58
  59 # CAS single logout handling
  60 # Will print header and exit
  61 C4::Context->preference('casAuthentication') and C4::Auth_with_cas::logout_if_required($query);
  62
  63 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  64     {
  65         template_name   => "opac-user.tt",
  66         query           => $query,
  67         type            => "opac",
  68         authnotrequired => 0,
  69         debug           => 1,
  70     }
  71 );
  72
  73 my %renewed = map { $_ => 1 } split( ':', $query->param('renewed') || '' );
  74
  75 my $show_priority;
  76 for ( C4::Context->preference("OPACShowHoldQueueDetails") ) {
  77     m/priority/ and $show_priority = 1;
  78 }
  79
  80 my $patronupdate = $query->param('patronupdate');
  81 my $canrenew = 1;
  82
  83 $template->param( shibbolethAuthentication => C4::Context->config('useshibboleth') );
  84
  85 # get borrower information ....
  86 my $patron = Koha::Patrons->find( $borrowernumber );
  87
  88 if( $query->param('update_arc') && C4::Context->preference("AllowPatronToControlAutorenewal") ){
  89     die "Wrong CSRF token"
  90         unless Koha::Token->new->check_csrf({
  91             session_id => scalar $query->cookie('CGISESSID'),
  92             token  => scalar $query->param('csrf_token'),
  93         });
  94
  95     my $autorenew_checkouts = $query->param('borrower_autorenew_checkouts');
  96     $patron->autorenew_checkouts( $autorenew_checkouts )->store() if defined $autorenew_checkouts;
  97 }
  98
  99 my $borr = $patron->unblessed;
 100 # unblessed is a hash vs. object/undef. Hence the use of curly braces here.
 101 my $borcat = $borr ? $borr->{categorycode} : q{};
 102
 103 my (  $today_year,   $today_month,   $today_day) = Today();
 104 my ($warning_year, $warning_month, $warning_day) = split /-/, $borr->{'dateexpiry'};
 105
 106 my $debar = Koha::Patrons->find( $borrowernumber )->is_debarred;
 107 my $userdebarred;
 108
 109 if ($debar) {
 110     $userdebarred = 1;
 111     $template->param( 'userdebarred' => $userdebarred );
 112     if ( $debar ne "9999-12-31" ) {
 113         $borr->{'userdebarreddate'} = $debar;
 114     }
 115     # FIXME looks like $available is not needed
 116     # If a user is discharged they have a validated discharge available
 117     my $available = Koha::Patron::Discharge::count({
 118         borrowernumber => $borrowernumber,
 119         validated      => 1,
 120     });
 121     $template->param( 'discharge_available' => $available && Koha::Patron::Discharge::is_discharged({borrowernumber => $borrowernumber}) );
 122 }
 123
 124 if ( $userdebarred || $borr->{'gonenoaddress'} || $borr->{'lost'} ) {
 125     $borr->{'flagged'} = 1;
 126     $canrenew = 0;
 127 }
 128
 129 my $amountoutstanding = $patron->account->balance;
 130 my $no_renewal_amt = C4::Context->preference( 'OPACFineNoRenewals' );
 131 $no_renewal_amt = undef unless looks_like_number( $no_renewal_amt );
 132 my $amountoutstandingfornewal =
 133   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
 134   ? $amountoutstanding
 135   : $patron->account->outstanding_debits->total_outstanding;
 136
 137 if (   C4::Context->preference('OpacRenewalAllowed')
 138     && defined($no_renewal_amt)
 139     && $amountoutstandingfornewal > $no_renewal_amt )
 140 {
 141     $borr->{'flagged'} = 1;
 142     $canrenew = 0;
 143     $template->param(
 144         renewal_blocked_fines => $no_renewal_amt,
 145         renewal_blocked_fines_amountoutstanding => $amountoutstandingfornewal,
 146     );
 147 }
 148
 149 my $maxoutstanding = C4::Context->preference('maxoutstanding');
 150 if ( $amountoutstanding && ( $amountoutstanding > $maxoutstanding ) ){
 151     $borr->{blockedonfines} = 1;
 152 }
 153
 154 # Warningdate is the date that the warning starts appearing
 155 if ( $borr->{'dateexpiry'} && C4::Context->preference('NotifyBorrowerDeparture') ) {
 156     my $days_to_expiry = Date_to_Days( $warning_year, $warning_month, $warning_day ) - Date_to_Days( $today_year, $today_month, $today_day );
 157     if ( $days_to_expiry < 0 ) {
 158         #borrower card has expired, warn the borrower
 159         $borr->{'warnexpired'} = $borr->{'dateexpiry'};
 160     } elsif ( $days_to_expiry < C4::Context->preference('NotifyBorrowerDeparture') ) {
 161         # borrower card soon to expire, warn the borrower
 162         $borr->{'warndeparture'} = $borr->{dateexpiry};
 163         if (C4::Context->preference('ReturnBeforeExpiry')){
 164             $borr->{'returnbeforeexpiry'} = 1;
 165         }
 166     }
 167 }
 168
 169 # pass on any renew errors to the template for displaying
 170 my $renew_error = $query->param('renew_error');
 171
 172 $template->param(
 173                     amountoutstanding => $amountoutstanding,
 174                     borrowernumber    => $borrowernumber,
 175                     patron_flagged    => $borr->{flagged},
 176                     OPACMySummaryHTML => (C4::Context->preference("OPACMySummaryHTML")) ? 1 : 0,
 177                     surname           => $borr->{surname},
 178                     RENEW_ERROR       => $renew_error,
 179                     borrower          => $borr,
 180                     csrf_token             => Koha::Token->new->generate_csrf({
 181                         session_id => scalar $query->cookie('CGISESSID'),
 182                     }),
 183                 );
 184
 185 #get issued items ....
 186
 187 my $count          = 0;
 188 my $overdues_count = 0;
 189 my @overdues;
 190 my @issuedat;
 191 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 192 my $pending_checkouts = $patron->pending_checkouts->search({}, { order_by => [ { -desc => 'date_due' }, { -asc => 'issue_id' } ] });
 193 if ( $pending_checkouts->count ) { # Useless test
 194     while ( my $c = $pending_checkouts->next ) {
 195         my $issue = $c->unblessed_all_relateds;
 196         # check for reserves
 197         my $restype = GetReserveStatus( $issue->{'itemnumber'} );
 198         if ( $restype ) {
 199             $issue->{'reserved'} = 1;
 200         }
 201
 202         # Must be moved in a module if reused
 203         my $charges = Koha::Account::Lines->search(
 204             {
 205                 borrowernumber    => $patron->borrowernumber,
 206                 amountoutstanding => { '>' => 0 },
 207                 debit_type_code   => [ 'OVERDUE', 'LOST' ],
 208                 itemnumber        => $issue->{itemnumber}
 209             },
 210         );
 211         $issue->{charges} = $charges->total_outstanding;
 212
 213         my $rental_fines = Koha::Account::Lines->search(
 214             {
 215                 borrowernumber    => $patron->borrowernumber,
 216                 amountoutstanding => { '>' => 0 },
 217                 debit_type_code   => { 'LIKE' => 'RENT_%' },
 218                 itemnumber        => $issue->{itemnumber}
 219             }
 220         );
 221         $issue->{rentalfines} = $rental_fines->total_outstanding;
 222
 223         # check if item is renewable
 224         my ($status,$renewerror) = CanBookBeRenewed( $borrowernumber, $issue->{'itemnumber'} );
 225         ($issue->{'renewcount'},$issue->{'renewsallowed'},$issue->{'renewsleft'}) = GetRenewCount($borrowernumber, $issue->{'itemnumber'});
 226         ( $issue->{'renewalfee'}, $issue->{'renewalitemtype'} ) = GetIssuingCharges( $issue->{'itemnumber'}, $borrowernumber );
 227         $issue->{itemtype_object} = Koha::ItemTypes->find( Koha::Items->find( $issue->{itemnumber} )->effective_itemtype );
 228         if($status && C4::Context->preference("OpacRenewalAllowed")){
 229             $issue->{'status'} = $status;
 230         }
 231
 232         $issue->{'renewed'} = $renewed{ $issue->{'itemnumber'} };
 233
 234         if ($renewerror) {
 235             $issue->{'too_many'}       = 1 if $renewerror eq 'too_many';
 236             $issue->{'on_reserve'}     = 1 if $renewerror eq 'on_reserve';
 237             $issue->{'norenew_overdue'} = 1 if $renewerror eq 'overdue';
 238             $issue->{'auto_renew'}     = 1 if $renewerror eq 'auto_renew';
 239             $issue->{'auto_too_soon'}  = 1 if $renewerror eq 'auto_too_soon';
 240             $issue->{'auto_too_late'}  = 1 if $renewerror eq 'auto_too_late';
 241             $issue->{'auto_too_much_oweing'}  = 1 if $renewerror eq 'auto_too_much_oweing';
 242             $issue->{'item_denied_renewal'}  = 1 if $renewerror eq 'item_denied_renewal';
 243
 244             if ( $renewerror eq 'too_soon' ) {
 245                 $issue->{'too_soon'}         = 1;
 246                 $issue->{'soonestrenewdate'} = output_pref(
 247                     C4::Circulation::GetSoonestRenewDate(
 248                         $issue->{borrowernumber},
 249                         $issue->{itemnumber}
 250                     )
 251                 );
 252             }
 253         }
 254
 255         if ( $c->is_overdue ) {
 256             push @overdues, $issue;
 257             $overdues_count++;
 258             $issue->{'overdue'} = 1;
 259         }
 260         else {
 261             $issue->{'issued'} = 1;
 262         }
 263         # imageurl:
 264         my $itemtype = $issue->{'itemtype'};
 265         if ( $itemtype ) {
 266             $issue->{'imageurl'}    = getitemtypeimagelocation( 'opac', $itemtypes->{$itemtype}->{'imageurl'} );
 267             $issue->{'description'} = $itemtypes->{$itemtype}->{'description'};
 268         }
 269
 270         $issue->{biblio_object} = Koha::Biblios->find($issue->{biblionumber});
 271         push @issuedat, $issue;
 272         $count++;
 273
 274         my $isbn = GetNormalizedISBN($issue->{'isbn'});
 275         $issue->{normalized_isbn} = $isbn;
 276         my $marcrecord = GetMarcBiblio({
 277             biblionumber => $issue->{'biblionumber'},
 278             embed_items  => 1,
 279             opac         => 1,
 280             borcat       => $borcat });
 281         $issue->{normalized_upc} = GetNormalizedUPC( $marcrecord, C4::Context->preference('marcflavour') );
 282
 283                 # My Summary HTML
 284                 if (my $my_summary_html = C4::Context->preference('OPACMySummaryHTML')){
 285                     $issue->{author} ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g : $my_summary_html =~ s/{AUTHOR}//g;
 286                     $issue->{title} =~ s/\/+$//; # remove trailing slash
 287                     $issue->{title} =~ s/\s+$//; # remove trailing space
 288                     $issue->{title} ? $my_summary_html =~ s/{TITLE}/$issue->{title}/g : $my_summary_html =~ s/{TITLE}//g;
 289                     $issue->{isbn} ? $my_summary_html =~ s/{ISBN}/$isbn/g : $my_summary_html =~ s/{ISBN}//g;
 290                     $issue->{biblionumber} ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 291                     $issue->{MySummaryHTML} = $my_summary_html;
 292                 }
 293     }
 294 }
 295 my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
 296 $canrenew = 0 if ($overduesblockrenewing ne 'allow' and $overdues_count == $count);
 297
 298 $template->param( ISSUES       => \@issuedat );
 299 $template->param( issues_count => $count );
 300 $template->param( canrenew     => $canrenew );
 301 $template->param( OVERDUES       => \@overdues );
 302 $template->param( overdues_count => $overdues_count );
 303
 304 my $show_barcode = Koha::Patron::Attribute::Types->search( # FIXME we should not need this search
 305     { code => ATTRIBUTE_SHOW_BARCODE } )->count;
 306 if ($show_barcode) {
 307     my $patron_show_barcode = $patron->get_extended_attribute(ATTRIBUTE_SHOW_BARCODE);
 308     undef $show_barcode if $patron_show_barcode and not $patron_show_barcode->attribute;
 309 }
 310 $template->param( show_barcode => 1 ) if $show_barcode;
 311
 312 # now the reserved items....
 313 my $reserves = Koha::Holds->search( { borrowernumber => $borrowernumber } );
 314
 315 $template->param(
 316     RESERVES       => $reserves,
 317     showpriority   => $show_priority,
 318 );
 319
 320 if (C4::Context->preference('BakerTaylorEnabled')) {
 321     $template->param(
 322         BakerTaylorEnabled  => 1,
 323         BakerTaylorImageURL => &image_url(),
 324         BakerTaylorLinkURL  => &link_url(),
 325         BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 326     );
 327 }
 328
 329 if (C4::Context->preference("OPACAmazonCoverImages") or
 330     C4::Context->preference("GoogleJackets") or
 331     C4::Context->preference("BakerTaylorEnabled") or
 332     C4::Context->preference("SyndeticsCoverImages") or
 333     ( C4::Context->preference('OPACCustomCoverImages') and C4::Context->preference('CustomCoverImagesURL') )
 334 ) {
 335         $template->param(JacketImages=>1);
 336 }
 337
 338 $template->param(
 339     OverDriveCirculation => C4::Context->preference('OverDriveCirculation') || 0,
 340     overdrive_error      => scalar $query->param('overdrive_error') || undef,
 341     overdrive_tab        => scalar $query->param('overdrive_tab') || 0,
 342     RecordedBooksCirculation => C4::Context->preference('RecordedBooksClientSecret') && C4::Context->preference('RecordedBooksLibraryID'),
 343 );
 344
 345 my $patron_messages = Koha::Patron::Messages->search(
 346     {
 347         borrowernumber => $borrowernumber,
 348         message_type => 'B',
 349     }
 350 );
 351
 352 if (   C4::Context->preference('AllowPatronToSetCheckoutsVisibilityForGuarantor')
 353     || C4::Context->preference('AllowStaffToSetCheckoutsVisibilityForGuarantor') )
 354 {
 355     my @relatives;
 356     # Filter out guarantees that don't want guarantor to see checkouts
 357     foreach my $gr ( $patron->guarantee_relationships() ) {
 358         my $g = $gr->guarantee;
 359         push( @relatives, $g ) if $g->privacy_guarantor_checkouts;
 360     }
 361     $template->param( relatives => \@relatives );
 362 }
 363
 364 if (   C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
 365     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor') )
 366 {
 367     my @relatives_with_fines;
 368     # Filter out guarantees that don't want guarantor to see checkouts
 369     foreach my $gr ( $patron->guarantee_relationships() ) {
 370         my $g = $gr->guarantee;
 371         push( @relatives_with_fines, $g ) if $g->privacy_guarantor_fines;
 372     }
 373     $template->param( relatives_with_fines => \@relatives_with_fines );
 374 }
 375
 376
 377 $template->param(
 378     patron_messages          => $patron_messages,
 379     opacnote                 => $borr->{opacnote},
 380     patronupdate             => $patronupdate,
 381     OpacRenewalAllowed       => C4::Context->preference("OpacRenewalAllowed"),
 382     userview                 => 1,
 383     SuspendHoldsOpac         => C4::Context->preference('SuspendHoldsOpac'),
 384     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 385     OpacHoldNotes            => C4::Context->preference('OpacHoldNotes'),
 386     failed_holds             => scalar $query->param('failed_holds'),
 387 );
 388
 389 # if not an empty string this indicates to return
 390 # back to the opac-results page
 391 my $search_query = $query->param('has-search-query');
 392
 393 if ($search_query) {
 394
 395     print $query->redirect(
 396         -uri    => "/cgi-bin/koha/opac-search.pl?$search_query",
 397         -cookie => $cookie,
 398     );
 399 }
 400
 401 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };