virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw( encode );
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::VirtualShelves;
  35 use Koha::Email;
  36
  37 my $query = new CGI;
  38
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name   => "virtualshelves/sendshelfform.tt",
  42         query           => $query,
  43         type            => "intranet",
  44         authnotrequired => 0,
  45         flagsrequired   => { catalogue => 1 },
  46     }
  47 );
  48
  49 my $shelfid = $query->param('shelfid');
  50 my $email   = $query->param('email');
  51
  52 my $dbh = C4::Context->dbh;
  53
  54 if ($email) {
  55     my $comment = $query->param('comment');
  56     my $message = Koha::Email->new();
  57     my %mail    = $message->create_message_headers(
  58         {
  59             to => $email
  60         }
  61     );
  62
  63     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  64         {
  65         template_name   => "virtualshelves/sendshelf.tt",
  66         query           => $query,
  67         type            => "intranet",
  68         authnotrequired => 0,
  69         flagsrequired   => { catalogue => 1 },
  70         }
  71     );
  72
  73     my @shelf = GetShelf($shelfid);
  74     my ( $items, $totitems ) = GetShelfContents($shelfid);
  75     my $marcflavour = C4::Context->preference('marcflavour');
  76     my $iso2709;
  77     my @results;
  78
  79     # retrieve biblios from shelf
  80     foreach my $biblio (@$items) {
  81         my $biblionumber     = $biblio->{biblionumber};
  82         my $fw               = GetFrameworkCode($biblionumber);
  83         my $dat              = GetBiblioData($biblionumber);
  84         my $record           = GetMarcBiblio($biblionumber, 1);
  85         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  86         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  87         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  88         my $subtitle         = GetRecordValue( 'subtitle', $record, $fw );
  89
  90         my @items = GetItemsInfo($biblionumber);
  91
  92         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  93         $dat->{MARCNOTES}      = $marcnotesarray;
  94         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  95         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  96         $dat->{'biblionumber'} = $biblionumber;
  97         $dat->{ITEM_RESULTS}   = \@items;
  98         $dat->{subtitle}       = $subtitle;
  99         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
 100
 101         $iso2709 .= $record->as_usmarc();
 102
 103         push( @results, $dat );
 104     }
 105
 106     $template2->param(
 107         BIBLIO_RESULTS => \@results,
 108         comment        => $comment,
 109         shelfname      => $shelf[1],
 110     );
 111
 112     # Getting template result
 113     my $template_res = $template2->output();
 114     my $body;
 115
 116     # Analysing information and getting mail properties
 117     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 118         $mail{'subject'} = Encode::encode("UTF-8", $1);
 119         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 120     }
 121     else { $mail{'subject'} = "no subject"; }
 122
 123     my $email_header = "";
 124     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 125         $email_header = $1;
 126         $email_header =~ s|\n?(.*)\n?|$1|;
 127         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 128     }
 129
 130     my $email_file = "list.txt";
 131     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 132         $email_file = $1;
 133         $email_file =~ s|\n?(.*)\n?|$1|;
 134     }
 135
 136     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 137         $body = $1;
 138         $body =~ s|\n?(.*)\n?|$1|;
 139         $body = encode_qp(Encode::encode("UTF-8", $body));
 140     }
 141
 142     my $boundary = "====" . time() . "====";
 143
 144     # We set and put the multipart content
 145     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 146
 147     my $isofile = encode_base64( encode( "UTF-8", $iso2709 ) );
 148     $boundary = '--' . $boundary;
 149
 150     $mail{body} = <<END_OF_BODY;
 151 $boundary
 152 Content-Type: text/plain; charset="utf-8"
 153 Content-Transfer-Encoding: quoted-printable
 154
 155 $email_header
 156 $body
 157 $boundary
 158 Content-Type: application/octet-stream; name="shelf.iso2709"
 159 Content-Transfer-Encoding: base64
 160 Content-Disposition: attachment; filename="shelf.iso2709"
 161
 162 $isofile
 163 $boundary--
 164 END_OF_BODY
 165
 166     # Sending mail
 167     if ( sendmail %mail ) {
 168
 169         # do something if it works....
 170         $template->param( SENT => "1" );
 171     }
 172     else {
 173         # do something if it doesnt work....
 174         carp "Error sending mail: $Mail::Sendmail::error \n";
 175         $template->param( error => 1 );
 176     }
 177
 178     $template->param( email => $email );
 179     output_html_with_http_headers $query, $cookie, $template->output;
 180
 181 }
 182 else {
 183     $template->param(
 184         shelfid => $shelfid,
 185         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 186     );
 187     output_html_with_http_headers $query, $cookie, $template->output;
 188 }