Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28
  29 use base qw(Koha::Object);
  30
  31 =head1 NAME
  32
  33 Koha::Library - Koha Library Object class
  34
  35 =head1 API
  36
  37 =head2 Class methods
  38
  39 =head3 stockrotationstages
  40
  41   my $stages = Koha::Library->stockrotationstages;
  42
  43 Returns the stockrotation stages associated with this Library.
  44
  45 =cut
  46
  47 sub stockrotationstages {
  48     my ( $self ) = @_;
  49     my $rs = $self->_result->stockrotationstages;
  50     return Koha::StockRotationStages->_new_from_dbic( $rs );
  51 }
  52
  53 =head3 get_effective_marcorgcode
  54
  55     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  56
  57 Returns the effective MARC organization code of the library. It falls back to the value
  58 from the I<MARCOrgCode> syspref if undefined for the library.
  59
  60 =cut
  61
  62 sub get_effective_marcorgcode {
  63     my ( $self )  = @_;
  64
  65     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  66 }
  67
  68 =head3 library_groups
  69
  70 Return the Library groups of this library
  71
  72 =cut
  73
  74 sub library_groups {
  75     my ( $self ) = @_;
  76     my $rs = $self->_result->library_groups;
  77     return Koha::Library::Groups->_new_from_dbic( $rs );
  78 }
  79
  80 =head3 cash_registers
  81
  82 Return Cash::Registers associated with this Library
  83
  84 =cut
  85
  86 sub cash_registers {
  87     my ( $self ) = @_;
  88     my $rs = $self->_result->cash_registers;
  89     return Koha::Cash::Registers->_new_from_dbic( $rs );
  90 }
  91
  92 =head3 to_api_mapping
  93
  94 This method returns the mapping for representing a Koha::Library object
  95 on the API.
  96
  97 =cut
  98
  99 sub to_api_mapping {
 100     return {
 101         branchcode       => 'library_id',
 102         branchname       => 'name',
 103         branchaddress1   => 'address1',
 104         branchaddress2   => 'address2',
 105         branchaddress3   => 'address3',
 106         branchzip        => 'postal_code',
 107         branchcity       => 'city',
 108         branchstate      => 'state',
 109         branchcountry    => 'country',
 110         branchphone      => 'phone',
 111         branchfax        => 'fax',
 112         branchemail      => 'email',
 113         branchreplyto    => 'reply_to_email',
 114         branchreturnpath => 'return_path_email',
 115         branchurl        => 'url',
 116         issuing          => undef,
 117         branchip         => 'ip',
 118         branchprinter    => undef,
 119         branchnotes      => 'notes',
 120         marcorgcode      => 'marc_org_code',
 121     };
 122 }
 123
 124 =head3 get_hold_libraries
 125
 126 Return all libraries (including self) that belong to the same hold groups
 127
 128 =cut
 129
 130 sub get_hold_libraries {
 131     my ( $self ) = @_;
 132     my $library_groups = $self->library_groups;
 133     my @hold_libraries;
 134     while ( my $library_group = $library_groups->next ) {
 135         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 136         if($root->ft_local_hold_group) {
 137             push @hold_libraries, $root->all_libraries;
 138         }
 139     }
 140
 141     my %seen;
 142     @hold_libraries =
 143       grep { !$seen{ $_->id }++ } @hold_libraries;
 144
 145     return @hold_libraries;
 146 }
 147
 148 =head3 validate_hold_sibling
 149
 150 Return if given library is a valid hold group member
 151
 152 =cut
 153
 154 sub validate_hold_sibling {
 155     my ( $self, $params ) = @_;
 156     my @hold_libraries = $self->get_hold_libraries;
 157
 158     foreach (@hold_libraries) {
 159         my $hold_library = $_;
 160         my $is_valid = 1;
 161         foreach my $key (keys %$params) {
 162             unless($hold_library->$key eq $params->{$key}) {
 163                 $is_valid=0;
 164                 last;
 165             }
 166         }
 167         if($is_valid) {
 168             #Found one library that meets all search parameters
 169             return 1;
 170         }
 171     }
 172     return 0;
 173 }
 174
 175 =head2 Internal methods
 176
 177 =head3 _type
 178
 179 =cut
 180
 181 sub _type {
 182     return 'Branch';
 183 }
 184
 185 1;