circ/returns.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN-OP
   5 #           2007-2010 BibLibre, Paul POULAIN
   6 #           2010 Catalyst IT
   7 #           2011 PTFS-Europe Ltd.
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 returns.pl
  25
  26 script to execute returns of books
  27
  28 =cut
  29
  30 use strict;
  31 use warnings;
  32
  33 use Carp 'verbose';
  34 $SIG{ __DIE__ } = sub { Carp::confess( @_ ) };
  35
  36 use CGI qw ( -utf8 );
  37 use DateTime;
  38 use C4::Context;
  39 use C4::Auth qw/:DEFAULT get_session/;
  40 use C4::Output;
  41 use C4::Circulation;
  42 use C4::Print;
  43 use C4::Reserves;
  44 use C4::Biblio;
  45 use C4::Items;
  46 use C4::Members;
  47 use C4::Members::Messaging;
  48 use C4::Koha;   # FIXME : is it still useful ?
  49 use C4::RotatingCollections;
  50 use Koha::AuthorisedValues;
  51 use Koha::DateUtils;
  52 use Koha::Calendar;
  53 use Koha::Checkouts;
  54 use Koha::BiblioFrameworks;
  55
  56 my $query = new CGI;
  57
  58 #getting the template
  59 my ( $template, $librarian, $cookie, $flags ) = get_template_and_user(
  60     {
  61         template_name   => "circ/returns.tt",
  62         query           => $query,
  63         type            => "intranet",
  64         authnotrequired => 0,
  65         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  66     }
  67 );
  68
  69 my $sessionID = $query->cookie("CGISESSID");
  70 my $session = get_session($sessionID);
  71 if ($session->param('branch') eq 'NO_LIBRARY_SET'){
  72     # no branch set we can't return
  73     print $query->redirect("/cgi-bin/koha/circ/selectbranchprinter.pl");
  74     exit;
  75 }
  76
  77 # Print a reserve slip on this page
  78 if ( $query->param('print_slip') ) {
  79     $template->param(
  80         print_slip     => 1,
  81         borrowernumber => scalar $query->param('borrowernumber'),
  82         biblionumber   => scalar $query->param('biblionumber'),
  83     );
  84 }
  85
  86 #####################
  87 #Global vars
  88 my $printers = GetPrinters();
  89 my $userenv = C4::Context->userenv;
  90 my $userenv_branch = $userenv->{'branch'} // '';
  91 my $printer = $userenv->{'branchprinter'} // '';
  92 my $forgivemanualholdsexpire = $query->param('forgivemanualholdsexpire');
  93
  94 my $overduecharges = (C4::Context->preference('finesMode') && C4::Context->preference('finesMode') ne 'off');
  95  #
  96 # Some code to handle the error if there is no branch or printer setting.....
  97 #
  98
  99 # Set up the item stack ....
 100 my %returneditems;
 101 my %riduedate;
 102 my %riborrowernumber;
 103 my @inputloop;
 104 foreach ( $query->param ) {
 105     my $counter;
 106     if (/ri-(\d*)/) {
 107         $counter = $1;
 108         if ($counter > 20) {
 109             next;
 110         }
 111     }
 112     else {
 113         next;
 114     }
 115
 116     my %input;
 117     my $barcode        = $query->param("ri-$counter");
 118     my $duedate        = $query->param("dd-$counter");
 119     my $borrowernumber = $query->param("bn-$counter");
 120     $counter++;
 121
 122     # decode barcode    ## Didn't we already decode them before passing them back last time??
 123     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 124     $barcode = barcodedecode($barcode) if(C4::Context->preference('itemBarcodeInputFilter'));
 125
 126     ######################
 127     #Are these lines still useful ?
 128     $returneditems{$counter}    = $barcode;
 129     $riduedate{$counter}        = $duedate;
 130     $riborrowernumber{$counter} = $borrowernumber;
 131
 132     #######################
 133     $input{counter}        = $counter;
 134     $input{barcode}        = $barcode;
 135     $input{duedate}        = $duedate;
 136     $input{borrowernumber} = $borrowernumber;
 137     push( @inputloop, \%input );
 138 }
 139
 140 ############
 141 # Deal with the requests....
 142
 143 if ($query->param('WT-itemNumber')){
 144         updateWrongTransfer ($query->param('WT-itemNumber'),$query->param('WT-waitingAt'),$query->param('WT-From'));
 145 }
 146
 147 if ( $query->param('reserve_id') ) {
 148     my $item           = $query->param('itemnumber');
 149     my $borrowernumber = $query->param('borrowernumber');
 150     my $reserve_id     = $query->param('reserve_id');
 151     my $diffBranchReturned = $query->param('diffBranch');
 152     my $iteminfo   = GetBiblioFromItemNumber($item);
 153     my $cancel_reserve = $query->param('cancel_reserve');
 154     # fix up item type for display
 155     $iteminfo->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $iteminfo->{'itype'} : $iteminfo->{'itemtype'};
 156
 157     if ( $cancel_reserve ) {
 158         CancelReserve({ reserve_id => $reserve_id, charge_cancel_fee => !$forgivemanualholdsexpire });
 159     } else {
 160         my $diffBranchSend = ($userenv_branch ne $diffBranchReturned) ? $diffBranchReturned : undef;
 161         # diffBranchSend tells ModReserveAffect whether document is expected in this library or not,
 162         # i.e., whether to apply waiting status
 163         ModReserveAffect( $item, $borrowernumber, $diffBranchSend, $reserve_id );
 164     }
 165 #   check if we have other reserves for this document, if we have a return send the message of transfer
 166     my ( $messages, $nextreservinfo ) = GetOtherReserves($item);
 167
 168     my $borr = GetMember( borrowernumber => $nextreservinfo );
 169     my $name   = $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'};
 170     if ( $messages->{'transfert'} ) {
 171         $template->param(
 172             itemtitle      => $iteminfo->{'title'},
 173             itemnumber     => $iteminfo->{'itemnumber'},
 174             itembiblionumber => $iteminfo->{'biblionumber'},
 175             iteminfo       => $iteminfo->{'author'},
 176             name           => $name,
 177             borrowernumber => $borrowernumber,
 178             borcnum        => $borr->{'cardnumber'},
 179             borfirstname   => $borr->{'firstname'},
 180             borsurname     => $borr->{'surname'},
 181             borcategory    => $borr->{'description'},
 182             diffbranch     => 1,
 183         );
 184     }
 185 }
 186
 187 my $borrower;
 188 my $returned = 0;
 189 my $messages;
 190 my $issueinformation;
 191 my $itemnumber;
 192 my $barcode     = $query->param('barcode');
 193 my $exemptfine  = $query->param('exemptfine');
 194 if (
 195   $exemptfine &&
 196   !C4::Auth::haspermission(C4::Context->userenv->{'id'}, {'updatecharges' => 'writeoff'})
 197 ) {
 198     # silently prevent unauthorized operator from forgiving overdue
 199     # fines by manually tweaking form parameters
 200     undef $exemptfine;
 201 }
 202 my $dropboxmode = $query->param('dropboxmode');
 203 my $dotransfer  = $query->param('dotransfer');
 204 my $canceltransfer = $query->param('canceltransfer');
 205 my $dest = $query->param('dest');
 206 my $calendar    = Koha::Calendar->new( branchcode => $userenv_branch );
 207 #dropbox: get last open day (today - 1)
 208 my $today       = DateTime->now( time_zone => C4::Context->tz());
 209 my $dropboxdate = $calendar->addDate($today, -1);
 210
 211 my $return_date_override = $query->param('return_date_override');
 212 my $return_date_override_remember =
 213   $query->param('return_date_override_remember');
 214 if ($return_date_override) {
 215     if ( C4::Context->preference('SpecifyReturnDate') ) {
 216         my $return_date_override_dt = eval {dt_from_string( $return_date_override ) };
 217         if ( $return_date_override_dt ) {
 218             # note that we've overriden the return date
 219             $template->param( return_date_was_overriden => 1);
 220             # Save the original format if we are remembering for this series
 221             $template->param(
 222                 return_date_override          => $return_date_override,
 223                 return_date_override_remember => 1
 224             ) if ($return_date_override_remember);
 225
 226             $return_date_override =
 227               DateTime::Format::MySQL->format_datetime( $return_date_override_dt );
 228         }
 229     }
 230     else {
 231         $return_date_override = q{};
 232     }
 233 }
 234
 235 if ($dotransfer){
 236 # An item has been returned to a branch other than the homebranch, and the librarian has chosen to initiate a transfer
 237     my $transferitem = $query->param('transferitem');
 238     my $tobranch     = $query->param('tobranch');
 239     ModItemTransfer($transferitem, $userenv_branch, $tobranch);
 240 }
 241
 242 if ($canceltransfer){
 243     $itemnumber=$query->param('itemnumber');
 244     DeleteTransfer($itemnumber);
 245     if($dest eq "ttr"){
 246         print $query->redirect("/cgi-bin/koha/circ/transferstoreceive.pl");
 247         exit;
 248     } else {
 249         $template->param( transfercancelled => 1);
 250     }
 251 }
 252
 253 # actually return book and prepare item table.....
 254 my $returnbranch;
 255 if ($barcode) {
 256     $barcode =~ s/^\s*|\s*$//g; # remove leading/trailing whitespace
 257     $barcode = barcodedecode($barcode) if C4::Context->preference('itemBarcodeInputFilter');
 258     $itemnumber = GetItemnumberFromBarcode($barcode);
 259
 260 #
 261 # save the return
 262 #
 263
 264     # get biblio description
 265     my $biblio = GetBiblioFromItemNumber($itemnumber);
 266     # fix up item type for display
 267     $biblio->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $biblio->{'itype'} : $biblio->{'itemtype'};
 268
 269     # Check if we should display a checkin message, based on the the item
 270     # type of the checked in item
 271     my $itemtype = Koha::ItemTypes->find( $biblio->{'itemtype'} );
 272     if ( $itemtype && $itemtype->checkinmsg ) {
 273         $template->param(
 274             checkinmsg     => $itemtype->checkinmsg,
 275             checkinmsgtype => $itemtype->checkinmsgtype,
 276         );
 277     }
 278
 279     # make sure return branch respects home branch circulation rules, default to homebranch
 280     my $hbr = GetBranchItemRule($biblio->{'homebranch'}, $itemtype ? $itemtype->itemtype : undef )->{'returnbranch'} || "homebranch";
 281     $returnbranch = $biblio->{$hbr};
 282
 283     my $materials = $biblio->{'materials'};
 284     my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => '', kohafield =>'items.materials', authorised_value => $materials });
 285     $materials = $descriptions->{lib} // $materials;
 286
 287     $template->param(
 288         title            => $biblio->{'title'},
 289         homebranch       => $biblio->{'homebranch'},
 290         holdingbranch    => $biblio->{'holdingbranch'},
 291         returnbranch     => $returnbranch,
 292         author           => $biblio->{'author'},
 293         itembarcode      => $biblio->{'barcode'},
 294         itemtype         => $biblio->{'itemtype'},
 295         ccode            => $biblio->{'ccode'},
 296         itembiblionumber => $biblio->{'biblionumber'},
 297         biblionumber     => $biblio->{'biblionumber'},
 298         borrower         => $borrower,
 299         additional_materials => $materials,
 300     );
 301
 302     my %input = (
 303         counter => 0,
 304         first   => 1,
 305         barcode => $barcode,
 306     );
 307
 308     # do the return
 309     ( $returned, $messages, $issueinformation, $borrower ) =
 310       AddReturn( $barcode, $userenv_branch, $exemptfine, $dropboxmode, $return_date_override, $dropboxdate );
 311
 312     if ($returned) {
 313         my $time_now = DateTime->now( time_zone => C4::Context->tz )->truncate( to => 'minute');
 314         my $duedate = $issueinformation->{date_due}->strftime('%Y-%m-%d %H:%M');
 315         $returneditems{0}      = $barcode;
 316         $riborrowernumber{0}   = $borrower->{'borrowernumber'};
 317         $riduedate{0}          = $duedate;
 318         $input{borrowernumber} = $borrower->{'borrowernumber'};
 319         $input{duedate}        = $duedate;
 320         unless ( $dropboxmode ) {
 321             $input{return_overdue} = 1 if (DateTime->compare($issueinformation->{date_due}, DateTime->now()) == -1);
 322         } else {
 323             $input{return_overdue} = 1 if (DateTime->compare($issueinformation->{date_due}, $dropboxdate) == -1);
 324         }
 325         push( @inputloop, \%input );
 326
 327         if ( C4::Context->preference("FineNotifyAtCheckin") ) {
 328             my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
 329             my $balance = $patron->account->balance;
 330
 331             if ($balance > 0) {
 332                 $template->param( fines => sprintf("%.2f", $balance) );
 333                 $template->param( fineborrowernumber => $borrower->{'borrowernumber'} );
 334             }
 335         }
 336
 337         if (C4::Context->preference("WaitingNotifyAtCheckin") ) {
 338             #Check for waiting holds
 339             my @reserves = GetReservesFromBorrowernumber($borrower->{'borrowernumber'});
 340             my $waiting_holds = 0;
 341             foreach my $num_res (@reserves) {
 342                 if ( $num_res->{'found'} eq 'W' && $num_res->{'branchcode'} eq $userenv_branch) {
 343                     $waiting_holds++;
 344                 }
 345             }
 346             if ($waiting_holds > 0) {
 347                 $template->param(
 348                     waiting_holds       => $waiting_holds,
 349                     holdsborrowernumber => $borrower->{'borrowernumber'},
 350                     holdsfirstname => $borrower->{'firstname'},
 351                     holdssurname => $borrower->{'surname'},
 352                 );
 353             }
 354         }
 355     } elsif ( C4::Context->preference('ShowAllCheckins') and !$messages->{'BadBarcode'} ) {
 356         $input{duedate}   = 0;
 357         $returneditems{0} = $barcode;
 358         $riduedate{0}     = 0;
 359         push( @inputloop, \%input );
 360     }
 361     $template->param( privacy => $borrower->{privacy} );
 362 }
 363 $template->param( inputloop => \@inputloop );
 364
 365 my $found    = 0;
 366 my $waiting  = 0;
 367 my $reserved = 0;
 368
 369 # new op dev : we check if the document must be returned to his homebranch directly,
 370 #  if the document is transfered, we have warning message .
 371
 372 if ( $messages->{'WasTransfered'} ) {
 373     $template->param(
 374         found          => 1,
 375         transfer       => 1,
 376         itemnumber     => $itemnumber,
 377     );
 378 }
 379
 380 if ( $messages->{'NeedsTransfer'} ){
 381     $template->param(
 382         found          => 1,
 383         needstransfer  => $messages->{'NeedsTransfer'},
 384         itemnumber     => $itemnumber,
 385     );
 386 }
 387
 388 if ( $messages->{'Wrongbranch'} ){
 389     $template->param(
 390         wrongbranch => 1,
 391         rightbranch => $messages->{'Wrongbranch'}->{'Rightbranch'},
 392     );
 393 }
 394
 395 # case of wrong transfert, if the document wasn't transfered to the right library (according to branchtransfer (tobranch) BDD)
 396
 397 if ( $messages->{'WrongTransfer'} and not $messages->{'WasTransfered'}) {
 398     $template->param(
 399         WrongTransfer  => 1,
 400         TransferWaitingAt => $messages->{'WrongTransfer'},
 401         WrongTransferItem => $messages->{'WrongTransferItem'},
 402         itemnumber => $itemnumber,
 403     );
 404
 405     my $reserve    = $messages->{'ResFound'};
 406     my $borr = C4::Members::GetMember( borrowernumber => $reserve->{'borrowernumber'} );
 407     my $name = $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'};
 408     $template->param(
 409             wname           => $name,
 410             wborfirstname   => $borr->{'firstname'},
 411             wborsurname     => $borr->{'surname'},
 412             wborcategory    => $borr->{'description'},
 413             wbortitle       => $borr->{'title'},
 414             wborphone       => $borr->{'phone'},
 415             wboremail       => $borr->{'email'},
 416             streetnumber    => $borr->{streetnumber},
 417             streettype      => $borr->{streettype},
 418             address         => $borr->{'address'},
 419             address2        => $borr->{'address2'},
 420             city            => $borr->{'city'},
 421             zipcode         => $borr->{'zipcode'},
 422             state           => $borr->{'state'},
 423             country         => $borr->{'country'},
 424             wborrowernumber => $reserve->{'borrowernumber'},
 425             wborcnum        => $borr->{'cardnumber'},
 426             wtransfertFrom  => $userenv_branch,
 427     );
 428 }
 429
 430 #
 431 # reserve found and item arrived at the expected branch
 432 #
 433 if ( $messages->{'ResFound'}) {
 434     my $reserve    = $messages->{'ResFound'};
 435     my $borr = C4::Members::GetMember( borrowernumber => $reserve->{'borrowernumber'} );
 436     my $holdmsgpreferences =  C4::Members::Messaging::GetMessagingPreferences( { borrowernumber => $reserve->{'borrowernumber'}, message_name   => 'Hold_Filled' } );
 437     if ( $reserve->{'ResFound'} eq "Waiting" or $reserve->{'ResFound'} eq "Reserved" ) {
 438         if ( $reserve->{'ResFound'} eq "Waiting" ) {
 439             $template->param(
 440                 waiting      => ($userenv_branch eq $reserve->{'branchcode'} ? 1 : 0 ),
 441             );
 442         } elsif ( $reserve->{'ResFound'} eq "Reserved" ) {
 443             $template->param(
 444                 intransit    => ($userenv_branch eq $reserve->{'branchcode'} ? 0 : 1 ),
 445                 transfertodo => ($userenv_branch eq $reserve->{'branchcode'} ? 0 : 1 ),
 446                 reserve_id   => $reserve->{reserve_id},
 447                 reserved     => 1,
 448             );
 449         }
 450
 451         # same params for Waiting or Reserved
 452         $template->param(
 453             found          => 1,
 454             name           => $borr->{'surname'} . ", " . $borr->{'title'} . " " . $borr->{'firstname'},
 455             borfirstname   => $borr->{'firstname'},
 456             borsurname     => $borr->{'surname'},
 457             borcategory    => $borr->{'description'},
 458             bortitle       => $borr->{'title'},
 459             borphone       => $borr->{'phone'},
 460             boremail       => $borr->{'email'},
 461             streetnumber   => $borr->{streetnumber},
 462             streettype     => $borr->{streettype},
 463             address        => $borr->{'address'},
 464             address2       => $borr->{'address2'},
 465             city           => $borr->{'city'},
 466             zipcode        => $borr->{'zipcode'},
 467             state          => $borr->{'state'},
 468             country        => $borr->{'country'},
 469             borcnum        => $borr->{'cardnumber'},
 470             debarred       => $borr->{'debarred'},
 471             gonenoaddress  => $borr->{'gonenoaddress'},
 472             barcode        => $barcode,
 473             destbranch     => $reserve->{'branchcode'},
 474             borrowernumber => $reserve->{'borrowernumber'},
 475             itemnumber     => $reserve->{'itemnumber'},
 476             reservenotes   => $reserve->{'reservenotes'},
 477             reserve_id     => $reserve->{reserve_id},
 478             bormessagepref => $holdmsgpreferences->{'transports'},
 479         );
 480     } # else { ; }  # error?
 481 }
 482
 483 # Error Messages
 484 my @errmsgloop;
 485 foreach my $code ( keys %$messages ) {
 486     my %err;
 487     my $exit_required_p = 0;
 488     if ( $code eq 'BadBarcode' ) {
 489         $err{badbarcode} = 1;
 490         $err{msg}        = $messages->{'BadBarcode'};
 491     }
 492     elsif ( $code eq 'NotIssued' ) {
 493         $err{notissued} = 1;
 494         $err{msg} = '';
 495         $err{msg} = $messages->{'IsPermanent'} if $messages->{'IsPermanent'};
 496     }
 497     elsif ( $code eq 'LocalUse' ) {
 498         $err{localuse} = 1;
 499     }
 500     elsif ( $code eq 'WasLost' ) {
 501         $err{waslost} = 1;
 502     }
 503     elsif ( $code eq 'LostItemFeeRefunded' ) {
 504         $template->param( LostItemFeeRefunded => 1 );
 505     }
 506     elsif ( $code eq 'ResFound' ) {
 507         ;    # FIXME... anything to do here?
 508     }
 509     elsif ( $code eq 'WasReturned' ) {
 510         ;    # FIXME... anything to do here?
 511     }
 512     elsif ( $code eq 'WasTransfered' ) {
 513         ;    # FIXME... anything to do here?
 514     }
 515     elsif ( $code eq 'withdrawn' ) {
 516         $err{withdrawn} = 1;
 517         $exit_required_p = 1 if C4::Context->preference("BlockReturnOfWithdrawnItems");
 518     }
 519     elsif ( ( $code eq 'IsPermanent' ) && ( not $messages->{'ResFound'} ) ) {
 520         if ( $messages->{'IsPermanent'} ne $userenv_branch ) {
 521             $err{ispermanent} = 1;
 522             $err{msg}         = $messages->{'IsPermanent'};
 523         }
 524     }
 525     elsif ( $code eq 'WrongTransfer' ) {
 526         ;    # FIXME... anything to do here?
 527     }
 528     elsif ( $code eq 'WrongTransferItem' ) {
 529         ;    # FIXME... anything to do here?
 530     }
 531     elsif ( $code eq 'NeedsTransfer' ) {
 532     }
 533     elsif ( $code eq 'Wrongbranch' ) {
 534     }
 535     elsif ( $code eq 'Debarred' ) {
 536         $err{debarred}            = $messages->{'Debarred'};
 537         $err{debarcardnumber}     = $borrower->{cardnumber};
 538         $err{debarborrowernumber} = $borrower->{borrowernumber};
 539         $err{debarname}           = "$borrower->{firstname} $borrower->{surname}";
 540     }
 541     elsif ( $code eq 'PrevDebarred' ) {
 542         $err{prevdebarred}        = $messages->{'PrevDebarred'};
 543     }
 544     elsif ( $code eq 'ForeverDebarred' ) {
 545         $err{foreverdebarred}        = $messages->{'ForeverDebarred'};
 546     }
 547     elsif ( $code eq 'NotForLoanStatusUpdated' ) {
 548         $err{NotForLoanStatusUpdated} = $messages->{NotForLoanStatusUpdated};
 549     }
 550     else {
 551         die "Unknown error code $code";    # note we need all the (empty) elsif's above, or we die.
 552         # This forces the issue of staying in sync w/ Circulation.pm
 553     }
 554     if (%err) {
 555         push( @errmsgloop, \%err );
 556     }
 557     last if $exit_required_p;
 558 }
 559 $template->param( errmsgloop => \@errmsgloop );
 560
 561 #set up so only the last 8 returned items display (make for faster loading pages)
 562 my $returned_counter = ( C4::Context->preference('numReturnedItemsToShow') ) ? C4::Context->preference('numReturnedItemsToShow') : 8;
 563 my $count = 0;
 564 my @riloop;
 565 my $shelflocations =
 566   { map { $_->{authorised_value} => $_->{lib} } Koha::AuthorisedValues->get_descriptions_by_koha_field( { frameworkcode => '', kohafield => 'items.location' } ) };
 567 foreach ( sort { $a <=> $b } keys %returneditems ) {
 568     my %ri;
 569     if ( $count++ < $returned_counter ) {
 570         my $bar_code = $returneditems{$_};
 571         if ($riduedate{$_}) {
 572             my $duedate = dt_from_string( $riduedate{$_}, 'sql');
 573             $ri{year}  = $duedate->year();
 574             $ri{month} = $duedate->month();
 575             $ri{day}   = $duedate->day();
 576             $ri{hour}   = $duedate->hour();
 577             $ri{minute}   = $duedate->minute();
 578             $ri{duedate} = output_pref($duedate);
 579             my $b      = C4::Members::GetMember( borrowernumber => $riborrowernumber{$_} );
 580             unless ( $dropboxmode ) {
 581                 $ri{return_overdue} = 1 if (DateTime->compare($duedate, DateTime->now()) == -1);
 582             } else {
 583                 $ri{return_overdue} = 1 if (DateTime->compare($duedate, $dropboxdate) == -1);
 584             }
 585             $ri{borrowernumber} = $b->{'borrowernumber'};
 586             $ri{borcnum}        = $b->{'cardnumber'};
 587             $ri{borfirstname}   = $b->{'firstname'};
 588             $ri{borsurname}     = $b->{'surname'};
 589             $ri{bortitle}       = $b->{'title'};
 590             $ri{bornote}        = $b->{'borrowernotes'};
 591             $ri{borcategorycode}= $b->{'categorycode'};
 592             $ri{borissuescount} = Koha::Checkouts->count( { borrowernumber => $b->{'borrowernumber'} } );
 593         }
 594         else {
 595             $ri{borrowernumber} = $riborrowernumber{$_};
 596         }
 597
 598         #        my %ri;
 599         my $biblio = GetBiblioFromItemNumber(GetItemnumberFromBarcode($bar_code));
 600         my $item   = GetItem( GetItemnumberFromBarcode($bar_code) );
 601         # fix up item type for display
 602         $biblio->{'itemtype'} = C4::Context->preference('item-level_itypes') ? $biblio->{'itype'} : $biblio->{'itemtype'};
 603         $ri{itembiblionumber}    = $biblio->{'biblionumber'};
 604         $ri{itemtitle}           = $biblio->{'title'};
 605         $ri{itemauthor}          = $biblio->{'author'};
 606         $ri{itemcallnumber}      = $biblio->{'itemcallnumber'};
 607         $ri{dateaccessioned}     = $item->{dateaccessioned};
 608         $ri{itemtype}            = $biblio->{'itemtype'};
 609         $ri{itemnote}            = $biblio->{'itemnotes'};
 610         $ri{itemnotes_nonpublic} = $item->{'itemnotes_nonpublic'};
 611         $ri{ccode}               = $biblio->{'ccode'};
 612         $ri{enumchron}           = $biblio->{'enumchron'};
 613         $ri{itemnumber}          = $biblio->{'itemnumber'};
 614         $ri{barcode}             = $bar_code;
 615         $ri{homebranch}          = $item->{'homebranch'};
 616         $ri{holdingbranch}       = $item->{'holdingbranch'};
 617
 618         $ri{location}         = $biblio->{'location'};
 619         my $shelfcode = $ri{'location'};
 620         $ri{'location'} = $shelflocations->{$shelfcode} if ( defined( $shelfcode ) && defined($shelflocations) && exists( $shelflocations->{$shelfcode} ) );
 621
 622     }
 623     else {
 624         last;
 625     }
 626     push @riloop, \%ri;
 627 }
 628
 629 $template->param(
 630     riloop         => \@riloop,
 631     printer        => $printer,
 632     errmsgloop     => \@errmsgloop,
 633     exemptfine     => $exemptfine,
 634     dropboxmode    => $dropboxmode,
 635     dropboxdate    => output_pref($dropboxdate),
 636     forgivemanualholdsexpire => $forgivemanualholdsexpire,
 637     overduecharges => $overduecharges,
 638     AudioAlerts        => C4::Context->preference("AudioAlerts"),
 639     BlockReturnOfWithdrawnItems => C4::Context->preference("BlockReturnOfWithdrawnItems"),
 640 );
 641
 642 $itemnumber = GetItemnumberFromBarcode( $barcode );
 643 if ( $itemnumber ) {
 644     my ( $holdingBranch, $collectionBranch ) = GetCollectionItemBranches( $itemnumber );
 645     if ( $holdingBranch and $collectionBranch ) {
 646         $holdingBranch //= '';
 647         $collectionBranch //= $returnbranch;
 648         if ( ! ( $holdingBranch eq $collectionBranch ) ) {
 649             $template->param(
 650               collectionItemNeedsTransferred => 1,
 651               collectionBranch => $collectionBranch,
 652               itemnumber => $itemnumber,
 653             );
 654         }
 655     }
 656 }
 657
 658 # Checking if there is a Fast Cataloging Framework
 659 $template->param( fast_cataloging => 1 ) if Koha::BiblioFrameworks->find( 'FA' );
 660
 661 # actually print the page!
 662 output_html_with_http_headers $query, $cookie, $template->output;