tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI;
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Branch; # GetBranches
  50 use C4::Letters;
  51 use C4::Members::Attributes;
  52
  53 # $protected_letters = protected_letters()
  54 # - return a hashref of letter_codes representing letters that should never be deleted
  55 sub protected_letters {
  56     my $dbh = C4::Context->dbh;
  57     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  58     return { map { $_->[0] => 1 } @{$codes} };
  59 }
  60
  61 our $input       = new CGI;
  62 my $searchfield = $input->param('searchfield');
  63 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  64 our $branchcode  = $input->param('branchcode');
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode') || q||;
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         branchloop => _branchloop($branchcode),
 107         copying => 1,
 108         modify => 0,
 109     );
 110 }
 111 elsif ( $op eq 'add_form' ) {
 112     add_form($branchcode, $module, $code);
 113 }
 114 elsif ( $op eq 'delete_confirm' ) {
 115     delete_confirm($branchcode, $module, $code);
 116 }
 117 elsif ( $op eq 'delete_confirmed' ) {
 118     delete_confirmed($branchcode, $module, $code);
 119     $op = q{}; # next operation is to return to default screen
 120 }
 121 else {
 122     default_display($branchcode,$searchfield);
 123 }
 124
 125 # Do this last as delete_confirmed resets
 126 if ($op) {
 127     $template->param($op  => 1);
 128 } else {
 129     $template->param(no_op_set => 1);
 130 }
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;
 133
 134 sub add_form {
 135     my ( $branchcode,$module, $code ) = @_;
 136
 137     my $letters;
 138     # if code has been passed we can identify letter and its an update action
 139     if ($code) {
 140         $letters = C4::Letters::GetLetterTemplates(
 141             {
 142                 branchcode => $branchcode,
 143                 module     => $module,
 144                 code       => $code,
 145             }
 146         );
 147     }
 148
 149     my $message_transport_types = GetMessageTransportTypes();
 150     my @letter_loop;
 151     if ($letters) {
 152         $template->param(
 153             modify     => 1,
 154             code       => $code,
 155             branchcode => $branchcode,
 156         );
 157         my $first_flag = 1;
 158         # The letter name is contained into each mtt row.
 159         # So we can only sent the first one to the template.
 160         for my $mtt ( @$message_transport_types ) {
 161             # The letter_name
 162             if ( $first_flag and $letters->{$mtt}{name} ) {
 163                 $template->param(
 164                     letter_name=> $letters->{$mtt}{name},
 165                 );
 166                 $first_flag = 0;
 167             }
 168
 169             push @letter_loop, {
 170                 message_transport_type => $mtt,
 171                 is_html    => $letters->{$mtt}{is_html},
 172                 title      => $letters->{$mtt}{title},
 173                 content    => $letters->{$mtt}{content}//'',
 174             };
 175         }
 176     }
 177     else { # initialize the new fields
 178         for my $mtt ( @$message_transport_types ) {
 179             push @letter_loop, {
 180                 message_transport_type => $mtt,
 181             }
 182         }
 183         $template->param(
 184             branchcode => $branchcode,
 185             module     => $module,
 186         );
 187         $template->param( adding => 1 );
 188     }
 189
 190     $template->param(
 191         letters => \@letter_loop,
 192     );
 193
 194     my $field_selection;
 195     push @{$field_selection}, add_fields('branches');
 196     if ($module eq 'reserves') {
 197         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'items');
 198     }
 199     elsif ($module eq 'claimacquisition') {
 200         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'biblioitems');
 201     }
 202     elsif ($module eq 'claimissues') {
 203         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 204         push @{$field_selection},
 205         {
 206             value => q{},
 207             text => '---BIBLIO---'
 208         };
 209         foreach(qw(title author serial)) {
 210             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 211         }
 212     }
 213     elsif ($module eq 'suggestions') {
 214         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 215     }
 216     else {
 217         push @{$field_selection}, add_fields('biblio','biblioitems'),
 218             add_fields('items'),
 219             {value => 'items.content', text => 'items.content'},
 220             {value => 'items.fine',    text => 'items.fine'},
 221             add_fields('borrowers');
 222         if ($module eq 'circulation') {
 223             push @{$field_selection}, add_fields('opac_news');
 224
 225         }
 226
 227         if ( $module eq 'circulation' && $code eq "CHECKIN" ) {
 228             push @{$field_selection}, add_fields('old_issues');
 229         } else {
 230             push @{$field_selection}, add_fields('issues');
 231         }
 232     }
 233
 234     $template->param(
 235         module     => $module,
 236         branchloop => _branchloop($branchcode),
 237         SQLfieldname => $field_selection,
 238     );
 239     return;
 240 }
 241
 242 sub add_validate {
 243     my $dbh        = C4::Context->dbh;
 244     my $branchcode    = $input->param('branchcode') || '';
 245     my $module        = $input->param('module');
 246     my $oldmodule     = $input->param('oldmodule');
 247     my $code          = $input->param('code');
 248     my $name          = $input->param('name');
 249     my @mtt           = $input->param('message_transport_type');
 250     my @title         = $input->param('title');
 251     my @content       = $input->param('content');
 252     for my $mtt ( @mtt ) {
 253         my $is_html = $input->param("is_html_$mtt");
 254         my $title   = shift @title;
 255         my $content = shift @content;
 256         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt);
 257
 258         # getletter can return the default letter even if we pass a branchcode
 259         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 260         if ( $letter and $branchcode ne $letter->{branchcode} ) {
 261             $letter = undef;
 262         }
 263         unless ( $title and $content ) {
 264             # Delete this mtt if no title or content given
 265             delete_confirmed( $branchcode, $oldmodule, $code, $mtt );
 266             next;
 267         }
 268         elsif ( $letter and $letter->{message_transport_type} eq $mtt ) {
 269             $dbh->do(
 270                 q{
 271                     UPDATE letter
 272                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?
 273                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 274                 },
 275                 undef,
 276                 $branchcode, $module, $name, $is_html || 0, $title, $content,
 277                 $branchcode, $oldmodule, $code, $mtt
 278             );
 279         } else {
 280             $dbh->do(
 281                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type) VALUES (?,?,?,?,?,?,?,?)},
 282                 undef,
 283                 $branchcode, $module, $code, $name, $is_html || 0, $title, $content, $mtt
 284             );
 285         }
 286     }
 287     # set up default display
 288     default_display($branchcode);
 289     return 1;
 290 }
 291
 292 sub delete_confirm {
 293     my ($branchcode, $module, $code) = @_;
 294     my $dbh = C4::Context->dbh;
 295     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 296     my @values = values %$letter;
 297     $template->param(
 298         letter => $letter,
 299     );
 300     return;
 301 }
 302
 303 sub delete_confirmed {
 304     my ($branchcode, $module, $code, $mtt) = @_;
 305     C4::Letters::DelLetter(
 306         {
 307             branchcode => $branchcode,
 308             module     => $module,
 309             code       => $code,
 310             mtt        => $mtt
 311         }
 312     );
 313     # setup default display for screen
 314     default_display($branchcode);
 315     return;
 316 }
 317
 318 sub retrieve_letters {
 319     my ($branchcode, $searchstring) = @_;
 320
 321     $branchcode = $my_branch if $branchcode && $my_branch;
 322
 323     my $dbh = C4::Context->dbh;
 324     my ($sql, @where, @args);
 325     $sql = "SELECT branchcode, module, code, name, branchname
 326             FROM letter
 327             LEFT OUTER JOIN branches USING (branchcode)
 328     ";
 329     if ($searchstring && $searchstring=~m/(\S+)/) {
 330         $searchstring = $1 . q{%};
 331         push @where, 'code LIKE ?';
 332         push @args, $searchstring;
 333     }
 334     elsif ($branchcode) {
 335         push @where, 'branchcode = ?';
 336         push @args, $branchcode || '';
 337     }
 338     elsif ($my_branch) {
 339         push @where, "(branchcode = ? OR branchcode = '')";
 340         push @args, $my_branch;
 341     }
 342
 343     $sql .= " WHERE ".join(" AND ", @where) if @where;
 344     $sql .= " GROUP BY branchcode,module,code";
 345     $sql .= " ORDER BY module, code, branchcode";
 346
 347     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 348 }
 349
 350 sub default_display {
 351     my ($branchcode, $searchfield) = @_;
 352
 353     if ( $searchfield  ) {
 354         $template->param( search      => 1 );
 355     }
 356     my $results = retrieve_letters($branchcode,$searchfield);
 357
 358     my $loop_data = [];
 359     my $protected_letters = protected_letters();
 360     foreach my $row (@{$results}) {
 361         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 362         push @{$loop_data}, $row;
 363
 364     }
 365
 366     $template->param(
 367         letter => $loop_data,
 368         branchloop => _branchloop($branchcode),
 369     );
 370 }
 371
 372 sub _branchloop {
 373     my ($branchcode) = @_;
 374
 375     my $branches = GetBranches();
 376     my @branchloop;
 377     for my $thisbranch (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 378         push @branchloop, {
 379             value      => $thisbranch,
 380             selected   => $branchcode && $thisbranch eq $branchcode,
 381             branchname => $branches->{$thisbranch}->{'branchname'},
 382         };
 383     }
 384
 385     return \@branchloop;
 386 }
 387
 388 sub add_fields {
 389     my @tables = @_;
 390     my @fields = ();
 391
 392     for my $table (@tables) {
 393         push @fields, get_columns_for($table);
 394
 395     }
 396     return @fields;
 397 }
 398
 399 sub get_columns_for {
 400     my $table = shift;
 401 # FIXME untranslateable
 402     my %column_map = (
 403         aqbooksellers => '---BOOKSELLERS---',
 404         aqorders      => '---ORDERS---',
 405         serial        => '---SERIALS---',
 406         reserves      => '---HOLDS---',
 407         suggestions   => '---SUGGESTIONS---',
 408     );
 409     my @fields = ();
 410     if (exists $column_map{$table} ) {
 411         push @fields, {
 412             value => q{},
 413             text  => $column_map{$table} ,
 414         };
 415     }
 416     else {
 417         my $tlabel = '---' . uc $table;
 418         $tlabel.= '---';
 419         push @fields, {
 420             value => q{},
 421             text  => $tlabel,
 422         };
 423     }
 424
 425     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 426     my $table_prefix = $table . q|.|;
 427     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 428     for my $row (@{$rows}) {
 429         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 430         push @fields, {
 431             value => $table_prefix . $row->{Field},
 432             text  => $table_prefix . $row->{Field},
 433         }
 434     }
 435     if ($table eq 'borrowers') {
 436         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 437             foreach (@$attributes) {
 438                 push @fields, {
 439                     value => "borrower-attribute:$_",
 440                     text  => "attribute:$_",
 441                 }
 442             }
 443         }
 444     }
 445     return @fields;
 446 }