tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI qw ( -utf8 );
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Branch; # GetBranches
  50 use C4::Letters;
  51 use C4::Members::Attributes;
  52
  53 # $protected_letters = protected_letters()
  54 # - return a hashref of letter_codes representing letters that should never be deleted
  55 sub protected_letters {
  56     my $dbh = C4::Context->dbh;
  57     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  58     return { map { $_->[0] => 1 } @{$codes} };
  59 }
  60
  61 our $input       = new CGI;
  62 my $searchfield = $input->param('searchfield');
  63 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  64 our $branchcode  = $input->param('branchcode');
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode') || q||;
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         branchloop => _branchloop($branchcode),
 107         copying => 1,
 108         modify => 0,
 109     );
 110 }
 111 elsif ( $op eq 'add_form' ) {
 112     add_form($branchcode, $module, $code);
 113 }
 114 elsif ( $op eq 'delete_confirm' ) {
 115     delete_confirm($branchcode, $module, $code);
 116 }
 117 elsif ( $op eq 'delete_confirmed' ) {
 118     delete_confirmed($branchcode, $module, $code);
 119     $op = q{}; # next operation is to return to default screen
 120 }
 121 else {
 122     default_display($branchcode,$searchfield);
 123 }
 124
 125 # Do this last as delete_confirmed resets
 126 if ($op) {
 127     $template->param($op  => 1);
 128 } else {
 129     $template->param(no_op_set => 1);
 130 }
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;
 133
 134 sub add_form {
 135     my ( $branchcode,$module, $code ) = @_;
 136
 137     my $letters;
 138     # if code has been passed we can identify letter and its an update action
 139     if ($code) {
 140         $letters = C4::Letters::GetLetterTemplates(
 141             {
 142                 branchcode => $branchcode,
 143                 module     => $module,
 144                 code       => $code,
 145             }
 146         );
 147     }
 148
 149     my $message_transport_types = GetMessageTransportTypes();
 150     my @letter_loop;
 151     if ($letters) {
 152         $template->param(
 153             modify     => 1,
 154             code       => $code,
 155             branchcode => $branchcode,
 156         );
 157         my $first_flag = 1;
 158         # The letter name is contained into each mtt row.
 159         # So we can only sent the first one to the template.
 160         for my $mtt ( @$message_transport_types ) {
 161             # The letter_name
 162             if ( $first_flag and $letters->{$mtt}{name} ) {
 163                 $template->param(
 164                     letter_name=> $letters->{$mtt}{name},
 165                 );
 166                 $first_flag = 0;
 167             }
 168
 169             push @letter_loop, {
 170                 message_transport_type => $mtt,
 171                 is_html    => $letters->{$mtt}{is_html},
 172                 title      => $letters->{$mtt}{title},
 173                 content    => $letters->{$mtt}{content}//'',
 174             };
 175         }
 176     }
 177     else { # initialize the new fields
 178         for my $mtt ( @$message_transport_types ) {
 179             push @letter_loop, {
 180                 message_transport_type => $mtt,
 181             }
 182         }
 183         $template->param(
 184             branchcode => $branchcode,
 185             module     => $module,
 186         );
 187         $template->param( adding => 1 );
 188     }
 189
 190     $template->param(
 191         letters => \@letter_loop,
 192     );
 193
 194     my $field_selection;
 195     push @{$field_selection}, add_fields('branches');
 196     if ($module eq 'reserves') {
 197         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'items');
 198     }
 199     elsif ( $module eq 'acquisition' ) {
 200         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 201     }
 202     elsif ($module eq 'claimacquisition') {
 203         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'biblioitems');
 204     }
 205     elsif ($module eq 'claimissues') {
 206         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 207         push @{$field_selection},
 208         {
 209             value => q{},
 210             text => '---BIBLIO---'
 211         };
 212         foreach(qw(title author serial)) {
 213             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 214         }
 215     }
 216     elsif ($module eq 'suggestions') {
 217         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 218     }
 219     else {
 220         push @{$field_selection}, add_fields('biblio','biblioitems'),
 221             add_fields('items'),
 222             {value => 'items.content', text => 'items.content'},
 223             {value => 'items.fine',    text => 'items.fine'},
 224             add_fields('borrowers');
 225         if ($module eq 'circulation') {
 226             push @{$field_selection}, add_fields('opac_news');
 227
 228         }
 229
 230         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 231             push @{$field_selection}, add_fields('old_issues');
 232         } else {
 233             push @{$field_selection}, add_fields('issues');
 234         }
 235     }
 236
 237     $template->param(
 238         module     => $module,
 239         branchloop => _branchloop($branchcode),
 240         SQLfieldnames => $field_selection,
 241         branchcode => $branchcode,
 242     );
 243     return;
 244 }
 245
 246 sub add_validate {
 247     my $dbh        = C4::Context->dbh;
 248     my $branchcode    = $input->param('branchcode') || '';
 249     my $module        = $input->param('module');
 250     my $oldmodule     = $input->param('oldmodule');
 251     my $code          = $input->param('code');
 252     my $name          = $input->param('name');
 253     my @mtt           = $input->param('message_transport_type');
 254     my @title         = $input->param('title');
 255     my @content       = $input->param('content');
 256     for my $mtt ( @mtt ) {
 257         my $is_html = $input->param("is_html_$mtt");
 258         my $title   = shift @title;
 259         my $content = shift @content;
 260         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt);
 261
 262         # getletter can return the default letter even if we pass a branchcode
 263         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 264         if ( $letter and $branchcode ne $letter->{branchcode} ) {
 265             $letter = undef;
 266         }
 267         unless ( $title and $content ) {
 268             # Delete this mtt if no title or content given
 269             delete_confirmed( $branchcode, $oldmodule, $code, $mtt );
 270             next;
 271         }
 272         elsif ( $letter and $letter->{message_transport_type} eq $mtt ) {
 273             $dbh->do(
 274                 q{
 275                     UPDATE letter
 276                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?
 277                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 278                 },
 279                 undef,
 280                 $branchcode, $module, $name, $is_html || 0, $title, $content,
 281                 $branchcode, $oldmodule, $code, $mtt
 282             );
 283         } else {
 284             $dbh->do(
 285                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type) VALUES (?,?,?,?,?,?,?,?)},
 286                 undef,
 287                 $branchcode, $module, $code, $name, $is_html || 0, $title, $content, $mtt
 288             );
 289         }
 290     }
 291     # set up default display
 292     default_display($branchcode);
 293     return 1;
 294 }
 295
 296 sub delete_confirm {
 297     my ($branchcode, $module, $code) = @_;
 298     my $dbh = C4::Context->dbh;
 299     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 300     my @values = values %$letter;
 301     $template->param(
 302         letter => $letter,
 303     );
 304     return;
 305 }
 306
 307 sub delete_confirmed {
 308     my ($branchcode, $module, $code, $mtt) = @_;
 309     C4::Letters::DelLetter(
 310         {
 311             branchcode => $branchcode,
 312             module     => $module,
 313             code       => $code,
 314             mtt        => $mtt
 315         }
 316     );
 317     # setup default display for screen
 318     default_display($branchcode);
 319     return;
 320 }
 321
 322 sub retrieve_letters {
 323     my ($branchcode, $searchstring) = @_;
 324
 325     $branchcode = $my_branch if $branchcode && $my_branch;
 326
 327     my $dbh = C4::Context->dbh;
 328     my ($sql, @where, @args);
 329     $sql = "SELECT branchcode, module, code, name, branchname
 330             FROM letter
 331             LEFT OUTER JOIN branches USING (branchcode)
 332     ";
 333     if ($searchstring && $searchstring=~m/(\S+)/) {
 334         $searchstring = $1 . q{%};
 335         push @where, 'code LIKE ?';
 336         push @args, $searchstring;
 337     }
 338     elsif ($branchcode) {
 339         push @where, 'branchcode = ?';
 340         push @args, $branchcode || '';
 341     }
 342     elsif ($my_branch) {
 343         push @where, "(branchcode = ? OR branchcode = '')";
 344         push @args, $my_branch;
 345     }
 346
 347     $sql .= " WHERE ".join(" AND ", @where) if @where;
 348     $sql .= " GROUP BY branchcode,module,code";
 349     $sql .= " ORDER BY module, code, branchcode";
 350
 351     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 352 }
 353
 354 sub default_display {
 355     my ($branchcode, $searchfield) = @_;
 356
 357     if ( $searchfield  ) {
 358         $template->param( search      => 1 );
 359     }
 360     my $results = retrieve_letters($branchcode,$searchfield);
 361
 362     my $loop_data = [];
 363     my $protected_letters = protected_letters();
 364     foreach my $row (@{$results}) {
 365         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 366         push @{$loop_data}, $row;
 367
 368     }
 369
 370     $template->param(
 371         letter => $loop_data,
 372         branchloop => _branchloop($branchcode),
 373     );
 374 }
 375
 376 sub _branchloop {
 377     my ($branchcode) = @_;
 378
 379     my $branches = GetBranches();
 380     my @branchloop;
 381     for my $thisbranch (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 382         push @branchloop, {
 383             value      => $thisbranch,
 384             selected   => $branchcode && $thisbranch eq $branchcode,
 385             branchname => $branches->{$thisbranch}->{'branchname'},
 386         };
 387     }
 388
 389     return \@branchloop;
 390 }
 391
 392 sub add_fields {
 393     my @tables = @_;
 394     my @fields = ();
 395
 396     for my $table (@tables) {
 397         push @fields, get_columns_for($table);
 398
 399     }
 400     return @fields;
 401 }
 402
 403 sub get_columns_for {
 404     my $table = shift;
 405 # FIXME untranslateable
 406     my %column_map = (
 407         aqbooksellers => '---BOOKSELLERS---',
 408         aqorders      => '---ORDERS---',
 409         serial        => '---SERIALS---',
 410         reserves      => '---HOLDS---',
 411         suggestions   => '---SUGGESTIONS---',
 412     );
 413     my @fields = ();
 414     if (exists $column_map{$table} ) {
 415         push @fields, {
 416             value => q{},
 417             text  => $column_map{$table} ,
 418         };
 419     }
 420     else {
 421         my $tlabel = '---' . uc $table;
 422         $tlabel.= '---';
 423         push @fields, {
 424             value => q{},
 425             text  => $tlabel,
 426         };
 427     }
 428
 429     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 430     my $table_prefix = $table . q|.|;
 431     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 432     for my $row (@{$rows}) {
 433         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 434         push @fields, {
 435             value => $table_prefix . $row->{Field},
 436             text  => $table_prefix . $row->{Field},
 437         }
 438     }
 439     if ($table eq 'borrowers') {
 440         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 441             foreach (@$attributes) {
 442                 push @fields, {
 443                     value => "borrower-attribute:$_",
 444                     text  => "attribute:$_",
 445                 }
 446             }
 447         }
 448     }
 449     return @fields;
 450 }