opac/opac-privacy.pl

   1 #!/usr/bin/perl
   2 # This script lets the users change their privacy rules
   3 #
   4 # copyright 2009, BibLibre, paul.poulain@biblibre.com
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use Modern::Perl;
  20 use CGI qw ( -utf8 );
  21
  22 use C4::Auth;    # checkauth, getborrowernumber.
  23 use C4::Context;
  24 use C4::Output;
  25 use Koha::Patrons;
  26
  27 my $query = CGI->new;
  28
  29 # if OPACPrivacy is disabled, leave immediately
  30 if ( ! C4::Context->preference('OPACPrivacy') || ! C4::Context->preference('opacreadinghistory') ) {
  31     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  32     exit;
  33 }
  34
  35 my $dbh   = C4::Context->dbh;
  36
  37 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  38     {
  39         template_name   => "opac-privacy.tt",
  40         query           => $query,
  41         type            => "opac",
  42         debug           => 1,
  43     }
  44 );
  45
  46 my $op                         = $query->param("op");
  47 my $privacy                    = $query->param("privacy");
  48 my $privacy_guarantor_checkouts = $query->param("privacy_guarantor_checkouts");
  49 my $privacy_guarantor_fines     = $query->param("privacy_guarantor_fines");
  50
  51 if ( $op eq "update_privacy" ) {
  52     my $patron = Koha::Patrons->find( $borrowernumber );
  53     if ( $patron ) {
  54         $patron->set({
  55             privacy                    => $privacy,
  56             privacy_guarantor_checkouts => defined $privacy_guarantor_checkouts?$privacy_guarantor_checkouts:$patron->privacy_guarantor_checkouts,
  57             privacy_guarantor_fines     => defined $privacy_guarantor_fines?$privacy_guarantor_fines:$patron->privacy_guarantor_fines,
  58         })->store;
  59         $template->param( 'privacy_updated' => 1 );
  60     }
  61 }
  62 elsif ( $op eq "delete_record" ) {
  63
  64     # delete all reading records for items returned
  65     my $rows = eval {
  66         Koha::Patrons->search({ 'me.borrowernumber' => $borrowernumber })->anonymise_issue_history;
  67     };
  68     $template->param(
  69         (
  70               $@    ? ( history_not_deleted => 1 )
  71             : $rows ? ( deleted             => int($rows) )
  72             :         ( nothing_to_delete => 1 )
  73         )
  74     );
  75 }
  76
  77 # get borrower privacy ....
  78 my $borrower = Koha::Patrons->find( $borrowernumber );;
  79
  80 $template->param(
  81     'Ask_data'                       => 1,
  82     'privacy' . $borrower->privacy() => 1,
  83     'privacyview'                    => 1,
  84     'borrower'                       => $borrower,
  85     'surname'                        => $borrower->surname,
  86     'firstname'                      => $borrower->firstname,
  87     'has_guarantor_flag'             => $borrower->guarantor_relationships->guarantors->_resultset->count
  88 );
  89
  90 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };