members/statistics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2012 BibLibre
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 2 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along with
  16 # Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 =head1 members/statistics.pl
  20
  21   Generate statistic issues for a member
  22
  23 =cut
  24
  25 use Modern::Perl;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Auth;
  29 use C4::Context;
  30 use C4::Members;
  31 use C4::Members::Statistics;
  32 use C4::Members::Attributes qw(GetBorrowerAttributes);
  33 use C4::Output;
  34 use Koha::Patron::Images;
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name   => "members/statistics.tt",
  40         query           => $input,
  41         type            => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { borrowers => 1 },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $borrowernumber = $input->param('borrowernumber');
  49
  50 # Set informations for the patron
  51 my $borrower = GetMember( borrowernumber => $borrowernumber );
  52 if ( not defined $borrower ) {
  53     $template->param (unknowuser => 1);
  54     output_html_with_http_headers $input, $cookie, $template->output;
  55     exit;
  56 }
  57
  58 foreach my $key ( keys %$borrower ) {
  59     $template->param( $key => $borrower->{$key} );
  60 }
  61 $template->param(
  62     categoryname    => $borrower->{'description'},
  63 );
  64 # Construct column names
  65 my $fields = C4::Members::Statistics::get_fields();
  66 our @statistic_column_names = split '\|', $fields;
  67 our @value_column_names = ( 'count_precedent_state', 'count_total_issues_today', 'count_total_issues_returned_today' );
  68 our @column_names = ( @statistic_column_names, @value_column_names );
  69
  70 # Get statistics
  71 my $precedent_state = GetPrecedentStateByBorrower( $borrowernumber );
  72 my $total_issues_today = GetTotalIssuesTodayByBorrower( $borrowernumber );
  73 my $total_issues_returned_today = GetTotalIssuesReturnedTodayByBorrower( $borrowernumber );
  74 my $r = merge (
  75     @$precedent_state, @$total_issues_today, @$total_issues_returned_today
  76 );
  77
  78 add_actual_state( $r );
  79 my ( $total, $datas ) = build_array( $r );
  80
  81 # Gettings sums
  82 my $count_total_precedent_state = $total->{count_precedent_state} || 0;
  83 my $count_total_issues = $total->{count_total_issues_today} || 0;
  84 my $count_total_issues_returned = $total->{count_total_issues_returned_today} || 0;
  85 my $count_total_actual_state = ($count_total_precedent_state - $count_total_issues_returned + $count_total_issues);
  86
  87 if (C4::Context->preference('ExtendedPatronAttributes')) {
  88     my $attributes = GetBorrowerAttributes($borrowernumber);
  89     $template->param(
  90         ExtendedPatronAttributes => 1,
  91         extendedattributes => $attributes
  92     );
  93 }
  94
  95 my $patron_image = Koha::Patron::Images->find($borrower->{borrowernumber});
  96 $template->param( picture => 1 ) if $patron_image;
  97
  98 $template->param(%$borrower);
  99
 100 $template->param(
 101     statisticsview     => 1,
 102     datas              => $datas,
 103     column_names       => \@statistic_column_names,
 104     count_total_issues => $count_total_issues,
 105     count_total_issues_returned => $count_total_issues_returned,
 106     count_total_precedent_state => $count_total_precedent_state,
 107     count_total_actual_state => $count_total_actual_state,
 108     RoutingSerials => C4::Context->preference('RoutingSerials'),
 109 );
 110
 111 output_html_with_http_headers $input, $cookie, $template->output;
 112
 113
 114 =head1 FUNCTIONS
 115
 116 =head2 add_actual_state
 117
 118   Add a 'count_actual_state' key in all hashes
 119   count_actual_state = count_precedent_state - count_total_issues_returned_today + count_total_issues_today
 120
 121 =cut
 122
 123 sub add_actual_state {
 124     my ( $array ) = @_;
 125     for my $hash ( @$array ) {
 126         $hash->{count_actual_state} = ( $hash->{count_precedent_state} // 0 ) - ( $hash->{count_total_issues_returned_today} // 0 ) + ( $hash->{count_total_issues_today} // 0 );
 127     }
 128 }
 129
 130 =head2 build_array
 131
 132   Build a new array containing values of hashes.
 133   It used by template whitch display silly values.
 134   ex:
 135     $array = [
 136       {
 137         'count_total_issues_returned_today' => 1,
 138         'ccode' => 'ccode',
 139         'count_actual_state' => 1,
 140         'count_precedent_state' => 1,
 141         'homebranch' => 'homebranch',
 142         'count_total_issues_today' => 1,
 143         'itype' => 'itype'
 144       }
 145     ];
 146   and returns:
 147     [
 148       [
 149         'homebranch',
 150         'itype',
 151         'ccode',
 152         1,
 153         1,
 154         1,
 155         1
 156       ]
 157     ];
 158
 159 =cut
 160
 161 sub build_array {
 162     my ( $array ) = @_;
 163     my ( @r, $total );
 164     for my $hash ( @$array) {
 165         my @line;
 166         for my $cn ( ( @column_names, 'count_actual_state') ) {
 167             if ( grep /$cn/, ( @value_column_names, 'count_actual_state') ) {
 168                 $hash->{$cn} //= 0;
 169                 if ( exists $total->{$cn} ) {
 170                     $total->{$cn} += $hash->{$cn} if $hash->{$cn};
 171                 } else {
 172                     $total->{$cn} = $hash->{$cn};
 173                 }
 174             }
 175             push @line, $hash->{$cn};
 176         }
 177         push @r, \@line;
 178     }
 179     return ( $total, \@r );
 180 }
 181
 182 =head2 merge
 183
 184   Merge hashes with the same statistic column names into one
 185   param: array, a arrayref of arrayrefs
 186   ex:
 187   @array = (
 188      {
 189        'ccode' => 'ccode',
 190        'count_precedent_state' => '1',
 191        'homebranch' => 'homebranch',
 192        'itype' => 'itype'
 193      },
 194      {
 195        'count_total_issues_returned_today' => '1',
 196        'ccode' => 'ccode',
 197        'homebranch' => 'homebranch',
 198        'itype' => 'itype'
 199      }
 200    );
 201    and returns:
 202    [
 203      {
 204        'count_total_issues_returned_today' => '1',
 205        'ccode' => 'ccode',
 206        'count_precedent_state' => '1',
 207        'homebranch' => 'homebranch',
 208        'itype' => 'itype'
 209      }
 210    ];
 211
 212 =cut
 213
 214 sub merge {
 215     my @array = @_;
 216     my @r;
 217     for my $h ( @array ) {
 218         my $exists = 0;
 219         for my $ch ( @r ) {
 220             $exists = 1;
 221             for my $cn ( @statistic_column_names ) {
 222                 if ( $ch->{$cn} and not $ch->{$cn} eq $h->{$cn} ) {
 223                     $exists = 0;
 224                     last;
 225                 }
 226             }
 227             if ($exists){
 228                 for my $cn ( @value_column_names ) {
 229                     next if not exists $h->{$cn};
 230                     $ch->{$cn} = $h->{$cn} ? $h->{$cn} : 0;
 231                 }
 232                 last;
 233             }
 234         }
 235
 236         if ( not $exists ) {push @r, $h;}
 237     }
 238     return \@r;
 239 }