admin/aqbudgets.pl

   1 #!/usr/bin/perl
   2
   3 #script to administer the aqbudget table
   4
   5 # Copyright 2008-2009 BibLibre SARL
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use List::Util qw/min/;
  26
  27 use Koha::Database;
  28 use C4::Auth qw/get_user_subpermissions/;
  29 use C4::Auth;
  30 use C4::Acquisition;
  31 use C4::Budgets;
  32 use C4::Context;
  33 use C4::Output;
  34 use C4::Koha;
  35 use C4::Debug;
  36 use Koha::Acquisition::Currencies;
  37 use Koha::Patrons;
  38
  39 my $input = new CGI;
  40 my $dbh     = C4::Context->dbh;
  41
  42 my ($template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  43     {   template_name   => "admin/aqbudgets.tt",
  44         query           => $input,
  45         type            => "intranet",
  46         authnotrequired => 0,
  47         flagsrequired   => { acquisition => 'budget_manage' },
  48         debug           => 0,
  49     }
  50 );
  51
  52 my $active_currency = Koha::Acquisition::Currencies->get_active;
  53 if ( $active_currency ) {
  54     $template->param( symbol => $active_currency->symbol,
  55                       currency => $active_currency->currency
  56                    );
  57 }
  58
  59 my $op = $input->param('op') || 'list';
  60
  61 # see if the user want to see all budgets or only owned ones by default
  62 my $show_mine = $input->param('show_mine') // 0;
  63
  64 # IF USER DOESN'T HAVE PERM FOR AN 'ADD', THEN REDIRECT TO THE DEFAULT VIEW...
  65 if (not defined $template->{VARS}->{'CAN_user_acquisition_budget_add_del'}
  66     and $op eq 'add_form')
  67 {
  68     $op = 'list';
  69 }
  70
  71 # get only the columns of aqbudgets in budget_hash
  72 my @columns = Koha::Database->new()->schema->source('Aqbudget')->columns;
  73 my $budget_hash = { map { join(' ',@columns) =~ /$_/ ? ( $_ => scalar $input->param($_) )  : () } keys( %{$input->Vars()}) } ;
  74
  75 my $budget_id                 = $input->param('budget_id');
  76 my $budget_period_id          = $input->param('budget_period_id');
  77 my $budget_permission         = $input->param('budget_permission');
  78 my $budget_users_ids          = $input->param('budget_users_ids');
  79 my $filter_budgetbranch       = $input->param('filter_budgetbranch') // '';
  80 my $filter_budgetname         = $input->param('filter_budgetname');
  81
  82
  83 # ' ------- get periods stuff ------------------'
  84 # IF PERIODID IS DEFINED,  GET THE PERIOD - ELSE JUST GET THE ACTIVE PERIOD BY DEFAULT
  85 my $period;
  86 if ( $budget_period_id ) {
  87     $period = GetBudgetPeriod( $budget_period_id );
  88 }
  89
  90 # ------- get periods stuff ------------------
  91
  92 # USED FOR PERMISSION COMPARISON LATER
  93 my $borrower_id         = $template->{VARS}->{'USER_INFO'}->{'borrowernumber'};
  94
  95 $template->param(
  96     show_mine   => $show_mine,
  97     op  => $op,
  98     selected_branchcode => $filter_budgetbranch,
  99 );
 100
 101 my $budget;
 102
 103 $template->param(auth_cats_loop => GetBudgetAuthCats( $budget_period_id ))
 104     if $budget_period_id;
 105
 106 # Used to create form to add or  modify a record
 107 if ($op eq 'add_form') {
 108 #### ------------------- ADD_FORM -------------------------
 109     # if no buget_id is passed then its an add
 110     #  pass the period_id to build the dropbox - because we only want to show  budgets from this period
 111     my $dropbox_disabled;
 112     if (defined $budget_id ) {    ### MOD
 113         $budget = GetBudget($budget_id);
 114         if (!CanUserModifyBudget($borrowernumber, $budget, $staffflags)) {
 115             $template->param(error_not_authorised_to_modify => 1);
 116             output_html_with_http_headers $input, $cookie, $template->output;
 117             exit;
 118         }
 119         $dropbox_disabled = BudgetHasChildren($budget_id);
 120         $budget->{budget_owner} = Koha::Patrons->find( $budget->{budget_owner_id} );
 121     }
 122
 123     # build budget hierarchy
 124     my %labels;
 125     my @values;
 126     my $hier = GetBudgetHierarchy($$period{budget_period_id});
 127     foreach my $r (@$hier) {
 128         $labels{"$r->{budget_id}"} = $r->{budget_code};
 129         push @values, $r->{budget_id};
 130     }
 131     push @values, '';
 132     # if no buget_id is passed then its an add
 133     my $budget_parent;
 134     my $budget_parent_id;
 135     if ($budget){
 136         $budget_parent_id = $budget->{'budget_parent_id'} ;
 137     }else{
 138         $budget_parent_id = $input->param('budget_parent_id');
 139     }
 140     $budget_parent = GetBudget($budget_parent_id);
 141
 142     # populates the planning button
 143     $template->param(
 144         sort1_auth => $budget->{sort1_authcat},
 145         sort2_auth => $budget->{sort2_authcat},
 146     );
 147
 148     if($budget->{'budget_permission'}){
 149         my $budget_permission = "budget_perm_".$budget->{'budget_permission'};
 150         $template->param($budget_permission => 1);
 151     }
 152
 153     if ($budget) {
 154         my @budgetusers = GetBudgetUsers($budget->{budget_id});
 155         my @budgetusers_loop;
 156         foreach my $borrowernumber (@budgetusers) {
 157             my $patron = Koha::Patrons->find( $borrowernumber );
 158             push @budgetusers_loop, {
 159                 firstname => $patron->firstname, # FIXME Should pass the patron object
 160                 surname => $patron->surname,
 161                 borrowernumber => $borrowernumber
 162             };
 163         }
 164         $template->param(
 165             budget_users => \@budgetusers_loop,
 166             budget_users_ids => join ':', @budgetusers
 167         );
 168     }
 169
 170     # if no buget_id is passed then its an add
 171     $template->param(
 172         budget_has_children => BudgetHasChildren( $budget->{budget_id} ),
 173         budget_parent_id                  => $budget_parent->{'budget_id'},
 174         budget_parent_name                => $budget_parent->{'budget_name'},
 175                 %$period,
 176                 %$budget,
 177     );
 178                                                     # END $OP eq ADD_FORM
 179 #---------------------- DEFAULT DISPLAY BELOW ---------------------
 180
 181 # called by default form, used to confirm deletion of data in DB
 182 } elsif ($op eq 'delete_confirm') {
 183
 184     my $budget = GetBudget($budget_id);
 185     $template->param(
 186         budget_id     => $budget->{'budget_id'},
 187         budget_code   => $budget->{'budget_code'},
 188         budget_name   => $budget->{'budget_name'},
 189         budget_amount => $budget->{'budget_amount'},
 190     );
 191                                                     # END $OP eq DELETE_CONFIRM
 192 # called by delete_confirm, used to effectively confirm deletion of data in DB
 193 } elsif ( $op eq 'delete_confirmed' ) {
 194     if ( BudgetHasChildren( $budget_id ) ) {
 195         # We should never be here, the interface does not provide this action.
 196         die("Delete a fund with children is not possible");
 197     }
 198     my $rc = DelBudget($budget_id);
 199     $op = 'list';
 200 } elsif( $op eq 'add_validate' ) {
 201     my @budgetusersid;
 202     if (defined $budget_users_ids){
 203         @budgetusersid = split(':', $budget_users_ids);
 204     }
 205
 206     my $budget_modified = 0;
 207     if (defined $budget_id) {
 208         if (CanUserModifyBudget($borrowernumber, $budget_hash->{budget_id},
 209             $staffflags)
 210         ) {
 211             ModBudget( $budget_hash );
 212             ModBudgetUsers($budget_hash->{budget_id}, @budgetusersid);
 213             $budget_modified = 1;
 214         }
 215         else {
 216             $template->param(error_not_authorised_to_modify => 1);
 217         }
 218     } else {
 219         $budget_hash->{budget_id} = AddBudget( $budget_hash );
 220         ModBudgetUsers($budget_hash->{budget_id}, @budgetusersid);
 221         $budget_modified = 1;
 222     }
 223
 224     my $set_owner_to_children = $input->param('set_owner_to_children');
 225     if ( $set_owner_to_children and $budget_modified ) {
 226         C4::Budgets::SetOwnerToFundHierarchy( $budget_hash->{budget_id}, $budget_hash->{budget_owner_id} );
 227     }
 228     $op = 'list';
 229 }
 230
 231 if ( $op eq 'list' ) {
 232     $template->param(
 233         budget_id => $budget_id,
 234         %$period,
 235     );
 236
 237     my @budgets = @{
 238         GetBudgetHierarchy( $$period{budget_period_id}, undef, ( $show_mine ? $borrower_id : 0 ))
 239     };
 240
 241     my $period_total = 0;
 242     my ($period_alloc_total, $spent_total, $ordered_total, $available_total) = (0,0,0,0);
 243
 244         #This Looks WEIRD to me : should budgets be filtered in such a way ppl who donot own it would not see the amount spent on the budget by others ?
 245
 246     my @budgets_to_display;
 247     foreach my $budget (@budgets) {
 248         # PERMISSIONS
 249         next unless CanUserUseBudget($borrowernumber, $budget, $staffflags);
 250         unless(CanUserModifyBudget($borrowernumber, $budget, $staffflags)) {
 251             $budget->{'budget_lock'} = 1;
 252         }
 253
 254         # if a budget search doesn't match, next
 255         if ($filter_budgetname) {
 256             next
 257               unless $budget->{budget_code} =~ m/$filter_budgetname/i
 258                   || $budget->{budget_name} =~ m/$filter_budgetname/i;
 259         }
 260         if ($filter_budgetbranch ) {
 261             next unless  $budget->{budget_branchcode} eq $filter_budgetbranch;
 262         }
 263
 264 ## TOTALS
 265         $budget->{'budget_remaining'} = $budget->{'budget_amount'} - $budget->{'budget_spent'} - $budget->{budget_ordered};
 266         $budget->{'total_remaining'} = $budget->{'budget_amount'} - $budget->{'total_spent'} - $budget->{total_ordered};
 267         # adds to total  - only if budget is a 'top-level' budget
 268         unless ( defined $budget->{budget_parent_id} ) {
 269             $period_alloc_total += $budget->{'budget_amount'};
 270             $spent_total += $budget->{total_spent};
 271             $ordered_total += $budget->{total_ordered};
 272             $available_total += $budget->{total_remaining};
 273         }
 274
 275 # if amount == 0 don't display...
 276         delete $budget->{'budget_unalloc_sublevel'}
 277             if (!defined $budget->{'budget_unalloc_sublevel'}
 278             or $budget->{'budget_unalloc_sublevel'} == 0);
 279
 280         # Value of budget_spent equals 0 instead of undefined value
 281         $budget->{budget_spent} = 0 unless defined($budget->{budget_spent});
 282         $budget->{budget_ordered} = 0 unless defined($budget->{budget_ordered});
 283
 284         #Make a list of parents of the bugdet
 285         my @budget_hierarchy;
 286         push  @budget_hierarchy, { element_name => $budget->{"budget_name"}, element_id => $budget->{"budget_id"} };
 287         my $parent_id = $budget->{"budget_parent_id"};
 288         while ($parent_id) {
 289             my $parent = GetBudget($parent_id);
 290             push @budget_hierarchy, { element_name => $parent->{"budget_name"}, element_id => $parent->{"budget_id"} };
 291             $parent_id = $parent->{"budget_parent_id"};
 292         }
 293         push  @budget_hierarchy, { element_name => $period->{"budget_period_description"} };
 294         @budget_hierarchy = reverse(@budget_hierarchy);
 295
 296         $budget->{budget_hierarchy} = \@budget_hierarchy;
 297
 298         $budget->{budget_has_children} = BudgetHasChildren( $budget->{budget_id} );
 299         push @budgets_to_display, $budget;
 300     }
 301
 302     my $budget_period_total = $period->{budget_period_total};
 303
 304     my $periods = GetBudgetPeriods();
 305
 306     $template->param(
 307         op                     => 'list',
 308         budgets                => \@budgets_to_display,
 309         periods                => $periods,
 310         budget_period_total    => $budget_period_total,
 311         period_alloc_total     => $period_alloc_total,
 312         spent_total            => $spent_total,
 313         ordered_total          => $ordered_total,
 314         available_total        => $available_total,
 315         filter_budgetname      => $filter_budgetname,
 316     );
 317
 318 } #---- END list
 319
 320 output_html_with_http_headers $input, $cookie, $template->output;