koha-tmpl/intranet-tmpl/prog/en/xslt/MARC21slimUtils.xsl

   1 <?xml version='1.0'?>
   2 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   3 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   4         <xsl:template name="datafield">
   5                 <xsl:param name="tag"/>
   6                 <xsl:param name="ind1"><xsl:text> </xsl:text></xsl:param>
   7                 <xsl:param name="ind2"><xsl:text> </xsl:text></xsl:param>
   8                 <xsl:param name="subfields"/>
   9                 <xsl:element name="datafield">
  10                         <xsl:attribute name="tag">
  11                                 <xsl:value-of select="$tag"/>
  12                         </xsl:attribute>
  13                         <xsl:attribute name="ind1">
  14                                 <xsl:value-of select="$ind1"/>
  15                         </xsl:attribute>
  16                         <xsl:attribute name="ind2">
  17                                 <xsl:value-of select="$ind2"/>
  18                         </xsl:attribute>
  19                         <xsl:copy-of select="$subfields"/>
  20                 </xsl:element>
  21         </xsl:template>
  22
  23         <xsl:template name="subfieldSelect">
  24                 <xsl:param name="codes"/>
  25                 <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
  26                 <xsl:param name="subdivCodes"/>
  27                 <xsl:param name="subdivDelimiter"/>
  28         <xsl:param name="prefix"/>
  29         <xsl:param name="suffix"/>
  30                 <xsl:variable name="str">
  31                         <xsl:for-each select="marc:subfield">
  32                                 <xsl:if test="contains($codes, @code)">
  33                     <xsl:if test="contains($subdivCodes, @code)">
  34                         <xsl:value-of select="$subdivDelimiter"/>
  35                     </xsl:if>
  36                                         <xsl:value-of select="$prefix"/><xsl:value-of select="text()"/><xsl:value-of select="$suffix"/><xsl:value-of select="$delimeter"/>
  37                                 </xsl:if>
  38                         </xsl:for-each>
  39                 </xsl:variable>
  40                 <xsl:value-of select="substring($str,1,string-length($str)-string-length($delimeter))"/>
  41         </xsl:template>
  42
  43         <xsl:template name="buildSpaces">
  44                 <xsl:param name="spaces"/>
  45                 <xsl:param name="char"><xsl:text> </xsl:text></xsl:param>
  46                 <xsl:if test="$spaces>0">
  47                         <xsl:value-of select="$char"/>
  48                         <xsl:call-template name="buildSpaces">
  49                                 <xsl:with-param name="spaces" select="$spaces - 1"/>
  50                                 <xsl:with-param name="char" select="$char"/>
  51                         </xsl:call-template>
  52                 </xsl:if>
  53         </xsl:template>
  54
  55         <xsl:template name="chopPunctuation">
  56                 <xsl:param name="chopString"/>
  57                 <xsl:variable name="length" select="string-length($chopString)"/>
  58                 <xsl:choose>
  59                         <xsl:when test="$length=0"/>
  60                         <xsl:when test="contains('.:,;/ ', substring($chopString,$length,1))">
  61                                 <xsl:call-template name="chopPunctuation">
  62                                         <xsl:with-param name="chopString" select="substring($chopString,1,$length - 1)"/>
  63                                 </xsl:call-template>
  64                         </xsl:when>
  65                         <xsl:when test="not($chopString)"/>
  66                         <xsl:otherwise><xsl:value-of select="$chopString"/></xsl:otherwise>
  67                 </xsl:choose>
  68 <xsl:text> </xsl:text>
  69         </xsl:template>
  70
  71         <!-- Function extractControlNumber is used to extract the control number (record number) from MARC tags 773/80/85 [etc.] subfield $w.
  72              Parameter: control number string.
  73              Assumes LOC convention: (OrgCode)recordNumber.
  74              If OrgCode is not present, return full string.
  75              Additionally, handle various brackets/parentheses. Chop leading and trailing spaces.
  76         -->
  77         <xsl:template name="extractControlNumber">
  78             <xsl:param name="subfieldW"/>
  79             <xsl:variable name="tranW" select="translate($subfieldW,']})&gt;','))))')"/>
  80             <xsl:choose>
  81               <xsl:when test="contains($tranW,')')">
  82                 <xsl:value-of select="normalize-space(translate(substring-after($tranW,')'),'[]{}()&lt;&gt;',''))"/>
  83               </xsl:when>
  84               <xsl:otherwise>
  85                 <xsl:value-of select="normalize-space($subfieldW)"/>
  86               </xsl:otherwise>
  87             </xsl:choose>
  88         </xsl:template>
  89
  90     <!-- Function m880Select:  Display Alternate Graphic Representation (MARC 880) for selected latin "base"tags
  91         - should be called immediately before the corresonding latin tags are processed
  92         - tags in right-to-left languages are displayed floating right
  93         * Parameter:
  94            + basetags: display these tags if found in linkage section ( subfield 6) of tag 880
  95            + codes: display these subfields codes
  96         * Options:
  97             - class: wrap output in <span class="$class">...</span>
  98             - label: prefix each(!) tag with label $label
  99             - bibno: link to biblionumber $bibno
 100             - index: build a search link using index $index with subfield $a as key; if subfield $9 is present use index 'an' with key $9 instead.
 101          * Limitations:
 102             - displays every field on a separate line (to switch between rtl and ltr)
 103          * Pitfalls:
 104            (!) output might be empty
 105     -->
 106     <xsl:template name="m880Select">
 107          <xsl:param name="basetags"/> <!-- e.g.  100,700,110,710 -->
 108         <xsl:param name="codes"/> <!-- e.g. abc  -->
 109         <xsl:param name="class"/> <!-- e.g. results_summary -->
 110         <xsl:param name="label"/> <!-- e.g.  Edition -->
 111         <xsl:param name="bibno"/>
 112         <xsl:param name="index"/> <!-- e.g.  au -->
 113         <xsl:param name="UseAuthoritiesForTracings"/>
 114
 115         <xsl:for-each select="marc:datafield[@tag=880]">
 116             <xsl:variable name="code6" select="marc:subfield[@code=6]"/>
 117             <xsl:if test="contains(string($basetags), substring($code6,1,3))">
 118                 <span>
 119                     <xsl:choose>
 120                     <xsl:when test="boolean($class) and substring($code6,string-length($code6)-1,2) ='/r'">
 121                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 122                         <xsl:attribute name="dir">rtl</xsl:attribute>
 123                     </xsl:when>
 124                      <xsl:when test="boolean($class)">
 125                         <xsl:attribute name="class"><xsl:value-of select="$class"/></xsl:attribute>
 126                         <xsl:attribute name="style">display:block; </xsl:attribute>
 127                     </xsl:when>
 128                      <xsl:when test="substring($code6,string-length($code6)-1,2) ='/r'">
 129                         <xsl:attribute name="class"><xsl:value-of select="$class"/> m880</xsl:attribute>
 130                     </xsl:when>
 131                     </xsl:choose>
 132                     <xsl:if test="boolean($label)">
 133                         <span class="label">
 134                             <xsl:value-of select="$label"/>
 135                         </span>
 136                     </xsl:if>
 137                     <xsl:variable name="str">
 138                         <xsl:for-each select="marc:subfield">
 139                             <xsl:if test="contains($codes, @code)">
 140                                 <xsl:value-of select="text()"/>
 141                                 <xsl:text> </xsl:text>
 142                             </xsl:if>
 143                         </xsl:for-each>
 144                     </xsl:variable>
 145                     <xsl:choose>
 146                         <xsl:when test="boolean($bibno)">
 147                             <a>
 148                                 <xsl:attribute name="href">/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of  select="$bibno"/></xsl:attribute>
 149                                 <xsl:value-of select="$str"/>
 150                             </a>
 151                         </xsl:when>
 152                        <xsl:when test="boolean($index) and boolean(marc:subfield[@code=9]) and $UseAuthoritiesForTracings='1'">
 153                             <a>
 154                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=an:<xsl:value-of  select="marc:subfield[@code=9]"/></xsl:attribute>
 155                                   <xsl:value-of select="$str"/>
 156                             </a>
 157                         </xsl:when>
 158                         <xsl:when test="boolean($index)">
 159                             <a>
 160                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of  select="$index"/>:<xsl:value-of  select="marc:subfield[@code='a']"/></xsl:attribute>
 161                                 <xsl:value-of select="$str"/>
 162                             </a>
 163                         </xsl:when>
 164                         <xsl:otherwise>
 165                             <xsl:value-of select="$str"/>
 166                         </xsl:otherwise>
 167                     </xsl:choose>
 168                 </span>
 169             </xsl:if>
 170         </xsl:for-each>
 171
 172     </xsl:template>
 173
 174 </xsl:stylesheet>
 175
 176 <!-- Stylus Studio meta-information - (c)1998-2002 eXcelon Corp.
 177 <metaInformation>
 178 <scenarios/><MapperInfo srcSchemaPath="" srcSchemaRoot="" srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/>
 179 </metaInformation>
 180 -->