t/Circulation_barcodedecode.t

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Test::More tests => 26;
  21 use t::lib::Mocks;
  22
  23 C4::Context->_new_userenv(123456);
  24 C4::Context->set_userenv(1,'kmkale' , 1, 'km', 'kale' , 'IMS', 'IMS Branch DEscription', 0, 'kmkale@anantcorp.com');
  25
  26 BEGIN {
  27     # Mock the DB connexion and C4::Context
  28     my $context = t::lib::Mocks::mock_dbh;
  29     use_ok('C4::Circulation');
  30 }
  31
  32 our %inputs = (
  33     cuecat     => ["26002315", '.C3nZC3nZC3nYD3b6ENnZCNnY.fHmc.C3D1Dxr2C3nZE3n7.', ".C3nZC3nZC3nYD3b6ENnZCNnY.fHmc.C3D1Dxr2C3nZE3n7.\r\n",
  34                     'q.C3nZC3nZC3nWDNzYDxf2CNnY.fHmc.C3DWC3nZCNjXD3nW.', '.C3nZC3nZC3nWCxjWE3D1C3nX.cGf2.ENr7C3v7D3T3ENj3C3zYDNnZ.' ],
  35     whitespace => [" 26002315", "26002315 ", "\n\t26002315\n"],
  36     'T-prefix' => [qw(T0031472 T32)],
  37     'libsuite8' => ['b000126', 'b12', 'B0126', 'IMS-B-126', 'ims-b-126','CD0000024','00123','11998'],
  38     EAN13      => [qw(892685001928 695152)],
  39     other      => [qw(26002315 T0031472 T32 Alphanum123), "Alpha Num 345"],
  40 );
  41 our %outputs = (
  42     cuecat     => ["26002315", "046675000808", "046675000808", "043000112403", "978068484914051500"],
  43     whitespace => [qw(26002315 26002315 26002315)],
  44     'T-prefix' => [qw(T0031472 T0000002         )],
  45     'libsuite8' => ['IMS-b-126', 'IMS-b-12', 'IMS-B-126', 'IMS-B-126', 'ims-b-126','IMS-CD-24','IMS-b-123','IMS-b-11998'],
  46     EAN13      => [qw(0892685001928 0000000695152)],
  47     other      => [qw(26002315 T0031472 T32 Alphanum123), "Alpha Num 345"],
  48 );
  49
  50 my @filters = sort keys %inputs;
  51 foreach my $filter (@filters) {
  52     foreach my $datum (@{$inputs{$filter}}) {
  53         my $expect = shift @{$outputs{$filter}} or die "Internal Test Error: missing expected output for filter '$filter' on input '$datum'";
  54         my $output = C4::Circulation::barcodedecode($datum, $filter);
  55         ok($output eq $expect, sprintf("%12s: %20s => %15s", $filter, "'$datum'", "'$expect'"));
  56         ($output eq $expect) or diag  "Bad output: '$output'";
  57     }
  58 }
  59
  60 __END__
  61
  62 =head2 C4::Circulation::barcodedecode()
  63
  64 This tests avoids being dependent on the database by using the optional
  65 second argument to barcodedecode.
  66
  67 T-prefix style is derived from zero-padded "Follett Classic Code 3 of 9".  From:
  68     www.fsc.follett.com/_file/File/pdf/Barcode%20Symbology%20Q%20%20A%203_05.pdf
  69
  70  ~ 1 to 7 characters
  71  ~ T, P or X followed by numeric characters
  72  ~ No checkdigit
  73
  74 =cut