t/db_dependent/Reports_Guided.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 17;
  21 use Test::Warn;
  22
  23 use C4::Context;
  24
  25 BEGIN {
  26     use_ok('C4::Reports::Guided');
  27 }
  28 can_ok(
  29     'C4::Reports::Guided',
  30     qw(save_report delete_report execute_query)
  31 );
  32
  33 #Start transaction
  34 my $dbh = C4::Context->dbh;
  35 $dbh->{RaiseError} = 1;
  36 $dbh->{AutoCommit} = 0;
  37
  38 $dbh->do(q|DELETE FROM saved_sql|);
  39
  40 #Start tests
  41
  42 #Test save_report
  43 my $count = scalar( @{ get_saved_reports() } );
  44 is( $count, 0, "There is no report" );
  45
  46 my @report_ids;
  47 for my $id ( 1 .. 3 ) {
  48     push @report_ids, save_report({
  49         borrowernumber => $id,
  50         savedsql       => "SQL$id",
  51         name           => "Name$id",
  52         area           => "area$id",
  53         group          => "group$id",
  54         subgroup       => "subgroup$id",
  55         type           => "type$id",
  56         notes          => "note$id",
  57         cache_expiry   => "null",
  58         public         => "null"
  59     });
  60     $count++;
  61 }
  62 like( $report_ids[0], '/^\d+$/', "Save_report returns an id for first" );
  63 like( $report_ids[1], '/^\d+$/', "Save_report returns an id for second" );
  64 like( $report_ids[2], '/^\d+$/', "Save_report returns an id for third" );
  65
  66 is( scalar( @{ get_saved_reports() } ),
  67     $count, "$count reports have been added" );
  68
  69 #Test delete_report
  70 is (delete_report(),undef, "Without id delete_report returns undef");
  71
  72 is( delete_report( $report_ids[0] ), 1, "report 1 is deleted" );
  73 $count--;
  74
  75 is( scalar( @{ get_saved_reports() } ), $count, "Report1 has been deleted" );
  76
  77 is( delete_report( $report_ids[1], $report_ids[2] ), 2, "report 2 and 3 are deleted" );
  78 $count -= 2;
  79
  80 is( scalar( @{ get_saved_reports() } ),
  81     $count, "Report2 and report3 have been deleted" );
  82
  83 my $sth = execute_query('SELECT COUNT(*) FROM systempreferences', 0, 10);
  84 my $results = $sth->fetchall_arrayref;
  85 is(scalar(@$results), 1, 'running a query returned a result');
  86
  87 my $version = C4::Context->preference('Version');
  88 $sth = execute_query(
  89     'SELECT value FROM systempreferences WHERE variable = ?',
  90     0,
  91     10,
  92     [ 'Version' ],
  93 );
  94 $results = $sth->fetchall_arrayref;
  95 is_deeply(
  96     $results,
  97     [ [ $version ] ],
  98     'running a query with a parameter returned the expected result'
  99 );
 100
 101 # for next test, we want to let execute_query capture any SQL errors
 102 $dbh->{RaiseError} = 0;
 103 my $errors;
 104 warning_like { ($sth, $errors) = execute_query(
 105         'SELECT surname FRM borrowers',  # error in the query is intentional
 106         0, 10 ) }
 107         qr/^DBD::mysql::st execute failed: You have an error in your SQL syntax;/,
 108         "Wrong SQL syntax raises warning";
 109 ok(
 110     defined($errors) && exists($errors->{queryerr}),
 111     'attempting to run a report with an SQL syntax error returns error message (Bug 12214)'
 112 );
 113
 114 is_deeply( get_report_areas(), [ 'CIRC', 'CAT', 'PAT', 'ACQ', 'ACC' ],
 115     "get_report_areas returns the correct array of report areas");
 116
 117 #End transaction
 118 $dbh->rollback;
 119