members/moremember.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 moremember.pl
  24
  25  script to do a borrower enquiry/bring up borrower details etc
  26  Displays all the details about a borrower
  27  written 20/12/99 by chris@katipo.co.nz
  28  last modified 21/1/2000 by chris@katipo.co.nz
  29  modified 31/1/2001 by chris@katipo.co.nz
  30    to not allow items on request to be renewed
  31
  32  needs html removed and to use the C4::Output more, but its tricky
  33
  34 =cut
  35
  36 use strict;
  37 #use warnings; FIXME - Bug 2505
  38 use CGI qw ( -utf8 );
  39 use Digest::MD5 qw(md5_base64);
  40 use C4::Context;
  41 use C4::Auth;
  42 use C4::Output;
  43 use C4::Members;
  44 use C4::Members::Attributes;
  45 use C4::Members::AttributeTypes;
  46 use C4::Reserves;
  47 use C4::Circulation;
  48 use C4::Koha;
  49 use C4::Letters;
  50 use C4::Biblio;
  51 use C4::Branch; # GetBranchName
  52 use C4::Form::MessagingPreferences;
  53 use List::MoreUtils qw/uniq/;
  54 use C4::Members::Attributes qw(GetBorrowerAttributes);
  55 use Koha::Patron::Debarments qw(GetDebarments IsDebarred);
  56 use Koha::Patron::Images;
  57 use Module::Load;
  58 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
  59     load Koha::NorwegianPatronDB, qw( NLGetSyncDataFromBorrowernumber );
  60 }
  61 #use Smart::Comments;
  62 #use Data::Dumper;
  63 use DateTime;
  64 use Koha::DateUtils;
  65 use Koha::Database;
  66
  67 use Koha::Patron::Categories;
  68 use Koha::Token;
  69
  70 use vars qw($debug);
  71
  72 BEGIN {
  73         $debug = $ENV{DEBUG} || 0;
  74 }
  75
  76 my $dbh = C4::Context->dbh;
  77
  78 my $input = CGI->new;
  79 $debug or $debug = $input->param('debug') || 0;
  80 my $print = $input->param('print');
  81
  82 my $template_name;
  83 my $quickslip = 0;
  84
  85 my $flagsrequired;
  86 if (defined $print and $print eq "page") {
  87     $template_name = "members/moremember-print.tt";
  88     # circ staff who process checkouts but can't edit
  89     # patrons still need to be able to access print view
  90     $flagsrequired = { circulate => "circulate_remaining_permissions" };
  91 } elsif (defined $print and $print eq "slip") {
  92     $template_name = "members/moremember-receipt.tt";
  93     # circ staff who process checkouts but can't edit
  94     # patrons still need to be able to print receipts
  95     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  96 } elsif (defined $print and $print eq "qslip") {
  97     $template_name = "members/moremember-receipt.tt";
  98     $quickslip = 1;
  99     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
 100 } elsif (defined $print and $print eq "brief") {
 101     $template_name = "members/moremember-brief.tt";
 102     $flagsrequired = { borrowers => 1 };
 103 } else {
 104     $template_name = "members/moremember.tt";
 105     $flagsrequired = { borrowers => 1 };
 106 }
 107
 108 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 109     {
 110         template_name   => $template_name,
 111         query           => $input,
 112         type            => "intranet",
 113         authnotrequired => 0,
 114         flagsrequired   => $flagsrequired,
 115         debug           => 1,
 116     }
 117 );
 118 my $borrowernumber = $input->param('borrowernumber');
 119 my $error = $input->param('error');
 120 $template->param( error => $error ) if ( $error );
 121
 122 my ( $od, $issue, $fines ) = GetMemberIssuesAndFines($borrowernumber);
 123 $template->param( issuecount => $issue, fines => $fines );
 124
 125 my $data = GetMember( 'borrowernumber' => $borrowernumber );
 126
 127 if ( not defined $data ) {
 128     $template->param (unknowuser => 1);
 129         output_html_with_http_headers $input, $cookie, $template->output;
 130     exit;
 131 }
 132
 133 my $category_type = $data->{'category_type'};
 134
 135 $debug and printf STDERR "dates (enrolled,expiry,birthdate) raw: (%s, %s, %s)\n", map {$data->{$_}} qw(dateenrolled dateexpiry dateofbirth);
 136 foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 137     my $userdate = $data->{$_};
 138     unless ($userdate) {
 139         $debug and warn sprintf "Empty \$data{%12s}", $_;
 140         $data->{$_} = '';
 141         next;
 142     }
 143     $template->param( $_ => dt_from_string( $userdate ) );
 144 }
 145 $data->{'IS_ADULT'} = ( $data->{'categorycode'} ne 'I' );
 146
 147 for (qw(gonenoaddress lost borrowernotes)) {
 148          $data->{$_} and $template->param(flagged => 1) and last;
 149 }
 150
 151 if ( IsDebarred($borrowernumber) ) {
 152     $template->param( 'userdebarred' => 1, 'flagged' => 1 );
 153     my $debar = $data->{'debarred'};
 154     if ( $debar ne "9999-12-31" ) {
 155         $template->param( 'userdebarreddate' => output_pref( { dt => dt_from_string( $debar ), dateonly => 1 } ) );
 156         $template->param( 'debarredcomment'  => $data->{debarredcomment} );
 157     }
 158 }
 159
 160 $data->{ "sex_".$data->{'sex'}."_p" } = 1 if defined $data->{sex};
 161
 162 if ( $category_type eq 'C') {
 163    my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 164    my $cnt = scalar(@$catcodes);
 165
 166    $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 167    $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 168 }
 169
 170 my $patron = Koha::Patrons->find($data->{borrowernumber});
 171 my @relatives;
 172 if ( my $guarantor = $patron->guarantor ) {
 173     $template->param( guarantor => $guarantor );
 174     push @relatives, $guarantor->borrowernumber;
 175     push @relatives, $_->borrowernumber for $patron->siblings;
 176 } elsif ( $patron->contactname || $patron->contactfirstname ) {
 177     $template->param(
 178         guarantor => {
 179             firstname => $patron->contactfirstname,
 180             surname   => $patron->contactname,
 181         }
 182     );
 183 } else {
 184     my @guarantees = $patron->guarantees;
 185     $template->param( guarantees => \@guarantees );
 186     push @relatives, $_->borrowernumber for @guarantees;
 187 }
 188
 189 my $relatives_issues_count =
 190   Koha::Database->new()->schema()->resultset('Issue')
 191   ->count( { borrowernumber => \@relatives } );
 192
 193 $template->param( adultborrower => 1 ) if ( $category_type eq 'A' || $category_type eq 'I' );
 194
 195 my %bor;
 196 $bor{'borrowernumber'} = $borrowernumber;
 197
 198 # Converts the branchcode to the branch name
 199 my $samebranch;
 200 if ( C4::Context->preference("IndependentBranches") ) {
 201     my $userenv = C4::Context->userenv;
 202     if ( C4::Context->IsSuperLibrarian() ) {
 203         $samebranch = 1;
 204     }
 205     else {
 206         $samebranch = ( $data->{'branchcode'} eq $userenv->{branch} );
 207     }
 208 }
 209 else {
 210     $samebranch = 1;
 211 }
 212 my $library = Koha::Libraries->find( $data->{branchcode})->unblessed;
 213 @{$data}{keys %$library} = values %$library; # merge in all branch columns
 214
 215 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 216 my $lib1 = &GetSortDetails( "Bsort1", $data->{'sort1'} );
 217 my $lib2 = &GetSortDetails( "Bsort2", $data->{'sort2'} );
 218 $template->param( lib1 => $lib1 ) if ($lib1);
 219 $template->param( lib2 => $lib2 ) if ($lib2);
 220
 221 # If printing a page, send the account informations to the template
 222 if ($print eq "page") {
 223     foreach my $accountline (@$accts) {
 224         $accountline->{amount} = sprintf '%.2f', $accountline->{amount};
 225         $accountline->{amountoutstanding} = sprintf '%.2f', $accountline->{amountoutstanding};
 226
 227         if ($accountline->{accounttype} ne 'F' && $accountline->{accounttype} ne 'FU'){
 228             $accountline->{printtitle} = 1;
 229         }
 230     }
 231     $template->param( accounts => $accts );
 232 }
 233
 234 # Show OPAC privacy preference is system preference is set
 235 if ( C4::Context->preference('OPACPrivacy') ) {
 236     $template->param( OPACPrivacy => 1);
 237     $template->param( "privacy".$data->{'privacy'} => 1);
 238 }
 239
 240 my $today       = DateTime->now( time_zone => C4::Context->tz);
 241 $today->truncate(to => 'day');
 242 my $overdues_exist = 0;
 243 my $totalprice = 0;
 244
 245 # Calculate and display patron's age
 246 my $dateofbirth = $data->{ 'dateofbirth' };
 247 my $age = GetAge($dateofbirth);
 248 $template->param( age => $age );
 249
 250 ### ###############################################################################
 251 # BUILD HTML
 252 # show all reserves of this borrower, and the position of the reservation ....
 253 if ($borrowernumber) {
 254     $template->param(
 255         holds_count => Koha::Database->new()->schema()->resultset('Reserve')
 256           ->count( { borrowernumber => $borrowernumber } ) );
 257 }
 258
 259 # current alert subscriptions
 260 my $alerts = getalert($borrowernumber);
 261 foreach (@$alerts) {
 262     $_->{ $_->{type} } = 1;
 263     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 264 }
 265
 266 # Add sync data to the user data
 267 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
 268     my $sync = NLGetSyncDataFromBorrowernumber( $borrowernumber );
 269     if ( $sync ) {
 270         $data->{'sync'}       = $sync->sync;
 271         $data->{'syncstatus'} = $sync->syncstatus;
 272         $data->{'lastsync'}   = $sync->lastsync;
 273     }
 274 }
 275
 276 # check to see if patron's image exists in the database
 277 # basically this gives us a template var to condition the display of
 278 # patronimage related interface on
 279 my $patron_image = Koha::Patron::Images->find($data->{borrowernumber});
 280 $template->param( picture => 1 ) if $patron_image;
 281 # Generate CSRF token for upload and delete image buttons
 282 $template->param(
 283     csrf_token => Koha::Token->new->generate_csrf({ session_id => $input->cookie('CGISESSID'),}),
 284 );
 285
 286 my $branch=C4::Context->userenv->{'branch'};
 287
 288 $template->param(%$data);
 289
 290 if (C4::Context->preference('ExtendedPatronAttributes')) {
 291     my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
 292     my @classes = uniq( map {$_->{class}} @$attributes );
 293     @classes = sort @classes;
 294
 295     my @attributes_loop;
 296     for my $class (@classes) {
 297         my @items;
 298         for my $attr (@$attributes) {
 299             push @items, $attr if $attr->{class} eq $class
 300         }
 301         my $lib = GetAuthorisedValueByCode( 'PA_CLASS', $class ) || $class;
 302         push @attributes_loop, {
 303             class => $class,
 304             items => \@items,
 305             lib   => $lib,
 306         };
 307     }
 308
 309     $template->param(
 310         ExtendedPatronAttributes => 1,
 311         attributes_loop => \@attributes_loop
 312     );
 313
 314     my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 315     if (scalar(@types) == 0) {
 316         $template->param(no_patron_attribute_types => 1);
 317     }
 318 }
 319
 320 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 321     C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 322     $template->param(messaging_form_inactive => 1);
 323     $template->param(SMSSendDriver => C4::Context->preference("SMSSendDriver"));
 324     $template->param(SMSnumber     => $data->{'smsalertnumber'});
 325     $template->param(TalkingTechItivaPhone => C4::Context->preference("TalkingTechItivaPhoneNotification"));
 326 }
 327
 328 # in template <TMPL_IF name="I"> => instutitional (A for Adult, C for children)
 329 $template->param( $data->{'categorycode'} => 1 );
 330 $template->param(
 331     detailview => 1,
 332     borrowernumber  => $borrowernumber,
 333     othernames      => $data->{'othernames'},
 334     categoryname    => $data->{'description'},
 335     was_renewed     => scalar $input->param('was_renewed') ? 1 : 0,
 336     branch          => $branch,
 337     todaysdate      => output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }),
 338     totalprice      => sprintf("%.2f", $totalprice),
 339     totaldue        => sprintf("%.2f", $total),
 340     totaldue_raw    => $total,
 341     overdues_exist  => $overdues_exist,
 342     StaffMember     => ($category_type eq 'S'),
 343     is_child        => ($category_type eq 'C'),
 344     samebranch      => $samebranch,
 345     quickslip       => $quickslip,
 346     privacy_guarantor_checkouts => $data->{'privacy_guarantor_checkouts'},
 347     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 348     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 349     RoutingSerials => C4::Context->preference('RoutingSerials'),
 350     debarments => GetDebarments({ borrowernumber => $borrowernumber }),
 351     PatronsPerPage => C4::Context->preference("PatronsPerPage") || 20,
 352     relatives_issues_count => $relatives_issues_count,
 353     relatives_borrowernumbers => \@relatives,
 354 );
 355
 356 output_html_with_http_headers $input, $cookie, $template->output;