C4/Circulation.pm

   1 package C4::Circulation;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # copyright 2010 BibLibre
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use DateTime;
  23 use POSIX qw( floor );
  24 use Koha::DateUtils;
  25 use C4::Context;
  26 use C4::Stats;
  27 use C4::Reserves;
  28 use C4::Biblio;
  29 use C4::Items;
  30 use C4::Members;
  31 use C4::Accounts;
  32 use C4::ItemCirculationAlertPreference;
  33 use C4::Message;
  34 use C4::Debug;
  35 use C4::Log; # logaction
  36 use C4::Overdues qw(CalcFine UpdateFine get_chargeable_units);
  37 use C4::RotatingCollections qw(GetCollectionItemBranches);
  38 use Algorithm::CheckDigits;
  39
  40 use Data::Dumper;
  41 use Koha::Account;
  42 use Koha::AuthorisedValues;
  43 use Koha::Biblioitems;
  44 use Koha::DateUtils;
  45 use Koha::Calendar;
  46 use Koha::Checkouts;
  47 use Koha::Illrequests;
  48 use Koha::Items;
  49 use Koha::Patrons;
  50 use Koha::Patron::Debarments;
  51 use Koha::Database;
  52 use Koha::Libraries;
  53 use Koha::Account::Lines;
  54 use Koha::Holds;
  55 use Koha::RefundLostItemFeeRules;
  56 use Koha::Account::Lines;
  57 use Koha::Account::Offsets;
  58 use Koha::Config::SysPrefs;
  59 use Koha::Charges::Fees;
  60 use Koha::Util::SystemPreferences;
  61 use Koha::Checkouts::ReturnClaims;
  62 use Carp;
  63 use List::MoreUtils qw( uniq any );
  64 use Scalar::Util qw( looks_like_number );
  65 use Try::Tiny;
  66 use Date::Calc qw(
  67   Today
  68   Today_and_Now
  69   Add_Delta_YM
  70   Add_Delta_DHMS
  71   Date_to_Days
  72   Day_of_Week
  73   Add_Delta_Days
  74 );
  75 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  76
  77 BEGIN {
  78         require Exporter;
  79         @ISA    = qw(Exporter);
  80
  81         # FIXME subs that should probably be elsewhere
  82         push @EXPORT, qw(
  83                 &barcodedecode
  84         &LostItem
  85         &ReturnLostItem
  86         &GetPendingOnSiteCheckouts
  87         );
  88
  89         # subs to deal with issuing a book
  90         push @EXPORT, qw(
  91                 &CanBookBeIssued
  92                 &CanBookBeRenewed
  93                 &AddIssue
  94                 &AddRenewal
  95                 &GetRenewCount
  96         &GetSoonestRenewDate
  97         &GetLatestAutoRenewDate
  98                 &GetIssuingCharges
  99         &GetBranchBorrowerCircRule
 100         &GetBranchItemRule
 101                 &GetBiblioIssues
 102                 &GetOpenIssue
 103         &CheckIfIssuedToPatron
 104         &IsItemIssued
 105         GetTopIssues
 106         );
 107
 108         # subs to deal with returns
 109         push @EXPORT, qw(
 110                 &AddReturn
 111         &MarkIssueReturned
 112         );
 113
 114         # subs to deal with transfers
 115         push @EXPORT, qw(
 116                 &transferbook
 117                 &GetTransfers
 118                 &GetTransfersFromTo
 119                 &updateWrongTransfer
 120                 &DeleteTransfer
 121                 &IsBranchTransferAllowed
 122                 &CreateBranchTransferLimit
 123                 &DeleteBranchTransferLimits
 124         &TransferSlip
 125         );
 126
 127     # subs to deal with offline circulation
 128     push @EXPORT, qw(
 129       &GetOfflineOperations
 130       &GetOfflineOperation
 131       &AddOfflineOperation
 132       &DeleteOfflineOperation
 133       &ProcessOfflineOperation
 134     );
 135 }
 136
 137 =head1 NAME
 138
 139 C4::Circulation - Koha circulation module
 140
 141 =head1 SYNOPSIS
 142
 143 use C4::Circulation;
 144
 145 =head1 DESCRIPTION
 146
 147 The functions in this module deal with circulation, issues, and
 148 returns, as well as general information about the library.
 149 Also deals with inventory.
 150
 151 =head1 FUNCTIONS
 152
 153 =head2 barcodedecode
 154
 155   $str = &barcodedecode($barcode, [$filter]);
 156
 157 Generic filter function for barcode string.
 158 Called on every circ if the System Pref itemBarcodeInputFilter is set.
 159 Will do some manipulation of the barcode for systems that deliver a barcode
 160 to circulation.pl that differs from the barcode stored for the item.
 161 For proper functioning of this filter, calling the function on the
 162 correct barcode string (items.barcode) should return an unaltered barcode.
 163
 164 The optional $filter argument is to allow for testing or explicit
 165 behavior that ignores the System Pref.  Valid values are the same as the
 166 System Pref options.
 167
 168 =cut
 169
 170 # FIXME -- the &decode fcn below should be wrapped into this one.
 171 # FIXME -- these plugins should be moved out of Circulation.pm
 172 #
 173 sub barcodedecode {
 174     my ($barcode, $filter) = @_;
 175     my $branch = C4::Context::mybranch();
 176     $filter = C4::Context->preference('itemBarcodeInputFilter') unless $filter;
 177     $filter or return $barcode;     # ensure filter is defined, else return untouched barcode
 178         if ($filter eq 'whitespace') {
 179                 $barcode =~ s/\s//g;
 180         } elsif ($filter eq 'cuecat') {
 181                 chomp($barcode);
 182             my @fields = split( /\./, $barcode );
 183             my @results = map( decode($_), @fields[ 1 .. $#fields ] );
 184             ($#results == 2) and return $results[2];
 185         } elsif ($filter eq 'T-prefix') {
 186                 if ($barcode =~ /^[Tt](\d)/) {
 187                         (defined($1) and $1 eq '0') and return $barcode;
 188             $barcode = substr($barcode, 2) + 0;     # FIXME: probably should be substr($barcode, 1)
 189                 }
 190         return sprintf("T%07d", $barcode);
 191         # FIXME: $barcode could be "T1", causing warning: substr outside of string
 192         # Why drop the nonzero digit after the T?
 193         # Why pass non-digits (or empty string) to "T%07d"?
 194         } elsif ($filter eq 'libsuite8') {
 195                 unless($barcode =~ m/^($branch)-/i){    #if barcode starts with branch code its in Koha style. Skip it.
 196                         if($barcode =~ m/^(\d)/i){      #Some barcodes even start with 0's & numbers and are assumed to have b as the item type in the libsuite8 software
 197                                 $barcode =~ s/^[0]*(\d+)$/$branch-b-$1/i;
 198                         }else{
 199                                 $barcode =~ s/^(\D+)[0]*(\d+)$/$branch-$1-$2/i;
 200                         }
 201                 }
 202     } elsif ($filter eq 'EAN13') {
 203         my $ean = CheckDigits('ean');
 204         if ( $ean->is_valid($barcode) ) {
 205             #$barcode = sprintf('%013d',$barcode); # this doesn't work on 32-bit systems
 206             $barcode = '0' x ( 13 - length($barcode) ) . $barcode;
 207         } else {
 208             warn "# [$barcode] not valid EAN-13/UPC-A\n";
 209         }
 210         }
 211     return $barcode;    # return barcode, modified or not
 212 }
 213
 214 =head2 decode
 215
 216   $str = &decode($chunk);
 217
 218 Decodes a segment of a string emitted by a CueCat barcode scanner and
 219 returns it.
 220
 221 FIXME: Should be replaced with Barcode::Cuecat from CPAN
 222 or Javascript based decoding on the client side.
 223
 224 =cut
 225
 226 sub decode {
 227     my ($encoded) = @_;
 228     my $seq =
 229       'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789+-';
 230     my @s = map { index( $seq, $_ ); } split( //, $encoded );
 231     my $l = ( $#s + 1 ) % 4;
 232     if ($l) {
 233         if ( $l == 1 ) {
 234             # warn "Error: Cuecat decode parsing failed!";
 235             return;
 236         }
 237         $l = 4 - $l;
 238         $#s += $l;
 239     }
 240     my $r = '';
 241     while ( $#s >= 0 ) {
 242         my $n = ( ( $s[0] << 6 | $s[1] ) << 6 | $s[2] ) << 6 | $s[3];
 243         $r .=
 244             chr( ( $n >> 16 ) ^ 67 )
 245          .chr( ( $n >> 8 & 255 ) ^ 67 )
 246          .chr( ( $n & 255 ) ^ 67 );
 247         @s = @s[ 4 .. $#s ];
 248     }
 249     $r = substr( $r, 0, length($r) - $l );
 250     return $r;
 251 }
 252
 253 =head2 transferbook
 254
 255   ($dotransfer, $messages, $iteminformation) = &transferbook($newbranch,
 256                                             $barcode, $ignore_reserves, $trigger);
 257
 258 Transfers an item to a new branch. If the item is currently on loan, it is automatically returned before the actual transfer.
 259
 260 C<$newbranch> is the code for the branch to which the item should be transferred.
 261
 262 C<$barcode> is the barcode of the item to be transferred.
 263
 264 If C<$ignore_reserves> is true, C<&transferbook> ignores reserves.
 265 Otherwise, if an item is reserved, the transfer fails.
 266
 267 C<$trigger> is the enum value for what triggered the transfer.
 268
 269 Returns three values:
 270
 271 =over
 272
 273 =item $dotransfer
 274
 275 is true if the transfer was successful.
 276
 277 =item $messages
 278
 279 is a reference-to-hash which may have any of the following keys:
 280
 281 =over
 282
 283 =item C<BadBarcode>
 284
 285 There is no item in the catalog with the given barcode. The value is C<$barcode>.
 286
 287 =item C<DestinationEqualsHolding>
 288
 289 The item is already at the branch to which it is being transferred. The transfer is nonetheless considered to have failed. The value should be ignored.
 290
 291 =item C<WasReturned>
 292
 293 The item was on loan, and C<&transferbook> automatically returned it before transferring it. The value is the borrower number of the patron who had the item.
 294
 295 =item C<ResFound>
 296
 297 The item was reserved. The value is a reference-to-hash whose keys are fields from the reserves table of the Koha database, and C<biblioitemnumber>. It also has the key C<ResFound>, whose value is either C<Waiting> or C<Reserved>.
 298
 299 =item C<WasTransferred>
 300
 301 The item was eligible to be transferred. Barring problems communicating with the database, the transfer should indeed have succeeded. The value should be ignored.
 302
 303 =back
 304
 305 =back
 306
 307 =cut
 308
 309 sub transferbook {
 310     my ( $tbr, $barcode, $ignoreRs, $trigger ) = @_;
 311     my $messages;
 312     my $dotransfer      = 1;
 313     my $item = Koha::Items->find( { barcode => $barcode } );
 314
 315     # bad barcode..
 316     unless ( $item ) {
 317         $messages->{'BadBarcode'} = $barcode;
 318         $dotransfer = 0;
 319         return ( $dotransfer, $messages );
 320     }
 321
 322     my $itemnumber = $item->itemnumber;
 323     # get branches of book...
 324     my $hbr = $item->homebranch;
 325     my $fbr = $item->holdingbranch;
 326
 327     # if using Branch Transfer Limits
 328     if ( C4::Context->preference("UseBranchTransferLimits") == 1 ) {
 329         my $code = C4::Context->preference("BranchTransferLimitsType") eq 'ccode' ? $item->ccode : $item->biblio->biblioitem->itemtype; # BranchTransferLimitsType is 'ccode' or 'itemtype'
 330         if ( C4::Context->preference("item-level_itypes") && C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ) {
 331             if ( ! IsBranchTransferAllowed( $tbr, $fbr, $item->itype ) ) {
 332                 $messages->{'NotAllowed'} = $tbr . "::" . $item->itype;
 333                 $dotransfer = 0;
 334             }
 335         } elsif ( ! IsBranchTransferAllowed( $tbr, $fbr, $code ) ) {
 336             $messages->{'NotAllowed'} = $tbr . "::" . $code;
 337             $dotransfer = 0;
 338         }
 339     }
 340
 341     # can't transfer book if is already there....
 342     if ( $fbr eq $tbr ) {
 343         $messages->{'DestinationEqualsHolding'} = 1;
 344         $dotransfer = 0;
 345     }
 346
 347     # check if it is still issued to someone, return it...
 348     my $issue = Koha::Checkouts->find({ itemnumber => $itemnumber });
 349     if ( $issue ) {
 350         AddReturn( $barcode, $fbr );
 351         $messages->{'WasReturned'} = $issue->borrowernumber;
 352     }
 353
 354     # find reserves.....
 355     # That'll save a database query.
 356     my ( $resfound, $resrec, undef ) =
 357       CheckReserves( $itemnumber );
 358     if ( $resfound and not $ignoreRs ) {
 359         $resrec->{'ResFound'} = $resfound;
 360         $messages->{'ResFound'} = $resrec;
 361         $dotransfer = 1;
 362     }
 363
 364     #actually do the transfer....
 365     if ($dotransfer) {
 366         ModItemTransfer( $itemnumber, $fbr, $tbr, $trigger );
 367
 368         # don't need to update MARC anymore, we do it in batch now
 369         $messages->{'WasTransfered'} = 1;
 370
 371     }
 372     ModDateLastSeen( $itemnumber );
 373     return ( $dotransfer, $messages );
 374 }
 375
 376
 377 sub TooMany {
 378     my $borrower        = shift;
 379     my $item_object = shift;
 380     my $params = shift;
 381     my $onsite_checkout = $params->{onsite_checkout} || 0;
 382     my $switch_onsite_checkout = $params->{switch_onsite_checkout} || 0;
 383     my $cat_borrower    = $borrower->{'categorycode'};
 384     my $dbh             = C4::Context->dbh;
 385         my $branch;
 386         # Get which branchcode we need
 387     $branch = _GetCircControlBranch($item_object->unblessed,$borrower);
 388     my $type = $item_object->effective_itemtype;
 389
 390     # given branch, patron category, and item type, determine
 391     # applicable issuing rule
 392     my $maxissueqty_rule = Koha::CirculationRules->get_effective_rule(
 393         {
 394             categorycode => $cat_borrower,
 395             itemtype     => $type,
 396             branchcode   => $branch,
 397             rule_name    => 'maxissueqty',
 398         }
 399     );
 400     my $maxonsiteissueqty_rule = Koha::CirculationRules->get_effective_rule(
 401         {
 402             categorycode => $cat_borrower,
 403             itemtype     => $type,
 404             branchcode   => $branch,
 405             rule_name    => 'maxonsiteissueqty',
 406         }
 407     );
 408
 409
 410     # if a rule is found and has a loan limit set, count
 411     # how many loans the patron already has that meet that
 412     # rule
 413     if (defined($maxissueqty_rule) and $maxissueqty_rule->rule_value ne '') {
 414         my @bind_params;
 415         my $count_query = q|
 416             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 417             FROM issues
 418             JOIN items USING (itemnumber)
 419         |;
 420
 421         my $rule_itemtype = $maxissueqty_rule->itemtype;
 422         unless ($rule_itemtype) {
 423             # matching rule has the default item type, so count only
 424             # those existing loans that don't fall under a more
 425             # specific rule
 426             if (C4::Context->preference('item-level_itypes')) {
 427                 $count_query .= " WHERE items.itype NOT IN (
 428                                     SELECT itemtype FROM circulation_rules
 429                                     WHERE branchcode = ?
 430                                     AND   (categorycode = ? OR categorycode = ?)
 431                                     AND   itemtype IS NOT NULL
 432                                     AND   rule_name = 'maxissueqty'
 433                                   ) ";
 434             } else {
 435                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 436                                   WHERE biblioitems.itemtype NOT IN (
 437                                     SELECT itemtype FROM circulation_rules
 438                                     WHERE branchcode = ?
 439                                     AND   (categorycode = ? OR categorycode = ?)
 440                                     AND   itemtype IS NOT NULL
 441                                     AND   rule_name = 'maxissueqty'
 442                                   ) ";
 443             }
 444             push @bind_params, $maxissueqty_rule->branchcode;
 445             push @bind_params, $maxissueqty_rule->categorycode;
 446             push @bind_params, $cat_borrower;
 447         } else {
 448             # rule has specific item type, so count loans of that
 449             # specific item type
 450             if (C4::Context->preference('item-level_itypes')) {
 451                 $count_query .= " WHERE items.itype = ? ";
 452             } else {
 453                 $count_query .= " JOIN  biblioitems USING (biblionumber)
 454                                   WHERE biblioitems.itemtype= ? ";
 455             }
 456             push @bind_params, $type;
 457         }
 458
 459         $count_query .= " AND borrowernumber = ? ";
 460         push @bind_params, $borrower->{'borrowernumber'};
 461         my $rule_branch = $maxissueqty_rule->branchcode;
 462         if ($rule_branch) {
 463             if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 464                 $count_query .= " AND issues.branchcode = ? ";
 465                 push @bind_params, $rule_branch;
 466             } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 467                 ; # if branch is the patron's home branch, then count all loans by patron
 468             } else {
 469                 $count_query .= " AND items.homebranch = ? ";
 470                 push @bind_params, $rule_branch;
 471             }
 472         }
 473
 474         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $count_query, {}, @bind_params );
 475
 476         my $max_checkouts_allowed = $maxissueqty_rule ? $maxissueqty_rule->rule_value : undef;
 477         my $max_onsite_checkouts_allowed = $maxonsiteissueqty_rule ? $maxonsiteissueqty_rule->rule_value : undef;
 478
 479         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 480             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 481                 return {
 482                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 483                     count => $onsite_checkout_count,
 484                     max_allowed => $max_onsite_checkouts_allowed,
 485                 }
 486             }
 487         }
 488         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 489             my $delta = $switch_onsite_checkout ? 1 : 0;
 490             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 491                 return {
 492                     reason => 'TOO_MANY_CHECKOUTS',
 493                     count => $checkout_count,
 494                     max_allowed => $max_checkouts_allowed,
 495                 };
 496             }
 497         } elsif ( not $onsite_checkout ) {
 498             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 499                 return {
 500                     reason => 'TOO_MANY_CHECKOUTS',
 501                     count => $checkout_count - $onsite_checkout_count,
 502                     max_allowed => $max_checkouts_allowed,
 503                 };
 504             }
 505         }
 506     }
 507
 508     # Now count total loans against the limit for the branch
 509     my $branch_borrower_circ_rule = GetBranchBorrowerCircRule($branch, $cat_borrower);
 510     if (defined($branch_borrower_circ_rule->{patron_maxissueqty}) and $branch_borrower_circ_rule->{patron_maxissueqty} ne '') {
 511         my @bind_params = ();
 512         my $branch_count_query = q|
 513             SELECT COUNT(*) AS total, COALESCE(SUM(onsite_checkout), 0) AS onsite_checkouts
 514             FROM issues
 515             JOIN items USING (itemnumber)
 516             WHERE borrowernumber = ?
 517         |;
 518         push @bind_params, $borrower->{borrowernumber};
 519
 520         if (C4::Context->preference('CircControl') eq 'PickupLibrary') {
 521             $branch_count_query .= " AND issues.branchcode = ? ";
 522             push @bind_params, $branch;
 523         } elsif (C4::Context->preference('CircControl') eq 'PatronLibrary') {
 524             ; # if branch is the patron's home branch, then count all loans by patron
 525         } else {
 526             $branch_count_query .= " AND items.homebranch = ? ";
 527             push @bind_params, $branch;
 528         }
 529         my ( $checkout_count, $onsite_checkout_count ) = $dbh->selectrow_array( $branch_count_query, {}, @bind_params );
 530         my $max_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxissueqty};
 531         my $max_onsite_checkouts_allowed = $branch_borrower_circ_rule->{patron_maxonsiteissueqty};
 532
 533         if ( $onsite_checkout and $max_onsite_checkouts_allowed ne '' ) {
 534             if ( $onsite_checkout_count >= $max_onsite_checkouts_allowed )  {
 535                 return {
 536                     reason => 'TOO_MANY_ONSITE_CHECKOUTS',
 537                     count => $onsite_checkout_count,
 538                     max_allowed => $max_onsite_checkouts_allowed,
 539                 }
 540             }
 541         }
 542         if ( C4::Context->preference('ConsiderOnSiteCheckoutsAsNormalCheckouts') ) {
 543             my $delta = $switch_onsite_checkout ? 1 : 0;
 544             if ( $checkout_count >= $max_checkouts_allowed + $delta ) {
 545                 return {
 546                     reason => 'TOO_MANY_CHECKOUTS',
 547                     count => $checkout_count,
 548                     max_allowed => $max_checkouts_allowed,
 549                 };
 550             }
 551         } elsif ( not $onsite_checkout ) {
 552             if ( $checkout_count - $onsite_checkout_count >= $max_checkouts_allowed )  {
 553                 return {
 554                     reason => 'TOO_MANY_CHECKOUTS',
 555                     count => $checkout_count - $onsite_checkout_count,
 556                     max_allowed => $max_checkouts_allowed,
 557                 };
 558             }
 559         }
 560     }
 561
 562     if ( not defined( $maxissueqty_rule ) and not defined($branch_borrower_circ_rule->{patron_maxissueqty}) ) {
 563         return { reason => 'NO_RULE_DEFINED', max_allowed => 0 };
 564     }
 565
 566     # OK, the patron can issue !!!
 567     return;
 568 }
 569
 570 =head2 CanBookBeIssued
 571
 572   ( $issuingimpossible, $needsconfirmation, [ $alerts ] ) =  CanBookBeIssued( $patron,
 573                       $barcode, $duedate, $inprocess, $ignore_reserves, $params );
 574
 575 Check if a book can be issued.
 576
 577 C<$issuingimpossible> and C<$needsconfirmation> are hashrefs.
 578
 579 IMPORTANT: The assumption by users of this routine is that causes blocking
 580 the issue are keyed by uppercase labels and other returned
 581 data is keyed in lower case!
 582
 583 =over 4
 584
 585 =item C<$patron> is a Koha::Patron
 586
 587 =item C<$barcode> is the bar code of the book being issued.
 588
 589 =item C<$duedates> is a DateTime object.
 590
 591 =item C<$inprocess> boolean switch
 592
 593 =item C<$ignore_reserves> boolean switch
 594
 595 =item C<$params> Hashref of additional parameters
 596
 597 Available keys:
 598     override_high_holds - Ignore high holds
 599     onsite_checkout     - Checkout is an onsite checkout that will not leave the library
 600
 601 =back
 602
 603 Returns :
 604
 605 =over 4
 606
 607 =item C<$issuingimpossible> a reference to a hash. It contains reasons why issuing is impossible.
 608 Possible values are :
 609
 610 =back
 611
 612 =head3 INVALID_DATE
 613
 614 sticky due date is invalid
 615
 616 =head3 GNA
 617
 618 borrower gone with no address
 619
 620 =head3 CARD_LOST
 621
 622 borrower declared it's card lost
 623
 624 =head3 DEBARRED
 625
 626 borrower debarred
 627
 628 =head3 UNKNOWN_BARCODE
 629
 630 barcode unknown
 631
 632 =head3 NOT_FOR_LOAN
 633
 634 item is not for loan
 635
 636 =head3 WTHDRAWN
 637
 638 item withdrawn.
 639
 640 =head3 RESTRICTED
 641
 642 item is restricted (set by ??)
 643
 644 C<$needsconfirmation> a reference to a hash. It contains reasons why the loan
 645 could be prevented, but ones that can be overriden by the operator.
 646
 647 Possible values are :
 648
 649 =head3 DEBT
 650
 651 borrower has debts.
 652
 653 =head3 RENEW_ISSUE
 654
 655 renewing, not issuing
 656
 657 =head3 ISSUED_TO_ANOTHER
 658
 659 issued to someone else.
 660
 661 =head3 RESERVED
 662
 663 reserved for someone else.
 664
 665 =head3 INVALID_DATE
 666
 667 sticky due date is invalid or due date in the past
 668
 669 =head3 TOO_MANY
 670
 671 if the borrower borrows to much things
 672
 673 =cut
 674
 675 sub CanBookBeIssued {
 676     my ( $patron, $barcode, $duedate, $inprocess, $ignore_reserves, $params ) = @_;
 677     my %needsconfirmation;    # filled with problems that needs confirmations
 678     my %issuingimpossible;    # filled with problems that causes the issue to be IMPOSSIBLE
 679     my %alerts;               # filled with messages that shouldn't stop issuing, but the librarian should be aware of.
 680     my %messages;             # filled with information messages that should be displayed.
 681
 682     my $onsite_checkout     = $params->{onsite_checkout}     || 0;
 683     my $override_high_holds = $params->{override_high_holds} || 0;
 684
 685     my $item_object = Koha::Items->find({barcode => $barcode });
 686
 687     # MANDATORY CHECKS - unless item exists, nothing else matters
 688     unless ( $item_object ) {
 689         $issuingimpossible{UNKNOWN_BARCODE} = 1;
 690     }
 691     return ( \%issuingimpossible, \%needsconfirmation ) if %issuingimpossible;
 692
 693     my $item_unblessed = $item_object->unblessed; # Transition...
 694     my $issue = $item_object->checkout;
 695     my $biblio = $item_object->biblio;
 696
 697     my $biblioitem = $biblio->biblioitem;
 698     my $effective_itemtype = $item_object->effective_itemtype;
 699     my $dbh             = C4::Context->dbh;
 700     my $patron_unblessed = $patron->unblessed;
 701
 702     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
 703     #
 704     # DUE DATE is OK ? -- should already have checked.
 705     #
 706     if ($duedate && ref $duedate ne 'DateTime') {
 707         $duedate = dt_from_string($duedate);
 708     }
 709     my $now = dt_from_string();
 710     unless ( $duedate ) {
 711         my $issuedate = $now->clone();
 712
 713         $duedate = CalcDateDue( $issuedate, $effective_itemtype, $circ_library->branchcode, $patron_unblessed );
 714
 715         # Offline circ calls AddIssue directly, doesn't run through here
 716         #  So issuingimpossible should be ok.
 717     }
 718
 719     my $fees = Koha::Charges::Fees->new(
 720         {
 721             patron    => $patron,
 722             library   => $circ_library,
 723             item      => $item_object,
 724             to_date   => $duedate,
 725         }
 726     );
 727
 728     if ($duedate) {
 729         my $today = $now->clone();
 730         $today->truncate( to => 'minute');
 731         if (DateTime->compare($duedate,$today) == -1 ) { # duedate cannot be before now
 732             $needsconfirmation{INVALID_DATE} = output_pref($duedate);
 733         }
 734     } else {
 735             $issuingimpossible{INVALID_DATE} = output_pref($duedate);
 736     }
 737
 738     #
 739     # BORROWER STATUS
 740     #
 741     if ( $patron->category->category_type eq 'X' && (  $item_object->barcode  )) {
 742         # stats only borrower -- add entry to statistics table, and return issuingimpossible{STATS} = 1  .
 743         &UpdateStats({
 744                      branch => C4::Context->userenv->{'branch'},
 745                      type => 'localuse',
 746                      itemnumber => $item_object->itemnumber,
 747                      itemtype => $effective_itemtype,
 748                      borrowernumber => $patron->borrowernumber,
 749                      ccode => $item_object->ccode}
 750                     );
 751         ModDateLastSeen( $item_object->itemnumber ); # FIXME Move to Koha::Item
 752         return( { STATS => 1 }, {});
 753     }
 754
 755     if ( $patron->gonenoaddress && $patron->gonenoaddress == 1 ) {
 756         $issuingimpossible{GNA} = 1;
 757     }
 758
 759     if ( $patron->lost && $patron->lost == 1 ) {
 760         $issuingimpossible{CARD_LOST} = 1;
 761     }
 762     if ( $patron->is_debarred ) {
 763         $issuingimpossible{DEBARRED} = 1;
 764     }
 765
 766     if ( $patron->is_expired ) {
 767         $issuingimpossible{EXPIRED} = 1;
 768     }
 769
 770     #
 771     # BORROWER STATUS
 772     #
 773
 774     # DEBTS
 775     my $account = $patron->account;
 776     my $balance = $account->balance;
 777     my $non_issues_charges = $account->non_issues_charges;
 778     my $other_charges = $balance - $non_issues_charges;
 779
 780     my $amountlimit = C4::Context->preference("noissuescharge");
 781     my $allowfineoverride = C4::Context->preference("AllowFineOverride");
 782     my $allfinesneedoverride = C4::Context->preference("AllFinesNeedOverride");
 783
 784     # Check the debt of this patrons guarantees
 785     my $no_issues_charge_guarantees = C4::Context->preference("NoIssuesChargeGuarantees");
 786     $no_issues_charge_guarantees = undef unless looks_like_number( $no_issues_charge_guarantees );
 787     if ( defined $no_issues_charge_guarantees ) {
 788         my @guarantees = map { $_->guarantee } $patron->guarantee_relationships();
 789         my $guarantees_non_issues_charges;
 790         foreach my $g ( @guarantees ) {
 791             $guarantees_non_issues_charges += $g->account->non_issues_charges;
 792         }
 793
 794         if ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && !$allowfineoverride) {
 795             $issuingimpossible{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 796         } elsif ( $guarantees_non_issues_charges > $no_issues_charge_guarantees && !$inprocess && $allowfineoverride) {
 797             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 798         } elsif ( $allfinesneedoverride && $guarantees_non_issues_charges > 0 && $guarantees_non_issues_charges <= $no_issues_charge_guarantees && !$inprocess ) {
 799             $needsconfirmation{DEBT_GUARANTEES} = $guarantees_non_issues_charges;
 800         }
 801     }
 802
 803     if ( C4::Context->preference("IssuingInProcess") ) {
 804         if ( $non_issues_charges > $amountlimit && !$inprocess && !$allowfineoverride) {
 805             $issuingimpossible{DEBT} = $non_issues_charges;
 806         } elsif ( $non_issues_charges > $amountlimit && !$inprocess && $allowfineoverride) {
 807             $needsconfirmation{DEBT} = $non_issues_charges;
 808         } elsif ( $allfinesneedoverride && $non_issues_charges > 0 && $non_issues_charges <= $amountlimit && !$inprocess ) {
 809             $needsconfirmation{DEBT} = $non_issues_charges;
 810         }
 811     }
 812     else {
 813         if ( $non_issues_charges > $amountlimit && $allowfineoverride ) {
 814             $needsconfirmation{DEBT} = $non_issues_charges;
 815         } elsif ( $non_issues_charges > $amountlimit && !$allowfineoverride) {
 816             $issuingimpossible{DEBT} = $non_issues_charges;
 817         } elsif ( $non_issues_charges > 0 && $allfinesneedoverride ) {
 818             $needsconfirmation{DEBT} = $non_issues_charges;
 819         }
 820     }
 821
 822     if ($balance > 0 && $other_charges > 0) {
 823         $alerts{OTHER_CHARGES} = sprintf( "%.2f", $other_charges );
 824     }
 825
 826     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 827     $patron_unblessed = $patron->unblessed;
 828
 829     if ( my $debarred_date = $patron->is_debarred ) {
 830          # patron has accrued fine days or has a restriction. $count is a date
 831         if ($debarred_date eq '9999-12-31') {
 832             $issuingimpossible{USERBLOCKEDNOENDDATE} = $debarred_date;
 833         }
 834         else {
 835             $issuingimpossible{USERBLOCKEDWITHENDDATE} = $debarred_date;
 836         }
 837     } elsif ( my $num_overdues = $patron->has_overdues ) {
 838         ## patron has outstanding overdue loans
 839         if ( C4::Context->preference("OverduesBlockCirc") eq 'block'){
 840             $issuingimpossible{USERBLOCKEDOVERDUE} = $num_overdues;
 841         }
 842         elsif ( C4::Context->preference("OverduesBlockCirc") eq 'confirmation'){
 843             $needsconfirmation{USERBLOCKEDOVERDUE} = $num_overdues;
 844         }
 845     }
 846
 847     #
 848     # CHECK IF BOOK ALREADY ISSUED TO THIS BORROWER
 849     #
 850     if ( $issue && $issue->borrowernumber eq $patron->borrowernumber ){
 851
 852         # Already issued to current borrower.
 853         # If it is an on-site checkout if it can be switched to a normal checkout
 854         # or ask whether the loan should be renewed
 855
 856         if ( $issue->onsite_checkout
 857                 and C4::Context->preference('SwitchOnSiteCheckouts') ) {
 858             $messages{ONSITE_CHECKOUT_WILL_BE_SWITCHED} = 1;
 859         } else {
 860             my ($CanBookBeRenewed,$renewerror) = CanBookBeRenewed(
 861                 $patron->borrowernumber,
 862                 $item_object->itemnumber,
 863             );
 864             if ( $CanBookBeRenewed == 0 ) {    # no more renewals allowed
 865                 if ( $renewerror eq 'onsite_checkout' ) {
 866                     $issuingimpossible{NO_RENEWAL_FOR_ONSITE_CHECKOUTS} = 1;
 867                 }
 868                 else {
 869                     $issuingimpossible{NO_MORE_RENEWALS} = 1;
 870                 }
 871             }
 872             else {
 873                 $needsconfirmation{RENEW_ISSUE} = 1;
 874             }
 875         }
 876     }
 877     elsif ( $issue ) {
 878
 879         # issued to someone else
 880
 881         my $patron = Koha::Patrons->find( $issue->borrowernumber );
 882
 883         my ( $can_be_returned, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
 884
 885         unless ( $can_be_returned ) {
 886             $issuingimpossible{RETURN_IMPOSSIBLE} = 1;
 887             $issuingimpossible{branch_to_return} = $message;
 888         } else {
 889             if ( C4::Context->preference('AutoReturnCheckedOutItems') ) {
 890                 $alerts{RETURNED_FROM_ANOTHER} = { patron => $patron };
 891             } else {
 892             $needsconfirmation{ISSUED_TO_ANOTHER} = 1;
 893             $needsconfirmation{issued_firstname} = $patron->firstname;
 894             $needsconfirmation{issued_surname} = $patron->surname;
 895             $needsconfirmation{issued_cardnumber} = $patron->cardnumber;
 896             $needsconfirmation{issued_borrowernumber} = $patron->borrowernumber;
 897             }
 898         }
 899     }
 900
 901     # JB34 CHECKS IF BORROWERS DON'T HAVE ISSUE TOO MANY BOOKS
 902     #
 903     my $switch_onsite_checkout = (
 904           C4::Context->preference('SwitchOnSiteCheckouts')
 905       and $issue
 906       and $issue->onsite_checkout
 907       and $issue->borrowernumber == $patron->borrowernumber ? 1 : 0 );
 908     my $toomany = TooMany( $patron_unblessed, $item_object, { onsite_checkout => $onsite_checkout, switch_onsite_checkout => $switch_onsite_checkout, } );
 909     # if TooMany max_allowed returns 0 the user doesn't have permission to check out this book
 910     if ( $toomany && not exists $needsconfirmation{RENEW_ISSUE} ) {
 911         if ( $toomany->{max_allowed} == 0 ) {
 912             $needsconfirmation{PATRON_CANT} = 1;
 913         }
 914         if ( C4::Context->preference("AllowTooManyOverride") ) {
 915             $needsconfirmation{TOO_MANY} = $toomany->{reason};
 916             $needsconfirmation{current_loan_count} = $toomany->{count};
 917             $needsconfirmation{max_loans_allowed} = $toomany->{max_allowed};
 918         } else {
 919             $issuingimpossible{TOO_MANY} = $toomany->{reason};
 920             $issuingimpossible{current_loan_count} = $toomany->{count};
 921             $issuingimpossible{max_loans_allowed} = $toomany->{max_allowed};
 922         }
 923     }
 924
 925     #
 926     # CHECKPREVCHECKOUT: CHECK IF ITEM HAS EVER BEEN LENT TO PATRON
 927     #
 928     $patron = Koha::Patrons->find( $patron->borrowernumber ); # FIXME Refetch just in case, to avoid regressions. But must not be needed
 929     my $wants_check = $patron->wants_check_for_previous_checkout;
 930     $needsconfirmation{PREVISSUE} = 1
 931         if ($wants_check and $patron->do_check_for_previous_checkout($item_unblessed));
 932
 933     #
 934     # ITEM CHECKING
 935     #
 936     if ( $item_object->notforloan )
 937     {
 938         if(!C4::Context->preference("AllowNotForLoanOverride")){
 939             $issuingimpossible{NOT_FOR_LOAN} = 1;
 940             $issuingimpossible{item_notforloan} = $item_object->notforloan;
 941         }else{
 942             $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 943             $needsconfirmation{item_notforloan} = $item_object->notforloan;
 944         }
 945     }
 946     else {
 947         # we have to check itemtypes.notforloan also
 948         if (C4::Context->preference('item-level_itypes')){
 949             # this should probably be a subroutine
 950             my $sth = $dbh->prepare("SELECT notforloan FROM itemtypes WHERE itemtype = ?");
 951             $sth->execute($effective_itemtype);
 952             my $notforloan=$sth->fetchrow_hashref();
 953             if ($notforloan->{'notforloan'}) {
 954                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 955                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 956                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 957                 } else {
 958                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 959                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 960                 }
 961             }
 962         }
 963         else {
 964             my $itemtype = Koha::ItemTypes->find($biblioitem->itemtype);
 965             if ( $itemtype && defined $itemtype->notforloan && $itemtype->notforloan == 1){
 966                 if (!C4::Context->preference("AllowNotForLoanOverride")) {
 967                     $issuingimpossible{NOT_FOR_LOAN} = 1;
 968                     $issuingimpossible{itemtype_notforloan} = $effective_itemtype;
 969                 } else {
 970                     $needsconfirmation{NOT_FOR_LOAN_FORCING} = 1;
 971                     $needsconfirmation{itemtype_notforloan} = $effective_itemtype;
 972                 }
 973             }
 974         }
 975     }
 976     if ( $item_object->withdrawn && $item_object->withdrawn > 0 )
 977     {
 978         $issuingimpossible{WTHDRAWN} = 1;
 979     }
 980     if (   $item_object->restricted
 981         && $item_object->restricted == 1 )
 982     {
 983         $issuingimpossible{RESTRICTED} = 1;
 984     }
 985     if ( $item_object->itemlost && C4::Context->preference("IssueLostItem") ne 'nothing' ) {
 986         my $av = Koha::AuthorisedValues->search({ category => 'LOST', authorised_value => $item_object->itemlost });
 987         my $code = $av->count ? $av->next->lib : '';
 988         $needsconfirmation{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'confirm' );
 989         $alerts{ITEM_LOST} = $code if ( C4::Context->preference("IssueLostItem") eq 'alert' );
 990     }
 991     if ( C4::Context->preference("IndependentBranches") ) {
 992         my $userenv = C4::Context->userenv;
 993         unless ( C4::Context->IsSuperLibrarian() ) {
 994             my $HomeOrHoldingBranch = C4::Context->preference("HomeOrHoldingBranch");
 995             if ( $item_object->$HomeOrHoldingBranch ne $userenv->{branch} ){
 996                 $issuingimpossible{ITEMNOTSAMEBRANCH} = 1;
 997                 $issuingimpossible{'itemhomebranch'} = $item_object->$HomeOrHoldingBranch;
 998             }
 999             $needsconfirmation{BORRNOTSAMEBRANCH} = $patron->branchcode
1000               if ( $patron->branchcode ne $userenv->{branch} );
1001         }
1002     }
1003
1004     #
1005     # CHECK IF THERE IS RENTAL CHARGES. RENTAL MUST BE CONFIRMED BY THE BORROWER
1006     #
1007     my $rentalConfirmation = C4::Context->preference("RentalFeesCheckoutConfirmation");
1008     if ($rentalConfirmation) {
1009         my ($rentalCharge) = GetIssuingCharges( $item_object->itemnumber, $patron->borrowernumber );
1010
1011         my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1012         if ($itemtype_object) {
1013             my $accumulate_charge = $fees->accumulate_rentalcharge();
1014             if ( $accumulate_charge > 0 ) {
1015                 $rentalCharge += $accumulate_charge;
1016             }
1017         }
1018
1019         if ( $rentalCharge > 0 ) {
1020             $needsconfirmation{RENTALCHARGE} = $rentalCharge;
1021         }
1022     }
1023
1024     unless ( $ignore_reserves ) {
1025         # See if the item is on reserve.
1026         my ( $restype, $res ) = C4::Reserves::CheckReserves( $item_object->itemnumber );
1027         if ($restype) {
1028             my $resbor = $res->{'borrowernumber'};
1029             if ( $resbor ne $patron->borrowernumber ) {
1030                 my $patron = Koha::Patrons->find( $resbor );
1031                 if ( $restype eq "Waiting" )
1032                 {
1033                     # The item is on reserve and waiting, but has been
1034                     # reserved by some other patron.
1035                     $needsconfirmation{RESERVE_WAITING} = 1;
1036                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1037                     $needsconfirmation{'ressurname'} = $patron->surname;
1038                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1039                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1040                     $needsconfirmation{'resbranchcode'} = $res->{branchcode};
1041                     $needsconfirmation{'reswaitingdate'} = $res->{'waitingdate'};
1042                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1043                 }
1044                 elsif ( $restype eq "Reserved" ) {
1045                     # The item is on reserve for someone else.
1046                     $needsconfirmation{RESERVED} = 1;
1047                     $needsconfirmation{'resfirstname'} = $patron->firstname;
1048                     $needsconfirmation{'ressurname'} = $patron->surname;
1049                     $needsconfirmation{'rescardnumber'} = $patron->cardnumber;
1050                     $needsconfirmation{'resborrowernumber'} = $patron->borrowernumber;
1051                     $needsconfirmation{'resbranchcode'} = $patron->branchcode;
1052                     $needsconfirmation{'resreservedate'} = $res->{reservedate};
1053                     $needsconfirmation{'reserve_id'} = $res->{reserve_id};
1054                 }
1055             }
1056         }
1057     }
1058
1059     ## CHECK AGE RESTRICTION
1060     my $agerestriction  = $biblioitem->agerestriction;
1061     my ($restriction_age, $daysToAgeRestriction) = GetAgeRestriction( $agerestriction, $patron->unblessed );
1062     if ( $daysToAgeRestriction && $daysToAgeRestriction > 0 ) {
1063         if ( C4::Context->preference('AgeRestrictionOverride') ) {
1064             $needsconfirmation{AGE_RESTRICTION} = "$agerestriction";
1065         }
1066         else {
1067             $issuingimpossible{AGE_RESTRICTION} = "$agerestriction";
1068         }
1069     }
1070
1071     ## check for high holds decreasing loan period
1072     if ( C4::Context->preference('decreaseLoanHighHolds') ) {
1073         my $check = checkHighHolds( $item_unblessed, $patron_unblessed );
1074
1075         if ( $check->{exceeded} ) {
1076             if ($override_high_holds) {
1077                 $alerts{HIGHHOLDS} = {
1078                     num_holds  => $check->{outstanding},
1079                     duration   => $check->{duration},
1080                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1081                 };
1082             }
1083             else {
1084                 $needsconfirmation{HIGHHOLDS} = {
1085                     num_holds  => $check->{outstanding},
1086                     duration   => $check->{duration},
1087                     returndate => output_pref( { dt => dt_from_string($check->{due_date}), dateformat => 'iso', timeformat => '24hr' }),
1088                 };
1089             }
1090         }
1091     }
1092
1093     if (
1094         !C4::Context->preference('AllowMultipleIssuesOnABiblio') &&
1095         # don't do the multiple loans per bib check if we've
1096         # already determined that we've got a loan on the same item
1097         !$issuingimpossible{NO_MORE_RENEWALS} &&
1098         !$needsconfirmation{RENEW_ISSUE}
1099     ) {
1100         # Check if borrower has already issued an item from the same biblio
1101         # Only if it's not a subscription
1102         my $biblionumber = $item_object->biblionumber;
1103         require C4::Serials;
1104         my $is_a_subscription = C4::Serials::CountSubscriptionFromBiblionumber($biblionumber);
1105         unless ($is_a_subscription) {
1106             # FIXME Should be $patron->checkouts($args);
1107             my $checkouts = Koha::Checkouts->search(
1108                 {
1109                     borrowernumber => $patron->borrowernumber,
1110                     biblionumber   => $biblionumber,
1111                 },
1112                 {
1113                     join => 'item',
1114                 }
1115             );
1116             # if we get here, we don't already have a loan on this item,
1117             # so if there are any loans on this bib, ask for confirmation
1118             if ( $checkouts->count ) {
1119                 $needsconfirmation{BIBLIO_ALREADY_ISSUED} = 1;
1120             }
1121         }
1122     }
1123
1124     return ( \%issuingimpossible, \%needsconfirmation, \%alerts, \%messages, );
1125 }
1126
1127 =head2 CanBookBeReturned
1128
1129   ($returnallowed, $message) = CanBookBeReturned($item, $branch)
1130
1131 Check whether the item can be returned to the provided branch
1132
1133 =over 4
1134
1135 =item C<$item> is a hash of item information as returned Koha::Items->find->unblessed (Temporary, should be a Koha::Item instead)
1136
1137 =item C<$branch> is the branchcode where the return is taking place
1138
1139 =back
1140
1141 Returns:
1142
1143 =over 4
1144
1145 =item C<$returnallowed> is 0 or 1, corresponding to whether the return is allowed (1) or not (0)
1146
1147 =item C<$message> is the branchcode where the item SHOULD be returned, if the return is not allowed
1148
1149 =back
1150
1151 =cut
1152
1153 sub CanBookBeReturned {
1154   my ($item, $branch) = @_;
1155   my $allowreturntobranch = C4::Context->preference("AllowReturnToBranch") || 'anywhere';
1156
1157   # assume return is allowed to start
1158   my $allowed = 1;
1159   my $message;
1160
1161   # identify all cases where return is forbidden
1162   if ($allowreturntobranch eq 'homebranch' && $branch ne $item->{'homebranch'}) {
1163      $allowed = 0;
1164      $message = $item->{'homebranch'};
1165   } elsif ($allowreturntobranch eq 'holdingbranch' && $branch ne $item->{'holdingbranch'}) {
1166      $allowed = 0;
1167      $message = $item->{'holdingbranch'};
1168   } elsif ($allowreturntobranch eq 'homeorholdingbranch' && $branch ne $item->{'homebranch'} && $branch ne $item->{'holdingbranch'}) {
1169      $allowed = 0;
1170      $message = $item->{'homebranch'}; # FIXME: choice of homebranch is arbitrary
1171   }
1172
1173   return ($allowed, $message);
1174 }
1175
1176 =head2 CheckHighHolds
1177
1178     used when syspref decreaseLoanHighHolds is active. Returns 1 or 0 to define whether the minimum value held in
1179     decreaseLoanHighHoldsValue is exceeded, the total number of outstanding holds, the number of days the loan
1180     has been decreased to (held in syspref decreaseLoanHighHoldsValue), and the new due date
1181
1182 =cut
1183
1184 sub checkHighHolds {
1185     my ( $item, $borrower ) = @_;
1186     my $branchcode = _GetCircControlBranch( $item, $borrower );
1187     my $item_object = Koha::Items->find( $item->{itemnumber} );
1188
1189     my $return_data = {
1190         exceeded    => 0,
1191         outstanding => 0,
1192         duration    => 0,
1193         due_date    => undef,
1194     };
1195
1196     my $holds = Koha::Holds->search( { biblionumber => $item->{'biblionumber'} } );
1197
1198     if ( $holds->count() ) {
1199         $return_data->{outstanding} = $holds->count();
1200
1201         my $decreaseLoanHighHoldsControl        = C4::Context->preference('decreaseLoanHighHoldsControl');
1202         my $decreaseLoanHighHoldsValue          = C4::Context->preference('decreaseLoanHighHoldsValue');
1203         my $decreaseLoanHighHoldsIgnoreStatuses = C4::Context->preference('decreaseLoanHighHoldsIgnoreStatuses');
1204
1205         my @decreaseLoanHighHoldsIgnoreStatuses = split( /,/, $decreaseLoanHighHoldsIgnoreStatuses );
1206
1207         if ( $decreaseLoanHighHoldsControl eq 'static' ) {
1208
1209             # static means just more than a given number of holds on the record
1210
1211             # If the number of holds is less than the threshold, we can stop here
1212             if ( $holds->count() < $decreaseLoanHighHoldsValue ) {
1213                 return $return_data;
1214             }
1215         }
1216         elsif ( $decreaseLoanHighHoldsControl eq 'dynamic' ) {
1217
1218             # dynamic means X more than the number of holdable items on the record
1219
1220             # let's get the items
1221             my @items = $holds->next()->biblio()->items()->as_list;
1222
1223             # Remove any items with status defined to be ignored even if the would not make item unholdable
1224             foreach my $status (@decreaseLoanHighHoldsIgnoreStatuses) {
1225                 @items = grep { !$_->$status } @items;
1226             }
1227
1228             # Remove any items that are not holdable for this patron
1229             @items = grep { CanItemBeReserved( $borrower->{borrowernumber}, $_->itemnumber, undef, { ignore_found_holds => 1 } )->{status} eq 'OK' } @items;
1230
1231             my $items_count = scalar @items;
1232
1233             my $threshold = $items_count + $decreaseLoanHighHoldsValue;
1234
1235             # If the number of holds is less than the count of items we have
1236             # plus the number of holds allowed above that count, we can stop here
1237             if ( $holds->count() <= $threshold ) {
1238                 return $return_data;
1239             }
1240         }
1241
1242         my $issuedate = dt_from_string();
1243
1244         my $itype = $item_object->effective_itemtype;
1245         my $daysmode = Koha::CirculationRules->get_effective_daysmode(
1246             {
1247                 categorycode => $borrower->{categorycode},
1248                 itemtype     => $itype,
1249                 branchcode   => $branchcode,
1250             }
1251         );
1252         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => $daysmode );
1253
1254         my $orig_due = C4::Circulation::CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1255
1256         my $decreaseLoanHighHoldsDuration = C4::Context->preference('decreaseLoanHighHoldsDuration');
1257
1258         my $reduced_datedue = $calendar->addDate( $issuedate, $decreaseLoanHighHoldsDuration );
1259         $reduced_datedue->set_hour($orig_due->hour);
1260         $reduced_datedue->set_minute($orig_due->minute);
1261         $reduced_datedue->truncate( to => 'minute' );
1262
1263         if ( DateTime->compare( $reduced_datedue, $orig_due ) == -1 ) {
1264             $return_data->{exceeded} = 1;
1265             $return_data->{duration} = $decreaseLoanHighHoldsDuration;
1266             $return_data->{due_date} = $reduced_datedue;
1267         }
1268     }
1269
1270     return $return_data;
1271 }
1272
1273 =head2 AddIssue
1274
1275   &AddIssue($borrower, $barcode, [$datedue], [$cancelreserve], [$issuedate])
1276
1277 Issue a book. Does no check, they are done in CanBookBeIssued. If we reach this sub, it means the user confirmed if needed.
1278
1279 =over 4
1280
1281 =item C<$borrower> is a hash with borrower informations (from Koha::Patron->unblessed).
1282
1283 =item C<$barcode> is the barcode of the item being issued.
1284
1285 =item C<$datedue> is a DateTime object for the max date of return, i.e. the date due (optional).
1286 Calculated if empty.
1287
1288 =item C<$cancelreserve> is 1 to override and cancel any pending reserves for the item (optional).
1289
1290 =item C<$issuedate> is the date to issue the item in iso (YYYY-MM-DD) format (optional).
1291 Defaults to today.  Unlike C<$datedue>, NOT a DateTime object, unfortunately.
1292
1293 AddIssue does the following things :
1294
1295   - step 01: check that there is a borrowernumber & a barcode provided
1296   - check for RENEWAL (book issued & being issued to the same patron)
1297       - renewal YES = Calculate Charge & renew
1298       - renewal NO  =
1299           * BOOK ACTUALLY ISSUED ? do a return if book is actually issued (but to someone else)
1300           * RESERVE PLACED ?
1301               - fill reserve if reserve to this patron
1302               - cancel reserve or not, otherwise
1303           * TRANSFERT PENDING ?
1304               - complete the transfert
1305           * ISSUE THE BOOK
1306
1307 =back
1308
1309 =cut
1310
1311 sub AddIssue {
1312     my ( $borrower, $barcode, $datedue, $cancelreserve, $issuedate, $sipmode, $params ) = @_;
1313
1314     my $onsite_checkout = $params && $params->{onsite_checkout} ? 1 : 0;
1315     my $switch_onsite_checkout = $params && $params->{switch_onsite_checkout};
1316     my $auto_renew = $params && $params->{auto_renew};
1317     my $dbh          = C4::Context->dbh;
1318     my $barcodecheck = CheckValidBarcode($barcode);
1319
1320     my $issue;
1321
1322     if ( $datedue && ref $datedue ne 'DateTime' ) {
1323         $datedue = dt_from_string($datedue);
1324     }
1325
1326     # $issuedate defaults to today.
1327     if ( !defined $issuedate ) {
1328         $issuedate = dt_from_string();
1329     }
1330     else {
1331         if ( ref $issuedate ne 'DateTime' ) {
1332             $issuedate = dt_from_string($issuedate);
1333
1334         }
1335     }
1336
1337     # Stop here if the patron or barcode doesn't exist
1338     if ( $borrower && $barcode && $barcodecheck ) {
1339         # find which item we issue
1340         my $item_object = Koha::Items->find({ barcode => $barcode })
1341           or return;    # if we don't get an Item, abort.
1342         my $item_unblessed = $item_object->unblessed;
1343
1344         my $branchcode = _GetCircControlBranch( $item_unblessed, $borrower );
1345
1346         # get actual issuing if there is one
1347         my $actualissue = $item_object->checkout;
1348
1349         # check if we just renew the issue.
1350         if ( $actualissue and $actualissue->borrowernumber eq $borrower->{'borrowernumber'}
1351                 and not $switch_onsite_checkout ) {
1352             $datedue = AddRenewal(
1353                 $borrower->{'borrowernumber'},
1354                 $item_object->itemnumber,
1355                 $branchcode,
1356                 $datedue,
1357                 $issuedate,    # here interpreted as the renewal date
1358             );
1359         }
1360         else {
1361             unless ($datedue) {
1362                 my $itype = $item_object->effective_itemtype;
1363                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1364
1365             }
1366             $datedue->truncate( to => 'minute' );
1367
1368             my $patron = Koha::Patrons->find( $borrower );
1369             my $library = Koha::Libraries->find( $branchcode );
1370             my $fees = Koha::Charges::Fees->new(
1371                 {
1372                     patron    => $patron,
1373                     library   => $library,
1374                     item      => $item_object,
1375                     to_date   => $datedue,
1376                 }
1377             );
1378
1379             # it's NOT a renewal
1380             if ( $actualissue and not $switch_onsite_checkout ) {
1381                 # This book is currently on loan, but not to the person
1382                 # who wants to borrow it now. mark it returned before issuing to the new borrower
1383                 my ( $allowed, $message ) = CanBookBeReturned( $item_unblessed, C4::Context->userenv->{branch} );
1384                 return unless $allowed;
1385                 AddReturn( $item_object->barcode, C4::Context->userenv->{'branch'} );
1386             }
1387
1388             C4::Reserves::MoveReserve( $item_object->itemnumber, $borrower->{'borrowernumber'}, $cancelreserve );
1389
1390             # Starting process for transfer job (checking transfert and validate it if we have one)
1391             my ($datesent) = GetTransfers( $item_object->itemnumber );
1392             if ($datesent) {
1393                 # updating line of branchtranfert to finish it, and changing the to branch value, implement a comment for visibility of this case (maybe for stats ....)
1394                 my $sth = $dbh->prepare(
1395                     "UPDATE branchtransfers
1396                         SET datearrived = now(),
1397                         tobranch = ?,
1398                         comments = 'Forced branchtransfer'
1399                     WHERE itemnumber= ? AND datearrived IS NULL"
1400                 );
1401                 $sth->execute( C4::Context->userenv->{'branch'},
1402                     $item_object->itemnumber );
1403             }
1404
1405             # If automatic renewal wasn't selected while issuing, set the value according to the issuing rule.
1406             unless ($auto_renew) {
1407                 my $rule = Koha::CirculationRules->get_effective_rule(
1408                     {
1409                         categorycode => $borrower->{categorycode},
1410                         itemtype     => $item_object->effective_itemtype,
1411                         branchcode   => $branchcode,
1412                         rule_name    => 'auto_renew'
1413                     }
1414                 );
1415
1416                 $auto_renew = $rule->rule_value if $rule;
1417             }
1418
1419             # Record in the database the fact that the book was issued.
1420             unless ($datedue) {
1421                 my $itype = $item_object->effective_itemtype;
1422                 $datedue = CalcDateDue( $issuedate, $itype, $branchcode, $borrower );
1423
1424             }
1425             $datedue->truncate( to => 'minute' );
1426
1427             my $issue_attributes = {
1428                 borrowernumber  => $borrower->{'borrowernumber'},
1429                 issuedate       => $issuedate->strftime('%Y-%m-%d %H:%M:%S'),
1430                 date_due        => $datedue->strftime('%Y-%m-%d %H:%M:%S'),
1431                 branchcode      => C4::Context->userenv->{'branch'},
1432                 onsite_checkout => $onsite_checkout,
1433                 auto_renew      => $auto_renew ? 1 : 0,
1434             };
1435
1436             $issue = Koha::Checkouts->find( { itemnumber => $item_object->itemnumber } );
1437             if ($issue) {
1438                 $issue->set($issue_attributes)->store;
1439             }
1440             else {
1441                 $issue = Koha::Checkout->new(
1442                     {
1443                         itemnumber => $item_object->itemnumber,
1444                         %$issue_attributes,
1445                     }
1446                 )->store;
1447             }
1448             if ( $item_object->location && $item_object->location eq 'CART'
1449                 && ( !$item_object->permanent_location || $item_object->permanent_location ne 'CART' ) ) {
1450             ## Item was moved to cart via UpdateItemLocationOnCheckin, anything issued should be taken off the cart.
1451                 CartToShelf( $item_object->itemnumber );
1452             }
1453
1454             if ( C4::Context->preference('UpdateTotalIssuesOnCirc') ) {
1455                 UpdateTotalIssues( $item_object->biblionumber, 1 );
1456             }
1457
1458             ## If item was lost, it has now been found, reverse any list item charges if necessary.
1459             if ( $item_object->itemlost ) {
1460                 my $refund = 1;
1461                 my $no_refund_after_days = C4::Context->preference('NoRefundOnLostReturnedItemsAge');
1462                 if ($no_refund_after_days) {
1463                     my $today = dt_from_string();
1464                     my $lost_age_in_days =
1465                       dt_from_string( $item_object->itemlost_on )
1466                       ->delta_days($today)
1467                       ->in_units('days');
1468
1469                     $refund = 0 unless ( $lost_age_in_days < $no_refund_after_days );
1470                 }
1471
1472                 if (
1473                     $refund
1474                     && Koha::RefundLostItemFeeRules->should_refund(
1475                         {
1476                             current_branch   => C4::Context->userenv->{branch},
1477                             item_home_branch => $item_object->homebranch,
1478                             item_holding_branch => $item_object->holdingbranch,
1479                         }
1480                     )
1481                   )
1482                 {
1483                     _FixAccountForLostAndFound( $item_object->itemnumber, undef,
1484                         $item_object->barcode );
1485                 }
1486             }
1487
1488             $item_object->issues( ( $item_object->issues || 0 ) + 1);
1489             $item_object->holdingbranch(C4::Context->userenv->{'branch'});
1490             $item_object->itemlost(0);
1491             $item_object->onloan($datedue->ymd());
1492             $item_object->datelastborrowed( dt_from_string()->ymd() );
1493             $item_object->store({log_action => 0});
1494             ModDateLastSeen( $item_object->itemnumber );
1495
1496             # If it costs to borrow this book, charge it to the patron's account.
1497             my ( $charge, $itemtype ) = GetIssuingCharges( $item_object->itemnumber, $borrower->{'borrowernumber'} );
1498             if ( $charge && $charge > 0 ) {
1499                 AddIssuingCharge( $issue, $charge, 'RENT' );
1500             }
1501
1502             my $itemtype_object = Koha::ItemTypes->find( $item_object->effective_itemtype );
1503             if ( $itemtype_object ) {
1504                 my $accumulate_charge = $fees->accumulate_rentalcharge();
1505                 if ( $accumulate_charge > 0 ) {
1506                     AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY' );
1507                     $charge += $accumulate_charge;
1508                     $item_unblessed->{charge} = $charge;
1509                 }
1510             }
1511
1512             # Record the fact that this book was issued.
1513             &UpdateStats(
1514                 {
1515                     branch => C4::Context->userenv->{'branch'},
1516                     type => ( $onsite_checkout ? 'onsite_checkout' : 'issue' ),
1517                     amount         => $charge,
1518                     other          => ( $sipmode ? "SIP-$sipmode" : '' ),
1519                     itemnumber     => $item_object->itemnumber,
1520                     itemtype       => $item_object->effective_itemtype,
1521                     location       => $item_object->location,
1522                     borrowernumber => $borrower->{'borrowernumber'},
1523                     ccode          => $item_object->ccode,
1524                 }
1525             );
1526
1527             # Send a checkout slip.
1528             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
1529             my %conditions        = (
1530                 branchcode   => $branchcode,
1531                 categorycode => $borrower->{categorycode},
1532                 item_type    => $item_object->effective_itemtype,
1533                 notification => 'CHECKOUT',
1534             );
1535             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
1536                 SendCirculationAlert(
1537                     {
1538                         type     => 'CHECKOUT',
1539                         item     => $item_object->unblessed,
1540                         borrower => $borrower,
1541                         branch   => $branchcode,
1542                     }
1543                 );
1544             }
1545             logaction(
1546                 "CIRCULATION", "ISSUE",
1547                 $borrower->{'borrowernumber'},
1548                 $item_object->itemnumber,
1549             ) if C4::Context->preference("IssueLog");
1550         }
1551     }
1552     return $issue;
1553 }
1554
1555 =head2 GetLoanLength
1556
1557   my $loanlength = &GetLoanLength($borrowertype,$itemtype,branchcode)
1558
1559 Get loan length for an itemtype, a borrower type and a branch
1560
1561 =cut
1562
1563 sub GetLoanLength {
1564     my ( $categorycode, $itemtype, $branchcode ) = @_;
1565
1566     # Set search precedences
1567     my @params = (
1568         {
1569             categorycode => $categorycode,
1570             itemtype     => $itemtype,
1571             branchcode   => $branchcode,
1572         },
1573         {
1574             categorycode => $categorycode,
1575             itemtype     => undef,
1576             branchcode   => $branchcode,
1577         },
1578         {
1579             categorycode => undef,
1580             itemtype     => $itemtype,
1581             branchcode   => $branchcode,
1582         },
1583         {
1584             categorycode => undef,
1585             itemtype     => undef,
1586             branchcode   => $branchcode,
1587         },
1588         {
1589             categorycode => $categorycode,
1590             itemtype     => $itemtype,
1591             branchcode   => undef,
1592         },
1593         {
1594             categorycode => $categorycode,
1595             itemtype     => undef,
1596             branchcode   => undef,
1597         },
1598         {
1599             categorycode => undef,
1600             itemtype     => $itemtype,
1601             branchcode   => undef,
1602         },
1603         {
1604             categorycode => undef,
1605             itemtype     => undef,
1606             branchcode   => undef,
1607         },
1608     );
1609
1610     # Initialize default values
1611     my $rules = {
1612         issuelength   => 0,
1613         renewalperiod => 0,
1614         lengthunit    => 'days',
1615     };
1616
1617     # Search for rules!
1618     foreach my $rule_name (qw( issuelength renewalperiod lengthunit )) {
1619         foreach my $params (@params) {
1620             my $rule = Koha::CirculationRules->search(
1621                 {
1622                     rule_name => $rule_name,
1623                     %$params,
1624                 }
1625             )->next();
1626
1627             if ($rule) {
1628                 $rules->{$rule_name} = $rule->rule_value;
1629                 last;
1630             }
1631         }
1632     }
1633
1634     return $rules;
1635 }
1636
1637
1638 =head2 GetHardDueDate
1639
1640   my ($hardduedate,$hardduedatecompare) = &GetHardDueDate($borrowertype,$itemtype,branchcode)
1641
1642 Get the Hard Due Date and it's comparison for an itemtype, a borrower type and a branch
1643
1644 =cut
1645
1646 sub GetHardDueDate {
1647     my ( $borrowertype, $itemtype, $branchcode ) = @_;
1648
1649     my $rules = Koha::CirculationRules->get_effective_rules(
1650         {
1651             categorycode => $borrowertype,
1652             itemtype     => $itemtype,
1653             branchcode   => $branchcode,
1654             rules        => [ 'hardduedate', 'hardduedatecompare' ],
1655         }
1656     );
1657
1658     if ( defined( $rules->{hardduedate} ) ) {
1659         if ( $rules->{hardduedate} ) {
1660             return ( dt_from_string( $rules->{hardduedate}, 'iso' ), $rules->{hardduedatecompare} );
1661         }
1662         else {
1663             return ( undef, undef );
1664         }
1665     }
1666 }
1667
1668 =head2 GetBranchBorrowerCircRule
1669
1670   my $branch_cat_rule = GetBranchBorrowerCircRule($branchcode, $categorycode);
1671
1672 Retrieves circulation rule attributes that apply to the given
1673 branch and patron category, regardless of item type.
1674 The return value is a hashref containing the following key:
1675
1676 patron_maxissueqty - maximum number of loans that a
1677 patron of the given category can have at the given
1678 branch.  If the value is undef, no limit.
1679
1680 patron_maxonsiteissueqty - maximum of on-site checkouts that a
1681 patron of the given category can have at the given
1682 branch.  If the value is undef, no limit.
1683
1684 This will check for different branch/category combinations in the following order:
1685 branch and category
1686 branch only
1687 category only
1688 default branch and category
1689
1690 If no rule has been found in the database, it will default to
1691 the buillt in rule:
1692
1693 patron_maxissueqty - undef
1694 patron_maxonsiteissueqty - undef
1695
1696 C<$branchcode> and C<$categorycode> should contain the
1697 literal branch code and patron category code, respectively - no
1698 wildcards.
1699
1700 =cut
1701
1702 sub GetBranchBorrowerCircRule {
1703     my ( $branchcode, $categorycode ) = @_;
1704
1705     # Initialize default values
1706     my $rules = {
1707         patron_maxissueqty       => undef,
1708         patron_maxonsiteissueqty => undef,
1709     };
1710
1711     # Search for rules!
1712     foreach my $rule_name (qw( patron_maxissueqty patron_maxonsiteissueqty )) {
1713         my $rule = Koha::CirculationRules->get_effective_rule(
1714             {
1715                 categorycode => $categorycode,
1716                 itemtype     => undef,
1717                 branchcode   => $branchcode,
1718                 rule_name    => $rule_name,
1719             }
1720         );
1721
1722         $rules->{$rule_name} = $rule->rule_value if defined $rule;
1723     }
1724
1725     return $rules;
1726 }
1727
1728 =head2 GetBranchItemRule
1729
1730   my $branch_item_rule = GetBranchItemRule($branchcode, $itemtype);
1731
1732 Retrieves circulation rule attributes that apply to the given
1733 branch and item type, regardless of patron category.
1734
1735 The return value is a hashref containing the following keys:
1736
1737 holdallowed => Hold policy for this branch and itemtype. Possible values:
1738   0: No holds allowed.
1739   1: Holds allowed only by patrons that have the same homebranch as the item.
1740   2: Holds allowed from any patron.
1741
1742 returnbranch => branch to which to return item.  Possible values:
1743   noreturn: do not return, let item remain where checked in (floating collections)
1744   homebranch: return to item's home branch
1745   holdingbranch: return to issuer branch
1746
1747 This searches branchitemrules in the following order:
1748
1749   * Same branchcode and itemtype
1750   * Same branchcode, itemtype '*'
1751   * branchcode '*', same itemtype
1752   * branchcode and itemtype '*'
1753
1754 Neither C<$branchcode> nor C<$itemtype> should be '*'.
1755
1756 =cut
1757
1758 sub GetBranchItemRule {
1759     my ( $branchcode, $itemtype ) = @_;
1760
1761     # Search for rules!
1762     my $holdallowed_rule = Koha::CirculationRules->get_effective_rule(
1763         {
1764             branchcode => $branchcode,
1765             itemtype => $itemtype,
1766             rule_name => 'holdallowed',
1767         }
1768     );
1769     my $hold_fulfillment_policy_rule = Koha::CirculationRules->get_effective_rule(
1770         {
1771             branchcode => $branchcode,
1772             itemtype => $itemtype,
1773             rule_name => 'hold_fulfillment_policy',
1774         }
1775     );
1776     my $returnbranch_rule = Koha::CirculationRules->get_effective_rule(
1777         {
1778             branchcode => $branchcode,
1779             itemtype => $itemtype,
1780             rule_name => 'returnbranch',
1781         }
1782     );
1783
1784     # built-in default circulation rule
1785     my $rules;
1786     $rules->{holdallowed} = defined $holdallowed_rule
1787         ? $holdallowed_rule->rule_value
1788         : 2;
1789     $rules->{hold_fulfillment_policy} = defined $hold_fulfillment_policy_rule
1790         ? $hold_fulfillment_policy_rule->rule_value
1791         : 'any';
1792     $rules->{returnbranch} = defined $returnbranch_rule
1793         ? $returnbranch_rule->rule_value
1794         : 'homebranch';
1795
1796     return $rules;
1797 }
1798
1799 =head2 AddReturn
1800
1801   ($doreturn, $messages, $iteminformation, $borrower) =
1802       &AddReturn( $barcode, $branch [,$exemptfine] [,$returndate] );
1803
1804 Returns a book.
1805
1806 =over 4
1807
1808 =item C<$barcode> is the bar code of the book being returned.
1809
1810 =item C<$branch> is the code of the branch where the book is being returned.
1811
1812 =item C<$exemptfine> indicates that overdue charges for the item will be
1813 removed. Optional.
1814
1815 =item C<$return_date> allows the default return date to be overridden
1816 by the given return date. Optional.
1817
1818 =back
1819
1820 C<&AddReturn> returns a list of four items:
1821
1822 C<$doreturn> is true iff the return succeeded.
1823
1824 C<$messages> is a reference-to-hash giving feedback on the operation.
1825 The keys of the hash are:
1826
1827 =over 4
1828
1829 =item C<BadBarcode>
1830
1831 No item with this barcode exists. The value is C<$barcode>.
1832
1833 =item C<NotIssued>
1834
1835 The book is not currently on loan. The value is C<$barcode>.
1836
1837 =item C<withdrawn>
1838
1839 This book has been withdrawn/cancelled. The value should be ignored.
1840
1841 =item C<Wrongbranch>
1842
1843 This book has was returned to the wrong branch.  The value is a hashref
1844 so that C<$messages->{Wrongbranch}->{Wrongbranch}> and C<$messages->{Wrongbranch}->{Rightbranch}>
1845 contain the branchcode of the incorrect and correct return library, respectively.
1846
1847 =item C<ResFound>
1848
1849 The item was reserved. The value is a reference-to-hash whose keys are
1850 fields from the reserves table of the Koha database, and
1851 C<biblioitemnumber>. It also has the key C<ResFound>, whose value is
1852 either C<Waiting>, C<Reserved>, or 0.
1853
1854 =item C<WasReturned>
1855
1856 Value 1 if return is successful.
1857
1858 =item C<NeedsTransfer>
1859
1860 If AutomaticItemReturn is disabled, return branch is given as value of NeedsTransfer.
1861
1862 =back
1863
1864 C<$iteminformation> is a reference-to-hash, giving information about the
1865 returned item from the issues table.
1866
1867 C<$borrower> is a reference-to-hash, giving information about the
1868 patron who last borrowed the book.
1869
1870 =cut
1871
1872 sub AddReturn {
1873     my ( $barcode, $branch, $exemptfine, $return_date ) = @_;
1874
1875     if ($branch and not Koha::Libraries->find($branch)) {
1876         warn "AddReturn error: branch '$branch' not found.  Reverting to " . C4::Context->userenv->{'branch'};
1877         undef $branch;
1878     }
1879     $branch = C4::Context->userenv->{'branch'} unless $branch;  # we trust userenv to be a safe fallback/default
1880     my $return_date_specified = !!$return_date;
1881     $return_date //= dt_from_string();
1882     my $messages;
1883     my $patron;
1884     my $doreturn       = 1;
1885     my $validTransfert = 0;
1886     my $stat_type = 'return';
1887
1888     # get information on item
1889     my $item = Koha::Items->find({ barcode => $barcode });
1890     unless ($item) {
1891         return ( 0, { BadBarcode => $barcode } );    # no barcode means no item or borrower.  bail out.
1892     }
1893
1894     my $itemnumber = $item->itemnumber;
1895     my $itemtype = $item->effective_itemtype;
1896
1897     my $issue  = $item->checkout;
1898     if ( $issue ) {
1899         $patron = $issue->patron
1900             or die "Data inconsistency: barcode $barcode (itemnumber:$itemnumber) claims to be issued to non-existent borrowernumber '" . $issue->borrowernumber . "'\n"
1901                 . Dumper($issue->unblessed) . "\n";
1902     } else {
1903         $messages->{'NotIssued'} = $barcode;
1904         $item->onloan(undef)->store if defined $item->onloan;
1905
1906         # even though item is not on loan, it may still be transferred;  therefore, get current branch info
1907         $doreturn = 0;
1908         # No issue, no borrowernumber.  ONLY if $doreturn, *might* you have a $borrower later.
1909         # Record this as a local use, instead of a return, if the RecordLocalUseOnReturn is on
1910         if (C4::Context->preference("RecordLocalUseOnReturn")) {
1911            $messages->{'LocalUse'} = 1;
1912            $stat_type = 'localuse';
1913         }
1914     }
1915
1916         # full item data, but no borrowernumber or checkout info (no issue)
1917     my $hbr = GetBranchItemRule($item->homebranch, $itemtype)->{'returnbranch'} || "homebranch";
1918         # get the proper branch to which to return the item
1919     my $returnbranch = $hbr ne 'noreturn' ? $item->$hbr : $branch;
1920         # if $hbr was "noreturn" or any other non-item table value, then it should 'float' (i.e. stay at this branch)
1921     my $transfer_trigger = $hbr eq 'homebranch' ? 'ReturnToHome' : $hbr eq 'holdingbranch' ? 'ReturnToHolding' : undef;
1922
1923     my $borrowernumber = $patron ? $patron->borrowernumber : undef;    # we don't know if we had a borrower or not
1924     my $patron_unblessed = $patron ? $patron->unblessed : {};
1925
1926     my $update_loc_rules = get_yaml_pref_hash('UpdateItemLocationOnCheckin');
1927     map { $update_loc_rules->{$_} = $update_loc_rules->{$_}[0] } keys %$update_loc_rules; #We can only move to one location so we flatten the arrays
1928     if ($update_loc_rules) {
1929         if (defined $update_loc_rules->{_ALL_}) {
1930             if ($update_loc_rules->{_ALL_} eq '_PERM_') { $update_loc_rules->{_ALL_} = $item->permanent_location; }
1931             if ($update_loc_rules->{_ALL_} eq '_BLANK_') { $update_loc_rules->{_ALL_} = ''; }
1932             if ( $item->location ne $update_loc_rules->{_ALL_}) {
1933                 $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{_ALL_} };
1934                 $item->location($update_loc_rules->{_ALL_})->store;
1935             }
1936         }
1937         else {
1938             foreach my $key ( keys %$update_loc_rules ) {
1939                 if ( $update_loc_rules->{$key} eq '_PERM_' ) { $update_loc_rules->{$key} = $item->permanent_location; }
1940                 if ( $update_loc_rules->{$key} eq '_BLANK_') { $update_loc_rules->{$key} = '' ;}
1941                 if ( ($item->location eq $key && $item->location ne $update_loc_rules->{$key}) || ($key eq '_BLANK_' && $item->location eq '' && $update_loc_rules->{$key} ne '') ) {
1942                     $messages->{'ItemLocationUpdated'} = { from => $item->location, to => $update_loc_rules->{$key} };
1943                     $item->location($update_loc_rules->{$key})->store;
1944                     last;
1945                 }
1946             }
1947         }
1948     }
1949
1950     my $yaml = C4::Context->preference('UpdateNotForLoanStatusOnCheckin');
1951     if ($yaml) {
1952         $yaml = "$yaml\n\n";  # YAML is anal on ending \n. Surplus does not hurt
1953         my $rules;
1954         eval { $rules = YAML::Load($yaml); };
1955         if ($@) {
1956             warn "Unable to parse UpdateNotForLoanStatusOnCheckin syspref : $@";
1957         }
1958         else {
1959             foreach my $key ( keys %$rules ) {
1960                 if ( $item->notforloan eq $key ) {
1961                     $messages->{'NotForLoanStatusUpdated'} = { from => $item->notforloan, to => $rules->{$key} };
1962                     $item->notforloan($rules->{$key})->store({ log_action => 0 });
1963                     last;
1964                 }
1965             }
1966         }
1967     }
1968
1969     # check if the return is allowed at this branch
1970     my ($returnallowed, $message) = CanBookBeReturned($item->unblessed, $branch);
1971     unless ($returnallowed){
1972         $messages->{'Wrongbranch'} = {
1973             Wrongbranch => $branch,
1974             Rightbranch => $message
1975         };
1976         $doreturn = 0;
1977         return ( $doreturn, $messages, $issue, $patron_unblessed);
1978     }
1979
1980     if ( $item->withdrawn ) { # book has been cancelled
1981         $messages->{'withdrawn'} = 1;
1982         $doreturn = 0 if C4::Context->preference("BlockReturnOfWithdrawnItems");
1983     }
1984
1985     if ( $item->itemlost and C4::Context->preference("BlockReturnOfLostItems") ) {
1986         $doreturn = 0;
1987     }
1988
1989     # case of a return of document (deal with issues and holdingbranch)
1990     if ($doreturn) {
1991         die "The item is not issed and cannot be returned" unless $issue; # Just in case...
1992         $patron or warn "AddReturn without current borrower";
1993
1994         if ($patron) {
1995             eval {
1996                 MarkIssueReturned( $borrowernumber, $item->itemnumber, $return_date, $patron->privacy );
1997             };
1998             unless ( $@ ) {
1999                 if (
2000                     (
2001                         C4::Context->preference('CalculateFinesOnReturn')
2002                         || ( $return_date_specified && C4::Context->preference('CalculateFinesOnBackdate') )
2003                     )
2004                     && !$item->itemlost
2005                   )
2006                 {
2007                     _CalculateAndUpdateFine( { issue => $issue, item => $item->unblessed, borrower => $patron_unblessed, return_date => $return_date } );
2008                 }
2009             } else {
2010                 carp "The checkin for the following issue failed, Please go to the about page, section 'data corrupted' to know how to fix this problem ($@)" . Dumper( $issue->unblessed );
2011
2012                 return ( 0, { WasReturned => 0, DataCorrupted => 1 }, $issue, $patron_unblessed );
2013             }
2014
2015             # FIXME is the "= 1" right?  This could be the borrower hash.
2016             $messages->{'WasReturned'} = 1;
2017
2018         }
2019
2020         $item->onloan(undef)->store({ log_action => 0 });
2021     }
2022
2023     # the holdingbranch is updated if the document is returned to another location.
2024     # this is always done regardless of whether the item was on loan or not
2025     my $item_holding_branch = $item->holdingbranch;
2026     if ($item->holdingbranch ne $branch) {
2027         $item->holdingbranch($branch)->store;
2028     }
2029
2030     my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
2031     ModDateLastSeen( $item->itemnumber, $leave_item_lost );
2032
2033     # check if we have a transfer for this document
2034     my ($datesent,$frombranch,$tobranch) = GetTransfers( $item->itemnumber );
2035
2036     # if we have a transfer to do, we update the line of transfers with the datearrived
2037     my $is_in_rotating_collection = C4::RotatingCollections::isItemInAnyCollection( $item->itemnumber );
2038     if ($datesent) {
2039         if ( $tobranch eq $branch ) {
2040             my $sth = C4::Context->dbh->prepare(
2041                 "UPDATE branchtransfers SET datearrived = now() WHERE itemnumber= ? AND datearrived IS NULL"
2042             );
2043             $sth->execute( $item->itemnumber );
2044         } else {
2045             $messages->{'WrongTransfer'}     = $tobranch;
2046             $messages->{'WrongTransferItem'} = $item->itemnumber;
2047         }
2048         $validTransfert = 1;
2049     }
2050
2051     # fix up the accounts.....
2052     if ( $item->itemlost ) {
2053         $messages->{'WasLost'} = 1;
2054         unless ( C4::Context->preference("BlockReturnOfLostItems") ) {
2055             my $refund = 1;
2056             my $no_refund_after_days = C4::Context->preference('NoRefundOnLostReturnedItemsAge');
2057             if ($no_refund_after_days) {
2058                 my $today = dt_from_string();
2059                 my $lost_age_in_days =
2060                   dt_from_string( $item->itemlost_on )
2061                   ->delta_days($today)
2062                   ->in_units('days');
2063
2064                 $refund = 0 unless ( $lost_age_in_days < $no_refund_after_days );
2065             }
2066
2067             if (
2068                 $refund &&
2069                 Koha::RefundLostItemFeeRules->should_refund(
2070                     {
2071                         current_branch      => C4::Context->userenv->{branch},
2072                         item_home_branch    => $item->homebranch,
2073                         item_holding_branch => $item_holding_branch
2074                     }
2075                 )
2076               )
2077             {
2078                 _FixAccountForLostAndFound( $item->itemnumber,
2079                     $borrowernumber, $barcode );
2080                 $messages->{'LostItemFeeRefunded'} = 1;
2081             }
2082         }
2083     }
2084
2085     # fix up the overdues in accounts...
2086     if ($borrowernumber) {
2087         my $fix = _FixOverduesOnReturn( $borrowernumber, $item->itemnumber, $exemptfine, 'RETURNED' );
2088         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, ".$item->itemnumber."...) failed!";  # zero is OK, check defined
2089
2090         if ( $issue and $issue->is_overdue($return_date) ) {
2091         # fix fine days
2092             my ($debardate,$reminder) = _debar_user_on_return( $patron_unblessed, $item->unblessed, dt_from_string($issue->date_due), $return_date );
2093             if ($reminder){
2094                 $messages->{'PrevDebarred'} = $debardate;
2095             } else {
2096                 $messages->{'Debarred'} = $debardate if $debardate;
2097             }
2098         # there's no overdue on the item but borrower had been previously debarred
2099         } elsif ( $issue->date_due and $patron->debarred ) {
2100              if ( $patron->debarred eq "9999-12-31") {
2101                 $messages->{'ForeverDebarred'} = $patron->debarred;
2102              } else {
2103                   my $borrower_debar_dt = dt_from_string( $patron->debarred );
2104                   $borrower_debar_dt->truncate(to => 'day');
2105                   my $today_dt = $return_date->clone()->truncate(to => 'day');
2106                   if ( DateTime->compare( $borrower_debar_dt, $today_dt ) != -1 ) {
2107                       $messages->{'PrevDebarred'} = $patron->debarred;
2108                   }
2109              }
2110         }
2111     }
2112
2113     # find reserves.....
2114     # launch the Checkreserves routine to find any holds
2115     my ($resfound, $resrec);
2116     my $lookahead= C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
2117     ($resfound, $resrec, undef) = C4::Reserves::CheckReserves( $item->itemnumber, undef, $lookahead ) unless ( $item->withdrawn );
2118     # if a hold is found and is waiting at another branch, change the priority back to 1 and trigger the hold (this will trigger a transfer and update the hold status properly)
2119     if ( $resfound eq "Waiting" and $branch ne $resrec->{branchcode} ) {
2120         my $hold = C4::Reserves::RevertWaitingStatus( { itemnumber => $item->itemnumber } );
2121         $resfound = 'Reserved';
2122         $resrec = $hold->unblessed;
2123     }
2124     if ($resfound) {
2125           $resrec->{'ResFound'} = $resfound;
2126         $messages->{'ResFound'} = $resrec;
2127     }
2128
2129     # Record the fact that this book was returned.
2130     UpdateStats({
2131         branch         => $branch,
2132         type           => $stat_type,
2133         itemnumber     => $itemnumber,
2134         itemtype       => $itemtype,
2135         location       => $item->location,
2136         borrowernumber => $borrowernumber,
2137         ccode          => $item->ccode,
2138     });
2139
2140     # Send a check-in slip. # NOTE: borrower may be undef. Do not try to send messages then.
2141     if ( $patron ) {
2142         my $circulation_alert = 'C4::ItemCirculationAlertPreference';
2143         my %conditions = (
2144             branchcode   => $branch,
2145             categorycode => $patron->categorycode,
2146             item_type    => $itemtype,
2147             notification => 'CHECKIN',
2148         );
2149         if ($doreturn && $circulation_alert->is_enabled_for(\%conditions)) {
2150             SendCirculationAlert({
2151                 type     => 'CHECKIN',
2152                 item     => $item->unblessed,
2153                 borrower => $patron->unblessed,
2154                 branch   => $branch,
2155             });
2156         }
2157
2158         logaction("CIRCULATION", "RETURN", $borrowernumber, $item->itemnumber)
2159             if C4::Context->preference("ReturnLog");
2160         }
2161
2162     # Check if this item belongs to a biblio record that is attached to an
2163     # ILL request, if it is we need to update the ILL request's status
2164     if (C4::Context->preference('CirculateILL')) {
2165         my $request = Koha::Illrequests->find(
2166             { biblio_id => $item->biblio->biblionumber }
2167         );
2168         $request->status('RET') if $request;
2169     }
2170
2171     # Transfer to returnbranch if Automatic transfer set or append message NeedsTransfer
2172     if (!$is_in_rotating_collection && ($doreturn or $messages->{'NotIssued'}) and !$resfound and ($branch ne $returnbranch) and not $messages->{'WrongTransfer'}){
2173         my $BranchTransferLimitsType = C4::Context->preference("BranchTransferLimitsType") eq 'itemtype' ? 'effective_itemtype' : 'ccode';
2174         if  (C4::Context->preference("AutomaticItemReturn"    ) or
2175             (C4::Context->preference("UseBranchTransferLimits") and
2176              ! IsBranchTransferAllowed($branch, $returnbranch, $item->$BranchTransferLimitsType )
2177            )) {
2178             $debug and warn sprintf "about to call ModItemTransfer(%s, %s, %s, %s)", $item->itemnumber,$branch, $returnbranch, $transfer_trigger;
2179             $debug and warn "item: " . Dumper($item->unblessed);
2180             ModItemTransfer($item->itemnumber, $branch, $returnbranch, $transfer_trigger);
2181             $messages->{'WasTransfered'} = 1;
2182         } else {
2183             $messages->{'NeedsTransfer'} = $returnbranch;
2184             $messages->{'TransferTrigger'} = $transfer_trigger;
2185         }
2186     }
2187
2188     if ( C4::Context->preference('ClaimReturnedLostValue') ) {
2189         my $claims = Koha::Checkouts::ReturnClaims->search(
2190            {
2191                itemnumber => $item->id,
2192                resolution => undef,
2193            }
2194         );
2195
2196         if ( $claims->count ) {
2197             $messages->{ReturnClaims} = $claims;
2198         }
2199     }
2200
2201     return ( $doreturn, $messages, $issue, ( $patron ? $patron->unblessed : {} ));
2202 }
2203
2204 =head2 MarkIssueReturned
2205
2206   MarkIssueReturned($borrowernumber, $itemnumber, $returndate, $privacy);
2207
2208 Unconditionally marks an issue as being returned by
2209 moving the C<issues> row to C<old_issues> and
2210 setting C<returndate> to the current date.
2211
2212 if C<$returndate> is specified (in iso format), it is used as the date
2213 of the return.
2214
2215 C<$privacy> contains the privacy parameter. If the patron has set privacy to 2,
2216 the old_issue is immediately anonymised
2217
2218 Ideally, this function would be internal to C<C4::Circulation>,
2219 not exported, but it is currently used in misc/cronjobs/longoverdue.pl
2220 and offline_circ/process_koc.pl.
2221
2222 =cut
2223
2224 sub MarkIssueReturned {
2225     my ( $borrowernumber, $itemnumber, $returndate, $privacy ) = @_;
2226
2227     # Retrieve the issue
2228     my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } ) or return;
2229
2230     return unless $issue->borrowernumber == $borrowernumber; # If the item is checked out to another patron we do not return it
2231
2232     my $issue_id = $issue->issue_id;
2233
2234     my $anonymouspatron;
2235     if ( $privacy && $privacy == 2 ) {
2236         # The default of 0 will not work due to foreign key constraints
2237         # The anonymisation will fail if AnonymousPatron is not a valid entry
2238         # We need to check if the anonymous patron exist, Koha will fail loudly if it does not
2239         # Note that a warning should appear on the about page (System information tab).
2240         $anonymouspatron = C4::Context->preference('AnonymousPatron');
2241         die "Fatal error: the patron ($borrowernumber) has requested their circulation history be anonymized on check-in, but the AnonymousPatron system preference is empty or not set correctly."
2242             unless Koha::Patrons->find( $anonymouspatron );
2243     }
2244
2245     my $schema = Koha::Database->schema;
2246
2247     # FIXME Improve the return value and handle it from callers
2248     $schema->txn_do(sub {
2249
2250         my $patron = Koha::Patrons->find( $borrowernumber );
2251
2252         # Update the returndate value
2253         if ( $returndate ) {
2254             $issue->returndate( $returndate )->store->discard_changes; # update and refetch
2255         }
2256         else {
2257             $issue->returndate( \'NOW()' )->store->discard_changes; # update and refetch
2258         }
2259
2260         # Create the old_issues entry
2261         my $old_checkout = Koha::Old::Checkout->new($issue->unblessed)->store;
2262
2263         # anonymise patron checkout immediately if $privacy set to 2 and AnonymousPatron is set to a valid borrowernumber
2264         if ( $privacy && $privacy == 2) {
2265             $old_checkout->borrowernumber($anonymouspatron)->store;
2266         }
2267
2268         # And finally delete the issue
2269         $issue->delete;
2270
2271         $issue->item->onloan(undef)->store({ log_action => 0 });
2272
2273         if ( C4::Context->preference('StoreLastBorrower') ) {
2274             my $item = Koha::Items->find( $itemnumber );
2275             $item->last_returned_by( $patron );
2276         }
2277
2278         # Remove any OVERDUES related debarment if the borrower has no overdues
2279         if ( C4::Context->preference('AutoRemoveOverduesRestrictions')
2280           && $patron->debarred
2281           && !$patron->has_overdues
2282           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
2283         ) {
2284             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
2285         }
2286
2287     });
2288
2289     return $issue_id;
2290 }
2291
2292 =head2 _debar_user_on_return
2293
2294     _debar_user_on_return($borrower, $item, $datedue, $returndate);
2295
2296 C<$borrower> borrower hashref
2297
2298 C<$item> item hashref
2299
2300 C<$datedue> date due DateTime object
2301
2302 C<$returndate> DateTime object representing the return time
2303
2304 Internal function, called only by AddReturn that calculates and updates
2305  the user fine days, and debars them if necessary.
2306
2307 Should only be called for overdue returns
2308
2309 Calculation of the debarment date has been moved to a separate subroutine _calculate_new_debar_dt
2310 to ease testing.
2311
2312 =cut
2313
2314 sub _calculate_new_debar_dt {
2315     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2316
2317     my $branchcode = _GetCircControlBranch( $item, $borrower );
2318     my $circcontrol = C4::Context->preference('CircControl');
2319     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2320         {   categorycode => $borrower->{categorycode},
2321             itemtype     => $item->{itype},
2322             branchcode   => $branchcode,
2323             rules => [
2324                 'finedays',
2325                 'lengthunit',
2326                 'firstremind',
2327                 'maxsuspensiondays',
2328                 'suspension_chargeperiod',
2329             ]
2330         }
2331     );
2332     my $finedays = $issuing_rule ? $issuing_rule->{finedays} : undef;
2333     my $unit     = $issuing_rule ? $issuing_rule->{lengthunit} : undef;
2334     my $chargeable_units = C4::Overdues::get_chargeable_units($unit, $dt_due, $return_date, $branchcode);
2335
2336     return unless $finedays;
2337
2338     # finedays is in days, so hourly loans must multiply by 24
2339     # thus 1 hour late equals 1 day suspension * finedays rate
2340     $finedays = $finedays * 24 if ( $unit eq 'hours' );
2341
2342     # grace period is measured in the same units as the loan
2343     my $grace =
2344       DateTime::Duration->new( $unit => $issuing_rule->{firstremind} );
2345
2346     my $deltadays = DateTime::Duration->new(
2347         days => $chargeable_units
2348     );
2349
2350     if ( $deltadays->subtract($grace)->is_positive() ) {
2351         my $suspension_days = $deltadays * $finedays;
2352
2353         if ( defined $issuing_rule->{suspension_chargeperiod} && $issuing_rule->{suspension_chargeperiod} > 1 ) {
2354             # No need to / 1 and do not consider / 0
2355             $suspension_days = DateTime::Duration->new(
2356                 days => floor( $suspension_days->in_units('days') / $issuing_rule->{suspension_chargeperiod} )
2357             );
2358         }
2359
2360         # If the max suspension days is < than the suspension days
2361         # the suspension days is limited to this maximum period.
2362         my $max_sd = $issuing_rule->{maxsuspensiondays};
2363         if ( defined $max_sd && $max_sd ne '' ) {
2364             $max_sd = DateTime::Duration->new( days => $max_sd );
2365             $suspension_days = $max_sd
2366               if DateTime::Duration->compare( $max_sd, $suspension_days ) < 0;
2367         }
2368
2369         my ( $has_been_extended );
2370         if ( C4::Context->preference('CumulativeRestrictionPeriods') and $borrower->{debarred} ) {
2371             my $debarment = @{ GetDebarments( { borrowernumber => $borrower->{borrowernumber}, type => 'SUSPENSION' } ) }[0];
2372             if ( $debarment ) {
2373                 $return_date = dt_from_string( $debarment->{expiration}, 'sql' );
2374                 $has_been_extended = 1;
2375             }
2376         }
2377
2378         my $new_debar_dt;
2379         # Use the calendar or not to calculate the debarment date
2380         if ( C4::Context->preference('SuspensionsCalendar') eq 'noSuspensionsWhenClosed' ) {
2381             my $calendar = Koha::Calendar->new(
2382                 branchcode => $branchcode,
2383                 days_mode  => 'Calendar'
2384             );
2385             $new_debar_dt = $calendar->addDate( $return_date, $suspension_days );
2386         }
2387         else {
2388             $new_debar_dt = $return_date->clone()->add_duration($suspension_days);
2389         }
2390         return $new_debar_dt;
2391     }
2392     return;
2393 }
2394
2395 sub _debar_user_on_return {
2396     my ( $borrower, $item, $dt_due, $return_date ) = @_;
2397
2398     $return_date //= dt_from_string();
2399
2400     my $new_debar_dt = _calculate_new_debar_dt ($borrower, $item, $dt_due, $return_date);
2401
2402     return unless $new_debar_dt;
2403
2404     Koha::Patron::Debarments::AddUniqueDebarment({
2405         borrowernumber => $borrower->{borrowernumber},
2406         expiration     => $new_debar_dt->ymd(),
2407         type           => 'SUSPENSION',
2408     });
2409     # if borrower was already debarred but does not get an extra debarment
2410     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
2411     my ($new_debarment_str, $is_a_reminder);
2412     if ( $borrower->{debarred} && $borrower->{debarred} eq $patron->is_debarred ) {
2413         $is_a_reminder = 1;
2414         $new_debarment_str = $borrower->{debarred};
2415     } else {
2416         $new_debarment_str = $new_debar_dt->ymd();
2417     }
2418     # FIXME Should return a DateTime object
2419     return $new_debarment_str, $is_a_reminder;
2420 }
2421
2422 =head2 _FixOverduesOnReturn
2423
2424    &_FixOverduesOnReturn($borrowernumber, $itemnumber, $exemptfine, $status);
2425
2426 C<$borrowernumber> borrowernumber
2427
2428 C<$itemnumber> itemnumber
2429
2430 C<$exemptfine> BOOL -- remove overdue charge associated with this issue.
2431
2432 C<$status> ENUM -- reason for fix [ RETURNED, RENEWED, LOST, FORGIVEN ]
2433
2434 Internal function
2435
2436 =cut
2437
2438 sub _FixOverduesOnReturn {
2439     my ( $borrowernumber, $item, $exemptfine, $status ) = @_;
2440     unless( $borrowernumber ) {
2441         warn "_FixOverduesOnReturn() not supplied valid borrowernumber";
2442         return;
2443     }
2444     unless( $item ) {
2445         warn "_FixOverduesOnReturn() not supplied valid itemnumber";
2446         return;
2447     }
2448     unless( $status ) {
2449         warn "_FixOverduesOnReturn() not supplied valid status";
2450         return;
2451     }
2452
2453     my $schema = Koha::Database->schema;
2454
2455     my $result = $schema->txn_do(
2456         sub {
2457             # check for overdue fine
2458             my $accountlines = Koha::Account::Lines->search(
2459                 {
2460                     borrowernumber  => $borrowernumber,
2461                     itemnumber      => $item,
2462                     debit_type_code => 'OVERDUE',
2463                     status          => 'UNRETURNED'
2464                 }
2465             );
2466             return 0 unless $accountlines->count; # no warning, there's just nothing to fix
2467
2468             my $accountline = $accountlines->next;
2469             my $payments = $accountline->credits;
2470
2471             my $amountoutstanding = $accountline->amountoutstanding;
2472             if ( $accountline->amount == 0 && $payments->count == 0 ) {
2473                 $accountline->delete;
2474             } elsif ($exemptfine && ($amountoutstanding != 0)) {
2475                 my $account = Koha::Account->new({patron_id => $borrowernumber});
2476                 my $credit = $account->add_credit(
2477                     {
2478                         amount     => $amountoutstanding,
2479                         user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
2480                         library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
2481                         interface  => C4::Context->interface,
2482                         type       => 'FORGIVEN',
2483                         item_id    => $item
2484                     }
2485                 );
2486
2487                 $credit->apply({ debits => [ $accountline ], offset_type => 'Forgiven' });
2488
2489                 if (C4::Context->preference("FinesLog")) {
2490                     &logaction("FINES", 'MODIFY',$borrowernumber,"Overdue forgiven: item $item");
2491                 }
2492
2493                 $accountline->status('FORGIVEN');
2494                 $accountline->store();
2495             } else {
2496                 $accountline->status($status);
2497                 $accountline->store();
2498
2499             }
2500         }
2501     );
2502
2503     return $result;
2504 }
2505
2506 =head2 _FixAccountForLostAndFound
2507
2508   &_FixAccountForLostAndFound($itemnumber, [$borrowernumber, $barcode]);
2509
2510 Finds the most recent lost item charge for this item and refunds the borrower
2511 appropriatly, taking into account any payments or writeoffs already applied
2512 against the charge.
2513
2514 Internal function, not exported, called only by AddReturn.
2515
2516 =cut
2517
2518 sub _FixAccountForLostAndFound {
2519     my $itemnumber     = shift or return;
2520     my $borrowernumber = @_ ? shift : undef;
2521     my $item_id        = @_ ? shift : $itemnumber;  # Send the barcode if you want that logged in the description
2522
2523     my $credit;
2524
2525     # check for charge made for lost book
2526     my $accountlines = Koha::Account::Lines->search(
2527         {
2528             itemnumber      => $itemnumber,
2529             debit_type_code => 'LOST',
2530             status          => [ undef, { '<>' => 'FOUND' } ]
2531         },
2532         {
2533             order_by => { -desc => [ 'date', 'accountlines_id' ] }
2534         }
2535     );
2536
2537     return unless $accountlines->count > 0;
2538     my $accountline     = $accountlines->next;
2539     my $total_to_refund = 0;
2540
2541     return unless $accountline->borrowernumber;
2542     my $patron = Koha::Patrons->find( $accountline->borrowernumber );
2543     return unless $patron; # Patron has been deleted, nobody to credit the return to
2544
2545     my $account = $patron->account;
2546
2547     # Use cases
2548     if ( $accountline->amount > $accountline->amountoutstanding ) {
2549         # some amount has been cancelled. collect the offsets that are not writeoffs
2550         # this works because the only way to subtract from this kind of a debt is
2551         # using the UI buttons 'Pay' and 'Write off'
2552         my $credits_offsets = Koha::Account::Offsets->search({
2553             debit_id  => $accountline->id,
2554             credit_id => { '!=' => undef }, # it is not the debit itself
2555             type      => { '!=' => 'Writeoff' },
2556             amount    => { '<'  => 0 } # credits are negative on the DB
2557         });
2558
2559         $total_to_refund = ( $credits_offsets->count > 0 )
2560                             ? $credits_offsets->total * -1 # credits are negative on the DB
2561                             : 0;
2562     }
2563
2564     my $credit_total = $accountline->amountoutstanding + $total_to_refund;
2565
2566     if ( $credit_total > 0 ) {
2567         my $branchcode = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
2568         $credit = $account->add_credit(
2569             {
2570                 amount      => $credit_total,
2571                 description => 'Item found ' . $item_id,
2572                 type        => 'LOST_FOUND',
2573                 interface   => C4::Context->interface,
2574                 library_id  => $branchcode,
2575                 item_id     => $itemnumber
2576             }
2577         );
2578
2579         $credit->apply( { debits => [ $accountline ] } );
2580     }
2581
2582     # Update the account status
2583     $accountline->discard_changes->status('FOUND');
2584     $accountline->store;
2585
2586     $accountline->item->paidfor('')->store({ log_action => 0 });
2587
2588     if ( defined $account and C4::Context->preference('AccountAutoReconcile') ) {
2589         $account->reconcile_balance;
2590     }
2591
2592     return ($credit) ? $credit->id : undef;
2593 }
2594
2595 =head2 _GetCircControlBranch
2596
2597    my $circ_control_branch = _GetCircControlBranch($iteminfos, $borrower);
2598
2599 Internal function :
2600
2601 Return the library code to be used to determine which circulation
2602 policy applies to a transaction.  Looks up the CircControl and
2603 HomeOrHoldingBranch system preferences.
2604
2605 C<$iteminfos> is a hashref to iteminfo. Only {homebranch or holdingbranch} is used.
2606
2607 C<$borrower> is a hashref to borrower. Only {branchcode} is used.
2608
2609 =cut
2610
2611 sub _GetCircControlBranch {
2612     my ($item, $borrower) = @_;
2613     my $circcontrol = C4::Context->preference('CircControl');
2614     my $branch;
2615
2616     if ($circcontrol eq 'PickupLibrary' and (C4::Context->userenv and C4::Context->userenv->{'branch'}) ) {
2617         $branch= C4::Context->userenv->{'branch'};
2618     } elsif ($circcontrol eq 'PatronLibrary') {
2619         $branch=$borrower->{branchcode};
2620     } else {
2621         my $branchfield = C4::Context->preference('HomeOrHoldingBranch') || 'homebranch';
2622         $branch = $item->{$branchfield};
2623         # default to item home branch if holdingbranch is used
2624         # and is not defined
2625         if (!defined($branch) && $branchfield eq 'holdingbranch') {
2626             $branch = $item->{homebranch};
2627         }
2628     }
2629     return $branch;
2630 }
2631
2632 =head2 GetOpenIssue
2633
2634   $issue = GetOpenIssue( $itemnumber );
2635
2636 Returns the row from the issues table if the item is currently issued, undef if the item is not currently issued
2637
2638 C<$itemnumber> is the item's itemnumber
2639
2640 Returns a hashref
2641
2642 =cut
2643
2644 sub GetOpenIssue {
2645   my ( $itemnumber ) = @_;
2646   return unless $itemnumber;
2647   my $dbh = C4::Context->dbh;
2648   my $sth = $dbh->prepare( "SELECT * FROM issues WHERE itemnumber = ? AND returndate IS NULL" );
2649   $sth->execute( $itemnumber );
2650   return $sth->fetchrow_hashref();
2651
2652 }
2653
2654 =head2 GetBiblioIssues
2655
2656   $issues = GetBiblioIssues($biblionumber);
2657
2658 this function get all issues from a biblionumber.
2659
2660 Return:
2661 C<$issues> is a reference to array which each value is ref-to-hash. This ref-to-hash contains all column from
2662 tables issues and the firstname,surname & cardnumber from borrowers.
2663
2664 =cut
2665
2666 sub GetBiblioIssues {
2667     my $biblionumber = shift;
2668     return unless $biblionumber;
2669     my $dbh   = C4::Context->dbh;
2670     my $query = "
2671         SELECT issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2672         FROM issues
2673             LEFT JOIN borrowers ON borrowers.borrowernumber = issues.borrowernumber
2674             LEFT JOIN items ON issues.itemnumber = items.itemnumber
2675             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2676             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2677         WHERE biblio.biblionumber = ?
2678         UNION ALL
2679         SELECT old_issues.*,items.barcode,biblio.biblionumber,biblio.title, biblio.author,borrowers.cardnumber,borrowers.surname,borrowers.firstname
2680         FROM old_issues
2681             LEFT JOIN borrowers ON borrowers.borrowernumber = old_issues.borrowernumber
2682             LEFT JOIN items ON old_issues.itemnumber = items.itemnumber
2683             LEFT JOIN biblioitems ON items.itemnumber = biblioitems.biblioitemnumber
2684             LEFT JOIN biblio ON biblio.biblionumber = items.biblionumber
2685         WHERE biblio.biblionumber = ?
2686         ORDER BY timestamp
2687     ";
2688     my $sth = $dbh->prepare($query);
2689     $sth->execute($biblionumber, $biblionumber);
2690
2691     my @issues;
2692     while ( my $data = $sth->fetchrow_hashref ) {
2693         push @issues, $data;
2694     }
2695     return \@issues;
2696 }
2697
2698 =head2 GetUpcomingDueIssues
2699
2700   my $upcoming_dues = GetUpcomingDueIssues( { days_in_advance => 4 } );
2701
2702 =cut
2703
2704 sub GetUpcomingDueIssues {
2705     my $params = shift;
2706
2707     $params->{'days_in_advance'} = 7 unless exists $params->{'days_in_advance'};
2708     my $dbh = C4::Context->dbh;
2709
2710     my $statement = <<END_SQL;
2711 SELECT *
2712 FROM (
2713     SELECT issues.*, items.itype as itemtype, items.homebranch, TO_DAYS( date_due )-TO_DAYS( NOW() ) as days_until_due, branches.branchemail
2714     FROM issues
2715     LEFT JOIN items USING (itemnumber)
2716     LEFT OUTER JOIN branches USING (branchcode)
2717     WHERE returndate is NULL
2718 ) tmp
2719 WHERE days_until_due >= 0 AND days_until_due <= ?
2720 END_SQL
2721
2722     my @bind_parameters = ( $params->{'days_in_advance'} );
2723
2724     my $sth = $dbh->prepare( $statement );
2725     $sth->execute( @bind_parameters );
2726     my $upcoming_dues = $sth->fetchall_arrayref({});
2727
2728     return $upcoming_dues;
2729 }
2730
2731 =head2 CanBookBeRenewed
2732
2733   ($ok,$error) = &CanBookBeRenewed($borrowernumber, $itemnumber[, $override_limit]);
2734
2735 Find out whether a borrowed item may be renewed.
2736
2737 C<$borrowernumber> is the borrower number of the patron who currently
2738 has the item on loan.
2739
2740 C<$itemnumber> is the number of the item to renew.
2741
2742 C<$override_limit>, if supplied with a true value, causes
2743 the limit on the number of times that the loan can be renewed
2744 (as controlled by the item type) to be ignored. Overriding also allows
2745 to renew sooner than "No renewal before" and to manually renew loans
2746 that are automatically renewed.
2747
2748 C<$CanBookBeRenewed> returns a true value if the item may be renewed. The
2749 item must currently be on loan to the specified borrower; renewals
2750 must be allowed for the item's type; and the borrower must not have
2751 already renewed the loan. $error will contain the reason the renewal can not proceed
2752
2753 =cut
2754
2755 sub CanBookBeRenewed {
2756     my ( $borrowernumber, $itemnumber, $override_limit ) = @_;
2757
2758     my $dbh    = C4::Context->dbh;
2759     my $renews = 1;
2760     my $auto_renew = 0;
2761
2762     my $item      = Koha::Items->find($itemnumber)      or return ( 0, 'no_item' );
2763     my $issue = $item->checkout or return ( 0, 'no_checkout' );
2764     return ( 0, 'onsite_checkout' ) if $issue->onsite_checkout;
2765     return ( 0, 'item_denied_renewal') if _item_denied_renewal({ item => $item });
2766
2767     my $patron = $issue->patron or return;
2768
2769     # override_limit will override anything else except on_reserve
2770     unless ( $override_limit ){
2771         my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
2772         my $issuing_rule = Koha::CirculationRules->get_effective_rules(
2773             {
2774                 categorycode => $patron->categorycode,
2775                 itemtype     => $item->effective_itemtype,
2776                 branchcode   => $branchcode,
2777                 rules => [
2778                     'renewalsallowed',
2779                     'no_auto_renewal_after',
2780                     'no_auto_renewal_after_hard_limit',
2781                     'lengthunit',
2782                     'norenewalbefore',
2783                 ]
2784             }
2785         );
2786
2787         return ( 0, "too_many" )
2788           if not $issuing_rule->{renewalsallowed} or $issuing_rule->{renewalsallowed} <= $issue->renewals;
2789
2790         my $overduesblockrenewing = C4::Context->preference('OverduesBlockRenewing');
2791         my $restrictionblockrenewing = C4::Context->preference('RestrictionBlockRenewing');
2792         $patron         = Koha::Patrons->find($borrowernumber); # FIXME Is this really useful?
2793         my $restricted  = $patron->is_debarred;
2794         my $hasoverdues = $patron->has_overdues;
2795
2796         if ( $restricted and $restrictionblockrenewing ) {
2797             return ( 0, 'restriction');
2798         } elsif ( ($hasoverdues and $overduesblockrenewing eq 'block') || ($issue->is_overdue and $overduesblockrenewing eq 'blockitem') ) {
2799             return ( 0, 'overdue');
2800         }
2801
2802         if ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2803
2804             if ( $patron->category->effective_BlockExpiredPatronOpacActions and $patron->is_expired ) {
2805                 return ( 0, 'auto_account_expired' );
2806             }
2807
2808             if ( defined $issuing_rule->{no_auto_renewal_after}
2809                     and $issuing_rule->{no_auto_renewal_after} ne "" ) {
2810                 # Get issue_date and add no_auto_renewal_after
2811                 # If this is greater than today, it's too late for renewal.
2812                 my $maximum_renewal_date = dt_from_string($issue->issuedate, 'sql');
2813                 $maximum_renewal_date->add(
2814                     $issuing_rule->{lengthunit} => $issuing_rule->{no_auto_renewal_after}
2815                 );
2816                 my $now = dt_from_string;
2817                 if ( $now >= $maximum_renewal_date ) {
2818                     return ( 0, "auto_too_late" );
2819                 }
2820             }
2821             if ( defined $issuing_rule->{no_auto_renewal_after_hard_limit}
2822                           and $issuing_rule->{no_auto_renewal_after_hard_limit} ne "" ) {
2823                 # If no_auto_renewal_after_hard_limit is >= today, it's also too late for renewal
2824                 if ( dt_from_string >= dt_from_string( $issuing_rule->{no_auto_renewal_after_hard_limit} ) ) {
2825                     return ( 0, "auto_too_late" );
2826                 }
2827             }
2828
2829             if ( C4::Context->preference('OPACFineNoRenewalsBlockAutoRenew') ) {
2830                 my $fine_no_renewals = C4::Context->preference("OPACFineNoRenewals");
2831                 my $amountoutstanding =
2832                   C4::Context->preference("OPACFineNoRenewalsIncludeCredit")
2833                   ? $patron->account->balance
2834                   : $patron->account->outstanding_debits->total_outstanding;
2835                 if ( $amountoutstanding and $amountoutstanding > $fine_no_renewals ) {
2836                     return ( 0, "auto_too_much_oweing" );
2837                 }
2838             }
2839         }
2840
2841         if ( defined $issuing_rule->{norenewalbefore}
2842             and $issuing_rule->{norenewalbefore} ne "" )
2843         {
2844
2845             # Calculate soonest renewal by subtracting 'No renewal before' from due date
2846             my $soonestrenewal = dt_from_string( $issue->date_due, 'sql' )->subtract(
2847                 $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
2848
2849             # Depending on syspref reset the exact time, only check the date
2850             if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
2851                 and $issuing_rule->{lengthunit} eq 'days' )
2852             {
2853                 $soonestrenewal->truncate( to => 'day' );
2854             }
2855
2856             if ( $soonestrenewal > dt_from_string() )
2857             {
2858                 return ( 0, "auto_too_soon" ) if $issue->auto_renew && $patron->autorenew_checkouts;
2859                 return ( 0, "too_soon" );
2860             }
2861             elsif ( $issue->auto_renew && $patron->autorenew_checkouts ) {
2862                 $auto_renew = 1;
2863             }
2864         }
2865
2866         # Fallback for automatic renewals:
2867         # If norenewalbefore is undef, don't renew before due date.
2868         if ( $issue->auto_renew && !$auto_renew && $patron->autorenew_checkouts ) {
2869             my $now = dt_from_string;
2870             if ( $now >= dt_from_string( $issue->date_due, 'sql' ) ){
2871                 $auto_renew = 1;
2872             } else {
2873                 return ( 0, "auto_too_soon" );
2874             }
2875         }
2876     }
2877
2878     my ( $resfound, $resrec, undef ) = C4::Reserves::CheckReserves($itemnumber);
2879
2880     # This item can fill one or more unfilled reserve, can those unfilled reserves
2881     # all be filled by other available items?
2882     if ( $resfound
2883         && C4::Context->preference('AllowRenewalIfOtherItemsAvailable') )
2884     {
2885         my $schema = Koha::Database->new()->schema();
2886
2887         my $item_holds = $schema->resultset('Reserve')->search( { itemnumber => $itemnumber, found => undef } )->count();
2888         if ($item_holds) {
2889             # There is an item level hold on this item, no other item can fill the hold
2890             $resfound = 1;
2891         }
2892         else {
2893
2894             # Get all other items that could possibly fill reserves
2895             my @itemnumbers = $schema->resultset('Item')->search(
2896                 {
2897                     biblionumber => $resrec->{biblionumber},
2898                     onloan       => undef,
2899                     notforloan   => 0,
2900                     -not         => { itemnumber => $itemnumber }
2901                 },
2902                 { columns => 'itemnumber' }
2903             )->get_column('itemnumber')->all();
2904
2905             # Get all other reserves that could have been filled by this item
2906             my @borrowernumbers;
2907             while (1) {
2908                 my ( $reserve_found, $reserve, undef ) =
2909                   C4::Reserves::CheckReserves( $itemnumber, undef, undef, \@borrowernumbers );
2910
2911                 if ($reserve_found) {
2912                     push( @borrowernumbers, $reserve->{borrowernumber} );
2913                 }
2914                 else {
2915                     last;
2916                 }
2917             }
2918
2919             # If the count of the union of the lists of reservable items for each borrower
2920             # is equal or greater than the number of borrowers, we know that all reserves
2921             # can be filled with available items. We can get the union of the sets simply
2922             # by pushing all the elements onto an array and removing the duplicates.
2923             my @reservable;
2924             my %patrons;
2925             ITEM: foreach my $itemnumber (@itemnumbers) {
2926                 my $item = Koha::Items->find( $itemnumber );
2927                 next if IsItemOnHoldAndFound( $itemnumber );
2928                 for my $borrowernumber (@borrowernumbers) {
2929                     my $patron = $patrons{$borrowernumber} //= Koha::Patrons->find( $borrowernumber );
2930                     next unless IsAvailableForItemLevelRequest($item, $patron);
2931                     next unless CanItemBeReserved($borrowernumber,$itemnumber);
2932
2933                     push @reservable, $itemnumber;
2934                     if (@reservable >= @borrowernumbers) {
2935                         $resfound = 0;
2936                         last ITEM;
2937                     }
2938                     last;
2939                 }
2940             }
2941         }
2942     }
2943     return ( 0, "on_reserve" ) if $resfound;    # '' when no hold was found
2944     return ( 0, "auto_renew" ) if $auto_renew && !$override_limit; # 0 if auto-renewal should not succeed
2945
2946     return ( 1, undef );
2947 }
2948
2949 =head2 AddRenewal
2950
2951   &AddRenewal($borrowernumber, $itemnumber, $branch, [$datedue], [$lastreneweddate]);
2952
2953 Renews a loan.
2954
2955 C<$borrowernumber> is the borrower number of the patron who currently
2956 has the item.
2957
2958 C<$itemnumber> is the number of the item to renew.
2959
2960 C<$branch> is the library where the renewal took place (if any).
2961            The library that controls the circ policies for the renewal is retrieved from the issues record.
2962
2963 C<$datedue> can be a DateTime object used to set the due date.
2964
2965 C<$lastreneweddate> is an optional ISO-formatted date used to set issues.lastreneweddate.  If
2966 this parameter is not supplied, lastreneweddate is set to the current date.
2967
2968 C<$skipfinecalc> is an optional boolean. There may be circumstances where, even if the
2969 CalculateFinesOnReturn syspref is enabled, we don't want to calculate fines upon renew,
2970 for example, when we're renewing as a result of a fine being paid (see RenewAccruingItemWhenPaid
2971 syspref)
2972
2973 If C<$datedue> is the empty string, C<&AddRenewal> will calculate the due date automatically
2974 from the book's item type.
2975
2976 =cut
2977
2978 sub AddRenewal {
2979     my $borrowernumber  = shift;
2980     my $itemnumber      = shift or return;
2981     my $branch          = shift;
2982     my $datedue         = shift;
2983     my $lastreneweddate = shift || dt_from_string();
2984     my $skipfinecalc    = shift;
2985
2986     my $item_object   = Koha::Items->find($itemnumber) or return;
2987     my $biblio = $item_object->biblio;
2988     my $issue  = $item_object->checkout;
2989     my $item_unblessed = $item_object->unblessed;
2990
2991     my $dbh = C4::Context->dbh;
2992
2993     return unless $issue;
2994
2995     $borrowernumber ||= $issue->borrowernumber;
2996
2997     if ( defined $datedue && ref $datedue ne 'DateTime' ) {
2998         carp 'Invalid date passed to AddRenewal.';
2999         return;
3000     }
3001
3002     my $patron = Koha::Patrons->find( $borrowernumber ) or return; # FIXME Should do more than just return
3003     my $patron_unblessed = $patron->unblessed;
3004
3005     my $circ_library = Koha::Libraries->find( _GetCircControlBranch($item_unblessed, $patron_unblessed) );
3006
3007     my $schema = Koha::Database->schema;
3008     $schema->txn_do(sub{
3009
3010         if ( !$skipfinecalc && C4::Context->preference('CalculateFinesOnReturn') ) {
3011             _CalculateAndUpdateFine( { issue => $issue, item => $item_unblessed, borrower => $patron_unblessed } );
3012         }
3013         _FixOverduesOnReturn( $borrowernumber, $itemnumber, undef, 'RENEWED' );
3014
3015         # If the due date wasn't specified, calculate it by adding the
3016         # book's loan length to today's date or the current due date
3017         # based on the value of the RenewalPeriodBase syspref.
3018         my $itemtype = $item_object->effective_itemtype;
3019         unless ($datedue) {
3020
3021             $datedue = (C4::Context->preference('RenewalPeriodBase') eq 'date_due') ?
3022                                             dt_from_string( $issue->date_due, 'sql' ) :
3023                                             dt_from_string();
3024             $datedue =  CalcDateDue($datedue, $itemtype, $circ_library->branchcode, $patron_unblessed, 'is a renewal');
3025         }
3026
3027         my $fees = Koha::Charges::Fees->new(
3028             {
3029                 patron    => $patron,
3030                 library   => $circ_library,
3031                 item      => $item_object,
3032                 from_date => dt_from_string( $issue->date_due, 'sql' ),
3033                 to_date   => dt_from_string($datedue),
3034             }
3035         );
3036
3037         # Update the issues record to have the new due date, and a new count
3038         # of how many times it has been renewed.
3039         my $renews = ( $issue->renewals || 0 ) + 1;
3040         my $sth = $dbh->prepare("UPDATE issues SET date_due = ?, renewals = ?, lastreneweddate = ?
3041                                 WHERE borrowernumber=?
3042                                 AND itemnumber=?"
3043         );
3044
3045         $sth->execute( $datedue->strftime('%Y-%m-%d %H:%M'), $renews, $lastreneweddate, $borrowernumber, $itemnumber );
3046
3047         # Update the renewal count on the item, and tell zebra to reindex
3048         $renews = ( $item_object->renewals || 0 ) + 1;
3049         $item_object->renewals($renews);
3050         $item_object->onloan($datedue);
3051         $item_object->store({ log_action => 0 });
3052
3053         # Charge a new rental fee, if applicable
3054         my ( $charge, $type ) = GetIssuingCharges( $itemnumber, $borrowernumber );
3055         if ( $charge > 0 ) {
3056             AddIssuingCharge($issue, $charge, 'RENT_RENEW');
3057         }
3058
3059         # Charge a new accumulate rental fee, if applicable
3060         my $itemtype_object = Koha::ItemTypes->find( $itemtype );
3061         if ( $itemtype_object ) {
3062             my $accumulate_charge = $fees->accumulate_rentalcharge();
3063             if ( $accumulate_charge > 0 ) {
3064                 AddIssuingCharge( $issue, $accumulate_charge, 'RENT_DAILY_RENEW' )
3065             }
3066             $charge += $accumulate_charge;
3067         }
3068
3069         # Send a renewal slip according to checkout alert preferencei
3070         if ( C4::Context->preference('RenewalSendNotice') eq '1' ) {
3071             my $circulation_alert = 'C4::ItemCirculationAlertPreference';
3072             my %conditions        = (
3073                 branchcode   => $branch,
3074                 categorycode => $patron->categorycode,
3075                 item_type    => $itemtype,
3076                 notification => 'CHECKOUT',
3077             );
3078             if ( $circulation_alert->is_enabled_for( \%conditions ) ) {
3079                 SendCirculationAlert(
3080                     {
3081                         type     => 'RENEWAL',
3082                         item     => $item_unblessed,
3083                         borrower => $patron->unblessed,
3084                         branch   => $branch,
3085                     }
3086                 );
3087             }
3088         }
3089
3090         # Remove any OVERDUES related debarment if the borrower has no overdues
3091         if ( $patron
3092           && $patron->is_debarred
3093           && ! $patron->has_overdues
3094           && @{ GetDebarments({ borrowernumber => $borrowernumber, type => 'OVERDUES' }) }
3095         ) {
3096             DelUniqueDebarment({ borrowernumber => $borrowernumber, type => 'OVERDUES' });
3097         }
3098
3099         # Add the renewal to stats
3100         UpdateStats(
3101             {
3102                 branch         => $item_object->renewal_branchcode({branch => $branch}),
3103                 type           => 'renew',
3104                 amount         => $charge,
3105                 itemnumber     => $itemnumber,
3106                 itemtype       => $itemtype,
3107                 location       => $item_object->location,
3108                 borrowernumber => $borrowernumber,
3109                 ccode          => $item_object->ccode,
3110             }
3111         );
3112
3113         #Log the renewal
3114         logaction("CIRCULATION", "RENEWAL", $borrowernumber, $itemnumber) if C4::Context->preference("RenewalLog");
3115
3116         _after_circ_actions(
3117             {
3118                 action  => 'renewal',
3119                 payload => {
3120                     checkout  => $issue->get_from_storage
3121                 }
3122             }
3123         ) if C4::Context->config("enable_plugins");
3124     });
3125
3126     return $datedue;
3127 }
3128
3129 sub GetRenewCount {
3130     # check renewal status
3131     my ( $bornum, $itemno ) = @_;
3132     my $dbh           = C4::Context->dbh;
3133     my $renewcount    = 0;
3134     my $renewsallowed = 0;
3135     my $renewsleft    = 0;
3136
3137     my $patron = Koha::Patrons->find( $bornum );
3138     my $item   = Koha::Items->find($itemno);
3139
3140     return (0, 0, 0) unless $patron or $item; # Wrong call, no renewal allowed
3141
3142     # Look in the issues table for this item, lent to this borrower,
3143     # and not yet returned.
3144
3145     # FIXME - I think this function could be redone to use only one SQL call.
3146     my $sth = $dbh->prepare(
3147         "select * from issues
3148                                 where (borrowernumber = ?)
3149                                 and (itemnumber = ?)"
3150     );
3151     $sth->execute( $bornum, $itemno );
3152     my $data = $sth->fetchrow_hashref;
3153     $renewcount = $data->{'renewals'} if $data->{'renewals'};
3154     # $item and $borrower should be calculated
3155     my $branchcode = _GetCircControlBranch($item->unblessed, $patron->unblessed);
3156
3157     my $rule = Koha::CirculationRules->get_effective_rule(
3158         {
3159             categorycode => $patron->categorycode,
3160             itemtype     => $item->effective_itemtype,
3161             branchcode   => $branchcode,
3162             rule_name    => 'renewalsallowed',
3163         }
3164     );
3165
3166     $renewsallowed = $rule ? $rule->rule_value : 0;
3167     $renewsleft    = $renewsallowed - $renewcount;
3168     if($renewsleft < 0){ $renewsleft = 0; }
3169     return ( $renewcount, $renewsallowed, $renewsleft );
3170 }
3171
3172 =head2 GetSoonestRenewDate
3173
3174   $NoRenewalBeforeThisDate = &GetSoonestRenewDate($borrowernumber, $itemnumber);
3175
3176 Find out the soonest possible renew date of a borrowed item.
3177
3178 C<$borrowernumber> is the borrower number of the patron who currently
3179 has the item on loan.
3180
3181 C<$itemnumber> is the number of the item to renew.
3182
3183 C<$GetSoonestRenewDate> returns the DateTime of the soonest possible
3184 renew date, based on the value "No renewal before" of the applicable
3185 issuing rule. Returns the current date if the item can already be
3186 renewed, and returns undefined if the borrower, loan, or item
3187 cannot be found.
3188
3189 =cut
3190
3191 sub GetSoonestRenewDate {
3192     my ( $borrowernumber, $itemnumber ) = @_;
3193
3194     my $dbh = C4::Context->dbh;
3195
3196     my $item      = Koha::Items->find($itemnumber)      or return;
3197     my $itemissue = $item->checkout or return;
3198
3199     $borrowernumber ||= $itemissue->borrowernumber;
3200     my $patron = Koha::Patrons->find( $borrowernumber )
3201       or return;
3202
3203     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3204     my $issuing_rule = Koha::CirculationRules->get_effective_rules(
3205         {   categorycode => $patron->categorycode,
3206             itemtype     => $item->effective_itemtype,
3207             branchcode   => $branchcode,
3208             rules => [
3209                 'norenewalbefore',
3210                 'lengthunit',
3211             ]
3212         }
3213     );
3214
3215     my $now = dt_from_string;
3216     return $now unless $issuing_rule;
3217
3218     if ( defined $issuing_rule->{norenewalbefore}
3219         and $issuing_rule->{norenewalbefore} ne "" )
3220     {
3221         my $soonestrenewal =
3222           dt_from_string( $itemissue->date_due )->subtract(
3223             $issuing_rule->{lengthunit} => $issuing_rule->{norenewalbefore} );
3224
3225         if ( C4::Context->preference('NoRenewalBeforePrecision') eq 'date'
3226             and $issuing_rule->{lengthunit} eq 'days' )
3227         {
3228             $soonestrenewal->truncate( to => 'day' );
3229         }
3230         return $soonestrenewal if $now < $soonestrenewal;
3231     }
3232     return $now;
3233 }
3234
3235 =head2 GetLatestAutoRenewDate
3236
3237   $NoAutoRenewalAfterThisDate = &GetLatestAutoRenewDate($borrowernumber, $itemnumber);
3238
3239 Find out the latest possible auto renew date of a borrowed item.
3240
3241 C<$borrowernumber> is the borrower number of the patron who currently
3242 has the item on loan.
3243
3244 C<$itemnumber> is the number of the item to renew.
3245
3246 C<$GetLatestAutoRenewDate> returns the DateTime of the latest possible
3247 auto renew date, based on the value "No auto renewal after" and the "No auto
3248 renewal after (hard limit) of the applicable issuing rule.
3249 Returns undef if there is no date specify in the circ rules or if the patron, loan,
3250 or item cannot be found.
3251
3252 =cut
3253
3254 sub GetLatestAutoRenewDate {
3255     my ( $borrowernumber, $itemnumber ) = @_;
3256
3257     my $dbh = C4::Context->dbh;
3258
3259     my $item      = Koha::Items->find($itemnumber)  or return;
3260     my $itemissue = $item->checkout                 or return;
3261
3262     $borrowernumber ||= $itemissue->borrowernumber;
3263     my $patron = Koha::Patrons->find( $borrowernumber )
3264       or return;
3265
3266     my $branchcode = _GetCircControlBranch( $item->unblessed, $patron->unblessed );
3267     my $circulation_rules = Koha::CirculationRules->get_effective_rules(
3268         {
3269             categorycode => $patron->categorycode,
3270             itemtype     => $item->effective_itemtype,
3271             branchcode   => $branchcode,
3272             rules => [
3273                 'no_auto_renewal_after',
3274                 'no_auto_renewal_after_hard_limit',
3275                 'lengthunit',
3276             ]
3277         }
3278     );
3279
3280     return unless $circulation_rules;
3281     return
3282       if ( not $circulation_rules->{no_auto_renewal_after}
3283             or $circulation_rules->{no_auto_renewal_after} eq '' )
3284       and ( not $circulation_rules->{no_auto_renewal_after_hard_limit}
3285              or $circulation_rules->{no_auto_renewal_after_hard_limit} eq '' );
3286
3287     my $maximum_renewal_date;
3288     if ( $circulation_rules->{no_auto_renewal_after} ) {
3289         $maximum_renewal_date = dt_from_string($itemissue->issuedate);
3290         $maximum_renewal_date->add(
3291             $circulation_rules->{lengthunit} => $circulation_rules->{no_auto_renewal_after}
3292         );
3293     }
3294
3295     if ( $circulation_rules->{no_auto_renewal_after_hard_limit} ) {
3296         my $dt = dt_from_string( $circulation_rules->{no_auto_renewal_after_hard_limit} );
3297         $maximum_renewal_date = $dt if not $maximum_renewal_date or $maximum_renewal_date > $dt;
3298     }
3299     return $maximum_renewal_date;
3300 }
3301
3302
3303 =head2 GetIssuingCharges
3304
3305   ($charge, $item_type) = &GetIssuingCharges($itemnumber, $borrowernumber);
3306
3307 Calculate how much it would cost for a given patron to borrow a given
3308 item, including any applicable discounts.
3309
3310 C<$itemnumber> is the item number of item the patron wishes to borrow.
3311
3312 C<$borrowernumber> is the patron's borrower number.
3313
3314 C<&GetIssuingCharges> returns two values: C<$charge> is the rental charge,
3315 and C<$item_type> is the code for the item's item type (e.g., C<VID>
3316 if it's a video).
3317
3318 =cut
3319
3320 sub GetIssuingCharges {
3321
3322     # calculate charges due
3323     my ( $itemnumber, $borrowernumber ) = @_;
3324     my $charge = 0;
3325     my $dbh    = C4::Context->dbh;
3326     my $item_type;
3327
3328     # Get the book's item type and rental charge (via its biblioitem).
3329     my $charge_query = 'SELECT itemtypes.itemtype,rentalcharge FROM items
3330         LEFT JOIN biblioitems ON biblioitems.biblioitemnumber = items.biblioitemnumber';
3331     $charge_query .= (C4::Context->preference('item-level_itypes'))
3332         ? ' LEFT JOIN itemtypes ON items.itype = itemtypes.itemtype'
3333         : ' LEFT JOIN itemtypes ON biblioitems.itemtype = itemtypes.itemtype';
3334
3335     $charge_query .= ' WHERE items.itemnumber =?';
3336
3337     my $sth = $dbh->prepare($charge_query);
3338     $sth->execute($itemnumber);
3339     if ( my $item_data = $sth->fetchrow_hashref ) {
3340         $item_type = $item_data->{itemtype};
3341         $charge    = $item_data->{rentalcharge};
3342         my $branch = C4::Context::mybranch();
3343         my $patron = Koha::Patrons->find( $borrowernumber );
3344         my $discount = _get_discount_from_rule($patron->categorycode, $branch, $item_type);
3345         if ($discount) {
3346             # We may have multiple rules so get the most specific
3347             $charge = ( $charge * ( 100 - $discount ) ) / 100;
3348         }
3349         if ($charge) {
3350             $charge = sprintf '%.2f', $charge; # ensure no fractions of a penny returned
3351         }
3352     }
3353
3354     return ( $charge, $item_type );
3355 }
3356
3357 # Select most appropriate discount rule from those returned
3358 sub _get_discount_from_rule {
3359     my ($categorycode, $branchcode, $itemtype) = @_;
3360
3361     # Set search precedences
3362     my @params = (
3363         {
3364             branchcode   => $branchcode,
3365             itemtype     => $itemtype,
3366             categorycode => $categorycode,
3367         },
3368         {
3369             branchcode   => undef,
3370             categorycode => $categorycode,
3371             itemtype     => $itemtype,
3372         },
3373         {
3374             branchcode   => $branchcode,
3375             categorycode => $categorycode,
3376             itemtype     => undef,
3377         },
3378         {
3379             branchcode   => undef,
3380             categorycode => $categorycode,
3381             itemtype     => undef,
3382         },
3383     );
3384
3385     foreach my $params (@params) {
3386         my $rule = Koha::CirculationRules->search(
3387             {
3388                 rule_name => 'rentaldiscount',
3389                 %$params,
3390             }
3391         )->next();
3392
3393         return $rule->rule_value if $rule;
3394     }
3395
3396     # none of the above
3397     return 0;
3398 }
3399
3400 =head2 AddIssuingCharge
3401
3402   &AddIssuingCharge( $checkout, $charge, $type )
3403
3404 =cut
3405
3406 sub AddIssuingCharge {
3407     my ( $checkout, $charge, $type ) = @_;
3408
3409     # FIXME What if checkout does not exist?
3410
3411     my $account = Koha::Account->new({ patron_id => $checkout->borrowernumber });
3412     my $accountline = $account->add_debit(
3413         {
3414             amount      => $charge,
3415             note        => undef,
3416             user_id     => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
3417             library_id  => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
3418             interface   => C4::Context->interface,
3419             type        => $type,
3420             item_id     => $checkout->itemnumber,
3421             issue_id    => $checkout->issue_id,
3422         }
3423     );
3424 }
3425
3426 =head2 GetTransfers
3427
3428   GetTransfers($itemnumber);
3429
3430 =cut
3431
3432 sub GetTransfers {
3433     my ($itemnumber) = @_;
3434
3435     my $dbh = C4::Context->dbh;
3436
3437     my $query = '
3438         SELECT datesent,
3439                frombranch,
3440                tobranch,
3441                branchtransfer_id
3442         FROM branchtransfers
3443         WHERE itemnumber = ?
3444           AND datearrived IS NULL
3445         ';
3446     my $sth = $dbh->prepare($query);
3447     $sth->execute($itemnumber);
3448     my @row = $sth->fetchrow_array();
3449     return @row;
3450 }
3451
3452 =head2 GetTransfersFromTo
3453
3454   @results = GetTransfersFromTo($frombranch,$tobranch);
3455
3456 Returns the list of pending transfers between $from and $to branch
3457
3458 =cut
3459
3460 sub GetTransfersFromTo {
3461     my ( $frombranch, $tobranch ) = @_;
3462     return unless ( $frombranch && $tobranch );
3463     my $dbh   = C4::Context->dbh;
3464     my $query = "
3465         SELECT branchtransfer_id,itemnumber,datesent,frombranch
3466         FROM   branchtransfers
3467         WHERE  frombranch=?
3468           AND  tobranch=?
3469           AND datearrived IS NULL
3470     ";
3471     my $sth = $dbh->prepare($query);
3472     $sth->execute( $frombranch, $tobranch );
3473     my @gettransfers;
3474
3475     while ( my $data = $sth->fetchrow_hashref ) {
3476         push @gettransfers, $data;
3477     }
3478     return (@gettransfers);
3479 }
3480
3481 =head2 DeleteTransfer
3482
3483   &DeleteTransfer($itemnumber);
3484
3485 =cut
3486
3487 sub DeleteTransfer {
3488     my ($itemnumber) = @_;
3489     return unless $itemnumber;
3490     my $dbh          = C4::Context->dbh;
3491     my $sth          = $dbh->prepare(
3492         "DELETE FROM branchtransfers
3493          WHERE itemnumber=?
3494          AND datearrived IS NULL "
3495     );
3496     return $sth->execute($itemnumber);
3497 }
3498
3499 =head2 SendCirculationAlert
3500
3501 Send out a C<check-in> or C<checkout> alert using the messaging system.
3502
3503 B<Parameters>:
3504
3505 =over 4
3506
3507 =item type
3508
3509 Valid values for this parameter are: C<CHECKIN> and C<CHECKOUT>.
3510
3511 =item item
3512
3513 Hashref of information about the item being checked in or out.
3514
3515 =item borrower
3516
3517 Hashref of information about the borrower of the item.
3518
3519 =item branch
3520
3521 The branchcode from where the checkout or check-in took place.
3522
3523 =back
3524
3525 B<Example>:
3526
3527     SendCirculationAlert({
3528         type     => 'CHECKOUT',
3529         item     => $item,
3530         borrower => $borrower,
3531         branch   => $branch,
3532     });
3533
3534 =cut
3535
3536 sub SendCirculationAlert {
3537     my ($opts) = @_;
3538     my ($type, $item, $borrower, $branch) =
3539         ($opts->{type}, $opts->{item}, $opts->{borrower}, $opts->{branch});
3540     my %message_name = (
3541         CHECKIN  => 'Item_Check_in',
3542         CHECKOUT => 'Item_Checkout',
3543         RENEWAL  => 'Item_Checkout',
3544     );
3545     my $borrower_preferences = C4::Members::Messaging::GetMessagingPreferences({
3546         borrowernumber => $borrower->{borrowernumber},
3547         message_name   => $message_name{$type},
3548     });
3549     my $issues_table = ( $type eq 'CHECKOUT' || $type eq 'RENEWAL' ) ? 'issues' : 'old_issues';
3550
3551     my $schema = Koha::Database->new->schema;
3552     my @transports = keys %{ $borrower_preferences->{transports} };
3553
3554     # From the MySQL doc:
3555     # LOCK TABLES is not transaction-safe and implicitly commits any active transaction before attempting to lock the tables.
3556     # If the LOCK/UNLOCK statements are executed from tests, the current transaction will be committed.
3557     # To avoid that we need to guess if this code is execute from tests or not (yes it is a bit hacky)
3558     my $do_not_lock = ( exists $ENV{_} && $ENV{_} =~ m|prove| ) || $ENV{KOHA_TESTING};
3559
3560     for my $mtt (@transports) {
3561         my $letter =  C4::Letters::GetPreparedLetter (
3562             module => 'circulation',
3563             letter_code => $type,
3564             branchcode => $branch,
3565             message_transport_type => $mtt,
3566             lang => $borrower->{lang},
3567             tables => {
3568                 $issues_table => $item->{itemnumber},
3569                 'items'       => $item->{itemnumber},
3570                 'biblio'      => $item->{biblionumber},
3571                 'biblioitems' => $item->{biblionumber},
3572                 'borrowers'   => $borrower,
3573                 'branches'    => $branch,
3574             }
3575         ) or next;
3576
3577         $schema->storage->txn_begin;
3578         C4::Context->dbh->do(q|LOCK TABLE message_queue READ|) unless $do_not_lock;
3579         C4::Context->dbh->do(q|LOCK TABLE message_queue WRITE|) unless $do_not_lock;
3580         my $message = C4::Message->find_last_message($borrower, $type, $mtt);
3581         unless ( $message ) {
3582             C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3583             C4::Message->enqueue($letter, $borrower, $mtt);
3584         } else {
3585             $message->append($letter);
3586             $message->update;
3587         }
3588         C4::Context->dbh->do(q|UNLOCK TABLES|) unless $do_not_lock;
3589         $schema->storage->txn_commit;
3590     }
3591
3592     return;
3593 }
3594
3595 =head2 updateWrongTransfer
3596
3597   $items = updateWrongTransfer($itemNumber,$borrowernumber,$waitingAtLibrary,$FromLibrary);
3598
3599 This function validate the line of brachtransfer but with the wrong destination (mistake from a librarian ...), and create a new line in branchtransfer from the actual library to the original library of reservation
3600
3601 =cut
3602
3603 sub updateWrongTransfer {
3604         my ( $itemNumber,$waitingAtLibrary,$FromLibrary ) = @_;
3605         my $dbh = C4::Context->dbh;
3606 # first step validate the actual line of transfert .
3607         my $sth =
3608                 $dbh->prepare(
3609                         "update branchtransfers set datearrived = now(),tobranch=?,comments='wrongtransfer' where itemnumber= ? AND datearrived IS NULL"
3610                 );
3611                 $sth->execute($FromLibrary,$itemNumber);
3612
3613 # second step create a new line of branchtransfer to the right location .
3614         ModItemTransfer($itemNumber, $FromLibrary, $waitingAtLibrary);
3615
3616 #third step changing holdingbranch of item
3617     my $item = Koha::Items->find($itemNumber)->holdingbranch($FromLibrary)->store;
3618 }
3619
3620 =head2 CalcDateDue
3621
3622 $newdatedue = CalcDateDue($startdate,$itemtype,$branchcode,$borrower);
3623
3624 this function calculates the due date given the start date and configured circulation rules,
3625 checking against the holidays calendar as per the daysmode circulation rule.
3626 C<$startdate>   = DateTime object representing start date of loan period (assumed to be today)
3627 C<$itemtype>  = itemtype code of item in question
3628 C<$branch>  = location whose calendar to use
3629 C<$borrower> = Borrower object
3630 C<$isrenewal> = Boolean: is true if we want to calculate the date due for a renewal. Else is false.
3631
3632 =cut
3633
3634 sub CalcDateDue {
3635     my ( $startdate, $itemtype, $branch, $borrower, $isrenewal ) = @_;
3636
3637     $isrenewal ||= 0;
3638
3639     # loanlength now a href
3640     my $loanlength =
3641             GetLoanLength( $borrower->{'categorycode'}, $itemtype, $branch );
3642
3643     my $length_key = ( $isrenewal and defined $loanlength->{renewalperiod} )
3644             ? qq{renewalperiod}
3645             : qq{issuelength};
3646
3647     my $datedue;
3648     if ( $startdate ) {
3649         if (ref $startdate ne 'DateTime' ) {
3650             $datedue = dt_from_string($datedue);
3651         } else {
3652             $datedue = $startdate->clone;
3653         }
3654     } else {
3655         $datedue = dt_from_string()->truncate( to => 'minute' );
3656     }
3657
3658
3659     my $daysmode = Koha::CirculationRules->get_effective_daysmode(
3660         {
3661             categorycode => $borrower->{categorycode},
3662             itemtype     => $itemtype,
3663             branchcode   => $branch,
3664         }
3665     );
3666
3667     # calculate the datedue as normal
3668     if ( $daysmode eq 'Days' )
3669     {    # ignoring calendar
3670         if ( $loanlength->{lengthunit} eq 'hours' ) {
3671             $datedue->add( hours => $loanlength->{$length_key} );
3672         } else {    # days
3673             $datedue->add( days => $loanlength->{$length_key} );
3674             $datedue->set_hour(23);
3675             $datedue->set_minute(59);
3676         }
3677     } else {
3678         my $dur;
3679         if ($loanlength->{lengthunit} eq 'hours') {
3680             $dur = DateTime::Duration->new( hours => $loanlength->{$length_key});
3681         }
3682         else { # days
3683             $dur = DateTime::Duration->new( days => $loanlength->{$length_key});
3684         }
3685         my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3686         $datedue = $calendar->addDate( $datedue, $dur, $loanlength->{lengthunit} );
3687         if ($loanlength->{lengthunit} eq 'days') {
3688             $datedue->set_hour(23);
3689             $datedue->set_minute(59);
3690         }
3691     }
3692
3693     # if Hard Due Dates are used, retrieve them and apply as necessary
3694     my ( $hardduedate, $hardduedatecompare ) =
3695       GetHardDueDate( $borrower->{'categorycode'}, $itemtype, $branch );
3696     if ($hardduedate) {    # hardduedates are currently dates
3697         $hardduedate->truncate( to => 'minute' );
3698         $hardduedate->set_hour(23);
3699         $hardduedate->set_minute(59);
3700         my $cmp = DateTime->compare( $hardduedate, $datedue );
3701
3702 # if the calculated due date is after the 'before' Hard Due Date (ceiling), override
3703 # if the calculated date is before the 'after' Hard Due Date (floor), override
3704 # if the hard due date is set to 'exactly', overrride
3705         if ( $hardduedatecompare == 0 || $hardduedatecompare == $cmp ) {
3706             $datedue = $hardduedate->clone;
3707         }
3708
3709         # in all other cases, keep the date due as it is
3710
3711     }
3712
3713     # if ReturnBeforeExpiry ON the datedue can't be after borrower expirydate
3714     if ( C4::Context->preference('ReturnBeforeExpiry') ) {
3715         my $expiry_dt = dt_from_string( $borrower->{dateexpiry}, 'iso', 'floating');
3716         if( $expiry_dt ) { #skip empty expiry date..
3717             $expiry_dt->set( hour => 23, minute => 59);
3718             my $d1= $datedue->clone->set_time_zone('floating');
3719             if ( DateTime->compare( $d1, $expiry_dt ) == 1 ) {
3720                 $datedue = $expiry_dt->clone->set_time_zone( C4::Context->tz );
3721             }
3722         }
3723         if ( $daysmode ne 'Days' ) {
3724           my $calendar = Koha::Calendar->new( branchcode => $branch, days_mode => $daysmode );
3725           if ( $calendar->is_holiday($datedue) ) {
3726               # Don't return on a closed day
3727               $datedue = $calendar->prev_open_days( $datedue, 1 );
3728           }
3729         }
3730     }
3731
3732     return $datedue;
3733 }
3734
3735
3736 sub CheckValidBarcode{
3737 my ($barcode) = @_;
3738 my $dbh = C4::Context->dbh;
3739 my $query=qq|SELECT count(*)
3740              FROM items
3741              WHERE barcode=?
3742             |;
3743 my $sth = $dbh->prepare($query);
3744 $sth->execute($barcode);
3745 my $exist=$sth->fetchrow ;
3746 return $exist;
3747 }
3748
3749 =head2 IsBranchTransferAllowed
3750
3751   $allowed = IsBranchTransferAllowed( $toBranch, $fromBranch, $code );
3752
3753 Code is either an itemtype or collection doe depending on the pref BranchTransferLimitsType
3754
3755 Deprecated in favor of Koha::Item::Transfer::Limits->find/search and
3756 Koha::Item->can_be_transferred.
3757
3758 =cut
3759
3760 sub IsBranchTransferAllowed {
3761         my ( $toBranch, $fromBranch, $code ) = @_;
3762
3763         if ( $toBranch eq $fromBranch ) { return 1; } ## Short circuit for speed.
3764
3765         my $limitType = C4::Context->preference("BranchTransferLimitsType");
3766         my $dbh = C4::Context->dbh;
3767
3768         my $sth = $dbh->prepare("SELECT * FROM branch_transfer_limits WHERE toBranch = ? AND fromBranch = ? AND $limitType = ?");
3769         $sth->execute( $toBranch, $fromBranch, $code );
3770         my $limit = $sth->fetchrow_hashref();
3771
3772         ## If a row is found, then that combination is not allowed, if no matching row is found, then the combination *is allowed*
3773         if ( $limit->{'limitId'} ) {
3774                 return 0;
3775         } else {
3776                 return 1;
3777         }
3778 }
3779
3780 =head2 CreateBranchTransferLimit
3781
3782   CreateBranchTransferLimit( $toBranch, $fromBranch, $code );
3783
3784 $code is either itemtype or collection code depending on what the pref BranchTransferLimitsType is set to.
3785
3786 Deprecated in favor of Koha::Item::Transfer::Limit->new.
3787
3788 =cut
3789
3790 sub CreateBranchTransferLimit {
3791    my ( $toBranch, $fromBranch, $code ) = @_;
3792    return unless defined($toBranch) && defined($fromBranch);
3793    my $limitType = C4::Context->preference("BranchTransferLimitsType");
3794
3795    my $dbh = C4::Context->dbh;
3796
3797    my $sth = $dbh->prepare("INSERT INTO branch_transfer_limits ( $limitType, toBranch, fromBranch ) VALUES ( ?, ?, ? )");
3798    return $sth->execute( $code, $toBranch, $fromBranch );
3799 }
3800
3801 =head2 DeleteBranchTransferLimits
3802
3803     my $result = DeleteBranchTransferLimits($frombranch);
3804
3805 Deletes all the library transfer limits for one library.  Returns the
3806 number of limits deleted, 0e0 if no limits were deleted, or undef if
3807 no arguments are supplied.
3808
3809 Deprecated in favor of Koha::Item::Transfer::Limits->search({
3810     fromBranch => $fromBranch
3811     })->delete.
3812
3813 =cut
3814
3815 sub DeleteBranchTransferLimits {
3816     my $branch = shift;
3817     return unless defined $branch;
3818     my $dbh    = C4::Context->dbh;
3819     my $sth    = $dbh->prepare("DELETE FROM branch_transfer_limits WHERE fromBranch = ?");
3820     return $sth->execute($branch);
3821 }
3822
3823 sub ReturnLostItem{
3824     my ( $borrowernumber, $itemnum ) = @_;
3825     MarkIssueReturned( $borrowernumber, $itemnum );
3826 }
3827
3828
3829 sub LostItem{
3830     my ($itemnumber, $mark_lost_from, $force_mark_returned) = @_;
3831
3832     unless ( $mark_lost_from ) {
3833         # Temporary check to avoid regressions
3834         die q|LostItem called without $mark_lost_from, check the API.|;
3835     }
3836
3837     my $mark_returned;
3838     if ( $force_mark_returned ) {
3839         $mark_returned = 1;
3840     } else {
3841         my $pref = C4::Context->preference('MarkLostItemsAsReturned') // q{};
3842         $mark_returned = ( $pref =~ m|$mark_lost_from| );
3843     }
3844
3845     my $dbh = C4::Context->dbh();
3846     my $sth=$dbh->prepare("SELECT issues.*,items.*,biblio.title
3847                            FROM issues
3848                            JOIN items USING (itemnumber)
3849                            JOIN biblio USING (biblionumber)
3850                            WHERE issues.itemnumber=?");
3851     $sth->execute($itemnumber);
3852     my $issues=$sth->fetchrow_hashref();
3853
3854     # If a borrower lost the item, add a replacement cost to the their record
3855     if ( my $borrowernumber = $issues->{borrowernumber} ){
3856         my $patron = Koha::Patrons->find( $borrowernumber );
3857
3858         my $fix = _FixOverduesOnReturn($borrowernumber, $itemnumber, C4::Context->preference('WhenLostForgiveFine'), 'LOST');
3859         defined($fix) or warn "_FixOverduesOnReturn($borrowernumber, $itemnumber...) failed!";  # zero is OK, check defined
3860
3861         if (C4::Context->preference('WhenLostChargeReplacementFee')){
3862             C4::Accounts::chargelostitem(
3863                 $borrowernumber,
3864                 $itemnumber,
3865                 $issues->{'replacementprice'},
3866                 sprintf( "%s %s %s",
3867                     $issues->{'title'}          || q{},
3868                     $issues->{'barcode'}        || q{},
3869                     $issues->{'itemcallnumber'} || q{},
3870                 ),
3871             );
3872             #FIXME : Should probably have a way to distinguish this from an item that really was returned.
3873             #warn " $issues->{'borrowernumber'}  /  $itemnumber ";
3874         }
3875
3876         MarkIssueReturned($borrowernumber,$itemnumber,undef,$patron->privacy) if $mark_returned;
3877     }
3878
3879     #When item is marked lost automatically cancel its outstanding transfers and set items holdingbranch to the transfer source branch (frombranch)
3880     if (my ( $datesent,$frombranch,$tobranch ) = GetTransfers($itemnumber)) {
3881         Koha::Items->find($itemnumber)->holdingbranch($frombranch)->store;
3882     }
3883     my $transferdeleted = DeleteTransfer($itemnumber);
3884 }
3885
3886 sub GetOfflineOperations {
3887     my $dbh = C4::Context->dbh;
3888     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE branchcode=? ORDER BY timestamp");
3889     $sth->execute(C4::Context->userenv->{'branch'});
3890     my $results = $sth->fetchall_arrayref({});
3891     return $results;
3892 }
3893
3894 sub GetOfflineOperation {
3895     my $operationid = shift;
3896     return unless $operationid;
3897     my $dbh = C4::Context->dbh;
3898     my $sth = $dbh->prepare("SELECT * FROM pending_offline_operations WHERE operationid=?");
3899     $sth->execute( $operationid );
3900     return $sth->fetchrow_hashref;
3901 }
3902
3903 sub AddOfflineOperation {
3904     my ( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount ) = @_;
3905     my $dbh = C4::Context->dbh;
3906     my $sth = $dbh->prepare("INSERT INTO pending_offline_operations (userid, branchcode, timestamp, action, barcode, cardnumber, amount) VALUES(?,?,?,?,?,?,?)");
3907     $sth->execute( $userid, $branchcode, $timestamp, $action, $barcode, $cardnumber, $amount );
3908     return "Added.";
3909 }
3910
3911 sub DeleteOfflineOperation {
3912     my $dbh = C4::Context->dbh;
3913     my $sth = $dbh->prepare("DELETE FROM pending_offline_operations WHERE operationid=?");
3914     $sth->execute( shift );
3915     return "Deleted.";
3916 }
3917
3918 sub ProcessOfflineOperation {
3919     my $operation = shift;
3920
3921     my $report;
3922     if ( $operation->{action} eq 'return' ) {
3923         $report = ProcessOfflineReturn( $operation );
3924     } elsif ( $operation->{action} eq 'issue' ) {
3925         $report = ProcessOfflineIssue( $operation );
3926     } elsif ( $operation->{action} eq 'payment' ) {
3927         $report = ProcessOfflinePayment( $operation );
3928     }
3929
3930     DeleteOfflineOperation( $operation->{operationid} ) if $operation->{operationid};
3931
3932     return $report;
3933 }
3934
3935 sub ProcessOfflineReturn {
3936     my $operation = shift;
3937
3938     my $item = Koha::Items->find({barcode => $operation->{barcode}});
3939
3940     if ( $item ) {
3941         my $itemnumber = $item->itemnumber;
3942         my $issue = GetOpenIssue( $itemnumber );
3943         if ( $issue ) {
3944             my $leave_item_lost = C4::Context->preference("BlockReturnOfLostItems") ? 1 : 0;
3945             ModDateLastSeen( $itemnumber, $leave_item_lost );
3946             MarkIssueReturned(
3947                 $issue->{borrowernumber},
3948                 $itemnumber,
3949                 $operation->{timestamp},
3950             );
3951             $item->renewals(0);
3952             $item->onloan(undef);
3953             $item->store({ log_action => 0 });
3954             return "Success.";
3955         } else {
3956             return "Item not issued.";
3957         }
3958     } else {
3959         return "Item not found.";
3960     }
3961 }
3962
3963 sub ProcessOfflineIssue {
3964     my $operation = shift;
3965
3966     my $patron = Koha::Patrons->find( { cardnumber => $operation->{cardnumber} } );
3967
3968     if ( $patron ) {
3969         my $item = Koha::Items->find({ barcode => $operation->{barcode} });
3970         unless ($item) {
3971             return "Barcode not found.";
3972         }
3973         my $itemnumber = $item->itemnumber;
3974         my $issue = GetOpenIssue( $itemnumber );
3975
3976         if ( $issue and ( $issue->{borrowernumber} ne $patron->borrowernumber ) ) { # Item already issued to another patron mark it returned
3977             MarkIssueReturned(
3978                 $issue->{borrowernumber},
3979                 $itemnumber,
3980                 $operation->{timestamp},
3981             );
3982         }
3983         AddIssue(
3984             $patron->unblessed,
3985             $operation->{'barcode'},
3986             undef,
3987             1,
3988             $operation->{timestamp},
3989             undef,
3990         );
3991         return "Success.";
3992     } else {
3993         return "Borrower not found.";
3994     }
3995 }
3996
3997 sub ProcessOfflinePayment {
3998     my $operation = shift;
3999
4000     my $patron = Koha::Patrons->find({ cardnumber => $operation->{cardnumber} });
4001
4002     $patron->account->pay(
4003         {
4004             amount     => $operation->{amount},
4005             library_id => $operation->{branchcode},
4006             interface  => 'koc'
4007         }
4008     );
4009
4010     return "Success.";
4011 }
4012
4013 =head2 TransferSlip
4014
4015   TransferSlip($user_branch, $itemnumber, $barcode, $to_branch)
4016
4017   Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
4018
4019 =cut
4020
4021 sub TransferSlip {
4022     my ($branch, $itemnumber, $barcode, $to_branch) = @_;
4023
4024     my $item =
4025       $itemnumber
4026       ? Koha::Items->find($itemnumber)
4027       : Koha::Items->find( { barcode => $barcode } );
4028
4029     $item or return;
4030
4031     return C4::Letters::GetPreparedLetter (
4032         module => 'circulation',
4033         letter_code => 'TRANSFERSLIP',
4034         branchcode => $branch,
4035         tables => {
4036             'branches'    => $to_branch,
4037             'biblio'      => $item->biblionumber,
4038             'items'       => $item->unblessed,
4039         },
4040     );
4041 }
4042
4043 =head2 CheckIfIssuedToPatron
4044
4045   CheckIfIssuedToPatron($borrowernumber, $biblionumber)
4046
4047   Return 1 if any record item is issued to patron, otherwise return 0
4048
4049 =cut
4050
4051 sub CheckIfIssuedToPatron {
4052     my ($borrowernumber, $biblionumber) = @_;
4053
4054     my $dbh = C4::Context->dbh;
4055     my $query = q|
4056         SELECT COUNT(*) FROM issues
4057         LEFT JOIN items ON items.itemnumber = issues.itemnumber
4058         WHERE items.biblionumber = ?
4059         AND issues.borrowernumber = ?
4060     |;
4061     my $is_issued = $dbh->selectrow_array($query, {}, $biblionumber, $borrowernumber );
4062     return 1 if $is_issued;
4063     return;
4064 }
4065
4066 =head2 IsItemIssued
4067
4068   IsItemIssued( $itemnumber )
4069
4070   Return 1 if the item is on loan, otherwise return 0
4071
4072 =cut
4073
4074 sub IsItemIssued {
4075     my $itemnumber = shift;
4076     my $dbh = C4::Context->dbh;
4077     my $sth = $dbh->prepare(q{
4078         SELECT COUNT(*)
4079         FROM issues
4080         WHERE itemnumber = ?
4081     });
4082     $sth->execute($itemnumber);
4083     return $sth->fetchrow;
4084 }
4085
4086 =head2 GetAgeRestriction
4087
4088   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions, $borrower);
4089   my ($ageRestriction, $daysToAgeRestriction) = GetAgeRestriction($record_restrictions);
4090
4091   if($daysToAgeRestriction <= 0) { #Borrower is allowed to access this material, as they are older or as old as the agerestriction }
4092   if($daysToAgeRestriction > 0) { #Borrower is this many days from meeting the agerestriction }
4093
4094 @PARAM1 the koha.biblioitems.agerestriction value, like K18, PEGI 13, ...
4095 @PARAM2 a borrower-object with koha.borrowers.dateofbirth. (OPTIONAL)
4096 @RETURNS The age restriction age in years and the days to fulfill the age restriction for the given borrower.
4097          Negative days mean the borrower has gone past the age restriction age.
4098
4099 =cut
4100
4101 sub GetAgeRestriction {
4102     my ($record_restrictions, $borrower) = @_;
4103     my $markers = C4::Context->preference('AgeRestrictionMarker');
4104
4105     return unless $record_restrictions;
4106     # Split $record_restrictions to something like FSK 16 or PEGI 6
4107     my @values = split ' ', uc($record_restrictions);
4108     return unless @values;
4109
4110     # Search first occurrence of one of the markers
4111     my @markers = split /\|/, uc($markers);
4112     return unless @markers;
4113
4114     my $index            = 0;
4115     my $restriction_year = 0;
4116     for my $value (@values) {
4117         $index++;
4118         for my $marker (@markers) {
4119             $marker =~ s/^\s+//;    #remove leading spaces
4120             $marker =~ s/\s+$//;    #remove trailing spaces
4121             if ( $marker eq $value ) {
4122                 if ( $index <= $#values ) {
4123                     $restriction_year += $values[$index];
4124                 }
4125                 last;
4126             }
4127             elsif ( $value =~ /^\Q$marker\E(\d+)$/ ) {
4128
4129                 # Perhaps it is something like "K16" (as in Finland)
4130                 $restriction_year += $1;
4131                 last;
4132             }
4133         }
4134         last if ( $restriction_year > 0 );
4135     }
4136
4137     #Check if the borrower is age restricted for this material and for how long.
4138     if ($restriction_year && $borrower) {
4139         if ( $borrower->{'dateofbirth'} ) {
4140             my @alloweddate = split /-/, $borrower->{'dateofbirth'};
4141             $alloweddate[0] += $restriction_year;
4142
4143             #Prevent runime eror on leap year (invalid date)
4144             if ( ( $alloweddate[1] == 2 ) && ( $alloweddate[2] == 29 ) ) {
4145                 $alloweddate[2] = 28;
4146             }
4147
4148             #Get how many days the borrower has to reach the age restriction
4149             my @Today = split /-/, dt_from_string()->ymd();
4150             my $daysToAgeRestriction = Date_to_Days(@alloweddate) - Date_to_Days(@Today);
4151             #Negative days means the borrower went past the age restriction age
4152             return ($restriction_year, $daysToAgeRestriction);
4153         }
4154     }
4155
4156     return ($restriction_year);
4157 }
4158
4159
4160 =head2 GetPendingOnSiteCheckouts
4161
4162 =cut
4163
4164 sub GetPendingOnSiteCheckouts {
4165     my $dbh = C4::Context->dbh;
4166     return $dbh->selectall_arrayref(q|
4167         SELECT
4168           items.barcode,
4169           items.biblionumber,
4170           items.itemnumber,
4171           items.itemnotes,
4172           items.itemcallnumber,
4173           items.location,
4174           issues.date_due,
4175           issues.branchcode,
4176           issues.date_due < NOW() AS is_overdue,
4177           biblio.author,
4178           biblio.title,
4179           borrowers.firstname,
4180           borrowers.surname,
4181           borrowers.cardnumber,
4182           borrowers.borrowernumber
4183         FROM items
4184         LEFT JOIN issues ON items.itemnumber = issues.itemnumber
4185         LEFT JOIN biblio ON items.biblionumber = biblio.biblionumber
4186         LEFT JOIN borrowers ON issues.borrowernumber = borrowers.borrowernumber
4187         WHERE issues.onsite_checkout = 1
4188     |, { Slice => {} } );
4189 }
4190
4191 sub GetTopIssues {
4192     my ($params) = @_;
4193
4194     my ($count, $branch, $itemtype, $ccode, $newness)
4195         = @$params{qw(count branch itemtype ccode newness)};
4196
4197     my $dbh = C4::Context->dbh;
4198     my $query = q{
4199         SELECT * FROM (
4200         SELECT b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4201           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4202           i.ccode, SUM(i.issues) AS count
4203         FROM biblio b
4204         LEFT JOIN items i ON (i.biblionumber = b.biblionumber)
4205         LEFT JOIN biblioitems bi ON (bi.biblionumber = b.biblionumber)
4206     };
4207
4208     my (@where_strs, @where_args);
4209
4210     if ($branch) {
4211         push @where_strs, 'i.homebranch = ?';
4212         push @where_args, $branch;
4213     }
4214     if ($itemtype) {
4215         if (C4::Context->preference('item-level_itypes')){
4216             push @where_strs, 'i.itype = ?';
4217             push @where_args, $itemtype;
4218         } else {
4219             push @where_strs, 'bi.itemtype = ?';
4220             push @where_args, $itemtype;
4221         }
4222     }
4223     if ($ccode) {
4224         push @where_strs, 'i.ccode = ?';
4225         push @where_args, $ccode;
4226     }
4227     if ($newness) {
4228         push @where_strs, 'TO_DAYS(NOW()) - TO_DAYS(b.datecreated) <= ?';
4229         push @where_args, $newness;
4230     }
4231
4232     if (@where_strs) {
4233         $query .= 'WHERE ' . join(' AND ', @where_strs);
4234     }
4235
4236     $query .= q{
4237         GROUP BY b.biblionumber, b.title, b.author, bi.itemtype, bi.publishercode,
4238           bi.place, bi.publicationyear, b.copyrightdate, bi.pages, bi.size,
4239           i.ccode
4240         ORDER BY count DESC
4241     };
4242
4243     $query .= q{ ) xxx WHERE count > 0 };
4244     $count = int($count);
4245     if ($count > 0) {
4246         $query .= "LIMIT $count";
4247     }
4248
4249     my $rows = $dbh->selectall_arrayref($query, { Slice => {} }, @where_args);
4250
4251     return @$rows;
4252 }
4253
4254 =head2 Internal methods
4255
4256 =cut
4257
4258 sub _CalculateAndUpdateFine {
4259     my ($params) = @_;
4260
4261     my $borrower    = $params->{borrower};
4262     my $item        = $params->{item};
4263     my $issue       = $params->{issue};
4264     my $return_date = $params->{return_date};
4265
4266     unless ($borrower) { carp "No borrower passed in!" && return; }
4267     unless ($item)     { carp "No item passed in!"     && return; }
4268     unless ($issue)    { carp "No issue passed in!"    && return; }
4269
4270     my $datedue = dt_from_string( $issue->date_due );
4271
4272     # we only need to calculate and change the fines if we want to do that on return
4273     # Should be on for hourly loans
4274     my $control = C4::Context->preference('CircControl');
4275     my $control_branchcode =
4276         ( $control eq 'ItemHomeLibrary' ) ? $item->{homebranch}
4277       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
4278       :                                     $issue->branchcode;
4279
4280     my $date_returned = $return_date ? $return_date : dt_from_string();
4281
4282     my ( $amount, $unitcounttotal, $unitcount  ) =
4283       C4::Overdues::CalcFine( $item, $borrower->{categorycode}, $control_branchcode, $datedue, $date_returned );
4284
4285     if ( C4::Context->preference('finesMode') eq 'production' ) {
4286         if ( $amount > 0 ) {
4287             C4::Overdues::UpdateFine({
4288                 issue_id       => $issue->issue_id,
4289                 itemnumber     => $issue->itemnumber,
4290                 borrowernumber => $issue->borrowernumber,
4291                 amount         => $amount,
4292                 due            => output_pref($datedue),
4293             });
4294         }
4295         elsif ($return_date) {
4296
4297             # Backdated returns may have fines that shouldn't exist,
4298             # so in this case, we need to drop those fines to 0
4299
4300             C4::Overdues::UpdateFine({
4301                 issue_id       => $issue->issue_id,
4302                 itemnumber     => $issue->itemnumber,
4303                 borrowernumber => $issue->borrowernumber,
4304                 amount         => 0,
4305                 due            => output_pref($datedue),
4306             });
4307         }
4308     }
4309 }
4310
4311 sub _item_denied_renewal {
4312     my ($params) = @_;
4313
4314     my $item = $params->{item};
4315     return unless $item;
4316
4317     my $denyingrules = Koha::Config::SysPrefs->find('ItemsDeniedRenewal')->get_yaml_pref_hash();
4318     return unless $denyingrules;
4319     foreach my $field (keys %$denyingrules) {
4320         my $val = $item->$field;
4321         if( !defined $val) {
4322             if ( any { !defined $_ }  @{$denyingrules->{$field}} ){
4323                 return 1;
4324             }
4325         } elsif (any { defined($_) && $val eq $_ } @{$denyingrules->{$field}}) {
4326            # If the results matches the values in the syspref
4327            # We return true if match found
4328             return 1;
4329         }
4330     }
4331     return 0;
4332 }
4333
4334 =head3 _after_circ_actions
4335
4336 Internal method that calls the after_circ_action plugin hook on configured
4337 plugins.
4338
4339 =cut
4340
4341 sub _after_circ_actions {
4342     my ($params) = @_;
4343
4344     my @plugins = Koha::Plugins->new->GetPlugins({
4345         method => 'after_circ_action',
4346     });
4347
4348     foreach my $plugin ( @plugins ) {
4349         try {
4350             $plugin->after_circ_action( $params );
4351         }
4352         catch {
4353             warn "$_";
4354         };
4355     }
4356 }
4357
4358 1;
4359
4360 __END__
4361
4362 =head1 AUTHOR
4363
4364 Koha Development Team <http://koha-community.org/>
4365
4366 =cut