svc/cover_images

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2013 Universidad Nacional de Cordoba
   6 #                Tomas Cohen Arazi
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24 use C4::Auth qw/check_cookie_auth/;
  25 use Koha::CoverImages;
  26 use JSON qw/to_json/;
  27
  28 my $input = CGI->new;
  29
  30 my ( $auth_status, $sessionID ) =
  31         check_cookie_auth(
  32             $input->cookie('CGISESSID'),
  33             { tools => 'upload_local_cover_images' } );
  34
  35 if ( $auth_status ne "ok" ) {
  36     exit 0;
  37 }
  38
  39 my $action       = $input->param('action');
  40 my @imagenumbers = $input->param('imagenumber');
  41
  42 # Array to store the reponse JSON
  43 my $response = [];
  44
  45 if ( $action eq "delete" ) {
  46
  47     foreach my $imagenumber ( @imagenumbers ) {
  48         eval {
  49             Koha::CoverImages->find($imagenumber)->delete;
  50         };
  51         if ( $@ ) {
  52             push @$response, {
  53                 imagenumber => $imagenumber,
  54                 deleted => 0,
  55                 error => "MSG_INVALID_IMAGENUMBER"
  56             };
  57         } else {
  58             push @$response, {
  59                 imagenumber => $imagenumber,
  60                 deleted => 1
  61             };
  62         }
  63     }
  64 } else {
  65     # invalid action
  66     exit 0;
  67 }
  68
  69 binmode STDOUT, ":encoding(UTF-8)";
  70 print $input->header(
  71     -type => 'application/json',
  72     -charset => 'UTF-8'
  73 );
  74
  75 print to_json( $response );