catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use strict;            # always use
 136 #use warnings; FIXME - Bug 2505
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth qw(:DEFAULT get_session);
 146 use C4::Search;
 147 use C4::Languages qw(getLanguages);
 148 use C4::Koha;
 149 use C4::Members qw(GetMember);
 150 use URI::Escape;
 151 use POSIX qw(ceil floor);
 152 use C4::Branch; # GetBranches
 153 use C4::Search::History;
 154
 155 use Koha::LibraryCategories;
 156 use Koha::Virtualshelves;
 157
 158 use URI::Escape;
 159
 160 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 161 # create a new CGI object
 162 # FIXME: no_undef_params needs to be tested
 163 use CGI qw('-no_undef_params' -utf8 );
 164 my $cgi = new CGI;
 165
 166 # decide which template to use
 167 my $template_name;
 168 my $template_type;
 169 my @params = $cgi->param("limit");
 170 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 171     $template_name = 'catalogue/results.tt';
 172 }
 173 else {
 174     $template_name = 'catalogue/advsearch.tt';
 175     $template_type = 'advsearch';
 176 }
 177 # load the template
 178 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 179     template_name => $template_name,
 180     query => $cgi,
 181     type => "intranet",
 182     authnotrequired => 0,
 183     flagsrequired   => { catalogue => 1 },
 184     }
 185 );
 186
 187 my $lang = C4::Languages::getlanguage($cgi);
 188
 189 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 190     $template->param('UNIMARC' => 1);
 191 }
 192 if (C4::Context->preference("IntranetNumbersPreferPhrase")) {
 193     $template->param('numbersphr' => 1);
 194 }
 195
 196 if($cgi->cookie("holdfor")){
 197     my $holdfor_patron = GetMember('borrowernumber' => $cgi->cookie("holdfor"));
 198     $template->param(
 199         holdfor => $cgi->cookie("holdfor"),
 200         holdfor_surname => $holdfor_patron->{'surname'},
 201         holdfor_firstname => $holdfor_patron->{'firstname'},
 202         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 203     );
 204 }
 205
 206 ## URI Re-Writing
 207 # Deprecated, but preserved because it's interesting :-)
 208 # The same thing can be accomplished with mod_rewrite in
 209 # a more elegant way
 210 #
 211 #my $rewrite_flag;
 212 #my $uri = $cgi->url(-base => 1);
 213 #my $relative_url = $cgi->url(-relative=>1);
 214 #$uri.="/".$relative_url."?";
 215 #warn "URI:$uri";
 216 #my @cgi_params_list = $cgi->param();
 217 #my $url_params = $cgi->Vars;
 218 #
 219 #for my $each_param_set (@cgi_params_list) {
 220 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 221 #}
 222 #warn "New URI:$uri";
 223 # Only re-write a URI if there are params or if it already hasn't been re-written
 224 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 225 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 226 #                            -cookie => $cookie);
 227 #    exit;
 228 #}
 229
 230 # load the branches
 231 my $branches = GetBranches();
 232
 233 # Populate branch_loop with all branches sorted by their name.  If
 234 # IndependentBranches is activated, set the default branch to the borrower
 235 # branch, except for superlibrarian who need to search all libraries.
 236 my $user = C4::Context->userenv;
 237 my @branch_loop = map {
 238      {
 239         value      => $_,
 240         branchname => $branches->{$_}->{branchname},
 241         selected   => $user->{branch} eq $_ && C4::Branch::onlymine(),
 242      }
 243 } sort {
 244     $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname}
 245 } keys %$branches;
 246
 247 my $categories = Koha::LibraryCategories->search( { categorytype => 'searchdomain' }, { order_by => [ 'categorytype', 'categorycode' ] } );
 248
 249 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 250
 251 # load the Type stuff
 252 my $itemtypes = GetItemTypes;
 253 # the index parameter is different for item-level itemtypes
 254 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 255 my @advancedsearchesloop;
 256 my $cnt;
 257 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 258 my @advanced_search_types = split(/\|/, $advanced_search_types);
 259
 260 foreach my $advanced_srch_type (@advanced_search_types) {
 261     $advanced_srch_type =~ s/^\s*//;
 262     $advanced_srch_type =~ s/\s*$//;
 263    if ($advanced_srch_type eq 'itemtypes') {
 264    # itemtype is a special case, since it's not defined in authorized values
 265         my @itypesloop;
 266         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 267             my %row =(  number=>$cnt++,
 268                 ccl => "$itype_or_itemtype,phr",
 269                 code => $thisitemtype,
 270                 description => $itemtypes->{$thisitemtype}->{translated_description},
 271                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 272             );
 273             push @itypesloop, \%row;
 274         }
 275         my %search_code = (  advanced_search_type => $advanced_srch_type,
 276                              code_loop => \@itypesloop );
 277         push @advancedsearchesloop, \%search_code;
 278     } else {
 279     # covers all the other cases: non-itemtype authorized values
 280        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 281         my @authvalueloop;
 282         for my $thisitemtype (@$advsearchtypes) {
 283                 my %row =(
 284                                 number=>$cnt++,
 285                                 ccl => $advanced_srch_type,
 286                 code => $thisitemtype->{authorised_value},
 287                 description => $thisitemtype->{'lib'},
 288                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 289                 );
 290                 push @authvalueloop, \%row;
 291         }
 292         my %search_code = (  advanced_search_type => $advanced_srch_type,
 293                              code_loop => \@authvalueloop );
 294         push @advancedsearchesloop, \%search_code;
 295     }
 296 }
 297 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 298
 299 # The following should only be loaded if we're bringing up the advanced search template
 300 if ( $template_type eq 'advsearch' ) {
 301
 302     # load the servers (used for searching -- to do federated searching, etc.)
 303     my $primary_servers_loop;# = displayPrimaryServers();
 304     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 305
 306     my $secondary_servers_loop;
 307     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 308
 309     # set the default sorting
 310     if (   C4::Context->preference('OPACdefaultSortField')
 311         && C4::Context->preference('OPACdefaultSortOrder') ) {
 312         my $default_sort_by =
 313             C4::Context->preference('defaultSortField') . '_'
 314           . C4::Context->preference('defaultSortOrder');
 315         $template->param( sort_by => $default_sort_by  );
 316     }
 317
 318     # determine what to display next to the search boxes (ie, boolean option
 319     # shouldn't appear on the first one, scan indexes should, adding a new
 320     # box should only appear on the last, etc.
 321     my @search_boxes_array;
 322     my $search_boxes_count = 3; # begin whith 3 boxes
 323     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 324     for (my $i=1;$i<=$search_boxes_count;$i++) {
 325         # if it's the first one, don't display boolean option, but show scan indexes
 326         if ($i==1) {
 327             push @search_boxes_array, {scan_index => 1};
 328         }
 329         # if it's the last one, show the 'add field' box
 330         elsif ($i==$search_boxes_count) {
 331             push @search_boxes_array,
 332                 {
 333                 boolean => 1,
 334                 add_field => 1,
 335                 };
 336         }
 337         else {
 338             push @search_boxes_array,
 339                 {
 340                 boolean => 1,
 341                 };
 342         }
 343
 344     }
 345     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 346                       search_boxes_loop => \@search_boxes_array);
 347
 348     # load the language limits (for search)
 349     my $languages_limit_loop = getLanguages($lang, 1);
 350     $template->param(search_languages_loop => $languages_limit_loop,);
 351
 352     # Expanded search options in advanced search:
 353     # use the global setting by default, but let the user override it
 354     {
 355         my $expanded = $cgi->param('expanded_options');
 356         $expanded = C4::Context->preference("expandedSearchOption") || 0
 357             if !defined($expanded) || $expanded !~ /^0|1$/;
 358         $template->param( expanded_options => $expanded );
 359     }
 360
 361     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 362
 363     output_html_with_http_headers $cgi, $cookie, $template->output;
 364     exit;
 365 }
 366
 367 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 368
 369 # Fetch the paramater list as a hash in scalar context:
 370 #  * returns paramater list as tied hash ref
 371 #  * we can edit the values by changing the key
 372 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 373 my $params = $cgi->Vars;
 374
 375 # Params that can have more than one value
 376 # sort by is used to sort the query
 377 # in theory can have more than one but generally there's just one
 378 my @sort_by;
 379 my $default_sort_by;
 380 if (   C4::Context->preference('defaultSortField')
 381     && C4::Context->preference('defaultSortOrder') ) {
 382     $default_sort_by =
 383         C4::Context->preference('defaultSortField') . '_'
 384       . C4::Context->preference('defaultSortOrder');
 385 }
 386
 387 @sort_by = $cgi->param('sort_by');
 388 $sort_by[0] = $default_sort_by unless $sort_by[0];
 389 foreach my $sort (@sort_by) {
 390     $template->param($sort => 1) if $sort;
 391 }
 392 $template->param('sort_by' => $sort_by[0]);
 393
 394 # Use the servers defined, or just search our local catalog(default)
 395 my @servers = $cgi->param('server');
 396 unless (@servers) {
 397     #FIXME: this should be handled using Context.pm
 398     @servers = ("biblioserver");
 399     # @servers = C4::Context->config("biblioserver");
 400 }
 401 # operators include boolean and proximity operators and are used
 402 # to evaluate multiple operands
 403 my @operators = map uri_unescape($_), $cgi->param('op');
 404
 405 # indexes are query qualifiers, like 'title', 'author', etc. They
 406 # can be single or multiple parameters separated by comma: kw,right-Truncation
 407 my @indexes = map uri_unescape($_), $cgi->param('idx');
 408
 409 # if a simple index (only one)  display the index used in the top search box
 410 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 411     my $idx = "ms_".$indexes[0];
 412     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 413     $template->param($idx => 1);
 414 }
 415
 416 # an operand can be a single term, a phrase, or a complete ccl query
 417 my @operands = map uri_unescape($_), $cgi->param('q');
 418
 419 # limits are use to limit to results to a pre-defined category such as branch or language
 420 my @limits = map uri_unescape($_), $cgi->param('limit');
 421 my @nolimits = map uri_unescape($_), $cgi->param('nolimit');
 422 my %is_nolimit = map { $_ => 1 } @nolimits;
 423 @limits = grep { not $is_nolimit{$_} } @limits;
 424
 425 if($params->{'multibranchlimit'}) {
 426     my $library_category = Koha::LibraryCategories->find( $params->{multibranchlimit} );
 427     my @libraries = $library_category->libraries;
 428     my $multibranch = '('.join( " or ", map { 'branch: ' . $_->id } @libraries ) .')';
 429     push @limits, $multibranch if ($multibranch ne  '()');
 430 }
 431
 432 my $available;
 433 foreach my $limit(@limits) {
 434     if ($limit =~/available/) {
 435         $available = 1;
 436     }
 437 }
 438 $template->param(available => $available);
 439
 440 # append year limits if they exist
 441 my $limit_yr;
 442 my $limit_yr_value;
 443 if ($params->{'limit-yr'}) {
 444     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 445         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 446         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 447         $limit_yr_value = "$yr1-$yr2";
 448     }
 449     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 450         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 451         $limit_yr_value = $params->{'limit-yr'};
 452     }
 453     push @limits,$limit_yr;
 454     #FIXME: Should return a error to the user, incorect date format specified
 455 }
 456
 457 # convert indexes and operands to corresponding parameter names for the z3950 search
 458 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 459 my $z3950par;
 460 my $indexes2z3950 = {
 461     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 462     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 463     ti=>'title', 'ti,phr'=>'title', se=>'title'
 464 };
 465 for (my $ii = 0; $ii < @operands; ++$ii)
 466 {
 467     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 468     if (defined $name && defined $operands[$ii])
 469     {
 470         $z3950par ||= {};
 471         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 472     }
 473 }
 474
 475
 476 # Params that can only have one value
 477 my $scan = $params->{'scan'};
 478 my $count = C4::Context->preference('numSearchResults') || 20;
 479 my $results_per_page = $params->{'count'} || $count;
 480 my $offset = $params->{'offset'} || 0;
 481 my $page = $cgi->param('page') || 1;
 482 #my $offset = ($page-1)*$results_per_page;
 483 my $hits;
 484 my $expanded_facet = $params->{'expand'};
 485
 486 # Define some global variables
 487 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 488
 489 ## I. BUILD THE QUERY
 490 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan,$lang);
 491
 492 ## parse the query_cgi string and put it into a form suitable for <input>s
 493 my @query_inputs;
 494 my $scan_index_to_use;
 495
 496 for my $this_cgi ( split('&',$query_cgi) ) {
 497     next unless $this_cgi;
 498     $this_cgi =~ m/(.*?)=(.*)/;
 499     my $input_name = $1;
 500     my $input_value = $2;
 501     push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 502     if ($input_name eq 'idx') {
 503         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 504     }
 505 }
 506 $template->param ( QUERY_INPUTS => \@query_inputs,
 507                    scan_index_to_use => $scan_index_to_use );
 508
 509 ## parse the limit_cgi string and put it into a form suitable for <input>s
 510 my @limit_inputs;
 511 for my $this_cgi ( split('&',$limit_cgi) ) {
 512     next unless $this_cgi;
 513     # handle special case limit-yr
 514     if ($this_cgi =~ /yr,st-numeric/) {
 515         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 516         next;
 517     }
 518     $this_cgi =~ m/(.*=)(.*)/;
 519     my $input_name = $1;
 520     my $input_value = $2;
 521     $input_name =~ s/=$//;
 522     push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 523 }
 524 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 525
 526 ## II. DO THE SEARCH AND GET THE RESULTS
 527 my $total; # the total results for the whole set
 528 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 529 my $results_hashref;
 530
 531 eval {
 532     ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$itemtypes,$query_type,$scan);
 533 };
 534
 535 # This sorts the facets into alphabetical order
 536 if ($facets) {
 537     foreach my $f (@$facets) {
 538         $f->{facets} = [ sort { uc($a->{facet_label_value}) cmp uc($b->{facet_label_value}) } @{ $f->{facets} } ];
 539     }
 540 }
 541 if ($@ || $error) {
 542     $template->param(query_error => $error.$@);
 543     output_html_with_http_headers $cgi, $cookie, $template->output;
 544     exit;
 545 }
 546
 547 # At this point, each server has given us a result set
 548 # now we build that set for template display
 549 my @sup_results_array;
 550 for (my $i=0;$i<@servers;$i++) {
 551     my $server = $servers[$i];
 552     if ($server =~/biblioserver/) { # this is the local bibliographic server
 553         $hits = $results_hashref->{$server}->{"hits"};
 554         my $page = $cgi->param('page') || 0;
 555         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 556                                        $results_hashref->{$server}->{"RECORDS"});
 557         $total = $total + $results_hashref->{$server}->{"hits"};
 558
 559         # Search history
 560         if (C4::Context->preference('EnableSearchHistory')) {
 561             unless ( $offset ) {
 562                 my $path_info = $cgi->url(-path_info=>1);
 563                 my $query_cgi_history = $cgi->url(-query=>1);
 564                 $query_cgi_history =~ s/^$path_info\?//;
 565                 $query_cgi_history =~ s/;/&/g;
 566                 my $query_desc_history = $query_desc;
 567                 $query_desc_history .= ", $limit_desc"
 568                     if $limit_desc;
 569
 570                 C4::Search::History::add({
 571                     userid => $borrowernumber,
 572                     sessionid => $cgi->cookie("CGISESSID"),
 573                     query_desc => $query_desc_history,
 574                     query_cgi => $query_cgi_history,
 575                     total => $total,
 576                     type => "biblio",
 577                 });
 578             }
 579             $template->param( EnableSearchHistory => 1 );
 580         }
 581
 582         ## If there's just one result, redirect to the detail page
 583         if ($total == 1) {
 584             my $biblionumber = $newresults[0]->{biblionumber};
 585             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 586             my $views = { C4::Search::enabled_staff_search_views };
 587             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 588                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 589             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 590                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 591             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 592                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 593             } else {
 594                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 595             }
 596             exit;
 597         }
 598
 599         # set up parameters if user wishes to re-run the search
 600         # as a Z39.50 search
 601         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 602
 603         if ($hits) {
 604             $template->param(total => $hits);
 605             my $limit_cgi_not_availablity = $limit_cgi;
 606             $limit_cgi_not_availablity =~ s/&limit=available//g;
 607             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 608             $template->param(limit_cgi => $limit_cgi);
 609             $template->param(query_cgi => $query_cgi);
 610             $template->param(query_desc => $query_desc);
 611             $template->param(limit_desc => $limit_desc);
 612             $template->param(offset     => $offset);
 613             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 614             if ($query_desc || $limit_desc) {
 615                 $template->param(searchdesc => 1);
 616             }
 617             $template->param(results_per_page =>  $results_per_page);
 618             # must define a value for size if not present in DB
 619             # in order to avoid problems generated by the default size value in TT
 620             foreach my $line (@newresults) {
 621                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 622             }
 623             $template->param(SEARCH_RESULTS => \@newresults);
 624             ## FIXME: add a global function for this, it's better than the current global one
 625             ## Build the page numbers on the bottom of the page
 626             my @page_numbers;
 627             # total number of pages there will be
 628             my $pages = ceil($hits / $results_per_page);
 629             # default page number
 630             my $current_page_number = 1;
 631             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 632             my $previous_page_offset;
 633             if ( $offset >= $results_per_page ) {
 634                 $previous_page_offset = $offset - $results_per_page;
 635             }
 636             my $next_page_offset = $offset + $results_per_page;
 637             # If we're within the first 10 pages, keep it simple
 638             #warn "current page:".$current_page_number;
 639             if ($current_page_number < 10) {
 640                 # just show the first 10 pages
 641                 # Loop through the pages
 642                 my $pages_to_show = 10;
 643                 $pages_to_show = $pages if $pages<10;
 644                 for (my $i=1; $i<=$pages_to_show;$i++) {
 645                     # the offset for this page
 646                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 647                     # the page number for this page
 648                     my $this_page_number = $i;
 649                     # put it in the array
 650                     push @page_numbers,
 651                       { offset    => $this_offset,
 652                         pg        => $this_page_number,
 653                         # it should only be highlighted if it's the current page
 654                         highlight => $this_page_number == $current_page_number,
 655                         sort_by   => join ' ', @sort_by
 656                       };
 657
 658                 }
 659
 660             }
 661
 662             # now, show twenty pages, with the current one smack in the middle
 663             else {
 664                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 665                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 666                     my $this_page_number = $i-9;
 667                     if ( $this_page_number <= $pages ) {
 668                         push @page_numbers,
 669                           { offset    => $this_offset,
 670                             pg        => $this_page_number,
 671                             highlight => $this_page_number == $current_page_number,
 672                             sort_by   => join ' ', @sort_by
 673                           };
 674                     }
 675                 }
 676             }
 677             # FIXME: no previous_page_offset when pages < 2
 678             $template->param(   PAGE_NUMBERS => \@page_numbers,
 679                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 680             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 681         }
 682
 683
 684         # no hits
 685         else {
 686             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 687         }
 688
 689     } # end of the if local
 690
 691     # asynchronously search the authority server
 692     elsif ($server =~/authorityserver/) { # this is the local authority server
 693         my @inner_sup_results_array;
 694         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 695             my $marc_record_object = C4::Search::new_record_from_zebra(
 696                 'authorityserver',
 697                 $sup_record
 698             );
 699             # warn "Authority Found: ".$marc_record_object->as_formatted();
 700             push @inner_sup_results_array, {
 701                 'title' => $marc_record_object->field(100)->subfield('a'),
 702                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 703             };
 704         }
 705         push @sup_results_array, {  servername => $server,
 706                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 707     }
 708     # FIXME: can add support for other targets as needed here
 709     $template->param(           outer_sup_results_loop => \@sup_results_array);
 710 } #/end of the for loop
 711 #$template->param(FEDERATED_RESULTS => \@results_array);
 712
 713 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 714
 715 my $gotonumber = $cgi->param('gotoNumber');
 716 if ($gotonumber eq 'last' || $gotonumber eq 'first') {
 717     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 718 }
 719 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 720 my $gotopage = $cgi->param('gotoPage');
 721 $template->{'VARS'}->{'gotoPage'} = $gotopage
 722   if $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 723
 724 for my $facet ( @$facets ) {
 725     for my $entry ( @{ $facet->{facets} } ) {
 726         my $index = $entry->{type_link_value};
 727         my $value = $entry->{facet_link_value};
 728         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 729     }
 730 }
 731
 732 $template->param(
 733             #classlist => $classlist,
 734             total => $total,
 735             opacfacets => 1,
 736             facets_loop => $facets,
 737             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 738             scan => $scan,
 739             search_error => $error,
 740 );
 741
 742 if ($query_desc || $limit_desc) {
 743     $template->param(searchdesc => 1);
 744 }
 745
 746 # VI. BUILD THE TEMPLATE
 747
 748 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 749     {
 750         borrowernumber => $borrowernumber,
 751         add_allowed    => 1,
 752         category       => 1,
 753     }
 754 );
 755 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 756     {
 757         borrowernumber => $borrowernumber,
 758         add_allowed    => 1,
 759         category       => 2,
 760     }
 761 );
 762
 763
 764 $template->param(
 765     add_to_some_private_shelves => $some_private_shelves,
 766     add_to_some_public_shelves  => $some_public_shelves,
 767 );
 768
 769 output_html_with_http_headers $cgi, $cookie, $template->output;