tools/viewlog.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2010 BibLibre
   4 # Copyright 2011 MJ Ray and software.coop
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use C4::Auth;
  24 use CGI qw ( -utf8 );
  25 use Text::CSV::Encoded;
  26 use C4::Context;
  27 use C4::Koha;
  28 use C4::Output;
  29 use C4::Log;
  30 use C4::Items;
  31 use C4::Serials;
  32 use C4::Debug;
  33 use C4::Search;    # enabled_staff_search_views
  34 use Koha::Patrons;
  35
  36 use vars qw($debug $cgi_debug);
  37
  38 =head1 viewlog.pl
  39
  40 plugin that shows stats
  41
  42 =cut
  43
  44 my $input = new CGI;
  45
  46 $debug or $debug = $cgi_debug;
  47 my $do_it    = $input->param('do_it');
  48 my @modules  = $input->multi_param("modules");
  49 my $user     = $input->param("user") // '';
  50 my @actions  = $input->multi_param("actions");
  51 my @interfaces  = $input->multi_param("interfaces");
  52 my $object   = $input->param("object");
  53 my $info     = $input->param("info");
  54 my $datefrom = $input->param("from");
  55 my $dateto   = $input->param("to");
  56 my $basename = $input->param("basename");
  57 my $output   = $input->param("output") || "screen";
  58 my $src      = $input->param("src") || ""; # this param allows us to be told where we were called from -fbcit
  59
  60 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  61     {
  62         template_name   => "tools/viewlog.tt",
  63         query           => $input,
  64         type            => "intranet",
  65         authnotrequired => 0,
  66         flagsrequired   => { tools => 'view_system_logs' },
  67         debug           => 1,
  68     }
  69 );
  70
  71 if ( $src eq 'circ' ) {
  72
  73     # if we were called from circulation, use the circulation menu and get data to populate it -fbcit
  74     use C4::Members::Attributes qw(GetBorrowerAttributes);
  75     my $borrowernumber = $object;
  76     my $patron = Koha::Patrons->find( $borrowernumber );
  77     my $circ_info = 1;
  78     unless ( $patron ) {
  79          $circ_info = 0;
  80     }
  81     if ( C4::Context->preference('ExtendedPatronAttributes') ) {
  82         my $attributes = GetBorrowerAttributes( $borrowernumber );
  83         $template->param(
  84             ExtendedPatronAttributes => 1,
  85             extendedattributes       => $attributes
  86         );
  87     }
  88
  89     $template->param(
  90         patron      => $patron,
  91         circulation => $circ_info,
  92     );
  93 }
  94
  95 $template->param(
  96     debug => $debug,
  97     C4::Search::enabled_staff_search_views,
  98     subscriptionsnumber => CountSubscriptionFromBiblionumber($input->param('object')),
  99     object => $object,
 100 );
 101
 102 if ($do_it) {
 103
 104     my @data;
 105     my ( $results, $modules, $actions, $interfaces );
 106     if ( defined $actions[0] && $actions[0] ne '' ) { $actions  = \@actions; }     # match All means no limit
 107     if ( $modules[0] ne '' ) { $modules = \@modules; }    # match All means no limit
 108     if ( defined $interfaces[0] && $interfaces[0] ne '' ) { $interfaces = \@interfaces; }    # match All means no limit
 109     $results = GetLogs( $datefrom, $dateto, $user, $modules, $actions, $object, $info, $interfaces );
 110     @data = @$results;
 111     foreach my $result (@data) {
 112
 113         # Init additional columns for CSV export
 114         $result->{'biblionumber'}      = q{};
 115         $result->{'biblioitemnumber'}  = q{};
 116         $result->{'barcode'}           = q{};
 117
 118         if ( substr( $result->{'info'}, 0, 4 ) eq 'item' || $result->{module} eq "CIRCULATION" ) {
 119
 120             # get item information so we can create a working link
 121             my $itemnumber = $result->{'object'};
 122             $itemnumber = $result->{'info'} if ( $result->{module} eq "CIRCULATION" );
 123             my $item = GetItem($itemnumber);
 124             if ($item) {
 125                 $result->{'biblionumber'}     = $item->{'biblionumber'};
 126                 $result->{'biblioitemnumber'} = $item->{'biblionumber'};
 127                 $result->{'barcode'}          = $item->{'barcode'};
 128             }
 129         }
 130
 131         #always add firstname and surname for librarian/user
 132         if ( $result->{'user'} ) {
 133             my $patron = Koha::Patrons->find( $result->{'user'} );
 134             if ($patron) {
 135                 $result->{librarian} = $patron;
 136             }
 137         }
 138
 139         #add firstname and surname for borrower, when using the CIRCULATION, MEMBERS, FINES
 140         if ( $result->{module} eq "CIRCULATION" || $result->{module} eq "MEMBERS" || $result->{module} eq "FINES" ) {
 141             if ( $result->{'object'} ) {
 142                 my $patron = Koha::Patrons->find( $result->{'object'} );
 143                 if ($patron) {
 144                     $result->{patron} = $patron;
 145                 }
 146             }
 147         }
 148     }
 149
 150     if ( $output eq "screen" ) {
 151
 152         # Printing results to screen
 153         $template->param(
 154             logview  => 1,
 155             total    => scalar @data,
 156             looprow  => \@data,
 157             do_it    => 1,
 158             datefrom => $datefrom,
 159             dateto   => $dateto,
 160             user     => $user,
 161             info     => $info,
 162             src      => $src,
 163             modules  => \@modules,
 164             actions  => \@actions,
 165             interfaces => \@interfaces
 166         );
 167
 168         # Used modules
 169         foreach my $module (@modules) {
 170             $template->param( $module => 1 );
 171         }
 172
 173         output_html_with_http_headers $input, $cookie, $template->output;
 174     }
 175     else {
 176
 177         # Printing to a csv file
 178         my $content = q{};
 179         my $delimiter = C4::Context->preference('delimiter') || ',';
 180         if (@data) {
 181             my $csv = Text::CSV::Encoded->new( { encoding_out => 'utf8', sep_char => $delimiter } );
 182             $csv or die "Text::CSV::Encoded->new FAILED: " . Text::CSV::Encoded->error_diag();
 183
 184             # First line with heading
 185             # Exporting bd id seems useless
 186             my @headings = grep { $_ ne 'action_id' } sort keys %{$data[0]};
 187             if ( $csv->combine(@headings) ) {
 188                 $content .= $csv->string() . "\n";
 189             }
 190
 191             # Lines of logs
 192             foreach my $line (@data) {
 193                 my @cells = map { $line->{$_} } @headings;
 194                 if ( $csv->combine(@cells) ) {
 195                     $content .= $csv->string() . "\n";
 196                 }
 197             }
 198         }
 199
 200         # Output
 201         print $input->header(
 202             -type       => 'text/csv',
 203             -attachment => $basename . '.csv',
 204         );
 205         print $content;
 206     }
 207     exit;
 208 }
 209 else {
 210     output_html_with_http_headers $input, $cookie, $template->output;
 211 }