members/paycollect.pl

   1 #!/usr/bin/perl
   2 # Copyright 2009,2010 PTFS Inc.
   3 # Copyright 2011 PTFS-Europe Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use URI::Escape;
  22 use CGI qw ( -utf8 );
  23
  24 use C4::Context;
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Members;
  28 use C4::Accounts;
  29 use C4::Koha;
  30
  31 use Koha::Cash::Registers;
  32 use Koha::Patrons;
  33 use Koha::Patron::Categories;
  34 use Koha::AuthorisedValues;
  35 use Koha::Account;
  36 use Koha::Token;
  37
  38 my $input = CGI->new();
  39
  40 my $payment_id          = $input->param('payment_id');
  41 my $writeoff_individual = $input->param('writeoff_individual');
  42 my $change_given        = $input->param('change_given');
  43 my $type                = scalar $input->param('type') || 'PAYMENT';
  44
  45 my $updatecharges_permissions = ($writeoff_individual || $type eq 'writeoff') ? 'writeoff' : 'remaining_permissions';
  46 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  47     {   template_name   => 'members/paycollect.tt',
  48         query           => $input,
  49         type            => 'intranet',
  50         authnotrequired => 0,
  51         flagsrequired   => { borrowers => 'edit_borrowers', updatecharges => $updatecharges_permissions },
  52         debug           => 1,
  53     }
  54 );
  55
  56 # get borrower details
  57 my $borrowernumber = $input->param('borrowernumber');
  58 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  59 my $patron         = Koha::Patrons->find( $borrowernumber );
  60 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  61
  62 my $borrower       = $patron->unblessed;
  63 my $account        = $patron->account;
  64 my $category       = $patron->category;
  65 my $user           = $input->remote_user;
  66
  67 my $library_id = C4::Context->userenv->{'branch'};
  68 my $total_due  = $account->outstanding_debits->total_outstanding;
  69
  70 my $total_paid = $input->param('paid');
  71
  72 my $selected_lines = $input->param('selected'); # comes from pay.pl
  73 my $pay_individual   = $input->param('pay_individual');
  74 my $selected_accts   = $input->param('selected_accts'); # comes from paycollect.pl
  75 my $payment_note = uri_unescape scalar $input->param('payment_note');
  76 my $payment_type = scalar $input->param('payment_type');
  77 my $accountlines_id;
  78
  79 my $registerid;
  80 if ( C4::Context->preference('UseCashRegisters') ) {
  81     $registerid = $input->param('registerid');
  82     my $registers  = Koha::Cash::Registers->search(
  83         { branch   => $library_id, archived => 0 },
  84         { order_by => { '-asc' => 'name' } }
  85     );
  86
  87     if ( !$registers->count ) {
  88         $template->param( error_registers => 1 );
  89     }
  90     else {
  91
  92         if ( !$registerid ) {
  93             my $default_register = Koha::Cash::Registers->find(
  94                 { branch => $library_id, branch_default => 1 } );
  95             $registerid = $default_register->id if $default_register;
  96         }
  97         $registerid = $registers->next->id if !$registerid;
  98
  99         $template->param(
 100             registerid => $registerid,
 101             registers  => $registers,
 102         );
 103     }
 104 }
 105
 106 if ( $pay_individual || $writeoff_individual ) {
 107     if ($pay_individual) {
 108         $template->param( pay_individual => 1 );
 109     } elsif ($writeoff_individual) {
 110         $template->param( writeoff_individual => 1 );
 111     }
 112     my $debit_type_code   = $input->param('debit_type_code');
 113     $accountlines_id      = $input->param('accountlines_id');
 114     my $amount            = $input->param('amount');
 115     my $amountoutstanding = $input->param('amountoutstanding');
 116     my $itemnumber  = $input->param('itemnumber');
 117     my $description  = $input->param('description');
 118     my $title        = $input->param('title');
 119     $total_due = $amountoutstanding;
 120     $template->param(
 121         debit_type_code    => $debit_type_code,
 122         accountlines_id    => $accountlines_id,
 123         amount            => $amount,
 124         amountoutstanding => $amountoutstanding,
 125         title             => $title,
 126         itemnumber        => $itemnumber,
 127         individual_description => $description,
 128         payment_note    => $payment_note,
 129     );
 130 } elsif ($selected_lines) {
 131     $total_due = $input->param('amt');
 132     $template->param(
 133         selected_accts => $selected_lines,
 134         amt            => $total_due,
 135         selected_accts_notes => scalar $input->param('notes'),
 136     );
 137 }
 138
 139 my @selected_accountlines;
 140 if ( $selected_accts ) {
 141     if ( $selected_accts =~ /^([\d,]*).*/ ) {
 142         $selected_accts = $1;    # ensure passing no junk
 143     }
 144     my @acc = split /,/, $selected_accts;
 145
 146     @selected_accountlines = Koha::Account::Lines->search(
 147         {
 148             borrowernumber    => $borrowernumber,
 149             amountoutstanding => { '<>' => 0 },
 150             accountlines_id   => { 'in' => \@acc },
 151         },
 152         { order_by => 'date' }
 153     );
 154
 155     $total_due = 0; # Reset and recalculate total due
 156     map { $total_due += $_->amountoutstanding } @selected_accountlines;
 157 }
 158
 159
 160 if ( $total_paid and $total_paid ne '0.00' ) {
 161     $total_paid = $total_due if (abs($total_paid - $total_due) < 0.01) && C4::Context->preference('RoundFinesAtPayment');
 162     if ( $total_paid < 0 or $total_paid > $total_due ) {
 163         $template->param(
 164             error_over => 1,
 165             total_due => $total_due
 166         );
 167     } else {
 168         output_and_exit( $input, $cookie, $template,  'wrong_csrf_token' )
 169             unless Koha::Token->new->check_csrf( {
 170                 session_id => $input->cookie('CGISESSID'),
 171                 token  => scalar $input->param('csrf_token'),
 172             });
 173
 174         if ($pay_individual) {
 175             my $line = Koha::Account::Lines->find($accountlines_id);
 176             $payment_id = $account->pay(
 177                 {
 178                     lines        => [$line],
 179                     amount       => $total_paid,
 180                     library_id   => $library_id,
 181                     note         => $payment_note,
 182                     interface    => C4::Context->interface,
 183                     payment_type => $payment_type,
 184                     cash_register => $registerid
 185                 }
 186             );
 187             print $input->redirect(
 188                 "/cgi-bin/koha/members/pay.pl?borrowernumber=$borrowernumber&payment_id=$payment_id&change_given=$change_given");
 189         } else {
 190             if ($selected_accts) {
 191                 if ( $total_paid > $total_due ) {
 192                     $template->param(
 193                         error_over => 1,
 194                         total_due => $total_due
 195                     );
 196                 } else {
 197                     my $note = $input->param('selected_accts_notes');
 198
 199                     $payment_id = $account->pay(
 200                         {
 201                             type         => $type,
 202                             amount       => $total_paid,
 203                             library_id   => $library_id,
 204                             lines        => \@selected_accountlines,
 205                             note         => $note,
 206                             interface    => C4::Context->interface,
 207                             payment_type => $payment_type,
 208                             cash_register => $registerid
 209                         }
 210                       );
 211                 }
 212             }
 213             else {
 214                 my $note = $input->param('selected_accts_notes');
 215                 $payment_id = $account->pay(
 216                     {
 217                         amount       => $total_paid,
 218                         library_id   => $library_id,
 219                         note         => $note,
 220                         payment_type => $payment_type,
 221                         interface    => C4::Context->interface,
 222                         payment_type => $payment_type,
 223                         cash_register => $registerid
 224                     }
 225                 );
 226             }
 227
 228             print $input->redirect("/cgi-bin/koha/members/boraccount.pl?borrowernumber=$borrowernumber&payment_id=$payment_id&change_given=$change_given");
 229         }
 230     }
 231 } else {
 232     $total_paid = '0.00';    #TODO not right with pay_individual
 233 }
 234
 235 $template->param(%$borrower);
 236
 237 if ( $input->param('error_over') ) {
 238     $template->param( error_over => 1, total_due => scalar $input->param('amountoutstanding') );
 239 }
 240
 241 $template->param(
 242     payment_id => $payment_id,
 243
 244     type           => $type,
 245     borrowernumber => $borrowernumber,    # some templates require global
 246     patron         => $patron,
 247     total          => $total_due,
 248
 249     csrf_token => Koha::Token->new->generate_csrf( { session_id => scalar $input->cookie('CGISESSID') } ),
 250 );
 251
 252 output_html_with_http_headers $input, $cookie, $template->output;