opac/ilsdi.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use List::MoreUtils qw(any);
  24
  25 use C4::ILSDI::Services;
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::Context;
  29 use XML::Simple;
  30 use CGI qw ( -utf8 );
  31
  32 =head1 DLF ILS-DI for Koha
  33
  34 This script is a basic implementation of ILS-DI protocol for Koha.
  35 It acts like a dispatcher, that get the CGI request, check required and
  36 optionals arguments, call a function from C4::ILS-DI, and finaly
  37 outputs the returned hashref as XML.
  38
  39 =cut
  40
  41 # Instanciate the CGI request
  42 my $cgi = new CGI;
  43
  44 # List of available services, sorted by level
  45 my @services = (
  46     'Describe',    # Not part of ILS-DI, online API doc
  47
  48     #   Level 1: Basic Discovery Interfaces
  49     #   'HarvestBibliographicRecords',       # OAI-PMH
  50     #   'HarvestExpandedRecords',            # OAI-PMH
  51     'GetAvailability',    # FIXME Add bibbliographic level
  52
  53     #   'GoToBibliographicRequestPage'       # I don't understant this one
  54     #   Level 2: Elementary OPAC supplement
  55     #   'HarvestAuthorityRecords',           # OAI-PMH
  56     #   'HarvestHoldingsRecords',            # OAI-PMH
  57     'GetRecords',         # Note that we can use OAI-PMH for this too
  58
  59     #   'Search',                            # TODO
  60     #   'Scan',                              # TODO
  61     'GetAuthorityRecords',
  62
  63     #   'OutputRewritablePage',              # I don't understant this one
  64     #   'OutputIntermediateFormat',          # I don't understant this one
  65     #   Level 3: Elementary OPAC alternative
  66     'LookupPatron',
  67     'AuthenticatePatron',
  68     'GetPatronInfo',
  69     'GetPatronStatus',
  70     'GetServices',    # FIXME Loans
  71     'RenewLoan',
  72     'HoldTitle',      # FIXME Add dates support
  73     'HoldItem',       # FIXME Add dates support
  74     'CancelHold',
  75
  76     #   'RecallItem',                        # Not supported by Koha
  77     #   'CancelRecall',                      # Not supported by Koha
  78     #   Level 4: Robust/domain specific discovery platforms
  79     #   'SearchCourseReserves',              # TODO
  80     #   'Explain'                            # TODO
  81 );
  82
  83 # List of required arguments
  84 my %required = (
  85     'Describe'            => ['verb'],
  86     'GetAvailability'     => [ 'id', 'id_type' ],
  87     'GetRecords'          => ['id'],
  88     'GetAuthorityRecords' => ['id'],
  89     'LookupPatron'        => ['id'],
  90     'AuthenticatePatron'  => [ 'username', 'password' ],
  91     'GetPatronInfo'       => ['patron_id'],
  92     'GetPatronStatus'     => ['patron_id'],
  93     'GetServices'         => [ 'patron_id', 'item_id' ],
  94     'RenewLoan'           => [ 'patron_id', 'item_id' ],
  95     'HoldTitle'           => [ 'patron_id', 'bib_id', 'request_location' ],
  96     'HoldItem'            => [ 'patron_id', 'bib_id', 'item_id' ],
  97     'CancelHold' => [ 'patron_id', 'item_id' ],
  98 );
  99
 100 # List of optional arguments
 101 my %optional = (
 102     'Describe'            => [],
 103     'GetAvailability'     => [ 'return_type', 'return_fmt' ],
 104     'GetRecords'          => ['schema'],
 105     'GetAuthorityRecords' => ['schema'],
 106     'LookupPatron'        => ['id_type'],
 107     'AuthenticatePatron'  => [],
 108     'GetPatronInfo'       => [ 'show_contact', 'show_fines', 'show_holds', 'show_loans' ],
 109     'GetPatronStatus'     => [],
 110     'GetServices'         => [],
 111     'RenewLoan'           => ['desired_due_date'],
 112     'HoldTitle'  => [ 'pickup_location', 'needed_before_date', 'pickup_expiry_date' ],
 113     'HoldItem'   => [ 'pickup_location', 'needed_before_date', 'pickup_expiry_date' ],
 114     'CancelHold' => [],
 115 );
 116
 117 # If no service is requested, display the online documentation
 118 unless ( $cgi->param('service') ) {
 119     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 120         {   template_name   => "ilsdi.tt",
 121             query           => $cgi,
 122             type            => "opac",
 123             authnotrequired => 1,
 124             debug           => 1,
 125         }
 126     );
 127     output_html_with_http_headers $cgi, $cookie, $template->output;
 128     exit 0;
 129 }
 130
 131 # If user requested a service description, then display it
 132 if ( $cgi->param('service') eq "Describe" and any { $cgi->param('verb') eq $_ } @services ) {
 133     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 134         {   template_name   => "ilsdi.tt",
 135             query           => $cgi,
 136             type            => "opac",
 137             authnotrequired => 1,
 138             debug           => 1,
 139         }
 140     );
 141     $template->param( $cgi->param('verb') => 1 );
 142     output_html_with_http_headers $cgi, $cookie, $template->output;
 143     exit 0;
 144 }
 145
 146 # any output after this point will be UTF-8 XML
 147 binmode STDOUT, ':encoding(UTF-8)';
 148 print CGI::header('-type'=>'text/xml', '-charset'=>'utf-8');
 149
 150 my $out;
 151
 152 # If ILS-DI module is disabled in System->Preferences, redirect to 404
 153 unless ( C4::Context->preference('ILS-DI') ) {
 154     $out->{'code'} = "NotAllowed";
 155     $out->{'message'} = "ILS-DI is disabled.";
 156 }
 157
 158 # If the remote address is not allowed, redirect to 403
 159 my @AuthorizedIPs = split(/,/, C4::Context->preference('ILS-DI:AuthorizedIPs'));
 160 if ( @AuthorizedIPs # If no filter set, allow access to everybody
 161     and not any { $ENV{'REMOTE_ADDR'} eq $_ } @AuthorizedIPs # IP Check
 162     ) {
 163     $out->{'code'} = "NotAllowed";
 164     $out->{'message'} = "Unauthorized IP address: ".$ENV{'REMOTE_ADDR'}.".";
 165 }
 166
 167 my $service = $cgi->param('service') || "ilsdi";
 168
 169 # Check if the requested service is in the list
 170 if ( $service and any { $service eq $_ } @services ) {
 171
 172     my @parmsrequired = @{ $required{$service} };
 173     my @parmsoptional = @{ $optional{$service} };
 174     my @parmsall      = ( @parmsrequired, @parmsoptional );
 175     my @names         = $cgi->param;
 176     my %paramhash;
 177     $paramhash{$_} = 1 for @names;
 178
 179     # check for missing parameters
 180     for ( @parmsrequired ) {
 181         unless ( exists $paramhash{$_} ) {
 182             $out->{'code'} = "MissingParameter";
 183             $out->{'message'} = "The required parameter ".$_." is missing.";
 184         }
 185     }
 186
 187     # check for illegal parameters
 188     for my $name ( @names ) {
 189         my $found = 0;
 190         for my $name2 (@parmsall) {
 191             if ( $name eq $name2 ) {
 192                 $found = 1;
 193             }
 194         }
 195         if ( $found == 0 && $name ne 'service' ) {
 196             $out->{'code'} = "IllegalParameter";
 197             $out->{'message'} = "The parameter ".$name." is illegal.";
 198         }
 199     }
 200
 201     # check for multiple parameters
 202     for ( @names ) {
 203         my @values = $cgi->param($_);
 204         if ( $#values != 0 ) {
 205             $out->{'code'} = "MultipleValuesNotAllowed";
 206             $out->{'message'} = "Multiple values not allowed for the parameter ".$_.".";
 207         }
 208     }
 209
 210     if ( !$out->{'message'} ) {
 211
 212         # GetAvailability is a special case, as it cannot use XML::Simple
 213         if ( $service eq "GetAvailability" ) {
 214             print C4::ILSDI::Services::GetAvailability($cgi);
 215             exit 0;
 216         } else {
 217
 218             # Variable functions
 219             my $sub = do {
 220                 no strict 'refs';
 221                 my $symbol = 'C4::ILSDI::Services::' . $service;
 222                 \&{"$symbol"};
 223             };
 224
 225             # Call the requested service, and get its return value
 226             $out = &$sub($cgi);
 227         }
 228     }
 229 } else {
 230     $out->{'message'} = "NotSupported";
 231 }
 232
 233 # Output XML by passing the hashref to XMLOut
 234 print XMLout(
 235     $out,
 236     noattr        => 1,
 237     nosort        => 1,
 238     xmldecl       => '<?xml version="1.0" encoding="UTF-8" ?>',
 239     RootName      => $service,
 240     SuppressEmpty => 1
 241 );
 242 exit 0;
 243