C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use Carp;
  22
  23 use C4::Debug;
  24 use C4::Context;
  25 use C4::Members::Messaging;
  26 use C4::Auth qw(checkpw_internal);
  27 use Koha::Patrons;
  28 use Koha::AuthUtils qw(hash_password);
  29 use List::MoreUtils qw( any );
  30 use Net::LDAP;
  31 use Net::LDAP::Filter;
  32
  33 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  34
  35 BEGIN {
  36         require Exporter;
  37         @ISA    = qw(Exporter);
  38         @EXPORT = qw( checkpw_ldap );
  39 }
  40
  41 # Redefine checkpw_ldap:
  42 # connect to LDAP (named or anonymous)
  43 # ~ retrieves $userid from KOHA_CONF mapping
  44 # ~ then compares $password with userPassword
  45 # ~ then gets the LDAP entry
  46 # ~ and calls the memberadd if necessary
  47
  48 sub ldapserver_error {
  49         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  50 }
  51
  52 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  53 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  54 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  55 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  56 my $base      = $ldap->{base}           or die ldapserver_error('base');
  57 $ldapname     = $ldap->{user}           ;
  58 $ldappassword = $ldap->{pass}           ;
  59 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  60 my @mapkeys = keys %mapping;
  61 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  62 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  63 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  64
  65 my %categorycode_conversions;
  66 my $default_categorycode;
  67 if(defined $ldap->{categorycode_mapping}) {
  68     $default_categorycode = $ldap->{categorycode_mapping}->{default};
  69     foreach my $cat (@{$ldap->{categorycode_mapping}->{categorycode}}) {
  70         $categorycode_conversions{$cat->{value}} = $cat->{content};
  71     }
  72 }
  73
  74 my %config = (
  75     anonymous => defined ($ldap->{anonymous_bind}) ? $ldap->{anonymous_bind} : 1,
  76     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  77        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  78 );
  79
  80 sub description {
  81         my $result = shift or return;
  82         return "LDAP error #" . $result->code
  83                         . ": " . $result->error_name . "\n"
  84                         . "# " . $result->error_text . "\n";
  85 }
  86
  87 sub search_method {
  88     my $db     = shift or return;
  89     my $userid = shift or return;
  90         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  91         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  92         my $search = $db->search(
  93                   base => $base,
  94                 filter => $filter,
  95                 # attrs => ['*'],
  96     );
  97     die "LDAP search failed to return object : " . $search->error if $search->code;
  98
  99         my $count = $search->count;
 100         if ($search->code > 0) {
 101                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
 102                 return 0;
 103         }
 104     if ($count == 0) {
 105         warn sprintf("LDAP Auth rejected : search with filter '%s' returns no hit\n", $filter->as_string);
 106         return 0;
 107     }
 108     return $search;
 109 }
 110
 111 sub checkpw_ldap {
 112     my ($dbh, $userid, $password) = @_;
 113     my @hosts = split(',', $prefhost);
 114     my $db = Net::LDAP->new(\@hosts);
 115     unless ( $db ) {
 116         warn "LDAP connexion failed";
 117         return 0;
 118     }
 119
 120         #$debug and $db->debug(5);
 121     my $userldapentry;
 122
 123     # first, LDAP authentication
 124     if ( $ldap->{auth_by_bind} ) {
 125         my $principal_name;
 126         if ( $config{anonymous} ) {
 127
 128             # Perform an anonymous bind
 129             my $res = $db->bind;
 130             if ( $res->code ) {
 131                 warn "Anonymous LDAP bind failed: " . description($res);
 132                 return 0;
 133             }
 134
 135             # Perform a LDAP search for the given username
 136             my $search = search_method( $db, $userid )
 137               or return 0;    # warnings are in the sub
 138             $userldapentry = $search->shift_entry;
 139             $principal_name = $userldapentry->dn;
 140         }
 141         else {
 142             $principal_name = $ldap->{principal_name};
 143             if ( $principal_name and $principal_name =~ /\%/ ) {
 144                 $principal_name = sprintf( $principal_name, $userid );
 145             }
 146             else {
 147                 $principal_name = $userid;
 148             }
 149         }
 150
 151         # Perform a LDAP bind for the given username using the matched DN
 152         my $res = $db->bind( $principal_name, password => $password );
 153         if ( $res->code ) {
 154             if ( $config{anonymous} ) {
 155                 # With anonymous_bind approach we can be sure we have found the correct user
 156                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 157                 # or password changed). We should not fall back to local accounts in this case.
 158                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 159                 return -1;
 160             } else {
 161                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 162                 # at all, and thus we should fall back to local logins to restore previous behaviour
 163                 # see bug 12831
 164                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 165                 return 0;
 166             }
 167         }
 168         if ( !defined($userldapentry)
 169             && ( $config{update} or $config{replicate} ) )
 170         {
 171             my $search = search_method( $db, $userid ) or return 0;
 172             $userldapentry = $search->shift_entry;
 173         }
 174     } else {
 175         my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 176                 if ($res->code) {               # connection refused
 177                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 178                         return 0;
 179                 }
 180         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 181         # Handle multiple branches. Same login exists several times in different branches.
 182         my $bind_ok = 0;
 183         while (my $entry = $search->shift_entry) {
 184             my $user_ldap_bind_ret = $db->bind($entry->dn, password => $password);
 185             unless ($user_ldap_bind_ret->code) {
 186                 $userldapentry = $entry;
 187                 $bind_ok = 1;
 188                 last;
 189             }
 190         }
 191
 192         unless ($bind_ok) {
 193             warn "LDAP Auth rejected : invalid password for user '$userid'.";
 194             return -1;
 195         }
 196
 197
 198     }
 199
 200     # To get here, LDAP has accepted our user's login attempt.
 201     # But we still have work to do.  See perldoc below for detailed breakdown.
 202
 203     my (%borrower);
 204         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 205
 206     if (( $borrowernumber and $config{update}   ) or
 207         (!$borrowernumber and $config{replicate})   ) {
 208         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 209         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 210     }
 211
 212     if ($borrowernumber) {
 213         if ($config{update}) { # A1, B1
 214             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 215             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 216         } else { # C1, D1
 217             # maybe update just the password?
 218                 return(1, $cardnumber, $local_userid);
 219         }
 220     } elsif ($config{replicate}) { # A2, C2
 221         my @columns = Koha::Patrons->columns;
 222         my $patron = Koha::Patron->new(
 223             {
 224                 map { exists( $borrower{$_} ) ? ( $_ => $borrower{$_} ) : () } @columns
 225             }
 226         )->store;
 227         die "Insert of new patron failed" unless $patron;
 228         $borrowernumber = $patron->borrowernumber;
 229         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 230    } else {
 231         return 0;   # B2, D2
 232     }
 233     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 234         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 235         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 236         while ( my $attribute_type = $attribute_types->next ) {
 237             my $code = $attribute_type->code;
 238             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 239                 next;
 240             }
 241             my $patron = Koha::Patrons->find($borrowernumber);
 242             if ( $patron ) { # Should not be needed, but we are in C4::Auth LDAP...
 243                 eval {
 244                     my $attribute = Koha::Patron::Attribute->new({code => $code, attribute => $borrower{$code}});
 245                     $patron->extended_attributes([$attribute->unblessed]);
 246                 };
 247                 if ($@) { # FIXME Test if Koha::Exceptions::Patron::Attribute::NonRepeatable
 248                     warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 249                 }
 250             }
 251         }
 252     }
 253     return(1, $cardnumber, $userid);
 254 }
 255
 256 # Pass LDAP entry object and local cardnumber (userid).
 257 # Returns borrower hash.
 258 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 259 # Ensure that mandatory fields are correctly filled!
 260 #
 261 sub ldap_entry_2_hash {
 262         my $userldapentry = shift;
 263         my %borrower = ( cardnumber => shift );
 264         my %memberhash;
 265         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 266         if ($debug) {
 267                 foreach (keys %$userldapentry) {
 268                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 269                 }
 270         }
 271         my $x = $userldapentry->{attrs} or return;
 272         foreach (keys %$x) {
 273                 $memberhash{$_} = join ' ', @{$x->{$_}};
 274                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 275         }
 276         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 277                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 278         foreach my $key (keys %mapping) {
 279                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 280                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 281                 unless (defined $data) {
 282             $data = $mapping{$key}->{content} || undef;
 283                 }
 284         $borrower{$key} = $data;
 285         }
 286         $borrower{initials} = $memberhash{initials} ||
 287                 ( substr($borrower{'firstname'},0,1)
 288                 . substr($borrower{ 'surname' },0,1)
 289                 . " ");
 290
 291     # categorycode conversions
 292     if(defined $categorycode_conversions{$borrower{categorycode}}) {
 293         $borrower{categorycode} = $categorycode_conversions{$borrower{categorycode}};
 294     }
 295     elsif($default_categorycode) {
 296         $borrower{categorycode} = $default_categorycode;
 297     }
 298
 299         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 300         my $dbh = C4::Context->dbh;
 301         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 302         $sth->execute( uc($borrower{'categorycode'}) );
 303         unless ( my $row = $sth->fetchrow_hashref ) {
 304                 my $default = $mapping{'categorycode'}->{content};
 305                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 306                 $borrower{'categorycode'} = $default
 307         }
 308
 309         return %borrower;
 310 }
 311
 312 sub exists_local {
 313         my $arg = shift;
 314         my $dbh = C4::Context->dbh;
 315         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 316
 317         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 318         $sth->execute($arg);
 319         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 320         ($sth->rows == 1) and return $sth->fetchrow;
 321
 322         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 323         $sth->execute($arg);
 324         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 325         ($sth->rows == 1) and return $sth->fetchrow;
 326         return 0;
 327 }
 328
 329 # This function performs a password update, given the userid, borrowerid,
 330 # and digested password. It will verify that things are correct and return the
 331 # borrowers cardnumber. The idea is that it is used to keep the local
 332 # passwords in sync with the LDAP passwords.
 333 #
 334 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 335 #
 336 # Note: if the LDAP config has the update_password tag set to a false value,
 337 # then this will not update the password, it will simply return the cardnumber.
 338 sub _do_changepassword {
 339     my ($userid, $borrowerid, $password) = @_;
 340
 341     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 342
 343         # We don't store the password in the database
 344         my $sth = C4::Context->dbh->prepare(
 345             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 346         $sth->execute($borrowerid);
 347         die "Unable to access borrowernumber "
 348             . "with userid=$userid, "
 349             . "borrowernumber=$borrowerid"
 350           if !$sth->rows;
 351         my ($cardnum) = $sth->fetchrow;
 352         $sth = C4::Context->dbh->prepare(
 353             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 354         $sth->execute($borrowerid);
 355         return $cardnum;
 356     }
 357
 358     my $digest = hash_password($password);
 359     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 360     Koha::Patrons->find($borrowerid)->set_password({ password => $password, skip_validation => 1 });
 361
 362     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 363     return $cardnum if $ok;
 364
 365     warn "Password mismatch after update to borrowernumber=$borrowerid";
 366     return;
 367 }
 368
 369 sub update_local {
 370     my $userid     = shift or croak "No userid";
 371     my $password   = shift or croak "No password";
 372     my $borrowerid = shift or croak "No borrowerid";
 373     my $borrower   = shift or croak "No borrower record";
 374
 375     # skip extended patron attributes in 'borrowers' attribute update
 376     my @keys = keys %$borrower;
 377     if (C4::Context->preference('ExtendedPatronAttributes')) {
 378         my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 379         my $attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id);
 380         while ( my $attribute_type = $attribute_types->next ) {
 381            my $code = $attribute_type->code;
 382            @keys = grep { $_ ne $code } @keys;
 383            $debug and printf STDERR "ignoring extended patron attribute '%s' in update_local()\n", $code;
 384         }
 385     }
 386
 387     my $dbh = C4::Context->dbh;
 388     my $query = "UPDATE  borrowers\nSET     " .
 389         join(',', map {"$_=?"} @keys) .
 390         "\nWHERE   borrowernumber=? ";
 391     my $sth = $dbh->prepare($query);
 392     if ($debug) {
 393         print STDERR $query, "\n",
 394             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 395         print STDERR "\nuserid = $userid\n";
 396     }
 397     $sth->execute(
 398         ((map {$borrower->{$_}} @keys), $borrowerid)
 399     );
 400
 401     # MODIFY PASSWORD/LOGIN if password was mapped
 402     _do_changepassword($userid, $borrowerid, $password) if exists( $borrower->{'password'} );
 403 }
 404
 405 1;
 406 __END__
 407
 408 =head1 NAME
 409
 410 C4::Auth - Authenticates Koha users
 411
 412 =head1 SYNOPSIS
 413
 414   use C4::Auth_with_ldap;
 415
 416 =head1 LDAP Configuration
 417
 418     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 419         working LDAP servers.
 420         To use it :
 421            * Modify ldapserver element in KOHA_CONF
 422            * Establish field mapping in <mapping> element.
 423
 424         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 425         the username would match the "uid" field, and the password should match the "userpassword" field.
 426
 427         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 428         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 429
 430         mysql> show COLUMNS from borrowers;
 431                 +---------------------+--------------+------+-----+---------+----------------+
 432                 | Field               | Type         | Null | Key | Default | Extra          |
 433                 +---------------------+--------------+------+-----+---------+----------------+
 434                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 435                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 436                 | surname             | mediumtext   | NO   |     | NULL    |                |
 437                 | firstname           | text         | YES  |     | NULL    |                |
 438                 | title               | mediumtext   | YES  |     | NULL    |                |
 439                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 440                 | initials            | text         | YES  |     | NULL    |                |
 441                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 442                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 443                 | address             | mediumtext   | NO   |     | NULL    |                |
 444                 | address2            | text         | YES  |     | NULL    |                |
 445                 | city                | mediumtext   | NO   |     | NULL    |                |
 446                 | state               | mediumtext   | YES  |     | NULL    |                |
 447                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 448                 | country             | text         | YES  |     | NULL    |                |
 449                 | email               | mediumtext   | YES  |     | NULL    |                |
 450                 | phone               | text         | YES  |     | NULL    |                |
 451                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 452                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 453                 | emailpro            | text         | YES  |     | NULL    |                |
 454                 | phonepro            | text         | YES  |     | NULL    |                |
 455                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 456                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 457                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 458                 | B_address2          | text         | YES  |     | NULL    |                |
 459                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 460                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 461                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 462                 | B_country           | text         | YES  |     | NULL    |                |
 463                 | B_email             | text         | YES  |     | NULL    |                |
 464                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 465                 | dateofbirth         | date         | YES  |     | NULL    |                |
 466                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 467                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 468                 | dateenrolled        | date         | YES  |     | NULL    |                |
 469                 | dateexpiry          | date         | YES  |     | NULL    |                |
 470                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 471                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 472                 | debarred            | date         | YES  |     | NULL    |                |
 473                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 474                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 475                 | contactfirstname    | text         | YES  |     | NULL    |                |
 476                 | contacttitle        | text         | YES  |     | NULL    |                |
 477                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 478                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 479                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 480                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 481                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 482                 | password            | varchar(30)  | YES  |     | NULL    |                |
 483                 | flags               | int(11)      | YES  |     | NULL    |                |
 484                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 485                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 486                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 487                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 488                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 489                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 490                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 491                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 492                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 493                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 494                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 495                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 496                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 497                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 498                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 499                 | privacy             | int(11)      | NO   |     | 1       |                |
 500                 +---------------------+--------------+------+-----+---------+----------------+
 501                 66 rows in set (0.00 sec)
 502                 Where Null="NO", the field is required.
 503
 504 =head1 KOHA_CONF and field mapping
 505
 506 Example XML stanza for LDAP configuration in KOHA_CONF.
 507
 508  <config>
 509   ...
 510   <useldapserver>1</useldapserver>
 511   <!-- LDAP SERVER (optional) -->
 512   <ldapserver id="ldapserver">
 513     <hostname>localhost</hostname>
 514     <base>dc=metavore,dc=com</base>
 515     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 516     <pass>metavore</pass>          <!-- password, if not anonymous -->
 517     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 518     <update>1</update>             <!-- update existing users in Koha database -->
 519     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 520                                         password comparison, e.g., to use Active Directory -->
 521     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 522                                             an anonymous bind, even when auth_by_bind is on -->
 523     <principal_name>%s@my_domain.com</principal_name>
 524                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 525                                         Not used with anonymous_bind. -->
 526     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 527                                               synced to the local database -->
 528     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 529       <firstname    is="givenname"      ></firstname>
 530       <surname      is="sn"             ></surname>
 531       <address      is="postaladdress"  ></address>
 532       <city         is="l"              >Athens, OH</city>
 533       <zipcode      is="postalcode"     ></zipcode>
 534       <branchcode   is="branch"         >MAIN</branchcode>
 535       <userid       is="uid"            ></userid>
 536       <password     is="userpassword"   ></password>
 537       <email        is="mail"           ></email>
 538       <categorycode is="employeetype"   >PT</categorycode>
 539       <phone        is="telephonenumber"></phone>
 540     </mapping>
 541   </ldapserver>
 542  </config>
 543
 544 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 545 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 546 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 547 patron).
 548
 549 =head1 CONFIGURATION
 550
 551 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 552 your configuration and the presence of a matching Koha user in your local DB:
 553
 554                          LOCAL_USER
 555  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 556    A1      1       1        1      OK : We're updating them anyway.
 557    A2      1       1        0      OK : We're adding them anyway.
 558    B1      1       0        1      OK : We update them.
 559    B2      1       0        0     FAIL: We cannot add new user.
 560    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 561    C2      0       1        0      OK : We add the new user.
 562    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 563    D2      0       0        0     FAIL: We cannot add new user.
 564
 565 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 566 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 567 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 568
 569 If you choose NOT to update local users, the borrowers table will not be affected at all.
 570 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 571 the local table never contained the LDAP values.
 572
 573 =head2 auth_by_bind
 574
 575 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 576
 577 =head2 principal_name
 578
 579 Provides an optional sprintf-style format for manipulating the userid before the bind.
 580 Even though the userPrincipalName is one intended target, any uniquely identifying
 581 attribute that the server allows to be used for binding could be used.
 582
 583 Currently, principal_name only operates when auth_by_bind is enabled.
 584
 585 =head2 update_password
 586
 587 If this tag is left out or set to a true value, then the user's LDAP password
 588 will be stored (hashed) in the local Koha database. If you don't want this
 589 to happen, then set the value of this to '0'. Note that if passwords are not
 590 stored locally, and the connection to the LDAP system fails, then the users
 591 will not be able to log in at all.
 592
 593 =head2 Active Directory
 594
 595 The auth_by_bind and principal_name settings are recommended for Active Directory.
 596
 597 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 598 we would typically under openldap.  Instead of:
 599
 600     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 601
 602 We might get:
 603
 604     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 605
 606 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 607 in Koha userids.  But the userPrincipalName should be consistent, something like:
 608
 609     userPrincipalName: barnes.7@my_company.com
 610
 611 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 612 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 613 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 614 like this:
 615     <principal_name>%s@core.my_company.com</principal_name>
 616
 617 The user of the previous example, barnes.7, would then attempt to bind as:
 618     barnes.7@core.my_company.com
 619
 620 =head1 SEE ALSO
 621
 622 CGI(3)
 623
 624 Net::LDAP()
 625
 626 XML::Simple()
 627
 628 Digest::MD5(3)
 629
 630 sprintf()
 631
 632 =cut
 633
 634 # For reference, here's an important difference in the data structure we rely on.
 635 # ========================================
 636 # Using attrs instead of {asn}->attributes
 637 # ========================================
 638 #
 639 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 640 #       LDAP key: ->{             cn}->{           sss} = sss
 641 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 642 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 643 #
 644 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 645 #       LDAP key: ->{      givenname}->{Steve} = Steve
 646 #