opac/opac-browser.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20
  21 =head1 opac-browser.pl
  22
  23 TODO :: Description here
  24
  25 =cut
  26
  27 use strict;
  28 use warnings;
  29
  30 use C4::Auth;
  31 use C4::Context;
  32 use C4::Output;
  33 use CGI;
  34 use C4::Biblio;
  35 use C4::Koha;       # use getitemtypeinfo
  36
  37 my $query = new CGI;
  38
  39 my $dbh = C4::Context->dbh;
  40
  41 # open template
  42 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  43     {
  44         template_name   => "opac-browser.tt",
  45         query           => $query,
  46         type            => "opac",
  47         authnotrequired => ( C4::Context->preference("OpacPublic") ? 1 : 0 ),
  48         debug           => 1,
  49     }
  50 );
  51
  52 # the level of browser to display
  53 my $level = $query->param('level') || 0;
  54 my $filter = $query->param('filter');
  55 $filter = '' unless defined $filter;
  56 $level++; # the level passed is the level of the PREVIOUS list, not the current one. Thus the ++
  57
  58 # build this level loop
  59 my $sth = $dbh->prepare("SELECT * FROM browser WHERE level=? and classification like ? ORDER BY classification");
  60 $sth->execute($level,$filter."%");
  61 my @level_loop;
  62 my $i=0;
  63 while (my $line = $sth->fetchrow_hashref) {
  64     $line->{description} =~ s/\((.*)\)//g;
  65     push @level_loop,$line;
  66 }
  67
  68 my $have_hierarchy = 0;
  69
  70 # now rebuild hierarchy loop
  71 $filter =~ s/\.//g;
  72 my @hierarchy_loop;
  73 if ($filter eq '' and $level == 1) {
  74     # we're starting from the top
  75     $have_hierarchy = 1 if @level_loop;
  76     unless (@level_loop) {
  77         $sth->execute(1, "%");
  78         while (my $line = $sth->fetchrow_hashref) {
  79             $line->{description} =~ s/\((.*)\)//g;
  80             push @level_loop,$line;
  81         }
  82     }
  83 } else {
  84     $sth = $dbh->prepare("SELECT * FROM browser where classification=?");
  85     for (my $i=1;$i <=length($filter);$i++) {
  86         $sth->execute(substr($filter,0,$i));
  87         my $line = $sth->fetchrow_hashref;
  88         push @hierarchy_loop,$line;
  89     }
  90     $have_hierarchy = 1 if @hierarchy_loop;
  91 }
  92
  93 # mark every third entry in level_loop
  94 for (my $i = 0; $i <= $#level_loop; $i++) {
  95     $level_loop[$i]->{count3} = 1 if 2 == $i % 3 && $i != $#level_loop;
  96 }
  97
  98 $template->param(
  99     LEVEL_LOOP => \@level_loop,
 100     HIERARCHY_LOOP => \@hierarchy_loop,
 101     have_hierarchy => $have_hierarchy,
 102 );
 103
 104 output_html_with_http_headers $query, $cookie, $template->output;